# LariskaHome
!2021/05/02
if $ARGS[0] = 'front_door':
	menu_off = 1
	$loc_arg = 'front_door'
	$loc = 'LariskaHome'
	$menu_loc = 'LariskaHome'
	$menu_arg = 'front_door'
	$location_type = 'indoors'
	*clr & cla
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	gs 'lariska_schedule'

	if frost > 0: frost = 0
	if lariloc['athome'] = 1:
		if week <= 5:
			'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big13.jpg"></center>'
			'You knock on Lariska''s apartment door.'
			*nl
			'Lariska answers the door. "Come in, <<$pcs_nickname>>."'
			act 'Enter the apartment':gt 'LariskaHome', 'hallway'
		else
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariskamother.jpg"></center>'
			if lariloc = 2 or lariloc = 8 or lariloc = 15 or lariloc = 22:
				$text_home = 'Lariska is in her room.'
			elseif lariloc = 3 or lariloc = 19 or lariloc = 12:
				$text_home = 'Lariska is in the kitchen.'
			elseif lariloc = 13:
				$text_home = 'Lariska is in the shower. She should be out soon.'
			elseif lariloc = 20:
				$text_home = 'Lariska is cleaning in the bathroom.'
			elseif lariloc = 14 or lariloc = 16 or lariloc = 18:
				$text_home = 'Lariska is in the living room.'
			else
				$text_home = 'Lariska is around here somewhere.'
			end
			'You knock on Lariska''s apartment door.'
			*nl
			if LariskaQW['metAnna'] = 0:
				'You knock on Lariska''s apartment door and a smart looking brunette opens the door. You look helplessly into her impressive cleavage and let out an involuntary sigh.'
				'"Hello, are you looking for Lariska?" the woman asks with a smile.'
				'"Yes, I''m <<$pcs_nickname>>." you reply tearing your eyes away from her nearly exposed breasts.'
				'"Ah, <<$pcs_nickname>>, Lariska has told me all about you. I''m Anna, Lariska''s mother. My bunny has been so joyous lately, I am so glad she has found such a good friend! She needed someone to help get her back on her feet."'
				'"<<$text_home>>"'
				LariskaQW['metAnna'] = 1
			else
				'Lariska''s mother opens the door. "Hello, <<$pcs_nickname>>. Come inside, <<$text_home>>"'
			end
			act 'Enter the apartment':gt 'LariskaHome', 'hallway'
		end
	else
		if lariloc = 9:
			$text_home = 'Lariska is at the Community Center around this time.'
		elseif lariloc = 6:
			$text_home = 'Lariska is at cheerleading practice right now.'
		elseif lariloc = 7:
			$text_home = 'Lariska is a cheerleader, so she is at the friday game.'
		elseif lariloc = 5 or lariloc = 4:
			$text_home = 'Lariska is at school right now.'
		elseif lariloc = 21:
			$text_home = 'Lariska is at the volleyball game.'
		elseif lariloc = 1:
			$text_home = 'Lariska is asleep right now. She should be up around 9am.'
		elseif lariloc = 13:
			$text_home = 'Lariska is unable to answer the door right now.'
		elseif lariloc = 15:
			$text_home = 'Lariska is in bed about this time.'
		else
			$text_home = 'I am not sure where Lariska is right now.'
		end
		if week >= 6:
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariskamother.jpg"></center>'
			if LariskaQW['metAnna'] = 0:
				'You knock on Lariska''s apartment door and a smart looking brunette opens the door. You look helplessly into her impressive cleavage and let out an involuntary sigh.'
				'"Hello, are you looking for Lariska?" the woman asks with a smile.'
				'"Yes, I''m <<$pcs_nickname>>." you reply tearing your eyes away from her nearly exposed breasts.'
				'"Ah, <<$pcs_nickname>>, Lariska has told me all about you. I''m Anna, Lariska''s mother. My bunny has been so joyous lately, I am so glad she has found such a good friend! She needed someone to help get her back on her feet."'
				'"<<$text_home>>"'
				LariskaQW['metAnna'] = 1
			else
				'Lariska''s mother opens the door. "Hello, <<$pcs_nickname>>. <<$text_home>>"'
			end
		else
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_door.jpg"></center>'
			'You knock on Lariska''s door, but nobody answers.'
			*nl
			'<<$text_home>>'
		end
		act 'Go back to town':gt'pav_residential'
	end
