glife/locations/kuhrPar.qsrc

# kuhrPar
CLOSE ALL
*clr & cla
if fullmorrout = 1:
	minut += 2
	act '<font color = maroon><b>Leave the apartment and go outside</b></font>':
		minut +=1
		killvar 'fullmorrout'
		gs 'korrPar'
		gt'pav_residential'		
	end
end

act 'Return to the hallway':
	killvar 'fullmorrout'
	gt 'korrPar'	
end

$loc = 'kuhrPar'
$loc_arg = ''
$locclass = 'kitr'
$menu_loc = 'kuhrPar'
$menu_arg = ''
menu_off = 0
minut += 1
gs 'stat'
gs 'kit_din'
gs 'themes', 'indoors'
gs 'family_schedule'
'<center><b><font color="maroon">Kitchen</font></b></center>'
'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/kuhrpar.jpg"></center>'

if momloc = 4:
	if momloc[1] = 1:
		'You <<$npc_nickname[''A29'']>> is here, busy making breakfast.'
	elseif momloc[1] = 2:
		npc_rel['A29'] += 1
		cla & *clr
		minut += 5
		gs'stat'
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/mom/gotovka.jpg"></center>'
		'Your <<$npc_nickname[''A29'']>> turns to you. "<<$pcs_nickname>>, please set the table for breakfast." You sigh and grab the dishes.'
		act 'Set the table for breakfast': gt 'kuhrPar'
		exit
	elseif momloc[1] = 4:
		$mombreak = ''
		'Your <a href="exec:gt''mother''"><<$npc_nickname[''A29'']>></a> is here clearing away the breakfast dishes.'
	else
		$mombreak = ', <a href="exec:gt''mother''">mother</a>'
	end
end

if hour = 7 and week < 6 and indorf = 0:
	'<a href="exec:gt''father''">Your stepfather</a><<$mombreak>>, <a href="exec:gt ''sister_chat'', ''sister_chat''">Anya</a> and <a href="exec:gt ''brother'', ''start''">Kolka</a> are sitting at the table eating breakfast. You could sit down and join them for breakfast or just grab something and go.'
elseif hour = 7 and week > 5 and indorf = 0:
	'<a href="exec:gt''father''">Your stepfather</a><<$mombreak>>, and <a href="exec:gt ''brother'', ''start''">Kolka</a> are sitting at the table eating breakfast. It seems your sister is sleeping in again. You could sit down and join them for breakfast or just grab something and go.'
elseif hour = 18 and minut <= 30 and indorf = 0 and anyaloc ! 25:
	'<a href="exec:gt''father''">Your stepfather</a>, <a href="exec:gt''mother''">mother</a>, <a href="exec:gt ''sister_chat'', ''sister_chat''">Anya</a> and <a href="exec:gt ''brother'', ''start''">Kolka</a> are sitting at the table eating dinner. You could sit down and join them for dinner or just grab something and go.'
elseif hour = 18 and minut <= 30 and indorf = 0:
	'<a href="exec:gt''father''">Your stepfather</a>, <a href="exec:gt''mother''">mother</a> and <a href="exec:gt ''brother'', ''start''">Kolka</a> are sitting at the table eating dinner. You could sit down and join them for dinner or just grab something and go.'
else
	'The kitchen is not very impressive, but it has everything your family needs. Since everyone can''t always join for family meals, <<$npc_nickname[''A29'']>> usually pre-cooks some meals and stores them in the fridge. Of course, you could also just have a snack if you''re not that hungry.'
end
if momloc = 11: 'Your <a href="exec:gt''mother''"><<$npc_nickname[''A29'']>></a> is here making diner.'
if momloc = 13: 'Your <a href="exec:gt''mother''"><<$npc_nickname[''A29'']>></a> is here cleaning up after dinner.'
if momloc = 23: 'Your <a href="exec:gt''mother''"><<$npc_nickname[''A29'']>></a> is here cleaning.'

