# city_marketwork
$location_type = 'event_outdoors'

! Variables used
! rinvesh = 	sold Items of clothing
! rinmon =		Total cash taken
! arturplan =	Amount Arthur expects min	
! arturnoo, arturyes = Times failed, reached sales
! workrin 		working in the market
! repa   ???????????
! pokupatel = 	customer interested
! prodpayum =	average price
! pokpay =		amount customer is willing to pay
! pcs_apprnc =	Attractiveness
! rinslut 		Arthur only keeps quiet if you do what he says
! palevorin =	0:Never had Sex w Arthur
! 				1:Had Sex w Arthur
!				2:Declined GB
!				3:Declined GB talked Arthur
!				4:Agreed GB
!				5:Agreed GB talked Arthur
!tetaKataQW		?
!annaQW 		?
!NadiaQW 		?
!

if $ARGS[0] = 'start':
	$loc_arg = 'start'
	$loc = 'city_marketwork'
	cla & *clr
	$menu_loc = 'city_marketwork'
	$menu_arg = 'start'
	menu_off = 0
	gs 'stat'
	'<center><b><font color="maroon">Marketplace</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/residential/market/rinok.jpg"></center>'
	'You stand at your clothes stall waiting for customers.'
	'You have sold <<rinvesh>> items and taken <<rinmon>> <b>₽</b> in cash.'
	'The average price on the market is <<prodpayum>>.'

	if hour = 14:
		'Arthur comes up to you and you start to calculate how much you should give him.'
		act 'Give money to Arthur':
			cla
			*clr
			rinart = rinvesh * 1000
			rinmon -= rinart
			money += rinmon
			gs 'stat'
			'You give Arthur <<rinart>> per sold <<rinvesh>> items.'
			'You have earned <<rinmon>> <b>₽</b> today.'

			rinmon = 0
			rinvesh = 0
			
			if rinart < arturplan:
				arturnoo += 1
				'This is bad, <<$pcs_nickname>>. You haven''t made enough money. You''ll completely ruin me!'
			else
				arturyes += 1
				'Well done <<$pcs_nickname>>, good job today.'
			end

			if arturnoo > arturyes:arturnoo = arturnoo - arturyes & arturyes = 0
			if arturyes > arturnoo:arturyes = arturyes - arturnoo & arturnoo = 0
			if arturnoo = arturyes:arturnoo = 0 & arturyes = 0

			if arturnoo > 10:
				arturnoo = 0
				work = 0
				workrin = 0
				'You''re fucking useless! Here''s your papers. I don''t want to see you again!'

				act 'Leave':gt 'city_residential'

				exit
			end

			rinrand = rand(1, 400)

			if rinrand < pcs_apprnc:
				if palevorin <= 1 or palevorin = 3:
					if palevorin = 0:
						'"Hey <<$pcs_nickname>>, you and I have not met properly. Come into the warehouse. We can have a drink and a bite to eat while we get acquainted."'
					elseif palevorin = 1:
						'"Hey <<$pcs_nickname>>, want to come to the warehouse again?"'
					else
						'"Hey <<$pcs_nickname>>. Come into the warehouse and have a drink with me." He walks right up to you and slaps you on the ass.'
					end

					act 'Refuse':
						cla
						'You start making excuses and Arthur frowns. "Hey, don''t insult me! Your stall is filthy, just look at all this dust and dirt! I should fine you, but if you''re nice, I''ll let you off.'

						act 'Go to the warehouse':gt 'city_marketsex', 'the_beginning'

						act 'No':
							cla
							arturplan += 1000

							if money >= 1000:
								money -= 1000
								'"Your stall is filthy! I''m fining you 1000 <b>₽</b>." You hand over the money and Arthur quickly snatches it.'
							else
								'Go with him before it gets worse.'
							end

							act 'Leave':gt 'city_residential'
						end
					end

					act 'Go with him':gt 'city_marketsex', 'the_beginning'
					
				elseif palevorin = 2:
					'Arthur walks into the stall behind you carrying some boxes. He places them down and walks up behind you, giving your ass a slap and squeeze. "I''m glad you turned Abdul and Hassan down. I like having you all to myself."'
					'You turn your head to look at him and smile. "I like that too, but maybe you can lock the door first from now on?"'
					'He laughs and nods. "Of course of course, anything for you my sweet. If you wish for the door to be locked, the door will be locked. Why don''t we go and make sure it works first..."'
					act 'Go with Arthur':palevorin = 3 & gt 'city_marketsex', 'the_beginning'
					
				elseif palevorin = 4:
					'Arthur walks into the stall behind you carrying some boxes. He places them down and walks up behind you, giving your ass a slap and squeeze with one hand while the other snakes around and roughly grabs your breast as he whispers in your ear. "So, you like cock? I didn''t think you were a little slut but that''s okay, I like dirty sluts."'
					'He cuts you off before you can protest. "No it''s good, I can use this. Now let''s go to the warehouse so I can fuck you."'
					
					act 'Go with him ':palevorin = 5 & gt 'city_marketsex', 'sex'
					
					gs 'willpower', 'sex', 'resist', 'hard'
					if will_cost <= pcs_willpwr:
						act 'Refuse (<<will_cost>> Willpower)':
							cla
							gs 'willpower', 'pay', 'resist'
							gs 'stat'
							'You shake your head and pull out of his grasp. "I''m not a slut and I''m sure as hell not going with you!"'
							'You see the anger flare up in his eyes. "So you think you''re too good for me whore? I gave you a job and treated you well. Then you fucked those two and now I''m not good enough?" He shakes his head. "Get your ass in the warehouse <i>now</i> or you''re fired and I''ll tell Abdul and Hassan they are free to tell everyone about how you greedily took their cocks like the little slut you are."'
							'You''re shocked at this level of anger and the ultimatum. You are unsure of what to do...'

							act 'Go to warehouse':palevorin = 5 & gt 'city_marketsex', 'sex'

							gs 'willpower', 'sex', 'resist', 'hard'
							if will_cost <= pcs_willpwr:
								act 'Get fired (<<will_cost>> Willpower)':
									cla
									gs 'pain', 5, 'cheeks', 'slap'
									gs 'willpower', 'pay', 'resist'
									gs 'stat'
									'You shake your head. "No, I won''t go with you."'
									'Before you notice him raising his hand, you feel the burning sensation on your cheek as he slaps you. "Then get out of here whore! You''re fired and I don''t want to see you back here!" He pushes you out from behind his stall, loud enough that many people are looking in your direction to what''s going on.'
									'You walk away in shame while rubbing your stinging cheek.'
									if rinslut = 0:rinslut = 1
									act 'Leave':gt 'city_residential'
								end
							else
								act 'Get fired (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
							end	
						end
					else
						act 'Refuse (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
					end	
					
				elseif palevorin = 5:
					sexgrouprand = rand(0,1)
					
					if sexgrouprand = 1:
						'Arthur walks up and slaps your ass hard before grabbing you roughly by the arm. "Hey bitch, how would you like to make some extra money? My friends need company."'
						
						act 'Go with him':gt 'city_marketsex', 'group'
					else
						'Arthur walks up and slaps your ass hard before grabbing you roughly by the arm. "Get your fucking ass in the warehouse, bitch."'
						
						act 'Go with him':gt 'city_marketsex', 'sex'
					end
					
					gs 'willpower', 'sex', 'resist', 'hard'
					if will_cost <= pcs_willpwr:
						act 'Refuse (<<will_cost>> Willpower)':
							cla
							gs 'willpower', 'pay', 'resist'
							gs 'stat'
							'You start making excuses and Arthur frowns. "Don''t insult me you little fucking slut! I was there. I know what a cock loving whore you are. Now get your fucking ass in the warehouse or the whole town will know about you!"'
							if sexgrouprand = 1:
								act 'Go to warehouse':gt 'city_marketsex', 'group'
							else
								act 'Go to warehouse':gt 'city_marketsex', 'sex'
							end
							
							gs 'willpower', 'sex', 'resist', 'hard'
							if will_cost <= pcs_willpwr:
								act 'No (<<will_cost>> Willpower)':
									cla
									arturnoo = 0
									work = 0
									workrin = 0
									gs 'willpower', 'pay', 'resist'
									gs 'stat'
									if rinslut = 0:rinslut = 1
									if repa < 6:repa = 6
									'"Then fuck you, you little fucking whore! You''re fired and by tomorrow the whole town will know what a cock loving whore you are!"'

									act 'Leave':gt 'city_residential'
								end
							else
								act 'No (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
							end	
						end
					else
						act 'Refuse (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
					end	
				else
					act 'Leave work':gt 'city_residential'
				end
			else
				act 'Leave work':gt 'city_residential'
			end	
		end
		exit
	elseif hour < 14:
		act 'Laze around (0:15)':
			minut += 15
			gt 'city_marketwork', 'start'
		end

		if money >= 200:
			act 'Buy a snack (200 <b>₽</b>) (0:15)':
				tetaKataQW += 1
				money -= 200
				gs 'kit_din'
				gs 'food', 'snack'
			end
		end
		
		rintakrand = rand(0, 5)
		talkrand = rand(0, 2)
		if hour = 9:
			if rintakrand = 0:
				$rintak = 'Hassan unloads clothes in front of Nadia''s stall.'

				act 'Watch Hassan and Nadia':
					cla
					minut += 15
					
					if talkrand = 0:'"You will sell more today, and to the rich ladies. I need the money, Nadia."'
					if talkrand = 1:'Hassan opens trunks and puts clothes on the counter.'
					if talkrand >= 2:'Hassan drags trunks to his stall.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 1:
				$rintak = 'Abdul is talking loudly and giving clothes to Anna at the next stall over.'

				act 'Watch Abdul and Anna':
					cla
					minut += 15

					if talkrand = 0:'"We''re fucked, you can''t sell anything!" Abdul shouts at Anna. "No wonder! You give me this rotten shit to sell! Nobody wants it!" she retorts.'
					if talkrand = 1:'Abdul slaps Anna''s ass, but she pretends that nothing happened.'
					if talkrand >= 2:'Abdul drags trunks to his stall.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 2:
				$rintak = 'Abdul and Hassan stand beside your stall speaking to each other in their native language.'

				act 'Watch them':
					cla
					minut += 15

					if talkrand = 0:'They continue to talk, but you don''t know the language and can''t understand what they''re saying.'
					if talkrand = 1:'They ignore you and discuss what sounds like clothes prices.'
					if talkrand >= 2:'Abdul looks at you. "Look at that girl. She looks like a good fuck." Hassan looks you over and nods in agreement.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 3:
				$rintak = 'Anna hangs clothes on her stall while shouting at Nadia.'

				act 'Chat with the girls':
					cla
					annaQW += 1
					NadiaQW += 1
					minut += 15

					if talkrand = 0:
						'Anna tells you that her skirt needed altering and that there is a great tailor''s shop nearby.'
					else
						'Nadia tells you how some pervert molested her on the subway by rubbing his dick on her ass.'
					end

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 4:
				$rintak = 'Arthur is talking about something with Abdul.'

				act 'Watch them':
					cla
					minut += 15

					if talkrand = 0:'They continue to talk, but you don''t know the language and can''t understand what they''re saying.'
					if talkrand = 1:'They ignore you and discuss what sounds like clothes prices.'
					if talkrand >= 2:'Abdul looks at you. "Nice looking girl you got there. You fucking her?"'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand >= 5:
				$rintak = 'Arthur, Abdul and Hassan are talking loudly to each other in their native language.'

				act 'View the Armenians':
					cla
					minut += 15

					if talkrand = 0:'They continue to talk, but you don''t know the language and can''t understand what they''re saying.'
					if talkrand = 1:'They ignore you and discuss what sounds like clothes prices.'
					if talkrand >= 2:'Abdul looks at you. "Pretty little girl you have there. Can I have her?"'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			end

			'<<$rintak>>'
		elseif hour = 10:
			if rintakrand = 0:
				$rintak = 'Hassan sits on a chair dejectedly chewing food and talking with his mouth full to his saleswoman Nadia.'

				act 'Watch':
					cla
					minut += 15
					'"Nadia, why do you refuse? Come and have some wine."'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 1:
				$rintak = 'Nadia sits in her stall doing crossword puzzles.'

				act 'Chat with Nadia':
					cla
					NadiaQW += 1
					minut += 15
					'Nadia sits her crossword down and willingly gossips with you.'
					
					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 2:
				$rintak = 'Customers are crowded around Nadia''s stall. She fusses around before them laying out her goods.'

				act 'Chat with Nadia':
					cla
					NadiaQW -= 1
					minut += 15
					'Nadia frowns at you. "Shoo, no distractions! I have customers."'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 3:
				$rintak = 'Anna is drinking coffee in her stall.'

				act 'Chat with Anna':
					cla
					annaQW += 1
					minut += 15
					'Anna is happy to chat with you about pretty much anything.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 4:
				$rintak = 'Anna is in her stall, trying to interest customers in her goods.'

				act 'Chat with Anna':
					cla
					annaQW -= 1
					minut += 15
					'Anna frowns at you. "Shoo, no distractions! I have customers."'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand >= 5:
				$rintak = 'Anna is gossiping with Aunt Katya.'

				act 'Chat with Anna and Aunt Katya':
					cla
					annaQW += 1
					tetaKataQW += 1
					minut += 15
					'Aunt Katya is talking about her pies and Anna complains that it''s because of her pies that her ass is twice as big as it was.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			end

			'<<$rintak>>'
		elseif hour = 11:
			if rintakrand = 0:
				$rintak = 'Nadia is approached by three Armenians who begin to molest her. She swears at them and tries to dodge their groping hands.'

				act 'Look at Nadia and Armenians':
					cla
					minut += 15
					'The Armenians seem to be trying to persuade Nadia to have sex with them.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 1:
				$rintak = 'Nadia is eating cake in her stall.'

				act 'Chat with Nadia':
					cla
					NadiaQW += 1
					minut += 15
					'Nadia finishes her cake and chats with you.'

					if clener = 0:
						clener = 1
						'Nadia tells you about an office building not too far away that is looking for a cleaner.'
					end

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 2:
				$rintak = 'Customers are crowded around Nadia''s stall. She fusses around before them laying out her goods.'

				act 'Chat with Nadia':
					cla
					NadiaQW -= 1
					minut += 15
					'Nadia frowns at you. "Shoo, no distractions! I have customers."'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 3:
				$rintak = 'Anna is reading a newspaper in her stall.'

				act 'Chat with Anna':
					cla
					annaQW += 1
					minut += 15
					'Anna is happy to chat with you about pretty much anything.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 4:
				$rintak = 'Anna is in her stall, trying to interest customers in her goods.'

				act 'Chat with Anna':
					cla
					annaQW -= 1
					minut += 15
					'Anya frowns at you. "Shoo, no distractions! I have customers."'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand >= 5:
				$rintak = 'Nadia is approached by three Armenians who begin to molest her. She swears at them and tries to dodge their groping hands.'

				act 'Look at Nadia and Armenians':
					cla
					minut += 15
					'The Armenians seem to be trying to persuade Nadia to have sex with them.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			end

			'<<$rintak>>'
		elseif hour = 12:
			if rintakrand = 0:
				$rintak = 'Hassan has bought chebureki and is eating it while sitting behind Nadia in the stall.'

				act 'Chat with Nadia':
					cla
					NadiaQW -= 1
					minut += 15
					'Nadia shies away from talking in front of Hassan.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 1:
				$rintak = 'Nadia is surrounded by customers.'

				act 'Chat with Nadia':
					cla
					NadiaQW -= 1
					minut += 15
					'Nadia frowns at you. "Shoo, no distractions! I have customers."'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 2:
				$rintak = 'Nadia is talking with Anna.'

				act 'Chat with the girls':
					cla
					annaQW += 1
					NadiaQW += 1
					minut += 15

					if talkrand = 0:
						'Anna tells you that her friend used to clean an office building not far from here and that they are looking for a new cleaner if you need to make some extra cash.'

						if clener = 0:clener = 1

					elseif talkrand = 1:
						'Nadia tells you how some pervert molested her on the subway by rubbing his dick on her ass.'
					end

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 3:
				$rintak = 'Anna is selling clothing to customers.'

				act 'Chat with Anna':
					cla
					annaQW -= 1
					minut += 15
					'Anna frowns at you. "Shoo, no distractions! I have customers."'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand = 4:
				$rintak = 'Anna is drinking coffee while sitting at her stall.'

				act 'Chat with Anna':
					cla
					annaQW += 1
					minut += 15
					'Anna happily chats with you about pretty much anything.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			elseif rintakrand >= 5:
				$rintak = 'A bored looking Nadia is idly sitting in her stall looking for something to do.'

				act 'Chat with Nadia':
					cla
					NadiaQW += 2
					minut += 15
					'Nadia is glad for the distraction and has fun chatting with you.'

					act 'Go back to work':gt 'city_marketwork', 'start'
				end
			end

			'<<$rintak>>'
		elseif hour = 13:
			if rintakrand = 0:
				$rintak = 'Hassan begins to slowly collect goods from Nadia.'
			elseif rintakrand = 1:
				$rintak = 'Anya sits and calculates her profit for the day.'
			elseif rintakrand = 2:
				$rintak = 'Nadia calculates her days profit.'
			elseif rintakrand = 3:
				$rintak = 'Abdul begins collecting goods from Anna.'
			elseif rintakrand = 4:
				$rintak = 'Arthur walks past your stall.'
			else
				$rintak = 'Aunt Katya stops trading pies and leaves.'
			end

			'<<$rintak>>'
		end	
		
		pokrand = rand(0, 1)

		if pokrand = 0:
			$pokup = 'You have no customers.'
			pokupatel = 0
			''
			'Aunt Katya pushes her trolley through the market carrying cakes and coffee.'
		else
			pokupatel = 1
			poktiprand = rand(0, 7)

			if poktiprand = 0:$pokup = 'A middle-aged man approaches your stall.' & $poktip = 'The man' & pokti = 1
			if poktiprand = 1:$pokup = 'A young man approaches your stall.' & $poktip = 'The guy' & pokti = 2
			if poktiprand = 2:$pokup = 'A teenage boy approaches your stall.' & $poktip = 'The boy' & pokti = 3
			if poktiprand = 3:$pokup = 'A woman approaches your stall.' & $poktip = 'The woman' & pokti = 1
			if poktiprand = 4:$pokup = 'A girl approaches your stall.' & $poktip = 'The girl' & pokti = 2
			if poktiprand = 5:$pokup = 'A teenage girl approaches your stall.' & $poktip = 'The teenager' & pokti = 3
			if poktiprand = 6:$pokup = 'An old man approaches your stall.' & $poktip = 'The old man' & pokti = 0
			if poktiprand = 7:$pokup = 'An old woman approaches your stall.' & $poktip = 'The old woman' & pokti = 0
		end

		'<b><<$pokup>></b>'

		if pokupatel = 1:
			act 'How can I help you?':
				cla
				minut += 15
				pokvnirand = rand(0, 2)

				if pokvnirand = 0:
					'<<$poktip>> examines your wares with little interest.'
				elseif pokvnirand = 1:
					'<<$poktip>> looks through your wares with interest.'
				elseif pokvnirand = 2:
					'<<$poktip>> picks up an item.'
				end

				act 'Now this is very fashionable':
					cla
					tipred = 3
					gs 'city_marketwork', 'answerrin'
				end

				act 'This item is very high quality and reliable':
					cla
					tipred = 1
					gs 'city_marketwork', 'answerrin'
				end

				act 'You''ll find this very reasonable':
					cla
					tipred = 0
					gs 'city_marketwork', 'answerrin'
				end

				act 'That is so you':
					cla
					tipred = 2
					gs 'city_marketwork', 'answerrin'
				end
			end
		end

	end