end

if $ARGS[0] = 'hallway':
	$loc = 'LariskaHome'
	$loc_arg = 'hallway'
	$menu_loc = 'LariskaHome'
	$menu_arg = 'hallway'
	$location_type = 'private'
	menu_off = 0
	*clr & cla
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	gs 'lariska_schedule'
	'<center><b><font color="DeepSkyBlue">Hallway</font></b></center>'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/home_1.jpg"></center>'
	'You stand in the main hallway of the japanese styled apartment. Everything looks clean, and the air smells nice.'
	if lariloc = 1 or lariloc = 2 or lariloc = 8 or lariloc = 15 or lariloc = 22:
		$text_home = 'is in her bedroom'
	elseif lariloc = 3 or lariloc = 19 or lariloc = 12 or lariloc = 11:
		$text_home = 'is in the kitchen'
	elseif lariloc = 13:
		$text_home = 'is in the shower'
	elseif lariloc = 8:
		$text_home = 'is in the bathroom, cleaning'
	elseif lariloc = 14 or lariloc = 16 or lariloc = 18:
		$text_home = 'should be in the living room'
	else
		$text_home = 'is no longer home.'
	end
	*nl
	'Lariska <<$text_home>>.'
	act 'Go back to town':gt'pav_residential'
	act 'Living Room':gt 'LariskaHome', 'livingroom'
	act 'Kitchen':gt 'LariskaHome', 'kitchen'
	act 'Bathroom':gt 'LariskaHome', 'bathroom'
	act 'Lariska''s Bedroom':gt 'LariskaHome', 'lariska_bedroom'
	if LariskaQW['metAnna'] >= 1: act 'Anna''s Bedroom':gt 'LariskaHome', 'anna_bedroom'
end

if $ARGS[0] = 'livingroom':
	$loc_arg = 'livingroom'
	$loc = 'LariskaHome'
	$menu_loc = 'LariskaHome'
	$menu_arg = 'livingroom'
	menu_off = 0
	$location_type = 'private'
	$locclass = 'livingr'
	*clr & cla
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	gs 'lariska_schedule'
	'<center><b><font color="DeepSkyBlue">Living Room</font></b></center>'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_livingroom.jpg"></center>'
	'A spacious room with a comfy looking couch and a nice tv hanging on the wall. Various plants adorn the room.'
	*nl
	if lariloc = 14:'<a href="exec: gt ''LariskaHome'', ''livingroom_tv_1''">Lariska</a> is curled up on the couch, watching tv.'
	if lariloc = 16:'<a href="exec: gt ''LariskaHome'', ''livingroom_exercise_1''">Lariska</a> is here working out.'
	if lariloc = 18:'You see <a href="exec: gt ''LariskaHome'', ''livingroom_clean_1''">Lariska</a> cleaning.'
	act 'Return to the hallway':gt 'LariskaHome', 'hallway'
end

if $ARGS[0] = 'livingroom_tv_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_tv_1.jpg"></center>'
	'You decide to join Lariska on the couch, and watch some tv with her.'
	minut += 30
	gs 'npc_relationship', 'modify', 'A13', 'like'
	pcs_mood += 20
	gs 'stat'
	act 'Continue':gt 'LariskaHome', 'livingroom'
end

if $ARGS[0] = 'livingroom_exercise_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_exercise_1.jpg"></center>'
	'You find Lariska stretching in front of her tv. Since you don''t feel like working out right now, you simply keep her company for awhile.'
	minut += 20
	gs 'npc_relationship', 'modify', 'A13', 'like'
	pcs_mood += 5
	gs 'stat'
	act 'Continue':gt 'LariskaHome', 'livingroom'
end

