glife/locations/city_island.qsrc

# city_island

$loc_arg = ''
$loc = 'city_island'
$location_type = 'public_outdoors'
$menu_loc = 'city_island'
$menu_arg = ''
menu_off = 0
CLOSE ALL
if sound = 0:
	if month >=11 and month <= 12 or month >=1 and month <=3:
		if hour >= 8 and hour <= 23: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/zima.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street_night.mp3',30 & PLAY 'sound/zima.mp3',30
	else
		if hour >= 8 and hour <= 23: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/street_leto.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street_night_leto.mp3' & PLAY 'sound/street_night.mp3',30
	end
end
clr
gs 'stat'
'<center><h2>St. Petersburg</h2></center>'
'<center><b>Vasilyevsky Island</b></center>'
if month >= 11 or month <= 3:
	if hour >= 8 and hour <= 21:
		'<center><img <<$set_imgh>> src="images/locations/city/island/islandw.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/island/islandwn.jpg"></center>'
	end
else
	if hour >= 8 and hour <= 21:
		'<center><img <<$set_imgh>> src="images/locations/city/island/island.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/island/islandn.jpg"></center>'
	end
end

'The University area of the city, the University, shops, clubs and the like that cater to the college kids dominate this area of the city. There is only three bridges onto and off the island, plus the metro line.'

!call random events from [street_events], and display them before show location.
gs'street_event','city_island' & if streetrand = -1:exit
if func('uniutil', 'student', 'enrolled'):act '<b>GO HOME</b> (University dorm)':gt 'dorm', 'start'

if car > 0 and cardrive = 25:'In the parking stands your <a href="exec:GS ''carF'', ''start''"><<$car>></a>.'


act 'Wait':gs 'obj_din', 'wait'

gs 'taxi'

if hour >= 8 and hour <= 22:
	'You can see the <a href="exec:$loc = ''city_island'' & minut += 1 & gt ''kiosk'', ''start''">kiosk</a> selling cigarettes and magazines.'
else
	'You can see a closed kiosk. It''s open between 08:00 - 23:00.'
end
if hour >= 8 and hour < 22:
	'You can see <a href="exec:gt ''shop_dolls'', ''start''">Patch Work Dolls</a> a clothing store that caters to Alternative styles, like gothic, punk, skater, and the like.'
else
	'You can see Patch Work Dolls a clothing store that caters to Alternative styles, like gothic, punk, skater, and the like. It''s open every day between 08:00 - 22:00'
end
if hour >= 4:
	'The <a href="exec:minut += 5 & gt ''metro'', ''start''">Metro</a> Station is within a 5 minute walk from here.'
else
	'The Metro Station is closed. The first train will depart at 04:00.'
end
if week < 6 and hour >= 7:
	'Dominating the island is the <a href="exec:gt ''univer'', ''start''">University</a> where you can earn your bachelors degree.'
else
	'The University is closed. It''s open during the week from 07:00.'
end
if func('uniutil', 'student', 'enrolled') or hour >= 6:'The <a href="exec:gt ''dorm'', ''start''">University dorms</a> offers small, but cheap, living space, for university students.'



--- city_island ---------------------------------