# vokzalGin
$metka = $ARGS[0]
$loc = $CURLOC
clr
frost = 0
poezddalsled = 0
gs 'vokdin'
gs 'vokdinvera'
gs 'vokmantoiev'
gs 'stat'
fcolor = rgb(0, 0, 0)
bcolor = rgb(255, 255, 255)
lcolor = rgb(106, 90, 205)


'<center><h4>Station</h4></center>'
'<center><img src="images/qwest/alter/vokzal.jpg"></center>'
'In the center of the station waiting room and <a href="exec:dynamic $din_vokzalg_kassi">Case</a> with the scoreboard. In one wing are <a href="exec:dynamic $din_vokzalg_kabinet">offices bosses</a>, and in the other <a href="exec:minut += 1 & dynamic $din_vokzalg_toilet">Toilets</a>.'

if katalkinSexOnce = 1:'There is a small <a href="exec:minut += 5 & gt ''katalkin''">police</a> station inside the terminal.'

if podbros = 0:
	podrand = rand(0, 1)

	if money >= 1000 and hour >= 8 and hour <= 20 and podrand = 0:'Walking along the station you notice how a man falls thick <a href="exec:dynamic $din_vokzalg_podbros">purse</a>.'
end

act 'Leave':minut += 3 & gt 'vokzalG'

if vokzalVork >= 1:
	if cleZalDay ! day:
		act 'Mopping the floor in the waiting room':
			cls
			cleZalDay = day
			minut += 60
			sweat += 1

			if vital < 15:vital += rand(0, 1)
			if stren < 15:stren += rand(0, 1)

			gs 'stat'
			'<center><img src="images/etogame/clener1.jpg"></center>'
			'You took inventory, poured water into a bucket and began to wash the floor in the waiting room.'

			act 'Leave':minut += 1 & gt 'vokzalGin'
		end
	end

	if cleMTDay ! day:
		act 'Mopping the floor in the men''s room':
			cls
			cleMTDay = day
			minut += 30
			sweat += 1

			if vital < 15:vital += rand(0, 1)
			if stren < 15:stren += rand(0, 1)

			gs 'stat'
			'<center><img src="images/etogame/clener1.jpg"></center>'
			'You took inventory, poured water into a bucket and went to the men''s room.'
			dynamic $d_vok_man_toilet_event
			!!'You began to wash the floor in the men''s room, and then began to scrub toilets.'

			act 'Leave':minut += 1 & gt 'vokzalGin'
		end
	end

	if cleWTDay ! day:
		act 'Mopping the floor in the women''s restroom':
			cls
			cleWTDay = day
			minut += 30
			sweat += 1

			if vital < 15:vital += rand(0, 1)
			if stren < 15:stren += rand(0, 1)

			gs 'stat'
			'<center><img src="images/etogame/clener1.jpg"></center>'
			'You took inventory, poured water into a bucket and began to wash the floor in the ladies'' room, and then began to scour bowls.'
			dynamic $d_vokzal_vera_talk

			act 'Leave':minut += 1 & gt 'vokzalGin'
		end
	end

	if cleMTDay = day and cleWTDay = day and cleZalDay = day and cleZarplatDay ! day:
		act 'Get salary':
			cls
			cleZarplatDay = day
			vokzalVork += 1
			money += 250
			minut += 3
			gs 'stat'
			'You went to the cashier and got their money.'

			act 'Leave':minut += 1 & gt 'vokzalGin'
		end
	end
end

if hour = 11 and minut = 0:
	poezddalsled = 1
	'The platform comes long-distance trains.'
elseif hour = 11 and minut > 0 and minut < 30:
	poezddalsled = 1
	'At the platform stands distance trains.'
elseif hour = 11 and minut = 30:
	poezddalsled = 1
	'Platform serving long-distance trains.'
elseif hour = 18 and minut = 0:
	poezddalsled = 1
	'The platform comes long-distance trains.'
elseif hour = 18 and minut > 0 and minut < 30:
	poezddalsled = 1
	'At the platform stands distance trains.'
elseif hour = 18 and minut = 30:
	poezddalsled = 1
	'Platform serving long-distance trains.'
end

if poezddalsled = 1:
	'Platform fussy run hucksters vtyuhivat their goods train passengers. On the part of all this fuss watches Police.'

	if tovarL > 0:
		act 'Vtyuhivat their goods passengers.':gt 'vokzaltorg'
	end
end

--- vokzalGin ---------------------------------