if $ARGS[0] = 'livingroom_clean_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_cleaning_3.jpg"></center>'
	'You find Lariska dusting and doing some general cleaning. Sitting nearby, you strike up a conversation.'
	minut += 15
	gs 'npc_relationship', 'modify', 'A13', 'like'
	pcs_mood += 5
	gs 'stat'
	act 'Continue':gt 'LariskaHome', 'livingroom'
end

if $ARGS[0] = 'kitchen':
	$loc_arg = 'kitchen'
	$loc = 'LariskaHome'
	$menu_loc = 'LariskaHome'
	$menu_arg = 'kitchen'
	menu_off = 0
	$location_type = 'private'
	$locclass = 'kitr'
	*clr & cla
	minut += 1
	gs 'stat'
	gs 'kit_din'
	gs 'themes', 'indoors'
	gs 'lariska_schedule'
	'<center><b><font color="DeepSkyBlue">Kitchen</font></b></center>'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_kitchen.jpg"></center>'
	'The kitchen in Lariska''s apartment is impressive, there are several small machines meant for cooking laid out, though you have no idea what most of them do.'
	if lariskalove >= 6:
		'Like your <<$npc_nickname[''A29'']>> does at home, somebody living here makes large batches of food, ready to eat anytime. You know you are welcome to anything in here though, so you look around, trying to decide what sounds good.'
	else
		'Like your <<$npc_nickname[''A29'']>> does at home, somebody living here makes large batches of food, ready to eat anytime. You don''t feel comfortable eating a full meal uninvited, but you know nobody will mind if you just have a snack.'
	end
	if lariloc = 3:'Have <a href="exec: gt ''LariskaHome'', ''kitchen_meal_1''">breakfast</a> with Lariska.'
	if lariloc = 11:
		if LariskaQW['story'] = 11 and week < 6 and LariskaBoyDay <= daystart:
			'<a href="exec: gt ''lariska_storyline'', ''Boyfriend_2''">Lariska</a> is cooking dinner.'
		else
			'<a href="exec: gt ''LariskaHome'', ''kitchen_cooking_1''">Lariska</a> is cooking dinner.'
		end
	end
	if lariloc = 12:'Have <a href="exec: gt ''LariskaHome'', ''kitchen_meal_1''">dinner</a> with Lariska.'
	if lariloc = 19:'<a href="exec: gt ''LariskaHome'', ''kitchen_cleaning_1''">Lariska</a> is here cleaning.'
	act 'Return to the hallway':gt 'LariskaHome', 'hallway'
	if lariskalove >= 6:
		act 'Eat a hearty meal (0:20)':gs 'food', 'l_meal'
		act 'Eat a normal meal (0:15)':gs 'food', 'm_meal'
		act 'Eat a light meal (0:10)':gs 'food', 's_meal'
	end

	dynamic $edasnack
	dynamic $sandwich
	dynamic $driwater
	dynamic $dritea
	dynamic $fill_bottle
	dynamic $edaD
	dynamic $pranik
	dynamic $fatdel
	dynamic $lekarstvo
	dynamic $vitamin
end

if $ARGS[0] = 'kitchen_meal_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_meal.jpg"></center>'
	'You grab a plate of food and join Lariska at the table. The two of you chat about random things as you eat. When you''re done you place the dishes in the sink.'
	gs 'npc_relationship', 'modify', 'A13', 'like'
	frost = 0
	minut += 20
	pcs_health += 10
	fat += 8
	pcs_energy += 60
	if pcs_hydra >= 100:
		pcs_hydra += 30
	else
		pcs_hydra += 60
	end
	cumspclnt = 2
	gs 'cum_cleanup'
	pcs_breath = 0
	pcs_mood += 25
	gs 'stat'
	act 'Finish eating':gt 'LariskaHome', 'kitchen'
end

if $ARGS[0] = 'kitchen_cooking_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_cooking_1.jpg"></center>'
	'You find Lariska in the kitchen, cooking dinner. Leaning up against the counter, you start chatting with her about random things, just passing the time.'
	minut += 10
	gs 'npc_relationship', 'modify', 'A13', 'like'
	pcs_mood += 5
	gs 'stat'
	act 'Finish the conversation':gt 'LariskaHome', 'kitchen'
