glife/locations/ykamin.qsrc

# ykamin

$loc_arg = ''
$loc = 'ykamin'
$menu_loc = 'ykamin'
$menu_arg = ''
menu_off = 0
*clr & cla
gs 'stat'

'<center><b><font color="maroon">Lounge</font></b></center>'
'<center>The lounge, where you can work on your tapestry and relax in front of the fireplace.</center>'

if ymanrem[8] = 0:'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/ynill.jpg"></center>'
if ymanrem[8] = 1:'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/yrem.jpg"></center>'
if ymanrem[8] = 2:'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/ykamin.jpg"></center>'
if ymanrem[8] = 2:'There''s a <a href="exec:gt ''stol'', ''start''">table</a> which you can sit at.'

act 'Leave the room':minut += 1 & gt 'ymans'

if gobelen>0:'You have completed <<gobelen>> tapestries.'
if pcs_sewng >= 40 and tkan > 0:'You have enough fabric for <<tkan>> more uses.'
if pcs_sewng >= 40 and tkan <= 0:'You do not have any fabric.'
if pcs_sewng >= 80:
	if newgobelen = 0 and tkan > 0:
		act'Start a new tapestry':
			cls
			tkan -= 1
			newgobelen = 1
			minut += 15
			gs'stat'
			'You spend 15 minutes on the embroidery frame, preparing the fabric and outlining the pattern for the tapestry.'
			act'Set the tapestry aside':gt $curloc
		end
	end
	if newgobelen >= 1:
		'Your tapestry is <<newgobelen/10>> percent finished.'
		act'Work on the tapestry for an hour':
			cls
			minut += 60
			sewng_exp += rand(pcs_intel/10, pcs_intel/5)
			gobramax = (pcs_sewng - 70) * 6
			gobramin = (pcs_sewng - 70) * 2
			newgobelen += rand(gobramin,gobramax)
			gs'stat'
			if newgobelen < 1000:'You spend an hour working on your tapestry, which is now <<newgobelen/10>> percent finished.'
				if newgobelen >= 1000:
				newgobelen = 0
				gobelen+=1
				'Your work on the tapestry is done. You feel pretty satisfied having finished a piece.'
			end
			act'Set the tapestry aside':gt $curloc
		end
	end
end

--- ykamin ---------------------------------