# lover_love

if loverlove[lover_number] = 3:
	'<<$loverdesc[lover_number]>> has hired a wedding limousine and it''s outside waiting for you. This is it, you are getting married today.'

	act 'Sit in the limousine':
		cla
		'You get into the limo, and it drives off. Soon you arrive at the wedding, <<$loverdesc[lover_number]>> is waiting for you as you walk down the aisle.'

		act 'Marry husband':
			cla
			minut += 60
			husband = 100
			husbanday = 0
			$husID = $lover[lover_number]
			$husName = $loverdesc[lover_number]
			$husHair = $loverface[lover_number]
			$husBody = $loverbod[lover_number]
			$husFat = $loverbod[lover_number]
			husDick = loverdick[lover_number]
			harakHusb = haraklover[lover_number]
			izvratH = loverizvrat[lover_number]
			silavagH = loversilaVag[lover_number]
			husbFin = loverfinance[lover_number]
			husbandMark = 1
			loverslove[lover_number] = 0
			gs 'lover', 'remove', lover_number
			'The wedding reception takes place at a cafe. There aren''t many guests since neither you nor the groom have that many friends or family members. There is a lot of congratulations, toasts, merrymaking and crying. By the evening, everybody is drunk and you and your husband stagger into a taxi, which takes you home.'

			act 'Wedding night':gt 'husbsex', 'room'
		end
	end

	exit
elseif loverlove[lover_number] = 2:
	'<<$loverdesc[lover_number]>> looks very excited and suddenly pulls a ring out of a box.'
	'<<$loverdesc[lover_number]>> says "<<$pcs_nickname>>. I offer you my hand and heart. Would you marry me?"'

	act 'No (turn him down)':
		minut += 60
		gs 'lover', 'remove', lover_number
		pregtalk = 0
		dynamic $go_home
		
	end

	act 'Yes':
		cla
		'You agree and put the ring on your finger. <<$loverdesc[lover_number]>> rejoices and happily hugs and kisses you.'
		'<<$loverdesc[lover_number]>> says "Now you need to find a wedding dress."'

		act 'Go looking for the dress':
			cla
			minut += 60
			loverlove[lover_number] = 3
			'You get into a taxi with your soon to be husband and go to the store to choose a dress. You choose an expensive and luxurious dress. <<$loverdesc[lover_number]>> pays for the purchase.'
			'After a long day you feel tired and ask <<$loverdesc[lover_number]>> to drive you home, warning him that the next time you''ll meet you will get married.'
			dynamic $go_home
		end
	end

	exit
end

if pcs_makeup > 1 and ($clothingworntype = 'expensive' or $clothingworntype = 'formal') and curly > 0 and loverlove[lover_number] = 1 and haraklover[lover_number] = 0:
	'<<$loverdesc[lover_number]>> looks very excited. He decides that you are now ready to meet his mother.'

	act 'Meet the parents':gt 'love', 'mother'

	exit
elseif pcs_makeup > 1 and ($clothingworntype = 'expensive' or $clothingworntype = 'formal') and curly > 0 and loverlove[lover_number] = 1 and haraklover[lover_number] = 1 and $pantyworntype ! 'none':
	'<<$loverdesc[lover_number]>> examins you and decides that you are ready to meet his friends.'

	act 'Meet his friends':gt 'love', 'frends'

	exit
end

--- lover_love ---------------------------------