end

if $ARGS[0] = 'kitchen_cleaning_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_cleaning_2.jpg"></center>'
	'You find Lariska in the kitchen, cleaning. You keep her company while she wipes down counters and mops the floor.'
	minut += 15
	gs 'npc_relationship', 'modify', 'A13', 'like'
	pcs_mood += 5
	gs 'stat'
	act 'Continue':gt 'LariskaHome', 'kitchen'
end

if $ARGS[0] = 'bathroom':
	$loc_arg = 'bathroom'
	$loc = 'LariskaHome'
	$locM = 'LariskaHome'
	$locM_arg ='bathroom'
	$menu_loc = 'LariskaHome'
	$menu_arg = 'bathroom'
	menu_off = 0
	$location_type = 'bathroom'
	$bathtype = 'bathtub shower'
	*clr & cla
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	gs 'lariska_schedule'
	'<center><b><font color="DeepSkyBlue">Bathroom</font></b></center>'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_bathroom.jpg"></center>'
	'The room is clean, and even smells like sage.'
	*nl
	'There is a shower, toilet, sink, <a href="exec:gt ''mirror'',''start''">mirror</a>, where you can ' + iif(pcs_hairbsh = 0,'<a href="exec:gt ''mirror'',''brush''">brush</a>','brush') + ' your hair, and even a separate bath tub.'
	if lariloc = 13:'Since <a href="exec: gt ''LariskaHome'', ''bathroom_join_1''">Lariska</a> didn''t lock the door, you are able to enter unnoticed. Maybe you can join her...'
	if lariloc = 20:'<a href="exec: gt ''LariskaHome'', ''bathroom_cleaning_1''">Lariska</a> is here, cleaning the bathroom.'
	act 'Return to the hallway':gt 'LariskaHome', 'hallway'
	if lariloc ! 13:
		gs 'din_van', 'private'
		gs 'din_van', 'prvt_pee'
	end
end

if $ARGS[0] = 'bathroom_cleaning_1':
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_cleaning_1.jpg"></center>'
	'Leaning up against wall, you have short conversation with Lariska while she cleans.'
	minut += 15
	gs 'npc_relationship', 'modify', 'A13', 'like'
	pcs_mood += 5
	gs 'stat'
	act 'Continue':gt 'LariskaHome', 'bathroom'
end

if $ARGS[0] = 'bathroom_join_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/school/gym/shower/watchlar.jpg"></center>'
	if lariskalove >= 6:
		'You take a minute to watch Lariska. She still hasn''t seen you yet, so you could leave without her knowing you were even there.'
		'Where would the fun be in that though.'
		gs 'arousal', 'voyeur', 3, 'lesbian'
		gs 'stat'
		act 'Tear yourself away and leave the room':
			gs 'arousal', 'end'
			gt 'LariskaHome', 'hallway'
		end
		act 'Join her':gt 'LariskaHome', 'bathroom_join_2'
	else
		'You take a minute to watch Lariska, but know you need to break down a few more barriers between you two before you attempt to join her.'
		gs 'arousal', 'voyeur', 3, 'lesbian'
		gs 'stat'
		act 'Tear yourself away and leave the room':
			gs 'arousal', 'end'
			gt 'LariskaHome', 'hallway'
		end
	end
end

if $ARGS[0] = 'bathroom_join_2':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_shower_2.jpg"></center>'
	'You quickly strip your clothing off, and gently tap on the shower door. Startled, she turns to see you standing there, before smiling shyly and opening the door for you.'
	
	act 'Finish the shower':
		noShampoo = 1
		dynamic $showerdin
		minut += 15
		pcs_horny += 10
		pcs_hairbsh = 1
		pcs_makeup = 1
		if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the shower.'
		gs 'arousal', 'erotic_nudity', -8, 'lesbian'
		gs 'stat'
		gs 'arousal', 'end'
		gt 'LariskaHome', 'bathroom'
	end
	if lariskalove >= 9:
		act 'Offer to wash her back':
			gs 'arousal', 'massage_give', -8, 'lesbian'
			gt 'LariskaHome', 'bathroom_join_3'
		end
	end
