# city_island

! 14-09-22 Added Metro link to navigation line 49

$loc_arg = ''
$loc = 'city_island'
$region = 'city_island'
$location_type = 'public_outdoors'
$menu_loc = 'city_island'
$menu_arg = ''
menu_off = 0
CLOSE ALL
if sound = 0:
	if month >=11 and month <= 12 or month >=1 and month <=3:
		if hour >= 8 and hour <= 23: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/zima.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street_night.mp3',30 & PLAY 'sound/zima.mp3',30
	else
		if hour >= 8 and hour <= 23: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/street_leto.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_noise_siren.mp3',30 & PLAY 'sound/street_night_leto.mp3' & PLAY 'sound/street_night.mp3',30
	end
end
clr
gs 'stat'
'<center><h2>St. Petersburg</h2></center>'
'<center><b>Vasilyevsky Island</b></center>'
if month >= 11 or month <= 3:
	if daystage = 2 or daystage = 3:
		'<center><img <<$set_imgh>> src="images/locations/city/island/islandw.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/island/islandwn.jpg"></center>'
	end
else
	if daystage = 2 or daystage = 3:
		'<center><img <<$set_imgh>> src="images/locations/city/island/island.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/island/islandn.jpg"></center>'
	end
end

'The University area of the city, the University, shops, clubs and the like that cater to the college kids dominate this area of the city. There is only three bridges onto and off the island, plus the metro line.'

!call random events from [street_events], and display them before show location.
if streetevent_hour + 2 < hour:gt'street_event','city_island', 'main'

gs 'street_event', 'city_island', 'extras'

if func('homes_properties', 'has_access', 'university_dorm') :act '<b>GO HOME</b> (University dorm)':gt 'uni_dorm', 'start'

if car > 0 and cardrive = 25:'In the parking stands your <a href="exec:GS ''carF'', ''start''"><<$car>></a>.'

if hour >= 4 and hour <= 23:
	act 'Walk to the Metro': gt 'metro', 'start'
end

act 'Wait':gs 'obj_din', 'wait'

gs 'taxi'
gs 'camera', 'check_location'

if hour >= 8 and hour <= 22:
	'The <a href="exec: minut += 3 & gt ''uni_shop'', ''start''">supermarket</a> is not far from here.'
	'You can see the <a href="exec:$loc = ''city_island'' & minut += 1 & gt ''kiosk'', ''start''">kiosk</a> selling cigarettes and magazines.'
else
	'The local convenience store is closed, they open again at 8:00'
	'You can see a closed kiosk. It''s open between 08:00 - 23:00.'
end
if hour >= 8 and hour < 22:
	'You can see <a href="exec:gt ''shop_dolls'', ''start''">Patch Work Dolls</a> a clothing store that caters to Alternative styles, like gothic, punk, skater, and the like. Next to <a href="exec:gt ''shop_nerdvana'', ''start''">Nerdvana</a> a clothing store for everything a nerd could desire.'
else
	'You can see Patch Work Dolls a clothing store that caters to Alternative styles, like gothic, punk, skater, and the like. Next to that is Nerdvana the nerd clothing store, they both open every day between 08:00 - 22:00'
end
if hour >= 7 and hour <= 23:
	'You can see a sign advertising a coffee shop called <a href="exec: minut += 3 & gt ''city_coffee_hole'', ''start''">The Coffee Hole</a> just a few blocks from the University.'
else
	'The The Coffee Hole, coffee shop is closed, they open again at 7:00'
end
if hour >= 4:
	'The <a href="exec:minut += 1 & gt ''metro'', ''start''">Metro</a> Station is within a 5 minute walk from here.'
else
	'The Metro Station is closed. The first train will depart at 04:00.'
end

act 'Go to the University campus': 
	minut += 1
	gt 'uni_grounds', 'main'
end

if func('homes_properties', 'has_access', 'university_dorm') or university['student'] = 1 or hour >= 6:'The <a href="exec:gt ''uni_dorm'', ''start''">University dorms</a> offers small, but cheap, living space, for university students.'

if pcs_magik >= 1 and mainQW = 0 and mid($start_type,1,3) = 'uni':
	*clr & cla
	menu_off = 1
	mainQW = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/lab/event/main.jpg"></center>'
	'In front of your dorm, you see Tatiana and Gustav. Tatiana adjusts her glasses and looks around, while Gustav seems to be distracted, glancing here and there with a strange look on his face as his tattoos are not visible.'
	'Tatiana looks at you closely, "I felt a burst of energy. Were you attacked by a magician?"'
	act 'No':gt 'mainQW'
	exit
end

--- city_island ---------------------------------

