glife/locations/gadforest

# gadforest

if $ARGS[0] = '1':
	!out skirt
	$location_type = 'secluded'
    $metka = $ARGS[0]
    $loc = $CURLOC
    gs 'gadukino_event', 'sound'
    cls
    gs'stat'
    !gs'time'
	
    if goforest < 20:goforest += rand(0,1)
    lost = 1
	!to determine the continuation of the way if he got lost
    lostrand = rand(1,30)
    !the chance to get lost
    foresteventrand = rand(1,20)
    new_boletus = 0
    new_bilberry = 0
    
    '<center><H4>Forest</H4></center>'
    if month >= 4 and month <= 10:
	    if hour >= 6 and hour < 22:
		    '<center><img src="images/qwest/gadukino/forest/gadforest1.jpg"></center>'
		    'The edge of the forest. There are a few mushrooms and you can often see mushroom pickers.'
	    else
		    '<center><img src="images/qwest/gadukino/forest/gadforest_night1.jpg"></center>'
		    'The edge of the forest. Night in the woods is scary and uncomfortable.'
	    end
    else
	    if hour >= 8 and hour < 18:
		    '<center><img src="images/qwest/gadukino/forest/gadforest_winter1.jpg"></center>'
		    'The edge of the forest. The forest in the winter is very beautiful.'
	    else
		    '<center><img src="images/qwest/gadukino/forest/gadforest_winter_night1.jpg"></center>'
		    'The edge of the forest. Night in the winter forest is very scary and uncomfortable.'
	    end
    end
    if forestpicnic = 1:'On the edge of the forest you see people. Apparently they are having a family <a href="exec:gt ''gadforest_event'',''picnic''">picnic</a>.'
    if mirainforest = 1:'Near you wandering in the forest is <a href="exec: gt ''Miroslava'' ">Mira</a>.'
    if clothesforest = 1:'On the ground lay your clothes.'
    if findvel = 2:'Near the tree is an old <a href="exec:gt ''bicycle'',''forest''">bike</a>.'
    if goforest < 10:'You dono''t know this forest very well, it''s better if you don''t wander too far.'
    
    if temper >= 20 and sunWeather = 1 and hour>=6 and hour<=20 and miratalkforest = 1:gt 'gadforest_event', 'nude_event'       
    if foresteventrand < 3 and month >= 6 and month <= 9 and mushroom_pickersday ! daystart:mushroom_pickers = 1 & gt'gadforest_event', 'mushroom_pickers1'
    if foresteventrand = 3 and month >= 5 and month <= 9 and temper >= 20 and sunWeather = 1 and week > 5 and forestpicnic = 0: forestpicnic = 1 & gt 'gadforest_event', 'picnic'    
    if foresteventrand = 4 and month >= 6 and month <= 9: gt 'gadforest_event', 'mushroom_pickers2'
    if foresteventrand = 5 and hour >= 8 and hour <= 15 and month >= 4 and month <= 10 and gadboyday ! daystart and week <= 5: gt 'gadforest_event', 'gopforest_mitka'
    if foresteventrand = 6 and hour >= 8 and hour <= 18 and month >= 4 and month <= 10 and gadboyday ! daystart and week <= 5: gt 'gadforest_event', 'gopforest_kolyamba'
    if foresteventrand = 7 and hour >= 8 and hour <= 18 and month >= 4 and month <= 10 and gadboyday ! daystart and week <= 5: gt 'gadforest_event', 'gopforest_vasyan'
    if foresteventrand = 8 and hour >= 8 and hour <= 15 and month >= 4 and month <= 10 and gadboyday ! daystart and week > 5: gt 'gadforest_event', 'gopforest_2boys'
    if foresteventrand = 9 and hour >= 8 and hour <= 15 and month >= 4 and month <= 10 and gadboyday ! daystart and week > 5: gt 'gadforest_event', 'gopforest_3boys' 
    
    if $clothingworntype ! 'nude' and clothforest = 0 and temper >= 20 and sunWeather = 1 and hour>=6 and hour<=20 and miratalkforest > 1 and mirainforest = 0:
	    act'Strip naked':
		    if forestpicnic = 0:
			    cla
			    *clr
			    !the clothing remains in the woods
			    clothesforest = 1
			    minut+=5
			    flag_tanga = tanga
			    tanga = 0
			    if CloSkirtShortness = 0:'<center><img src="images/qwest/gadukino/forest/nudeforest.jpg"></center>'
                if CloSkirtShortness > 0:'<center><img src="images/qwest/gadukino/forest/nudeforest1.'+rand(1,2)+'.jpg"></center>'				    
                gs 'clothing', 'strip'
				'You don''t hesitate and quickly get undressed, your clothes are left laying in a pile.'
				
			    act'Back':gt'gadforest','1'			
		    else
		        cla
			    *clr
		        '<center><img src="images/qwest/gadukino/Swamp/noundress.jpg"></center>'
			    'You see a number of people you are ashamed of.'
			    
			    act'Back':gt'gadforest','1'
		    end
	    end
    end
    if clothesforest = 1 and $clothingworntype = 'nude':
		act 'Dress':
			cla
			*clr
			clothesforest = 0
			swamp_clothes = 0
			minut += 5
			tanga = flag_tanga
			gs 'clothing', 'wear', $lastwornclothingtype, lastwornclothingnumber
			if CloSkirtShortness = 0:'<center><img src="images/qwest/gadukino/forest/nudeforest.jpg"></center>'
             if CloSkirtShortness > 0:'<center><img src="images/qwest/gadukino/forest/nudeforest1.'+rand(1,2)+'.jpg"></center>'
			'You change into your clothes.'	
			act 'Back': gt 'gadforest','1'
		end    
    end
    !if he had gone from the forest and put in another place    
    if clothesforest = 1 and $clothingworntype ! 'nude':
		act 'To pick up the abandoned clothing':
			cla
			*clr
			clothesforest = 0
			'You pick up your clothes.'
			act 'Back': gt 'gadforest','1'
		end    
    end
    if hour >= 6 and hour <= 20 and sunWeather = 1:
   	    act 'Walking in the woods':
   	        cla
   	        *clr
		    minut += 60
		    manna += mannamax/5
		    willpower += willpowermax/5
		    if $clothingworntype = 'nude':health += healthmax/5 & pcs_horny += 5
		    gs 'stat'
            
            if month >= 4 and month <= 10:
                if mirainforest = 0:
		            if ($clothingworntype ! 'nude' and $clothingworntype ! 'swimwear') and CloSkirtShortness = 0:'<center><img src="images/qwest/gadukino/forest/gulforest0.'+rand(1,2)+'.jpg"></center>'
	                if ($clothingworntype ! 'nude' and $clothingworntype ! 'swimwear') and tanga = 1 and CloSkirtShortness > 0:'<center><img src="images/qwest/gadukino/forest/gulforest1.'+rand(1,3)+'.jpg"></center>'			    
		            if ($clothingworntype ! 'nude' and $clothingworntype ! 'swimwear') and tanga = 0 and CloSkirtShortness > 0:'<center><img src="images/qwest/gadukino/forest/gulforest_tanga0.'+rand(1,2)+'.jpg"></center>'	
		            if $clothingworntype = 'nude':'<center><img src="images/qwest/gadukino/forest/gulforest_nude0.'+rand(1,4)+'.jpg"></center>'
		            'You are walking through the woods, enjoying the sounds of forest and the fresh air.'		            
		        else
		            if $clothingworntype ! 'nude':'<center><img src="images/qwest/gadukino/forest/miraforest'+rand(1,3)+'.jpg"></center>'
		            if $clothingworntype = 'nude':'<center><img src="images/qwest/gadukino/forest/miraforest_nude'+rand(1,3)+'.jpg"></center>'
		            'You walk with Mira through the woods, enjoying the sounds of the forest and the fresh air.'
                end        
		    else
		        if mirainforest = 0:
                    '<center><img src="images/qwest/gadukino/forest/gulforestwinter0.'+rand(1,2)+'.jpg"></center>' 
                    'You walk through the winter woods, enjoying the sounds of the forest and the fresh air.'
                else 
                    '<center><img src="images/qwest/gadukino/forest/miraforestwinter.jpg"></center>' 
                    'You walk with Mira through the winter woods, enjoying the sounds of the forest and the fresh air.'
                end
            end
    		
		    act 'Further':gt 'gadforest','1'    
	    end
    end
    if hour >= 6 and hour <= 20 and month >= 6 and month <= 9 and boletus + bilberry < 10 and edge_forestday ! daystart:
   	    act 'To look for mushrooms and berries':
   	        cla
            *clr
		    minut += 30
		    temp = RAND(1,2)
		    edge_forestday = daystart
		    if goforest < 20:goforest += rand(0,1)
		    gs 'stat'
		
		    if mushroom_pickers = 0 or mushroom_pickers = 2:
		        cla
		        new_boletus += rand(0,1)
		        new_bilberry += 1
		        boletus += new_boletus
		        bilberry += new_bilberry
		        manna += mannamax/20
		        gs 'stat'
		        
		        gs 'gadforest', 'clothes1'
		        if new_boletus = 0 and new_bilberry > 0:'You`re in for hours of wandering through the woods in search of mushrooms or berries and you found <<new_bilberry>> kg of berries.'
		        if new_boletus > 0 and new_bilberry > 0:'You`re in for hours of wandering through the woods in search of mushrooms or berries and you found <<new_boletus>> kg mushrooms and <<new_bilberry>> kg of berries.'
		    end    
			if  mushroom_pickers = 1 and temp = 1:  
                cla
		        new_bilberry += rand(0,1)
		        bilberry += new_bilberry
		        gs 'stat'
		        
		        if new_bilberry > 0: gs 'gadforest', 'clothes1'
		        if new_bilberry = 0: gs 'gadforest', 'clothes2'
		        if new_bilberry > 0:'Within half an hour of wandering through the woods in search of mushrooms or berries, you found <<new_bilberry>> kg of berries.'
		        if new_bilberry = 0:'You are wandering through the woods in search of mushrooms or berries for half an hour, but you found nothing.'
            end
            if  mushroom_pickers = 1 and temp = 2:
		        cla
		        manna -= mannamax/20
		        gs 'stat'
		        
		        gs 'gadforest', 'clothes2'
		        'You are wandering through the woods in search of mushrooms or berries for half an hour, but found nothing.'
			end  			        		    
		    act 'Further':gt 'gadforest','1'		    
		end 
 	end		        		    
    if hour >= 6 and hour <= 20 and month >= 6 and month <= 9 and mirainforest = 0:    
        act 'To go further into the forest':    
		    if goforest >= lostrand:minut += 30 & gt 'gadforest','2' 
		    if goforest < lostrand:gt 'gadforest', 'gadforestloststart'
     	end	    
    end
    if goswamp = 1 and mirainforest = 0:
        if hour >= 6 and hour < 20:
            act 'Go to the swamp':
				minut += 75
				!random chance to swamp road. It a pity to use it only in lost. ps. use bike to 100% there by illume
				if goforest >= lostrand:
					gt 'swamp'
				else
					gt 'gadforestswamp','1' 
				end
			end
        else
            act 'Go to the swamp':gt 'gadforest_event', 'swamp_road'
        end    
    end    
    act 'Out of the woods':
		if $clothingworntype = 'nude':
			if clothesforest = 0:
				!no cloth here, it must be broken. There may be a good exhibi or rape event entry point.
				'You sneak out the woods, hiding your naked body in shadow and moving toward grandparents house.'
				'You Successfully reach home without witness.'
				cla
				act 'Further':gt'Gadhouse'
			else
				'<B>You should dress before leave</B>'
			end
		else
			minut += 30 & gt'gadroad'
		end
	end
	if rand(1,10)> 9: gs 'gadforest', 'torncloth'