end

if $ARGS[0] = 'bathroom_join_3':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_shower_3.jpg"></center>'
	'Doesn''t take long before long before washing her back leads to kissing her neck. She turns and wraps her arms around you, and kisses your lips. You tease each other for awhile, taking your time.'
	'Pulling back she smiles sweetly at you and goes to her knees in front of you. She starts by kissing your feet softly, keeping her eyes locked on yours as she slowly works her way up your legs.'
	minut += 10
	pcs_horny += 10
	gs 'arousal', 'kiss', -8, 'lesbian'
	gs 'stat'
	act 'Spread your legs':
		*clr & cla
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_shower_4.jpg"></center>'
		'She kisses and licks her way up your thighs until she reaches your honeypot. Still going slowly, she licks your outer lips for a bit, before spreading them with her fingers and starts licking your inner lips.'
		'Throwing your head back, you thrust your hips against her face, as she works her way in until she is fucking you with her tongue. Waves of pleasure are flowing through you, an orgasm is not far away.'
		minut += 10
		pcs_horny += 10
		$orgasm_or = 'yes'
		gs 'arousal', 'cuni', -8, 'lesbian'
		gs 'stat'
		gs 'arousal', 'end'
		'As your body comes down from its high, she stands back up and kisses you some more. You taste yourself on her lips, you taste great! Eventually you break away to continue the shower.'
		act 'Finish your shower':
			noShampoo = 1
			dynamic $showerdin
			minut += 5
			pcs_horny += 10
			pcs_hairbsh = 1
			pcs_makeup = 1
			if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the shower.'
			gs 'stat'
			gt 'LariskaHome', 'bathroom'
		end
	end
end

if $ARGS[0] = 'anna_bedroom':
	$loc = 'LariskaHome'
	$loc_arg = 'anna_bedroom'
	$location_type = 'private'
	$locclass = 'bedr'
	$menu_loc = 'LariskaHome'
	$menu_arg = 'anna_bedroom'
	menu_off = 0
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	gs 'lariska_schedule'
	*clr & cla
	'<center><b><font color="DeepSkyBlue">Anna''s Bedroom</font></b></center>'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_mom_bedroom.jpg"></center>'
	'The japanese styled bedroom is clean and orderly. You see an extra door off to one side.'
	'There is not much for you to do here at this time.'
	act 'Return to the hallway':gt 'LariskaHome', 'hallway'
	act 'Go into the side room':
		'This door seems to big to be a closet, but it is locked right now.'
		act 'Continue':gt 'LariskaHome', 'anna_bedroom'
	end
end

if $ARGS[0] = 'bdsm_room':
	$loc = 'LariskaHome'
	$loc_arg = 'bdsm_room'
	$location_type = 'private'
	$menu_loc = 'LariskaHome'
	$menu_arg = 'bdsm_room'
	menu_off = 0
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	gs 'lariska_schedule'
	*clr & cla
	'<center><b><font color="DeepSkyBlue">BDSM Room</font></b></center>'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/home_2.jpg"></center>'
	'This room is full of all kinds of scary looking equipment.'
	'Until you get to know Anna better, you shouldn''t mess with anything here.'
	act 'Leave the room':gt 'LariskaHome', 'anna_bedroom'
end