if hour = 7 and breakfast_day ! daystart and indorf = 0: 
	act 'Eat breakfast with your family (0:20)': 
		*clr & cla
		gs 'food', 'family_meals', 'breakfast'
		npc_rel['A29'] += 1
		breakfast_day = daystart
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/breakfasthome.jpg"></center>'
		'As you sit down and join your family for breakfast, you stepfather asks. "How are you doing in school <<$pcs_nickname>>?"'
		if kanikuli = 0 and StoryLine > 0 and SchoolAtestat = 0 and SchoolBlock = 0:
            if pcs_grades >= 80:
                'You smile to him. "Really great. We were just learning something interesting the other day." You go on to talk about some of the stuff you have learned recently in school. He just nods, while you mother gives you a proud smile, Kolka just rolls his eyes.'
                'The rest of breakfast is taken up with some small talk about what everyone has been up to of late, You thoroughly enjoy your breakfast with your family.'
            else
                'You glance to him. "Um ok, I guess." You notice your mother frowning at you, so you quickly try to change the subject, but they won''t let you. You do your best to make them think you are doing better than you are, but neither seem to have bought it. Kolka snickers at you getting grilled.'
                'The rest of breakfast is taken up with talk about how Kolka is doing in school. He seems to be doing better than you and is showered with praise from your mother and stepfather. The food is good, even if the conversation wasn''t the best. You quickly finish your meal.'
            end
        else
            if kanikuli <> 0:
                'You smile to him. "I am enjoying some time away from school to hang out with my friends. Just to relax for a change."'
				'Then your mother speaks up. "It wouldn''t hurt you to study your school books and get ahead of your courses to get better grades." You roll your eyes, but before you can respond, your stepfather lays his hand on your mother''s. "Let her enjoy herself. This is her last year before she goes to university after all." he says with a little emphasis. You just sigh and nod as you both know that is what your mother wants.'
            else 
                'Vladamir looks over at you. "So have you found a cute boy that is head over heels in love with you, wanting to take you out on dates and buy you stuff yet?" he says in a slightly teasing tone. You mother smacks his arm. "She is too young for that! She needs to focus on school."'
				'You are about to answer, but Kolka chimes in. "Like any boy would want to be seen with her." This earns him a playful punch on the arm from you and before long, you are all bantering at the table.'
            end
        end
		act 'Get up from the table': gt $loc, $loc_arg
	end
elseif hour = 18 and minut <= 30 and dinner_day ! daystart and indorf = 0: 
	act 'Eat dinner with your family (0:20)': 
		*clr & cla
		gs 'food', 'family_meals', 'dinner'
		npc_rel['A29'] += 1
		dinner_day = daystart
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/dinnerhome.jpg"></center>'
		'As you sit down and join your family for dinner, you stepfather asks. "So <<$pcs_nickname>>, do you have a boyfriend yet?"'
		if pav_slut > 150 and motherKnowSpravka = 0:
			'You start to respond to him when your mother interrupts. "Of course not! She is still too young to be thinking about boys."'
			'Koka then chimes in. "Like any boy would date her when she sucks them all off anyways."'
			'You mother turns towards Kolka. "That''s not funny! Apologize to your sister right now! Right now!" Anya just smirks.'
			'Kolka freezes in place, but seeing that she is pissed he decides he doesn''t want to be the one to tell her about your reputation and just says. "Sorry."'
			'Your stepfather clears his throat and quickly changes the subject, talking about how his work went. After that, you have a fairly enjoyable dinner.'
		elseif pav_slut > 150:
			'You start to respond to him when your mother interrupts. "She is too young to worry about that and ... we talked about it." She gives you a meaningful glance and you shut your mouth.'
			'Kolka then chimes in. "Like any boy would date her when she sucks them all off anyways."'
			'You mother turns towards Kolka. "That''s not funny." Then she glances at you. "She might have made some mistakes, but she is trying to be a better girl now. Now apologize to your sister right now!" Anya just smirks.'
			'Kolka freezes in place. "Sorry."'
			'Your stepfather clears his throat and quickly changes the subject, talking about how his work went. After that, you have a fairly enjoyable dinner.'
		else
			'You start to respond to him when your mother interrupts. "Of course not, she is still too young to be thinking about boys."'
			'Your stepfather sighs a little. "She is old enough to start dating dear."'
			'You mother gives him a hard look. "No, she isn''t. She needs to focus on school and then going to the University before she can start thinking about boys."'
			'You stepfather decides to drop it and start talking about some of the stuff that happened at his work. All and all, you have a fairly enjoyable dinner.'
		end
		
		act 'Get up from the table': gt $loc, $loc_arg
	end
else
	if (hour = 8 or (hour = 7 and indorf = 1)) and breakfast_day ! daystart:
		act 'Eat breakfast alone (0:15)':
			*clr & cla
			menu_off = 1
			breakfast_day = daystart
			gs 'food', 'family_meals', 'breakfast'
			!!the line above adds 20mins so correction for it below
			minut -= 5
			gs 'stat'			
			'<center><img <<$set_imgh>> src="images/shared/food/breakfast_'+rand(0,1)+'.jpg"></center>'
			'You enjoy a nice and quiet breakfast. The portions were moderate and<<$mtxt>>'
			'You accompany it with a mug of tea.'
			
			act 'Get up from the table': gt $loc, $loc_arg
		end
	end
	act 'Eat a full meal (0:30)':gs 'food', 'm_meal'
	act 'Eat a light meal (0:25)':gs 'food', 's_meal'
	act 'Have a snack (0:15)':gs 'food', 'snack'
end

dynamic $sandwich
dynamic $driwater
dynamic $dritea
dynamic $fill_bottle
dynamic $edaD
dynamic $pranik
dynamic $fatdel
dynamic $lekarstvo
dynamic $vitamin

--- kuhrPar ---------------------------------