end
if $ARGS[0] = '2':
	$location_type = 'secluded'
	!inside
    $metka = $ARGS[0]
    $loc = $CURLOC
    gs 'gadukino_event', 'sound'
    cls
    gs'stat'
    !gs'time'
    if goforest < 40:goforest += rand(0,1)
	lost = 2
	!to determine the continuation of the path YY lost
    lostrand = rand(1,60)
    !the chance to get lost
    foresteventrand = rand(1,10)
    new_boletus = 0
    new_bilberry = 0     
    '<center><H4>Forest</H4></center>'
    if month >= 4 and month <= 10:
	    if hour >= 6 and hour < 22:
		    '<center><img src="images/qwest/gadukino/forest/gadforest2.jpg"></center>'
		    'Forest. The intoxicating fresh air and singing birds light up your soul with joy.'
	    else
		    '<center><img src="images/qwest/gadukino/forest/gadforest_night2.jpg"></center>'
		    'Forest. Night in the woods is scary and uncomfortable.'
	    end
    else
	    if hour >= 8 and hour < 18:
	        '<center><img src="images/qwest/gadukino/forest/gadforest_winter2.jpg"></center>'
	        'Forest. The forest in the winter is very beautiful, the fresh air makes you happy.'
	    else
		    '<center><img src="images/qwest/gadukino/forest/gadforest_winter_night2.jpg"></center>'
		    'Forest. Night in the winter forest is very scary and uncomfortable.'
	    end
    end
    if goforest < 20:'You do not know this part of the forest, it''s better not to wander too far.'
    
    if foresteventrand = 1 and month >= 6 and month <= 9 and mushroom_pickersday ! daystart:mushroom_pickers = 2 & gt 'gadforest_event', 'mushroom_pickers1'
    if foresteventrand = 2 and hour > 8 and hour < 20 and foresteventday ! daystart:gt 'gadforest_event', 'forest_hanters'   
    if foresteventrand > 7 and month >= 6 and month <= 9 and foresteventday ! daystart:mushroom_pickers = 2 &  gt 'gadforest_event', 'mushroom_pickers3'
    
    
	act 'Back':
	    lostrand = rand(1,30)
		if goforest >= lostrand:minut += 30 & gt 'gadforest','1' 
		if goforest < lostrand:gt 'gadforest', 'gadforestloststart'    
    end
    if hour >= 6 and hour <= 20 and month >= 6 and month <= 9 and boletus + bilberry < 10 and forestday ! daystart:
   	    act 'To look for mushrooms and berries':
   	        cla
            *clr
		    minut += 30
		    temp = RAND(1,2)
		    forestday = daystart
		    if goforest < 40:goforest += rand(0,1)
		    gs 'stat'
		
		    if mushroom_pickers < 2:
		        cla
		        new_boletus += 1
		        new_bilberry += rand(1,2)
		        boletus += new_boletus
		        bilberry += new_bilberry
		        manna += mannamax/20
		        gs 'stat'
		        
		        gs 'gadforest', 'clothes1'
		        'Within half an hour of wandering through the woods in search of mushrooms or berries, you found <<new_boletus>> kg mushrooms and <<new_bilberry>> kg of berries.'
		    end    
			if  mushroom_pickers = 2 and temp = 1:  
                cla
		        new_boletus += rand(0,1)
		        new_bilberry += 1
		        boletus += new_boletus
		        bilberry += new_bilberry		        
		        gs 'stat'
		        
		        if new_boletus > 0 or new_bilberry > 0: gs 'gadforest', 'clothes1'
		        if new_boletus = 0 and new_bilberry > 0:'Within half an hour of wandering through the woods in search of mushrooms or berries, you found <<new_bilberry>> kg of berries.'
		        if new_boletus > 0 and new_bilberry > 0:'Within half an hour of wandering through the woods in search of mushrooms or berries, you found <<new_boletus>> kg mushrooms and <<new_bilberry>> kg of berries.'    
            end
            if  mushroom_pickers = 2 and temp = 2:
		        cla
		        manna -= mannamax/20
		        gs 'stat'
		        
		        gs 'gadforest', 'clothes2'
		        'You are wandering through the woods in search of mushrooms or berries for half an hour, but found nothing.'
			end   			        		    
		    act 'Further':gt 'gadforest','2'		    
		end
	end	
    if hour >= 6 and hour <= 20 and month >= 6 and month <= 9:    
        act 'To go further into the forest':    
		    if goforest >= lostrand:minut += 30 & gt 'gadforest','3' 
		    if goforest < lostrand:gt 'gadforest', 'gadforestloststart'
     	end	    
    end   
	if rand(1,10)> 8: gs 'gadforest', 'torncloth'