if $ARGS[0] = 'lariska_bedroom':
	$loc = 'LariskaHome'
	$loc_arg = 'lariska_bedroom'
	$location_type = 'private'
	$locclass = 'bedr'
	$menu_loc = 'LariskaHome'
	$menu_arg = 'lariska_bedroom'
	menu_off = 0
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	gs 'lariska_schedule'
	*clr & cla
	'<center><b><font color="DeepSkyBlue">Lariska''s Bedroom</font></b></center>'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_bedroom.jpg"></center>'
	'The bedroom has hints of japanese style, although not as overwhelming as the rest of the apartment. Against the wall is a <a href="exec:gt ''wardrobe'', ''start''">wardrobe</a> where you can choose outfits and organise your clothing.'
	if lariskalove >= 12:
		'Her <a href="exec:gt ''bed2''">bed</a> sits directly on the floor, without space underneath.'
	else
		'Her bed sits directly on the floor, without space underneath.'
	end
	'<table><tr><td valign="top">Your <a href="exec:gt ''budilnik'', ''start''">phone alarm</a> is set to <b>'+iif(timer < 10,'0<<timer>>','<<timer>>')+':'+iif(timerM < 10,'0<<timerM>>','<<timerM>>')+'</b> during the week and <b>'+iif(timerEnd < 10,'0<<timerEnd>>','<<timerEnd>>')+':'+iif(timerEndM < 10,'0<<timerEndM>>','<<timerEndM>>')+'</b> during the weekend. It is currently turned '+iif(budilnikOn = 0, '<a href="exec: budilnikOn = 1 & gt $loc">OFF</a>.', '<a href="exec: budilnikOn = 0 & gt $loc">ON</a>.')
	*nl
	if lariloc = 1:'<a href="exec:gt ''LariskaHome'', ''lariska_asleep_1''">Lariska</a> is sound asleep, curled up and wrapped in blankets.'
	if lariloc = 2:'<a href="exec:gt ''LariskaHome'', ''lariska_dressing_1''">Lariska</a> is getting dressed right now.'
	if lariloc = 8:'Lariska is doing on her school work.'
	if lariloc = 15:'<a href="exec:gt ''LariskaHome'', ''lariska_reading_1''">Lariska</a> is reading in bed.'
	if lariloc = 17:'<a href="exec:gt ''LariskaHome'', ''lariska_cleaning_1''">Lariska</a> is here cleaning.'
	if lariloc = 22:'Lariska is here, doing various things.'
	if lariloc = 9:gt 'LariskaHome', 'community_center_invite'
	act 'Return to the hallway':gt 'LariskaHome', 'hallway'
	if lariloc = 2 or lariloc = 8 or lariloc = 22 or lariloc = 15 or lariloc = 17:
		act 'Chat with Lariska': gt 'LariskaHome', 'chat'
	end
	if lernHome > 0:
		act 'Do homework':gt 'LariskaHome','homework'
	end
	if lariskaTrain > 5 and LariskaQW['volleyball'] = 0 and (lariloc = 8 or (lariloc = 22 and hour < 16 and week <= 5)):
		act 'Talk to Lariska about becoming a pro volleyball player':
			cls
			minut += 5
			gs'stat'
			'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big13.jpg"></center>'
			'You decided to talk to Lariska about joining the professional volleyball team.'
			'"Lariska, you are an excellent volleyball player. Coach Mikheil Nikolayevich has a professional team, why don''t you ask to join it?" you ask your friend.'
			'"Well, I guess I''m afraid he''ll tell me I''m not good enough. I''ve seen him tell other good players they aren''t good enough to play for him."'
			if pcs_vball < 60 and volleysostav < 2:
				act 'Drop the subject':gt 'LariskaHome','lariska_bedroom'
				act 'Tell her you''ll go with her for support.':lariskaTrenerTalk = 1 & minut += 15 & gt 'Voltrener', 'start'
			elseif pcs_vball >= 60 and volleysostav = 1:
				act 'Drop the subject':gt 'LariskaHome','lariska_bedroom'
				act 'Tell her you''ll go with her for support.':lariskaTrenerTalk = 2 & minut += 15 & gt 'Voltrener', 'start'
			elseif pcs_vball >= 60 and volleysostav = 0:
				act 'Drop the subject':gt 'LariskaHome','lariska_bedroom'
				act 'Tell her that you should both try to get on the team.':lariskaTrenerTalk = 3 & minut += 15 & gt 'Voltrener', 'start'
			elseif volleysostav >= 2:
				act 'Drop the subject':gt 'LariskaHome','lariska_bedroom'
				act 'Tell her you''ll go with her and since you''re already on the team, you can help convince the coach.':lariskaTrenerTalk = 4 & minut += 15 & gt 'Voltrener', 'start'
			else
				act 'Drop the subject':gt 'LariskaHome','lariska_bedroom'
				act 'Tell her you''ll go with her for support.':lariskaTrenerTalk = 1 & minut += 15 & gt 'Voltrener', 'start'
			end
		end
	end
	if lariskaroomfun ! daystart and LariskaQW['story'] >= 8 and npc_rel['A13'] >= 80 and (lariloc = 2 or lariloc = 8 or lariloc = 22 or lariloc = 15 or lariloc = 17):
		act 'Flirt with her':
			*clr & cla
			menu_off = 1
			if LariskaQW['story'] = 8: LariskaQW['story'] = 9
			lariskaroomfun = daystart
			pcs_horny += 5
			gs 'stat'
			'<center><video autoplay loop  src="images/characters/pavlovsk/school/girl/lariska/sex/home/kiss_1.mp4"></center>'
			'You slide closer to her so your legs are touching and gently place your left hand on her shoulder.'
			*nl
			if lariskalove = 0:
				'Startled, her body stiffens up and she refuses to look anywhere but straight down. After what you did to Christina, she knows she is no match for you and is probably terrified of having traded one Mistress for another. You take your time, slowly running your hand across her back until she calms down a bit and suprisingly leans against you, still looking down. You reach across with your right hand and place it on top of hers and start softly running your fingers across it. You do this for a few minutes before she finally looks up and leans her face in, a happy look in her eye. Tilting your head to one side a bit, you close the distance left between your lips until they touch. She shivers a bit in pleasure, obviously not used to such a gentle touch, before pulling away, her face bright red.'
				gs 'npc_relationship', 'modify', 'A13', 'like'
				lariskalove = 1
				gs 'arousal', 'kiss', 3, 'lesbian'
				gs 'stat'
			elseif lariskalove <= 5:
				'She reacts better this time, cuddling up against you with a shy smile on her face. You let your left hand trail its way down her back until you reach her hips, then slide it around her waist. The two of you sit like that for a few minutes, enjoying each other company and the closeness it''s bringing. Eventually she sits up a bit, cheeks blushed, and puts her face next to yours, obviously hoping for another kiss. You lean the rest of the way in until your lips touch hers. The kiss lasts longer than the first time, by the time she pulls back you are both a little breathless. Suddenly she seems to realize what the two of you were just doing and gets nervous, standing up she starts moving around the room trying to come to terms with the feelings racing through her. Wisely, you decide to give her space for now.'
				gs 'npc_relationship', 'modify', 'A13', 'like'
				lariskalove += 1
				gs 'arousal', 'kiss', 5, 'lesbian'
				gs 'stat'
			else 
				'No longer shy around you, she wraps her hands around your waist and starts kissing you. You move your left hand down to the top of her butt while putting your right on her stomach and start rubbing in circular motions. You slowly start leaning back, pulling her with you until you are both laying on your sides, and her tongue slips between your lips and starts playing with yours. You feel her left hand slide down from your waist and starts rubbing your butt before working its way down from there to your thigh. Hooking her hand around it, she pulls your leg up and over her own before going back to massaging your butt again. Eventually she pulls back from your tongue fight, face flushed a deep red and panting from lack of breath. She gives you a long, hungry look, telling you without words she wants, no, NEEDS, to keep going.'
				gs 'npc_relationship', 'modify', 'A13', 'like'
				lariskalove += 1
				if LariskaQW['story'] = 9: LariskaQW['story'] = 10
				gs 'arousal', 'kiss', 5, 'foreplay','lesbian'
				gs 'stat'
			end
			if lariskalove >= 6:
				act 'Go further': gt 'LariskaSex', 'undressed1'
			end
			act 'Stop for now':
				gs 'arousal', 'end'
				gt 'LariskaHome','lariska_bedroom'
			end
		end
	end
