glife/locations/swamp_yard.qsrc

# swamp_yard

$loc = 'swamp_yard'
$metka = ''
$menu_loc = 'swamp_yard'
$menu_arg = ''
menu_off = 0
$location_type = 'secluded'

gs 'gadukino_event', 'sound'
gs 'stat'
!the chance of encountering hunters

if week = 6 or week = 7:huntersrand = RAND(1,3)
if week < 6:huntersrand = RAND(1,5)

if huntersrand = 1:hunters = 1
!the chance of hitting GG, if she`s a slut
huntslutsexrand = rand(1,3)
! to remember were cowards or not
!if lost_girl = 0:lost_girl += rand(40,60)
if StoryLine = 1 and lost_girl = 0 and forest_lostday > 0: lost_girl=daystart+2
dirty = 1

swiss_army_random_number = rand(1,10)

!Code blocks for leaf events (events not calling other dynamic events)

$yard_cleanup = {
	cla
	*clr

	if dirty_swamp_yard < 10:
		minut += 60 & pcs_sweat += 10
	elseif dirty_swamp_yard < 20:
		minut += 120 & pcs_sweat += 20
	else 
		minut += 180 & pcs_sweat += 30
	end

	if huntersAndreiQw < 15:huntersAndreiQw += 1
	if huntersIgorQw < 15:huntersIgorQw += 1
	if huntersSergeiQw < 15:huntersSergeiQw += 1
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/dirty_swamp_yard.jpg"></center>'
	'You notice that the yard has gotten pretty dirty. "I need to do something about this." you think to yourself.'
	'You grab a garbage bag and start picking up trash.'
	'After a while you''ve finished tidying up the yard and put the trash in the garbage bag. You''re quite pleased with yourself.'

	act 'Done':dirty_swamp_yard = 0 & hunter_collective_opinion += 2 & gt 'swamp_yard'
}

$swamp_escape = {
	!add chance to swamped by illume
	if hunters = 1:
		
		if hour >= 6 and hour < 21:
			minut += 5
			if rand(1,10)>9:
				gt 'swamp'
			else
				gt 'gadforestswamp','2'
			end		
		else
			*clr & cla
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/igorhanter.jpg"></center>'
			'As you start moving into the swamp Igor calls after you.'
			
			!TODO: Different line depending on opinion and slut
			'"<<$pcs_nickname>>, where are you going? You will get stuck in there!'
			
			act 'Turn back':gt 'swamp_yard'
			act 'Ignore him and keep going':
				minut += 5

				!TODO: Add skill clothing and temp check here instead of praying to RNGesus
				if rand(1,10)>8:
					gt 'swamp'
				else
					gt 'gadforestswamp','2'
				end
			end
		end
	else
		minut += 5

		!TODO: Here too, also see how to avoid duplicating. Maybe create a child event node?
		if (hour >= 6 and hour < 21) or rand(1,10)>7:
			gt 'swamp'
		else
			gt 'gadforestswamp','2'
		end
	end

	gt 'gadforestswamp','2'
}

$rescued_from_swamp = {
	*clr & cla
	minut += 5
	gs 'stat'

	if $clothingworntype ! 'nude':
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterhelp.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterhelp1.jpg"></center>'
	end
	
	if $clothingworntype = 'nude':
		if huntersKnow = 0:
			if pcs_apprnc >= 100:
			'"Are you... a mermaid?" You hear one of the men blurt out before blushing'
			else 
			'What the hell happened to you? Are you alright?'
			end
		end	
		if huntersKnow = 1 and huntersKnowSlut = 0:'"<<$pcs_nickname>>, what happened to you? Where are your clothes?" Andrei said concernedly.'
		if huntersKnow = 1 and huntersKnowSlut = 1:'Well isn''t this our favorite damsel in distress. And she''s even naked and ready for us so we can jump straight to the happy ending! Andrei grinned.'
	end
	
	if huntersKnow = 0:
		'The hunters help you to a dry place. For some time you just sit there, staring blankly ahead, trying to catch your breath. After a while feeling better you decide to find out where you are and who it was that saved you.'
		act 'Look':hunterhelp = 2 & gt 'swamp_yard'
	else
		'The hunters help you to a dry place. For some time you just sit there, staring blankly ahead, trying to catch your breath. After a short rest you go out to the yard.'
		act 'Further':hunterhelp = 0 & gt 'swamp_yard'
	end
}

$meet_hunters_after_rescue = {
	*clr & cla
	minut += 5
	huntersKnow = 1

	!TODO: More behavior variables w/ explanation
	hunter_collective_opinion = 30
	hunter_sexual_comfort = 10 + pcs_apprnc / 4
	hunters_violent = 0

	!TODO: Figure what to do with hunter inidividual opinion
	!huntersAndreiQw += 1
	!huntersIgorQw += 1
	!huntersSergeiQw += 1

!!julzor: Why did you comment out the gs 'stat'? If you change something in the stat window like the time you should call gs 'stat' to update the stat window	
	gs 'stat'

	'You see the three men talking to each other. They stop and approach you after noticing you have calmed down.'
	if $clothingworntype = 'nude':
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterhelp3.jpg"></center>'
		'You realize that you are totally naked in front of these three strangers, you quickly try to cover up your most private parts with your hands'
		'You start blushing feeling ashamed.'
		'Shortest of the men starts ogling you while the overweight one freezes up like a deer in the headlights.'
		'The third man turns his head away and hands you a burlap sack'
		'"Here, you can have this to cover up, you have nothing to be embarrassed about. Sorry we do not have any change of clothes for you."'
		act 'Cover up with the burlap sack': gs 'clothing', 'swamp_clothes', 1
		!TODO: Add exhibitionist option
		!if exhibitionist > 1: act 'I think I am fine, thank you'
	else
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterhelp2.jpg"></center>'
		hunter_collective_opinion += 3
	end

	if pcs_apprnc >= 70:'"Are you feeling better now? What''s your name, beautiful?" the short one asks.'
	if pcs_apprnc < 70:'"Are you feeling better now? What''s your name?" the short one asks.'
	'"<<$pcs_nickname>>, well, you can call me <<$pcs_nickname>>." you answer.'
		
	'"I''m Andrei," he replied, "and these are my friends, from the city, Igor and Sergei."'
	'"Is your lastname possibly <<$pcs_lastname>>?" You look at him surprised for a moment before nodding.'
	'"You look a lot like your mother that''s how I knew. I am also from Gadukino."'
	
	if pcs_sweat > 2 or dirty = 1:
		'You become aware of the dirty clothes sticking on your body, making you uncomfortable.'
		'"Is there somewhere I can clean myself up?"'
		'"Well, it''s still warm outside, so you can wash up in the creek, just follow the path behind the hut, you can''t miss it."'
		'"There is also a basin with some soap and a clothesline with a fresh towel you can use to wash and hang your clothes to dry."'
		act 'Walk too the creek': gt 'backwater'
		act '"Actually I am fine for now, I think"': gt 'swamp_yard'
	else
		'"Here, come have a seat" said Sergei, the overweight one, freeing up a place for you by the campfire.'
		act '"Sit down"': hunter_collective_opinion += 2 & gt 'swamp_yard'
	end
}

!Assorted sex scenes for the yard
$andrei_quick_fuck = {
	cla & *clr
	!TODO: bunch of images needed here
	!if hunter_collective_opinion > 45:
	if hunter_collective_opinion < 25:
	!elseif hunter_collective_opinion > 25:

	!else
		'Andrei walks up to you without saying another word and forcefully pulls you closer by your nipples.'
		gs 'pain', 10, 'pinch', 'nipples'
		'You yelp but it is cut short when he shoves his tongue down your throat, roughly fondling you all over'
		gs 'arousal', 'foreplay', 25, 'sub'
		act 'You feel your pussy starting to get wet':
			cla & *clr
			!TODO: Yes, images
			'He definitely feels it too as he keeps shoving his fingers in and out. Satisfied, he turns you around by the shoulders and forcefully bends you over'
			'You close your eyes anticipating what is coming. He wastes no time unzipping his pants and shoves his rock hard cock all the way in your ready pussy, eliciting a loud moan from you.'
			'He starts fucking you rough and hard, not caring what you are getting out of it. You are merely a cocksleeve for him.'
			gs 'arousal', 'vaginal_finger', '15', 'sub'
			gs 'arousal', 'vaginal', '30', 'sub', 'rough'
!!julzor: I removed the gs 'end' (also it was missing the 'arousal' part)			
			act '...':
				cla & *clr
				!TODO: Image here
				'After a few minutes he grabs you by the shoulders and unceremoniously shoves you on the ground on your back.'
				'You watch him furiously jerk standing over you. You realize you have been playing with yourself for some time when he starts shooting his load all over your tits and belly'
				
				gs 'arousal', 'masturbate', 15
!!julzor: added the gs 'arousal', 'end' here, because it should be after all other arousal calls
				gs 'arousal', 'end'
				gs 'cum_call', 'breasts', 'A172', 1
!!julzor: the number 1 indicates that the boy is known ... a 2 makes no sense, changed it into a 1
!!you can check the files arousal, cum_call and so on ... there should be always a explanation at the top
				gs 'cum_call', 'stomach', 'A172', 1
!!julzor: added missing gs 'stat'
				gs 'stat'
				
				act 'Further': gt 'swamp_yard'
			end 
		end
	end
} 

$igor_demonstration = {
	!TODO: Image here
	'Seeing Igor staring at your naked body like a deer in the headlights gives you an idea.'
	act 'Show him it is no big deal':
		cla & *clr
		hunter_sexual_comfort += 3
		hunter_collective_opinion += 7
							
		!TODO: Gif here 
!!julzor: we don''t use gifs, only mp4
		'You smile at Igor as you start swaying slowly, getting into something resembling a rhythm'
		'"The clothes just get in the way when I do this. Why not join me for a dance?" you say.'
		'He starts awkwardly swaying to match you as you two get into it, with you acting like you are not dancing completely naked in front of the men.'
		'As he starts getting into the rythm, the other men take notice and join in too. Sergei puts on some music as you all spend some time dancing like you are at a disco.'
							
		gs 'arousal', 'flash', 25, 'dom', 'exhibitionism'
!!julzor: added missing gs 'stat' and arousal end
		gs 'arousal', 'end'
		gs 'stat'

		act 'Further': gt 'swamp_yard'   
	end
!!julzor: missing : after the end						
	act 'Give him a hands on demonstration':
		cla & *clr
		hunter_sexual_comfort += 5
		hunter_collective_opinion += 1

		!TODO: Gif and images here as well as the rest of the scene
		'You smile at Igor as you approach him and grab his hand'
		'"It is no big deal to me, why are you the one that''s embarrassed?" you say as you put his hand on your breasts'
		'He starts blushing to his ears as you lead him to play with your tits. He starts kneading your breasts lightly after a minute but does not go further.'
		'After a minute he stops and starts going away but not before you notice the satisfied smirk on his face.'

		gs 'arousal', 'breasts', 5, 'dom', 'exhibitionism'
!!julzor: added missing gs 'stat' and arousal end
		gs 'arousal', 'end'
		gs 'stat'

		act 'Further': gt 'swamp_yard'
	end
}

$skirt_breeze = {
	*clr & cla
	hunter_sexual_comfort += 2
	

	'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/no_tanga.jpg"></center>'
	'You walk across the yard, when suddenly the wind lifts you skirt.'
	'"I forgot to put on panties...," you realize this seeing your bare pussy.'
	'You nervously started looking around if anyone caught a glimpse of your little wardrobe malfunction...'
	'You hoped that the men missed the opportunity seeing you exposed, however, Igor''s face had turned red and you see Andrei grinning, you realize quite quickly that your little show did not pass unappreciated.'
!!julzor: The arousal call was missing the time (I put in one minute, you have to change it to something appropriate for the scene)
	gs 'arousal', 'flashlite', 1
!!julzor: gs 'stat' should be at the end after all stat window changing things happen (arousal changes arousal and time)
	gs 'arousal', 'end'
	gs 'stat'
	
	act 'Further':gt 'swamp_yard'
}

!Code blocks for branch events (events calling other dynamic events)
!TODO: Return here to expand more.
$naked_encounter = {
	if huntersKnowSlut = 0 and $clothingworntype = 'nude':
		cla
		*clr
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swampdvornude.jpg"></center>'
		'Seeing some men in the yard, you try to cover up your private parts...'

		if FUNC('lost_clothes_here','swamphouse') = 1 and $lastwornclothingtype ! 'nude':
			act 'Run inside and get dressed':
				*clr & cla
				minut += 5
				gs 'underwear', 'wear'
				gs 'clothing', 'recover_lost_clothes', 'swamphouse', 1

				'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swampdvornude1.jpg"></center>'
				'You rush inside the hut so you can get dressed.'
				act'Further':gt 'swamphouse'
			end
		else
			act 'Run inside and cover up with a burlap sack':
				*clr & cla
				minut+=5
				gs 'clothing', 'swamp_clothes', 1
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/tkan_cloth.jpg"></center>'
				'You quickly rush inside the hut and wear a sack... It''s not much, but at least it''s better than nothing.'
				act'Further':gt 'swamphouse'
			end
		end

		!TODO: Make this dependent on exhibitionist or inhibition
		act'Remain naked':
			*clr & cla
			gs 'arousal', 'flash', 5, 'exhibitionism'
!!julzor: added missing arousal end
			gs 'arousal', 'end'
			hunterknowday = daystart
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swampdvornude2.jpg"></center>'
			'You decide that it doesn''t matter if you have clothes on or not, you leave it as is. The men stare at your naked body.'

			!Nudity reactions. Might need to split into more dynamic events if it gets too massive
			if hunter_sexual_comfort < 40:
				if hunter_collective_opinion > 45:
					hunter_sexual_comfort += 7
					'"<<$pcs_nickname>>, why are you not wearing clothes?" says Sergei'
					'"Leave the girl alone Sergei. It is just us around. In fact, we should go naked too!" says Andrei and starts unzippping his jacket'
					'"Okay, okay, you made your point. You do not have to do a striptease, <<$pcs_nickname>> can do whatever she is comfortable with." says Sergei'
					act 'Further': gt 'swamp_yard'
				elseif hunter_collective_opinion > 25:
					hunter_sexual_comfort += 5
					hunter_collective_opinion -= 2
					'"Well well, we have ourselves a free spirit here!" says Andrei'
					'"<<$pcs_nickname>>, please cover up. This is not very appropriate." says Sergei'
					act 'Further': gt 'swamp_yard'
				else
					hunter_sexual_comfort += 3
					hunter_collective_opinion -= 4
					'"What in the hell are you doing you dumb girl, put something on" says Sergei'
					'"Seriously <<$pcs_nickname>>. You are not a toddler, you can''t just run around naked like one." says Igor'
					act 'Further': gt 'swamp_yard'
				end
			else
				if hunter_collective_opinion > 45:
					hunter_sexual_comfort += 5
					hunter_collective_opinion += 5
					'"Wow nice dress!" says Andrei, grinning, and gives you a playful fondle and slap on the ass'
					gs 'arousal', 'fondling'
					
					!TODO: Find an image for here, preferably gif
					'"You sure do look good, <<$pcs_nickname>>" says Igor before pulling you in for a kiss.'
					
					act 'Return the kiss':
						*clr & cla
						!TODO: find image that fits here
						'You happily return the kiss, not caring if you are making out completely naked outside with the other men watching you'
						!TODO: find image that fits here
						'Igor''s fingers explore your body, fondling your tits and ass before slipping in your pussy. You start grinding against his fingers before he pulls back out and gives you a smirk before walking back, leaving you aching for more.'
						
						gs 'arousal', 'kiss', 5, 'exhibitionism'
						gs 'arousal', 'vaginal_fingering', 5, 'sub'
!!julzor: added missing arousal end and missing gs 'stat'
						gs 'arousal', 'end'
						gs 'stat'


						act 'Further': gt 'swamp_yard'
					end

					act 'Lightly push him away':
						hunter_sexual_comfort -= 3
						hunter_collective_opinion += 3
						
						'"Whoa there guy! Getting ahead of ourselves aren''t we?" you say before giving Igor a slap on the ass.'
						'He looks at you with a mix of confusion and amusement'
						
						gs 'arousal', 'fondling', 5, 'dom'
!!julzor: added missing arousal end and missing gs 'stat'
						gs 'arousal', 'end'
						gs 'stat'

						act 'Further': gt 'swamp_yard'
					end	

				elseif hunter_collective_opinion > 25:
					hunter_sexual_comfort += 3
					hunter_collective_opinion += 3
				
					'"That''s the spirit <<$pcs_nickname>>. You have got nothing to hide so why hide it?" says Andrei'
					'"I...uh...wow." stammers Igor. "Still not used to you prancing around like that"'
					act 'Help him get more used to it':	dynamic $igor_demonstration
				else
					hunter_sexual_comfort += 3
					hunter_collective_opinion += 1

					'"What in the hell are you doing you dumb girl, put something on" says Sergei'
					'"Leave her Sergei, she is not useful for anything else anyway. Might as well be eye candy and easy acccess for a quick fuck." says Andrei'
					'"In fact, let me demonstrate" he says before looking at you, grinning wolfishly"'
					dynamic $andrei_quick_fuck
				end
			act'Keep moving':gt 'swamp_yard'
			end
		end	
	end
}

$hunter_cleanup_request = {
	
	if hunters > 0 and huntersKnow = 1 and swiss_army_random_number < 3:
		*clr & cla
		swiss_army_random_number = rand(1,3)
		minut += 5
!!julzor: Changed the three if conditions into one if/elseif and moved the pictures there so I was able to delete the second set of three if conditions
		if swiss_army_random_number = 1:
			gs 'boyStat', 'A172'
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/andreihanter.jpg"></center>'
		elseif swiss_army_random_number = 2:
			gs 'boyStat', 'A174'
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/sergeihanter.jpg"></center>'
		elseif swiss_army_random_number = 3:
			gs 'boyStat', 'A173'
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/igorhanter.jpg"></center>'
		end
		gs 'stat'

		'<<$boydesc>> approaches you. "Hey I need your help with something"'
		
		act 'Sure what is it?':
			if dirty_swamphouse > 5:
				if huntersKnowSlut = 0:'"<<$pcs_nickname>>," he says. "The hut is a mess, could you take care of it please?"'
				if huntersKnowSlut = 1:'"<<$pcs_nickname>>," he uses his stern voice. "The house is a mess, take care of it."'
				act 'Clean the hut':hunter_collective_opinion += 2 & gt 'swamphouse', 'dirty_swamphouse'
			elseif dirty_swamp_yard > 5:
				if hunter_collective_opinion >= 15:'"<<$pcs_nickname>>," he says. "The yard is a mess. Can you please take care of it?"'
				if hunter_collective_opinion < 15:'"<<$pcs_nickname>>," he says sternly. "What the hell is all this trash doing out there? Go and pick it all."'
				act 'Clean the hut':hunter_collective_opinion += 2 & dynamic $yard_cleanup
			else
				if hunter_collective_opinion >= 15:'"Actually, nevermind. I got this, thanks though."'
				if hunter_collective_opinion < 15:'"Actually, nevermind. You are kinda useless for what I need"'
				act 'O...kay':hunter_collective_opinion += 1 & gt 'swamp_yard'
			end	
		end
	
		act '"I''ll help later, busy right now"':
			*clr & cla
			minut += 5
			hunter_collective_opinion -= 3
			
			!TODO: Find new image
			gt 'swamp_yard'
		end	

		!TODO: Make this act mood dependent
		act '"What?! Do I look like a servant to you?':	
			'<center><img <<$set_imgh>> src="images/pc/speak_to_the_hand.jpg"></center>'
			'You walk away from <<$boydesc>>'
			hunter_collective_opinion -= 10
			gt 'swamp_yard'
		end
!!julzor: missing end
	end
}

!TODO: Clean this up, divvy into leaf events, add additional checks and events for opinion and sexual comfort, and a random no check for the conversations to trigger instead of hunters being omniscient
$hunter_convo_sexworker = {
	if huntersKnow = 1 and hunters_check = 0:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterstalk.jpg"></center>'
		'While walking around the yard you hear the hunters discussing something excitedly.'
		
		convo_rng_roll = rand(1,50)
		
		!TODO: They do not just shut up when they notice Sveta, there is an opinion or comfort check
		if fame_sexind > 10 and city_modelling > 30 and huntersknowfoto = 0 and convo_rng_roll = 1:
			*clr & cla
			minut += 5
			hunters_check = 1
			huntersknowfoto = 1
			
			hunter_sexual_comfort += 5
			hunter_collective_opinion += 3
			
			gs 'stat'
			
			'"I''m telling you, I''ve seen her pictures in a men''s magazine." you overhear Igor.'
			'As soon as they noticed you the men stop talking and changed the subject to another topic.'
			act 'Further':gt 'swamp_yard'
		
		elseif stripdancesum > 0 and huntersknowstrip = 0 and convo_rng_roll = 2:
			*clr & cla
			minut += 5
			hunters_check = 1
			huntersknowstrip = 1

			hunter_sexual_comfort += 5
			hunter_collective_opinion -= 3

			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterstalk.jpg"></center>'
			'While walking around the swamp you hear the hunters discussing something very lively.'
			'"I promise you, it was her, I swear!" you overhear Sergei. "She was on the stage dancing."'
			'As soon as they noticed you the men stop talking and changed the subject to another topic.'

			act 'Further':gt 'swamp_yard'

		elseif film > 0 and huntersknowfilm = 0 and convo_rng_roll = 3:
			*clr & cla
			minut += 5
			hunters_check = 1
			huntersknowfilm = 1

			hunter_sexual_comfort += 7
			hunter_collective_opinion -= 5

			gs 'stat'
			'"I recently downloaded some porn, and guess who was in the video, trust me, she''s <<$pfname>>." you overhear Andrei.'
			'As soon as they noticed you the men stop talking and changed the subject to another topic.'

			act 'Further':gt 'swamp_yard'
		
		elseif gadriver_gang > 0 and convo_rng_roll > 45:
			*clr & cla
			minut += 5
			huntersRape = 1
			hunters_check = 1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterstalk.jpg"></center>'
			'While walking around the swamp you hear the hunters discussing something very lively.'
			'"I''m telling you, everyone in Gadukino has had the pleasure to "test out" the goods." you overhear Andrei. As soon as they noticed you the men stop talking and changed the subject to another topic.'

			act 'Further':gt 'swamp_yard'
		else
			*clr & cla
			minut += 5

			'"I swear, it was a large orangutan standing by the trees watching us! I also saw those massive prints the other day!" you overhear Andrei'
			'"Sure, it had nothing to with that vodka bottle you were chugging." says Igor'
			'"Nah I totally believe him. It was just his mom making sure his baby boy was fine" says Sergei before starting to laugh loudly' 

			'As soon as they noticed you the men stop talking and changed the subject to another topic.'

			act 'Further':gt 'swamp_yard'
		end
	end
}

$daytime_flavor_events = {
	!TODO: Move the conditionals inside the child events. Let''s keep this only foor rng rolls and event calls and no more
	if CloSkirtShortness > 1 and $pantyworntype = 'none' and rand(1,20) = 1: dynamic $skirt_breeze
	if rand(1,12) = 1 : dynamic $hunter_cleanup_request
	if rand(1,20) = 1: dynamic $hunter_convo_sexworker
	if rand(1,10) = 1: dynamic $naked_encounter
}

$nighttime_flavor_events = {
	!TODO: Add stuff here
}

'<center><B>The yard in front of the hut</B></center>'
if month >= 5 and month <= 9:
	if hour >= 6 and hour < 22:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swamp_yard.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swamp_yard_night.jpg"></center>'
	end
else
	if hour >= 8 and hour < 18:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swamp_yard_winter.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/swamp_yard_winter_night.jpg"></center>'
	end
end

'The yard in front of the hut.'
'Behind the hut there is a <a href="exec: gt ''swampspring'' ">spring</a>, if you continue a little further down there is a small <a href="exec: gt ''backwater'' ">creek</a> with relatively clean water.'
if findvel = 3:'On the side of the hut is an old <a href="exec:gt ''bicycle'',''swamp''">bike</a>.'
if hunters > 0 and huntersKnow = 0:'You spot some unfamiliar <a href="exec: gt ''hunters'', ''start'' ">people</a> standing in front of the hut.'
if hunters > 0 and huntersKnow > 0 and hour >= 8 and hour < 20:'You notice the <a href="exec: gt ''hunters'', ''start'' ">hunters</a> standing in the front yard.'

act 'Go into the hut':gt 'swamphouse'

!Conditional acts
if dirty_swamp_yard > 10:act 'Clean up the trash outside': dynamic $yard_cleanup
if collective_hunter_opinion < 10: act '<b>Escape to the swamp</b>': dynamic $swamp_escape

! TODO: Figure how to remove the sneaky gotos if not tied to other locations
if hunterhelp = 1: 
	dynamic $rescued_from_swamp
end

if hunterhelp = 2 and huntersKnow = 0:
	dynamic $meet_hunters_after_rescue
end

if hour >= 8 and hour < 20: 
	dynamic $daytime_flavor_events

	!TODO: Get rid of all this below here and move the dialogue to other events after revamping the other locs	
	!the conversation after a drunken Striptease and fuck GG hunters
	if huntdanceslut = 1:
		cla
		*clr
		minut+=5
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/andreihanter.jpg"></center>'
		'As soon as you walk into the yard, you immediately walk up to Andrei.'
		'"I need to talk to you, <<$pcs_nickname>>," he said. "Can you recall what happened last night?"'
		'"Well... uh... Yes, I think I can..." you reply, blushing, staring down at the ground.'
		'"I used to say that you look just like your mother," said Andrei looking at you. "After your little show yesterday, as it turns out, the resemblance doesn''t stop at just the looks."'
		'Andrei paused looking at you while you try to collect your thoughts to understand what he''s trying to imply.'
		'"To be frank, you''re as slutty as your mother was in her youth, the apple doesn''t fall far away from the tree as they say..." he chuckles. "Take it as a compliment."'
		'You look at Andrei, completely stunned by what you just heard.'
		'"And what are sluts best at?" he continues. "That''s right, to pleasure men. Don''t you agree?"'

!!julzor: I put the refuse option at the top ... we always try to put refuse/decline/leave options at the top
		if pcs_dom > 0 and alko < 8:act'Refuse':huntdanceslut = 3 & gt 'hunters', 'start'
		act'Agree':huntdanceslut = 2 & gt 'hunters', 'start'
	end
	!the conversation after the rape GG hunters
	if huntersRape = 4:
		cla
		*clr
		minut+=5
		huntersKnowSlut = 2
		huntersRape = 5
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/andreihanter.jpg"></center>'
		'As soon as you walk into the yard, you immediately walk up to Andrei.'
		'"I need to talk to you, <<$pcs_nickname>>," he said. "Do you understand what happened yesterday and that you should keep quiet about it?"'
		'You shamelessly nodded.'
		'"What happened to you is no one others fault but your own, you wanted to get fucked," said Andrei looking sternly at you. "Don''t pull off anything stupid like that anymore."'
		'"I wouldn''t advise you to call the police," he adds. "Sergei will cover for me. In fact, we''ll just cover for each other, and no one will believe your lying pretty ass. Understand?"'
		'You''re too afraid to look straight at Andrei, you just nod.'
		'"Perfect," said Andrei, moving away from you.'

		act 'Go':gt 'swamp_yard'
	end

	!sex with Igor
	if hunters > 0 and huntersIgorLove > 0 and huntersIgorQw >= 10 and swiss_army_random_number = 4 and huntersIgorsex = 0:
		*clr & cla
		minut += 5
		huntersIgorsex += rand(12,36)
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterlove1.4.jpg"></center>'
		'Igor appears in the yard noticing you. Smiling, he walks over and gives you a passionate kiss.'
		'"<<$pcs_nickname>>, I need you," he whispers, while breaking the kiss.'

		act 'Agree':
			*clr & cla
			huntersIgorQw += 1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterflirt2.'+rand(4,6)+'.jpg"></center>'
			'You flirt lewdly with Igor, licking your lips and winking that you''re ready for some fun. Igor, noticing your obvious signals takes you by the hand and leads you away...'
			gs 'arousal', 'foreplay', 5
			gs 'stat'
			act 'Go':gt 'hunterLoveSex','Igor'
		end
		act 'Refuse':
			*clr & cla
			minut += 5
			huntersIgorQw -= 1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/pc/speak_to_the_hand.jpg"></center>'
			'"I''m sorry, Igor. I''m not in the mood." you say avoiding eye contact. Disappointed Igor leaves...'
			act 'Go':gt $loc, $metka
		end
	end

	! communication with Sergey
	if hunters > 0 and huntersKnowSlut = 0 and ($clothingworntype ! 'nude' and $clothingworntype ! 'swimwear') and huntersSergeiQw >= 15 and swiss_army_random_number = 6 and huntersSergeiday ! daystart:
		*clr & cla
		minut += 5
		huntersSergeiday = daystart
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/sergeihanter.jpg"></center>'
		'You notice Sergei in the yard, who smiles and heads in your direction.'
		'"<<$pcs_nickname>>, let''s sit down and have a chat if you don''t mind?" he asks you a bit embarrassed.'

		act 'Agree':
			*clr & cla
			minut += 120
			hunterslut -= 1
			huntersSergeiQw += 1
			if huntersIgorQw >= 10 and huntersKnowSlut = 0:huntersIgorQw -= 2
			if huntersAndreiQw >= 10 and huntersKnowSlut = 0:huntersAndreiQw -= 2
			pcs_mood = 100
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterlove2.jpg"></center>'
			'You happily agree and the two of you spend the next two hours together chatting with each other...'

			act 'Further':gt $loc, $metka
		end
		act 'Refuse':
			*clr & cla
			minut += 5
			huntersSergeiQw -= 2
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/pc/speak_to_the_hand.jpg"></center>'
			'"No, Sergei, as I''ve told you before, I don''t want to talk to you..."'
			act 'Further':gt $loc, $metka
		end
	end
	! sex with Sergei
	if hunters > 0 and huntersSergeiLove > 0 and huntersSergeiQw >= 10 and swiss_army_random_number = 7 and huntersSergeisex = 0:
		*clr & cla
		minut += 5
		huntersSergeisex += rand(9,30)
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterlove1.4.jpg"></center>'
		'You see Sergei steping out of the hut into the yard. Smiling, he walks over and gives you a long passionate kiss.'
		'"<<$pcs_nickname>>, I want you," he said.'

		act 'Agree':
			*clr & cla
			huntersSergeiQw += 1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterflirt2.'+rand(4,6)+'.jpg"></center>'
			'You flirt lewdly with Sergei, licking your lips and winking that you''re ready for some fun. Sergei, noticing your obvious signals takes you by the hand and leads you away...'
			gs 'arousal', 'foreplay', 5
			gs 'stat'
			act 'Go':gt 'hunterLoveSex','Sergei'
		end
		act 'Refuse':
			*clr & cla
			minut += 5
			huntersSergeiQw -= 1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/pc/speak_to_the_hand.jpg"></center>'
			'"I''m sorry, Sergei. I''m not in the mood." you say avoiding eye contact. Disappointed Sergei leaves...'
			act 'Go':gt $loc, $metka
		end
	end
	! sex with Andrei
	if hunters > 0 and huntersAndreiLove > 0 and huntersAndreiQw >= 10 and swiss_army_random_number = 8 and huntersAndreisex = 0:
		*clr & cla
		huntersAndreisex += rand(6,24)
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterlove1.4.jpg"></center>'
		'You notice Andrei standing in the yard. Suddenly, he gives you a passionate kiss and without a word he drags you away with him...'
		gs 'arousal', 'foreplay', 5
		gs 'stat'
		act 'Follow Andrei':
			*clr & cla
			minut += 5
			huntersAndreiQw += 1
			pcs_horny += 5
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterhands.jpg"></center>'
			'You follow Andrei holding hands, knowing where he is about to lead you. You don''t mind you want him as bad as he wants you...'
			act 'Further':gt 'hunterLoveSex','Andrei'
		end
		act 'Refuse':
			*clr & cla
			minut += 5
			huntersAndreiQw -= 1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/pc/speak_to_the_hand.jpg"></center>'
			'"I''m sorry, Andrei. I''m not in the mood." you say avoiding eye contact. Disappointed Andrei leaves...'
			act 'Go':gt $loc, $metka
		end
	end
	! sex if GG whore
	if hunters > 0 and huntersRape = 5 and huntslutsexrand = 1 and huntslutsex = 0:
		*clr & cla
		minut += 5
		temphunt = rand(1,3)
		! the choice of who will fuck GG
		slutgosex = 1
		gs 'stat'

		if temphunt = 1:'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/andreihanter.jpg"></center>'
		if temphunt = 2:'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/sergeihanter.jpg"></center>'
		if temphunt = 3:'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/igorhanter.jpg"></center>'
		if temphunt = 1:'Andrei steps out of the hut, heading straight towards you. "<<$pcs_nickname>>, walk with me..." without uttering another word he grabs you by the arm and leads you to the nearest tree...'
		if temphunt = 2:'Sergei steps out of the hut, heading straight towards you. "<<$pcs_nickname>>, let''s go a bit aside you need to help me out with my itch," he said and lead you in the direction of the nearest thicket.'
		if temphunt = 3:'Igor steps out of the hut, heading straight towards you. "<<$pcs_nickname>>, I need you to help me with this bulge," he says pointing at his groin, leading you away from the yard...'
		if pcs_horny < 40:' You obediently follow along, well knowing the reason he wanted you to tag along.'
		if pcs_horny >= 40 and pcs_horny < 70:'"I need you to take me..." is all you manage to say while he''s leading you away.'
		if pcs_horny >= 70:'"I was hoping this would happened," you think to yourself, feeling your wet pussy pulsating with desire. You jump onto him, taking charge, leaving him stunned about who wants it more, you or him.'

		act 'Go':gt 'hunters', 'start'
	end
		
	! trio if GG whore
	if hunters > 0 and huntersRape = 5 and huntslutsexrand = 2 and huntslutsex = 0:
		*clr & cla
		minut += 5
		temphunt = rand(1,3)
		slutgosex = 2
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanterswork1.2.jpg"></center>'
!!julzor: Changed the three if''s into one if/elseif structure
		if temphunt = 1:
			'You see Andrei talking with Sergei in the yard. They notice you, and start moving towards you. "Come with us <<$pcs_nickname>>," without uttering another word Andrei grabs you by the arm and leads you to the nearest tree.... Sergei follows after.'
		elseif temphunt = 2:
			'Andrei and Igor notice you enter the yard, they call you over. "Come with us <<$pcs_nickname>>, you need to help us out with our itch," said Andrei pulling you in the direction of the nearest thicket. Igor follows behind.'
		elseif temphunt = 3:
			'You notice Igor and Sergei standing in the yard whispering something to each other. Igor approaches you and says "<<$pcs_nickname>>, "<<$pcs_nickname>>, I need you to help me with this bulge," he says pointing at his groin. He calls Sergei over and they start leading you away from the yard...'
		end
!!julzor: Changed the three if''s into one if/elseif structure
		if pcs_horny < 40: 
			'You obediently follow along, well knowing the reason they wanted you to tag along.'
		elseif pcs_horny >= 40 and pcs_horny < 70:
			'"I need you to take me..." is all you manage to say while they''re leading you away.'
		elseif pcs_horny >= 70:
			'"I was hoping this would happened," you think to yourself, feeling your wet pussy pulsating with desire. You jump onto one of them, taking charge, leaving the other one stunned about who wants it more, they or you.'
		end

		act 'Go with the guys':
			*clr & cla
			minut += 5
			pcs_horny += 5

			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/doublehanterlove.jpg"></center>'
			'You go along with the men holding their hands, knowing where they''re about to lead you. You don''t mind you want them as bad as they wants you...'
			act 'Further':gt 'huntersex', 'sluthomesex'
		end
	end
end

--- swamp_yard ---------------------------------