end

if $ARGS[0] = '3':
	!deep forest
	$location_type = 'secluded'
    $metka = $ARGS[0]
    $loc = $CURLOC
    gs 'gadukino_event', 'sound'
    cls
    gs'stat'
    !gs'time'
    if goforest < 60:goforest += rand(0,1)
	lost = 3	
    !to determine the continuation of the path YY lost
    lostrand = rand(1,100)
    !the chance to get lost
    foresteventrand = rand(1,10)
    new_boletus = 0
    new_bilberry = 0     
    '<center><H4>Thicket</H4></center>'
    if month >= 4 and month <= 10:
	    if hour >= 6 and hour < 22:
		    '<center><img src="images/qwest/gadukino/forest/gadforest3.jpg"></center>'
		    'Forest. The intoxicating fresh air and singing birds light up your soul with joy.'
	    else
		    '<center><img src="images/qwest/gadukino/forest/gadforest_night3.jpg"></center>'	
		    'Forest. Night in the woods is scary and uncomfortable.'
	    end
    else
	    if hour >= 8 and hour < 18:
		    '<center><img src="images/qwest/gadukino/forest/gadforest_winter3.jpg"></center>'
		    'Forest. The forest in the winter is very beautiful, the fresh air makes you happy.'
	    else
		    '<center><img src="images/qwest/gadukino/forest/gadforest_winter_night3.jpg"></center>'
		    'Forest. Night in the winter forest is very scary and uncomfortable.'
	    end
    end
    if goforest < 30:'You do not know this part of the forest, it''s better not to wander too far.'
    
    if foresteventrand = 1 and month >= 6 and month <= 9 and foresteventday ! daystart: gt 'gadforest_event', 'basket'
    if foresteventrand = 2 and month >= 6 and month <= 9 and foresteventday ! daystart: gt 'gadforest_event', 'bilberry' 
    if foresteventrand = 3 and foresteventday ! daystart: gt 'gadforest_event', 'mushroom'
    if foresteventrand = 4 and hour > 8 and hour < 20 and foresteventday ! daystart:gt 'gadforest_event', 'forest_hanters'    
    
	act 'Back':
	    lostrand = rand(1,60)
		if goforest >= lostrand:minut += 30 & gt 'gadforest','2' 
		if goforest < lostrand:gt 'gadforest', 'gadforestloststart'    
    end
    if hour >= 6 and hour <= 20 and month >= 6 and month <= 9 and boletus + bilberry < 10 and thicketday ! daystart:
   	    act 'To look for mushrooms and berries':
   	        cla
            *clr
		    minut += 30
		    thicketday = daystart
		    if goforest < 60:goforest += rand(0,1)
		    new_boletus += rand(1,2)
		    new_bilberry += rand(1,2)
		    boletus += new_boletus
		    bilberry += new_bilberry
		    manna += mannamax/20
		    gs 'stat'	
		    
		    gs 'gadforest', 'clothes1'
		    'Within half an hour of wandering through the woods in search of mushrooms or berries, you found <<new_boletus>> kg mushrooms and <<new_bilberry>> kg of berries.'    
    
		    act 'Further':gt 'gadforest','3'		    
        end
    end    
    if hour >= 6 and hour <= 20 and month >= 6 and month <= 9:    
        act 'To go further into the forest':    
		    if goforest >= lostrand:minut += 30 & gt 'gadforest','4' 
		    if goforest < lostrand:gt 'gadforest', 'gadforestloststart'
     	end	    
    end    	 		  
	if rand(1,10)> 6: gs 'gadforest', 'torncloth'
