glife/locations/shop_flamingos.qsrc

# shop_flamingos

if $ARGS[0] = 'start':
	$loc_arg = $ARGS[0]
	$loc = 'shop_flamingos'
    $location_type = 'public_indoors'
	$menu_loc = 'shop_flamingos'
	$menu_arg = 'start'
	menu_off = 0
	*clr & cla
	mag = 1
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">Flamingo''s</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/mall/flamingos/butik.jpg"></center>'
	*nl
	'Flamingos is trendy and modern while still keeping the prices low enough for the large student population on the Island. It mimics the latest fashions for young adults but cuts costs on material and manufacturing. This suits the clients who are likely to grow bored of an outfit before it falls apart and that''s why its always busy.'

	act 'Leave the flamingos': minut += 3 & gt 'torgcentr'
	
	act 'View clothing': minut += 5 & gt 'shop_flamingos', 'clothes'

	act 'View shoes': minut += 5 & gt 'shop_flamingos', 'shoes'

	act 'View purses': minut += 5 & gt 'shop_flamingos', 'purses'
end

if $ARGS[0] = 'clothes':
	$loc_arg = 'clothes'
	$loc = 'shop_flamingos'
	$menu_loc = 'shop_flamingos'
	$menu_arg = 'clothes'
	menu_off = 0
	*clr & cla
	gs'stat'
	'<center><b><font color="maroon">Viewing Flamingo''s outfits</font></b></center>'
	*nl

	gs 'clothing_QV', 'shop_header'

	act 'Return': minut += 1 & gt 'shop_flamingos', 'start'

	clothingfilter['qualitycheck'] = 7
	:loopquality
		if Clothingstock > 11:
			i = 1
		else
			i = 2
		end

		:loopflamingos
			if flamingos[i] = 0:
				gs 'clothing_attributes', 'flamingos', i
				gs 'clothing_QV', 'shop_filter'

				if clothingfilter['quality'] = 0 or clothingfilter['qualitycheck'] = CloQuality:
				
					if clothingfilter_risk = 1 and clothingfilter_pandb = 1 and clothingfilter_norm2 = 1: *p '<a href="exec: i = <<i>> & gt ''shop_flamingos'', ''flamingos''"><img src="images/pc/clothing/flamingos/<<i>>.jpg" 	height="250" /></a>'
				end
			end
			i += 2
		if i <= 185:jump 'loopflamingos'
	if clothingfilter['quality'] = 1 and clothingfilter['qualitycheck'] > 0: clothingfilter['qualitycheck'] -=1 & jump 'loopquality'
end

if $ARGS[0] = 'flamingos':
	cla
	menu_off = 1
	if flamingos[i] ! 0:
		msg 'You already own these clothes.'
		gt 'shop_flamingos', 'clothes'
	end

	gt 'clothing', 'view_clothing_item', 'shop', 'flamingos',i, 20000

end

if $ARGS[0] = 'shoes':
	$loc_arg = $ARGS[0]
	$loc = 'shop_flamingos'
	$menu_loc = 'shop_flamingos'
	$menu_arg = 'shoes'
	menu_off = 0
	*clr & cla
	gs'stat'

	act 'Return': minut += 1 & gt 'shop_flamingos', 'start'

	if Clothingstock > 11:
		i = 1
	else
		i = 2
	end

	:loopflamingos_shoes
		if sflamingos[i] = 0:*p '<a href="exec: i = <<i>> & gt ''shop_flamingos'', ''flamingos_shoes''"><img src="images/pc/shoes/flamingos/<<i>>.jpg" height="250" /></a>'
		i += 2
	if i <= 37:jump 'loopflamingos_shoes'
end

if $ARGS[0] = 'flamingos_shoes':	gt 'shoes', 'view_shoe_item', 'shop', 'flamingos',i, 5000

if $ARGS[0] = 'purses':
	$loc_arg = 'purses'
	$loc = 'shop_flamingos'
	$menu_loc = 'shop_flamingos'
	$menu_arg = 'purses'
	menu_off = 0
	*clr & cla
	gs'stat'

	act 'Return': minut += 1 & gt 'shop_flamingos', 'start'

	i = 1

	:loopflamingos_purses
		if flamingos_purses[i] = 0:*p '<a href="exec: i = <<i>> & gt ''shop_flamingos'', ''purses2''"><img src="images/pc/purses/flamingos/<<i>>.jpg" 	height="150" /></a> '
		i += 1
	if i <= 17:jump 'loopflamingos_purses'
end

if $ARGS[0] = 'purses2': gt 'purses', 'view_purse_item', 'shop', 'flamingos',i, 4000

--- shop_flamingos ---------------------------------