end

if $ARGS[0] = 'lariska_asleep_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_sleeping_1.jpg"></center>'
	'She is fast asleep in her bed, uncovered and nude. You cannot stop yourself from staring at her for a few minutes, before ripping your eyes away and deciding what you should do next.'
	gs 'npc_relationship', 'modify', 'A13', 'like'
	minut += 10
	gs'stat'
	act 'Move away from the bed':gt 'LariskaHome', 'lariska_bedroom'
end

if $ARGS[0] = 'lariska_dressing_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_dressing_1.jpg"></center>'
	'She blushes a bit when she realizes you are looking at her, but does not stop. You just sit and watch, while chatting with her.'
	gs 'npc_relationship', 'modify', 'A13', 'like'
	minut += 10
	gs'stat'
	act 'Finish this conversation':gt 'LariskaHome', 'lariska_bedroom'
end

if $ARGS[0] = 'lariska_cleaning_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_cleaning_1.jpg"></center>'
	'Sitting on the bed, you have short conversation with Lariska while she cleans.'
	gs 'npc_relationship', 'modify', 'A13', 'like'
	minut += 15
	gs'stat'
	act 'Finish this conversation':gt 'LariskaHome', 'lariska_bedroom'
end

if $ARGS[0] = 'lariska_reading_1':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/lariska/lariska_reading_1.jpg"></center>'
	'You lay next to her, your bodies pressed together, and chat aimlessly with her while she keeps reading.'
	gs 'npc_relationship', 'modify', 'A13', 'like'
	minut += 20
	gs'stat'
	act 'Finish this conversation':gt 'LariskaHome', 'lariska_bedroom'