end

if $ARGS[0] = '4':
	!near swamp
	$location_type = 'secluded'
    $metka = $ARGS[0]
    $loc = $CURLOC
    gs 'gadukino_event', 'sound'
    cls
    gs'stat'
    !gs'time'
    if goforest < 80:goforest += rand(0,1)
	lost = 4	
    !to determine the continuation of the path YY lost
    lostrand = rand(1,120)
    !the chance to get lost
    foresteventrand = rand(1,10)
    dirty = 0
    new_boletus = 0
    new_bilberry = 0     
    '<center><H4>Woods near swamps</H4></center>'
    if month >= 4 and month <= 10:
	    if hour >= 6 and hour < 22:
		    '<center><img src="images/qwest/gadukino/forest/gadforest4.jpg"></center>'
		    'Forest. The intoxicating fresh air and singing birds light up your soul with joy.'
	    else
		    '<center><img src="images/qwest/gadukino/forest/gadforest_night4.jpg"></center>'	
		    'Forest. Night in the woods is scary and uncomfortable.'
	    end
    else
	    if hour >= 8 and hour < 18:
		    '<center><img src="images/qwest/gadukino/forest/gadforest_winter4.jpg"></center>'
		    'Forest. The forest in the winter is very beautiful, the fresh air makes you happy.'
	    else
		    '<center><img src="images/qwest/gadukino/forest/gadforest_winter_night4.jpg"></center>'
		    'Forest. Night in the winter forest is very scary and uncomfortable.'
	    end
    end
    if goforest < 60:'You do not know this part of the forest, then it is better not to go too far.'
    
    if foresteventrand < 2 and month >= 6 and month <= 9 and foresteventday ! daystart: gt 'gadforest_event', 'bilberry' 
    if foresteventrand > 7 and month >= 6 and month <= 9 and foresteventday ! daystart: gt 'gadforest_event', 'mushroom'
    if foresteventrand = 5 and hour > 8 and hour < 20 and foresteventday ! daystart:gt 'gadforest_event', 'forest_hanters'    
    
	act 'Back':
	    lostrand = rand(1,100)
		if goforest >= lostrand:minut += 30 & gt 'gadforest','3' 
		if goforest < lostrand:gt 'gadforest', 'gadforestloststart'    
    end
    if hour >= 6 and hour <= 20 and month >= 6 and month <= 9 and boletus + bilberry < 10 and swampforest ! daystart:
   	    act 'To look for mushrooms and berries':
   	        cla
            *clr
		    minut += 30
		    swampforest = daystart
		    if goforest < 80:goforest += rand(0,1)
		    new_boletus += rand(1,2)
		    new_bilberry += rand(2,3)
		    boletus += new_boletus
		    bilberry += new_bilberry
		    manna += mannamax/20
		    gs 'stat'	
		    
		    gs 'gadforest', 'clothes1'
		    'Within half an hour of wandering through the woods in search of mushrooms or berries, you found <<new_boletus>> kg mushrooms and <<new_bilberry>> kg of berries.'    
    
		    act 'Further':gt 'gadforest','4'		    
        end    	 		           
	end
    act 'To go further into the forest':    
		if goforest >= lostrand  and goswamp = 1:minut += 30 & gt 'swamp'
		if goforest >= lostrand  and goswamp = 0:minut += 30 & gt 'gadforestswamp','1' 
		if goforest < lostrand:gt 'gadforest', 'gadforestloststart'     		    
    end    
	if rand(1,10)> 7: gs 'gadforest', 'torncloth'