end

if $ARGS[0] = 'answerrin':
	if tipred = pokti:
		''
		if pokvnirand = 0:
			pokpay = rand(1000, 1200)
		elseif pokvnirand = 1:
			pokpay = rand(1100, 1300)
		elseif pokvnirand = 2:
			pokpay = rand(1300, 1500)
		end
		'<<$poktip>> asks you for a price.'
		gs 'city_marketwork', 'tellprice'
	else
		'<<$poktip>> puts the item back and leaves.'
		act 'Further':gt 'city_marketwork', 'start'
	end
end

if $ARGS[0] = 'tellprice':
	act 'Name the price':
		cla
		prodpay = input ("Enter the selling price")

		if prodpay < 1000:prodpay = prodpayum
		poknorand = rand(1, 100 + pcs_apprnc/4)
		'"<<prodpay>> <b>₽</b>." you tell them.'

		if prodpay <= pokpay:
			if poknorand >= 10:
				rinmon += prodpay
				rinvesh += 1
				'The customer takes the item and pays <<prodpay>> <b>₽</b>.'

				act 'Sell it':gt 'city_marketwork', 'start'
			else
				'The customer twirls the clothing in their hands. "<<prodpay>> <b>₽</b> is too expensive."'
				gs 'city_marketwork', 'haggling'
			end
		elseif prodpay > pokpay and prodpay <= pokpay + 100:
			if poknorand >= 10:
				'The customer twirls clothing in their hands. "<<prodpay>> <b>₽</b> is too expensive."'
				gs 'city_marketwork', 'haggling'
			else
				'They put the item back and leaves'

				act 'Return':gt 'city_marketwork', 'start'
			end
		elseif prodpay > pokpay + 100:
			'The customer puts the item back and leaves.'

			act 'Return':gt 'city_marketwork', 'start'
		end
	end
end

if $ARGS[0] = 'haggling':
	if prodpay >= 1100:
		act 'Reduce the price by 100 <b>₽</b>':
			cla
			'You have reduced the price by 100 <b>₽</b>.'
			poknorand = rand(1, 100 + pcs_apprnc/4)

			if poknorand >= 10:
				rinmon += prodpay - 100
				rinvesh += 1
				'The customer takes the item and pays <<prodpay - 100>> <b>₽</b>'
			else
				'The customer puts the item back and leaves.'
			end
			
			act 'Haggle':gt 'city_marketwork', 'start'
		end
	elseif prodpay >= 1050:
		act 'Reduce the price by 50 <b>₽</b>':
			cla
			'You have reduced the price by 50 <b>₽</b>.'
			poknorand = rand(1, 100 + pcs_apprnc/4)

			if poknorand >= 30:
				rinmon += prodpay - 50
				rinvesh += 1
				'The customer takes the item and pays <<prodpay - 50>> <b>₽</b>'
			else
				'The customer puts the item back and leaves.'
			end
			
			act 'Haggle':gt 'city_marketwork', 'start'
		end
	end
	act 'Take the item back':gt 'city_marketwork', 'start'
end


--- city_marketwork ---------------------------------