end

if $ARGS[0] = 'homework':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big13.jpg"></center>'
	gs 'npc_relationship', 'modify', 'A13', 'like'
	if LariskaQW['story'] = 6: LariskaQW['story'] = 7
	gs 'grades', 'homework', 'school', 'yes', 1, 1, 'A13'
	lern += 1
	minut += 30
	gs'stat'
	if class['school_grade_average'] >= 80:
		'You did your homework with Lariska and figured out the hard parts together.'
	else
		'You did your homework together and Lariska explained the hard parts to you.'
	end
	act 'Finish up': gt 'LariskaHome','lariska_bedroom'
end

if $ARGS[0] = 'chat':
	menu_off = 1
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big13.jpg"></center>'
	gs 'npc_relationship', 'modify', 'A13', 'like'
	minut += 10
	gs'stat'
	if LariskaQW['story'] = 7:
		gt 'lariska_storyline', 'GettingToKnow'
	elseif LariskaQW['story'] = 10:
		gt 'lariska_storyline', 'Boyfriend_1'
	elseif LariskaQW['story'] = 13 and LariskaBoyDay <= daystart:
		gt 'lariska_storyline', 'Boyfriend_4'
	elseif LariskaQW['story'] = 15:
		gt 'lariska_storyline', 'Boyfriend_6'
	elseif LariskaQW['story'] = 16 and LariskaBoyDay <= daystart:
		gt 'lariska_storyline', 'Boyfriend_7'
	elseif LariskaQW['story'] = 17 and LariskaBoyDay <= daystart:
		gt 'lariska_storyline', 'Boyfriend_8'
	elseif LariskaQW['story'] = 18 and LariskaBoyDay <= daystart:
		gt 'lariska_storyline', 'Boyfriend_9'
	else
		'You spend some time chatting with Lariska about whatever comes to mind.'
		act 'Finish this conversation':gt 'LariskaHome', 'lariska_bedroom'
	end
end

if $ARGS[0] = 'community_center_invite':
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big13.jpg"></center>'
	'Lariska looks at her watch and says, "It''s time to go to the sports club."'
	act 'Say goodbye and leave':gt'pav_residential'
	act 'Go with Lariska':
		if lariskaTrain < 6 and LariskaQW['volleyball'] = 0: lariskaTrain += 1
		minut += 10
		gt 'gdksport', 'start'
	end
end

--- LariskaHome ---------------------------------