end             

!dynamics to ARGS by illume
if $ARGS[0] = 'clothes1':
    if mirainforest = 0:	
        if $clothingworntype ! 'nude' and CloSkirtShortness = 0:'<center><img src="images/qwest/gadukino/forest/mushroom1.jpg"></center>'
	    if $clothingworntype ! 'nude' and tanga = 1 and CloSkirtShortness > 0:'<center><img src="images/qwest/gadukino/forest/mushroom2.jpg"></center>'
	    if $clothingworntype ! 'nude' and tanga = 0 and CloSkirtShortness > 0:'<center><img src="images/qwest/gadukino/forest/mushroom3.jpg"></center>'
	    if $clothingworntype = 'nude':'<center><img src="images/qwest/gadukino/forest/mushroom4.'+rand(1,3)+'.jpg"></center>'
	    
	else
        if $clothingworntype ! 'nude':'<center><img src="images/qwest/gadukino/forest/miramushroom'+rand(1,2)+'.jpg"></center>'
	    if $clothingworntype = 'nude':'<center><img src="images/qwest/gadukino/forest/miramushroom_nude'+rand(1,2)+'.jpg"></center>'
    end    
end

if $ARGS[0] = 'clothes2':
    if mirainforest = 0:	
        if $clothingworntype ! 'nude' and CloSkirtShortness = 0:'<center><img src="images/qwest/gadukino/forest/gulforest2.jpg"></center>'
	    if $clothingworntype ! 'nude' and tanga = 1 and CloSkirtShortness > 0:'<center><img src="images/qwest/gadukino/forest/gulforest3.jpg"></center>'
	    if $clothingworntype ! 'nude' and tanga = 0 and CloSkirtShortness > 0:'<center><img src="images/qwest/gadukino/forest/gulforest_tanga1.'+rand(1,2)+'.jpg"></center>'
	    if $clothingworntype = 'nude':'<center><img src="images/qwest/gadukino/forest/gulforest_nude1.'+rand(1,4)+'.jpg"></center>'
	else
        if $clothingworntype ! 'nude':'<center><img src="images/qwest/gadukino/forest/miramushroom3.jpg"></center>'
	    if $clothingworntype = 'nude':'<center><img src="images/qwest/gadukino/forest/miramushroom_nude3.jpg"></center>'
    end    
end

if $ARGS[0] = 'gadforestloststart':
	cla
	*clr
	!gs'time'
	gs 'stat'
	
    '<center><H4>Somewhere in the woods</H4></center>'
    if month >= 5 and month <= 9:
        if $clothingworntype ! 'nude':'<center><img src="images/qwest/gadukino/forest/gadfear1.jpg"></center>'
        if $clothingworntype = 'nude':'<center><img src="images/qwest/gadukino/forest/gadfear2.jpg"></center>'
    else    
        '<center><img src="images/qwest/gadukino/forest/gadfear3.jpg"></center>'
    end    
    'You suddenly realize in horror that you are not familiar with the area you are in... you get lost.'
	
    act 'Further':
        if lost = 1: gt 'gadforestlost','1'
        if lost = 2: gt 'gadforestlost','2'
        if lost = 3: gt 'gadforestlost','3'
        if lost = 4: gt 'gadforestlost','4'
    end     
	
	!add for realistic, rescue in forest! by illume
	forest_lost = 1	
	if StoryLine = 1: forest_lostday = daystart + rand(1,3)
end

if $ARGS[0] = 'torncloth':
    !the withdrawal strength of the garment, if not jeans.  moved from gadforest 1 into args, and call in all forest by illume
	if $clothingworntype ! 'nude':
		if (PCloThinness = 1 or PCloSkirt > 0) and PCloQuality < 5:
			!skirts, not fit, and not high-class enough by illume
			'Oops, your cloth is spiked'
			dynamic $clothingworntype + 'H[<<clothingwornnumber>>] -= 1'
			!add remove cloth if worn out, need better texting by illume.
			if dyneval('RESULT = <<$clothingworntype>>H[<<clothingwornnumber>>]') <= 0:
				'Your clothes are torn to pieces, you are naked now.'
				gs 'clothing', 'strip'
			end
		end
	end
end

--- gadforest ---------------------------------