# lakecafe
!!Eugene model = Jessy Dubai
if $ARGS[0] = 'main':
	$loc_arg = 'main'
	$loc = 'lakecafe'
	$menu_loc = 'lakecafe'
	$menu_arg = 'main'
	menu_off = 0
	$location_type = 'public_indoors'
	*clr & cla
	barrnd = rand(1, 3)
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><B><font color=maroon>The Lake Cafe</font></B></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/bbq/lakecafe.jpg"></center>'
	'An old-fashioned BBQ café/diner near the lake, known for offering relatively cheap but tasty meals.'
	'Opening hours are from 14:00 until 04:00'
	*nl

	act 'Leave the cafe': minut += 2 & gt 'city_industrial'

	if hour >= 14 or hour < 4:
		if npc_QW['A89'] = 0:
			if barrnd = 1:'You see a smiling <a href="exec:gt ''lakecafe'', ''barmensha''">barmaid</a> behind the bar polishing some glasses.'
			if barrnd = 2:'When you walk into the diner, you see a smiling <a href="exec:gt ''lakecafe'', ''barmensha''">barmaid</a> picking up some dirty dishes and cleaning a table.'
			if barrnd = 3:'You see a smiling <a href="exec:gt ''lakecafe'', ''barmensha''">barmaid</a> behind the bar skilfully making some drinks.'
		elseif npc_QW['A89'] => 1:
			if barrnd = 1:'You see <a href="exec:gt ''lakecafe'', ''barmensha''">Eugene</a> behind the bar with that perpetual smile on her face. She''s currently polishing some glasses.'
			if barrnd = 2:'You walk into the diner and see <a href="exec:gt ''lakecafe'', ''barmensha''">Eugene</a> with that perpetual smile on her face collecting dirty dishes from tables.'
			if barrnd = 3:'You see <a href="exec:gt ''lakecafe'', ''barmensha''">Eugene</a> behind the bar with that perpetual smile on her face. She''s skilfully mixing some drinks.'
		end

		if week = 1 and hour = 22:
			LCWorkRand = rand(1,6)
			if LCWorkRand = 1:
				randguycafe = rand(3, 6)
				if LCwork = 0:'A group of men are seated at one of the tables. They''re talking loudly and laughing while having drinks.'
				if LCwork = 1:'<a href="exec:gt ''LCwork'', ''start1''"><<randguycafe>> men</a> are seated at one of the tables. They''re talking loudly and laughing while having drinks.'
			elseif LCWorkRand = 2:
				if LCwork = 0:'An older man is sitting at one of the tables, enjoying his meal.'
				if LCwork = 1:'<a href="exec:gt ''LCwork'', ''start2''">An older man</a> is sitting at one of the tables, enjoying his meal.'
			elseif LCWorkRand = 3:
				if LCwork = 0:'Two guys are sitting at one of the tables in a corner. They''ve clearly had a few drinks already.'
				if LCwork = 1:'<a href="exec:gt ''LCwork'', ''start3''">Two men</a> are sitting at one of the tables. They''ve clearly had a few drinks already.'
			elseif LCWorkRand = 4:
				if LCwork = 0:'A fairly young couple are seated at one of the tables having a lively discussion. The girl seems a bit embarrassed about something, while the guy exudes confidence.'
				if LCwork = 1:'<a href="exec:gt ''LCwork'', ''start4''">A fairly young couple</a> are seated at one of the tables having a lively discussion. The girl seems a bit embarrassed about something, while the guy exudes confidence.'
			elseif LCWorkRand = 5:
				if LCwork = 0:'A woman sits by herself at one of the tables, enjoying a nice meal.'
				if LCwork = 1:'<a href="exec:gt ''LCwork'', ''start5''">A woman</a> sits by herself at one of the tables, enjoying a nice meal.'
			elseif LCWorkRand = 6:
				if LCwork = 0:'A fat man is sitting at one of the tables. He''s loudly talking on his phone, receiving a few disgruntled looks from other diners.'
				if LCwork = 1:'<a href="exec:gt ''LCwork'', ''start6''">A fat man</a> is sitting at one of the tables. He''s loudly talking on his phone, receiving a few disgruntled looks from other diners.'
			end
		end

		if hour => 23: 'Several <a href="exec:gt ''lakecafe'',''bandits''">shady looking men</a> are sitting around a small table in a fairly secluded corner of the diner. They talk in hushed voices amongst each another, and look like they might very well be criminals.'
	
		'The diner has a single <a href="exec:gt ''laketoilet'', ''main''">toilet</a> available, for both males and females.'

		act 'Order from the menu (0:05)':gs 'food_menu'
		if money >= 350:
			act 'Order take-out (0:20) (350 <b>₽</b>)':money -= 350 & gt 'food', 'f_food'
		end
	end

	if LCwork2 >= 1 and LCwork2day ! daystart and hour = 18: 
		act 'Help out in the kitchen': gt 'lakecafe', 'Kitchen'
	end
end

if $ARGS[0] = 'barmensha':
	menu_off = 1
	$location_type = 'event'
	*clr & cla
	gs 'stat'
	if npc_QW['A89'] > 0:
		'<center><B><font color=maroon>Barmaid Eugene</font></B></center>'
		'<center><img <<$set_imgh>> src="images/locations/city/industrial/bbq/lakebarmensha.jpg"></center>'
		if npc_rel['A89'] < 20:
			'You have a bad relationship with Eugene.'
		elseif npc_rel['A89'] < 40:
			'You have cold relations with Eugene.'
		elseif npc_rel['A89'] < 60:
			'You have a normal relationship with Eugene.'
		elseif npc_rel['A89'] < 80:
			'You have a good relationship with Eugene.'
		else
			'You have an excellent relationship with Eugene.'
		end
	else
		'<center><B><font color=maroon>Barmaid</font></B></center>'
		'<center><img <<$set_imgh>> src="images/locations/city/industrial/bbq/lakebarmensha.jpg"></center>'
	end
	if npc_QW['A89'] = 0:
		'The barmaid gives you a warm smile as she looks you straight in the eyes. "Hi there! Can I get you anything?"'
	elseif npc_QW['A89'] => 1:
		'Eugene smiles as she sees you approach the bar and cheerfully greets you. "Hi <<$pcs_nickname>>! What''s up?"'
	end
	act 'Leave Eugene so she can work':gt 'lakecafe', 'main'
	if hour >= 14 or hour < 4:
		if npc_QW['A89'] = 0:
			act 'Chat with the barmaid':
				*clr & cla
				npc_QW['A89'] = 1
				npc_rel['A89'] = 20
				minut += 30
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/industrial/bbq/lakebarmensha.jpg"></center>'
				'You spend some time chatting with the barmaid. She''s very open, and you learn a lot about her.'
				'Her name is Eugene, and she works here with her sister, Angela, who is a chef in the kitchen. They both work every day of the week, and wouldn''t have it any other way.'
				act 'Continue':gt 'lakecafe', 'barmensha'
			end
		end
		if npc_QW['A89'] => 1:
			act 'Chat with Eugene':
				*clr & cla
				npc_rel['A89'] += 1
				minut += 30
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/industrial/bbq/lakebarmensha.jpg"></center>'
				if npc_rel['A89'] < 10:
					'Eugene glares at you. "I have nothing to say to you."'
				elseif npc_rel['A89'] < 40 and LCEugenefirst = 0:
					'You spend some time chatting with Eugene, getting to know her a little bit better. You chat about all sorts of things; your lives, work and current events.'
				elseif lakepater[0] > 0:
					'You spend time discussing family with Eugene.'
				else
					if rand(1,5) = 1 and LCEugenefirst > 0 and eugene_randy ! daystart:
						eugene_randy = daystart
						*clr & cla
						'Eugene smiles at you with a glimmer in her eye. You can see her clothing slightly bulging, making you think her cock is hard.'
						if LCknowslut > 0:
							'She grabs your hand and starts to lead you to the back room.'
							act 'Resist':
								*clr & cla
								'<center><img <<$set_imgh>> src="images/pc/reactions/no.jpg"></center>'
								'"No!" you shout in resistance.'
								'She seems disappointed as she lets go of your hand.'
								'"We both know what kind of girl you are, <<$pcs_nickname>>. Don''t pretend you aren''t."'
								act 'Resist':
									*clr & cla
									npc_rel['A89'] -= 5
									'<center><img <<$set_imgh>> src="images/pc/reactions/no.jpg"></center>'
									'"I said no!" you fiercely reply.'
									'She seems annoyed with you. "What? Suddenly I''m not good enough for you? Or do I need to pay for it? Never mind, just go."'
									act 'Continue':gt 'lakecafe', 'barmensha'
								end
								act 'Relent':
									*clr & cla
									npc_rel['A89'] += 1
									'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big89.jpg"></center>'
									'You sigh. "Okay, fine."'
									'She smiles and takes you by the hand. "Don''t worry, you won''t regret this."'
									act 'Go with her': gt 'eugeneev1', 'sex'
								end
							end
							act 'Agree':
								*clr & cla
								npc_rel['A89'] += 1
								'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big89.jpg"></center>'
								'You smile at her. "Sounds good to me."'
								'She smiles and leads you into the back.'
								act 'Go with her': gt 'eugeneev1', 'sex'
							end
						else
							'"I seem to have a growing problem, <<$pcs_nickname>>. Could you help me out?"'
							act 'Not today':
								*clr & cla
								npc_rel['A89'] -= 1
								'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big89.jpg"></center>'
								'You shake your head. "Maybe another day. I''m just not in the mood today." you reply.'
								'She lets go of your hand. "Okay, I understand. Maybe some other time." She goes back to work, but you can tell she is disappointed.'
								act 'Continue':gt 'lakecafe', 'barmensha'
							end
							act 'Of course':
								*clr & cla
								npc_rel['A89'] += 1
								'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big89.jpg"></center>'
								'She smiles when you nod. "Okay, how about you follow me and we have some fun?" she says as she grabs your hand and leads you out to the back room.'
								gt 'eugeneev1', 'sex'
							end
						end
					else
						'You spend time chatting with Eugene. You chat about all sorts of things; your lives, work and current events.'
						if portfolio_people[6] ! 1 and LCEugenefirst > 0:
							gs 'camera', 'check_person', 'eugene'
							act 'Don''t ask': gt 'lakecafe', 'barmensha'
						end
					end
				end
				act 'Continue':gt 'lakecafe', 'barmensha'
			end
		end
		if npc_rel['A89'] >= 40:
			act 'Flirt with Eugene':
				*clr & cla
				npc_rel['A89'] += 3
				minut += 10
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/industrial/bbq/lakebarmensha.jpg"></center>'
				if npc_rel['A89'] >= 60:
					'You flirt with Eugene as you chat, tossing in as many double innuendos as you can.'
					'After a few minutes, she smiles wolfishly at you. "You want me, don''t you?"'
					'She smiles when you nod. "How about you follow me out back and we have some fun?"'
					'You nod and follow Eugene, feeling your heart pound in your chest as you stare at her ass.'
					act 'Follow her':
						if LCEugenefirst = 0:gt 'eugeneev1', 'firsttime'
						if LCEugenefirst = 1:gt 'eugeneev1', 'sex'
					end
				else
					'You flirt with Eugene as you chat, tossing in as many double innuendos as you can.'
					'She flirts back a little, but it''s hard to tell if she''s just being friendly or not. She''s not given you a strong indication one way or the other yet.'
					act 'Continue':gt 'lakecafe', 'barmensha'
				end
			end
		end
		if npc_rel['A89'] >= 35:
			act 'Ask about work':
				*clr & cla
				'<center><img <<$set_imgh>> src="images/locations/city/industrial/bbq/lakebarmensha.jpg"></center>'
				if LCworkwork2 < 1:
					'"I''m looking for a job. Would you happen to know about anything?" you ask Eugene with a smile.'
					'She ponders for a second before answering. "Actually, my sister always complains about how busy she is in the kitchen during the early evening hours. If you come between 18:00 and 19:00, you could probably help her out for a bit. We''d pay you 300 <b>₽</b> for your troubles!"'
					'You smile at and thank her, saying you''ll keep it in mind.'
					LCworkwork2 = 1
					LCwork2 = 1
					act 'Continue':
						minut += 4
						gt 'lakecafe', 'barmensha'
					end
				else
					'When you ask Eugene about a job, she laughs. "Did you forget <<$pcs_nickname>>? I already told you that my sister could use some help in the kitchen! If you come between 18:00 and 19:00, you can help her out for a bit and we''ll pay you 300 <b>₽</b> for your time."'
					act 'Thank her for the reminder':
						minut += 4
						gt 'lakecafe', 'barmensha'
					end
				end
			end
		end
		if npc_rel['A89'] >= 80 and LCworkwork < 2:
			act 'Ask about the special work':
				*clr & cla
				'<center><img <<$set_imgh>> src="images/locations/city/industrial/bbq/lakebarmensha.jpg"></center>'
				if LCworkwork = 0:
					'You pull Eugene aside during a slow moment. "I''ve overheard some of the customers talking fondly about a ''special'' service this diner has. What''s that all about?"'
					if npc_love['A89'] > 80:
						'Eugene blushes. "That''s something some of the girls do here. It would hurt me to see you doing that though."'
					elseif npc_love['A89'] > 60:
						'Eugene blushes. "That''s something some of the girls do here. I don''t think you should do it, <<$pcs_nickname>>."'
						act 'Press for more information':
							*clr & cla
							'You press for more information, but Eugene seems to be hurt by your insistance. She begs you not to ask any more.'
							act 'Refuse to relent':
								*clr & cla
								npc_love['A89'] -= 5
								gs 'npc_relationship', 'modify', 'A89', -20
								'You refuse to relent and Eugene sighs. "All our regulars know that we ''arrange meetings'' every Monday between 22:00 and 23:00. If you''re here at that time and want to earn some money, introduce yourself to the person or group you want to service and say ''I''ll be your waitress tonight.'' They''ll know what it means, but I beg you, please don''t do it <<$pcs_nickname>>!"'
								'You see tears forming in her eyes.'
								gs 'willpower', 'misc', 'self', 'easy'
								if will_cost <= pcs_willpwr:
									act 'Say you won''t do it (<<will_cost>> Willpower)':
										*clr & cla
										gs 'willpower', 'pay', 'self'
										gs 'stat'
										'Eugene seems relieved as she looks back at you.'
										'"Thank you, <<$pcs_nickname>>. I don''t know what I would do if you were doing that..."'
										act 'Continue':
											*clr & cla
											LCworkwork = 2
											LCwork = 0
											minut += 4
											gt 'lakecafe', 'barmensha'
										end
									end
								else
									act 'Say you won''t do it (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
								end	
								act 'Walk away':
									*clr & cla
									npc_love['A89'] -= 30
									npc_rel['A89'] -= 40
									LCworkwork = 1
									LCwork = 1
									minut += 4
									gt 'lakecafe', 'main'
								end
							end
						end
					elseif npc_love['A89'] > 30:
						'Eugene blushes. "That''s something some of the girls do here, but it''s not something I would like to see you doing, <<$pcs_nickname>>."'
						act 'Press for more information':
							*clr & cla
							'You press Eugene for more information and Eugene seems to be hurt by your insistance, but she reluctantly relents.'
							'"All our regulars know that we ''arrange meetings'' every Monday between 22:00 and 23:00. If you''re here at that time and want to earn some money, introduce yourself to the person or group you want to service and say ''I''ll be your waitress tonight.'' They''ll know what it means. From what the girls told me, they get paid between 500 and 1,000 <b>₽</b>."'
							'Before you leave, she adds "Please don''t do it though. I''m starting to care for you and..." She looks away from you before finishing her sentence.'
							gs 'willpower', 'misc', 'self', 'easy'
							if will_cost <= pcs_willpwr:
								act 'Say you won''t do it (<<will_cost>> Willpower)':
									*clr & cla
									gs 'willpower', 'pay', 'self'
									gs 'stat'
									'Eugene seems relieved as she looks back at you.'
									'"Thank you, <<$pcs_nickname>>. I don''t know what I would do if you were doing that..."'
									act 'Continue':
										*clr & cla
										LCworkwork = 2
										LCwork = 0
										minut += 4
										gt 'lakecafe', 'barmensha'
									end
								end
							else
								act 'Say you won''t do it (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
							end	
							act 'Walk away':
								*clr & cla
								npc_love['A89'] -= 5
								gs 'npc_relationship', 'modify', 'A89', -20
								LCworkwork = 1
								LCwork = 1
								minut += 4
								gt 'lakecafe', 'main'
							end
						end
					else
						if LCknowslut = 0:
							'Eugene ponders for a minute before deciding that she can trust you. "We... we do offer special services, once a week. It''s every Monday, at 22:00. I''m not sure it''s something you would be interested in though..."'
							'She confesses when she sees the confusion on your face. "It''s... it''s borderline prostitution, really. Some of the girls working here earn some extra money on the side by offering themselves to our customers after work. It happened sporadically at first, but then it became so popular that we organize a weekly event now. Customers can hook up with our waitresses, and our waitresses can earn some extra cash if they want. Everybody wins... right?"'
							act 'Ask for more information':
								*clr & cla
								'Eugene notices the spark in your eye and laughs. "I see you might be interested after all!"'
								'You play it cool. "Maybe. But just in case I were, how does it work?"'
								'She gives you a kind smile. "I trust you, so... okay. I''ll let you do it if you want. Like I said, all our regulars know that we ''arrange meetings'' every Monday between 22:00 and 23:00. If you''re here at that time and want to earn some money, introduce yourself to the person or group you want to service and say ''I''ll be your waitress tonight.'' They''ll know what it means. From what the girls told me, they get paid between 500 and 1,000 <b>₽</b>."'
								'Before you leave, she adds "Keep in mind that the diner is just a meeting area; whatever happens when you leave with someone is between you and them! Don''t embarrass us though, we''d hate to lose regular customers, no matter how perverted they might be!" She added the last bit with a laugh and a wink.'
								act 'Say you''ll think about it':
									*clr & cla
									LCworkwork = 1
									LCwork = 1
									minut += 4
									gt 'lakecafe', 'barmensha'
								end
							end
						else
							'Eugene smiles at you. "This is something right up your alley"'
							'All our regulars know that we ''arrange meetings'' every Monday between 22:00 and 23:00. If you''re here at that time and want to earn some money, introduce yourself to the person or group you want to service and say: ''I''ll be your waitress tonight.'' They''ll know what it means. From what the girls told me, they get paid between 500 and 2,000 <b>₽</b>."'
							'Before you leave, she adds "Keep in mind that the diner is just a meeting area; whatever happens when you leave with someone is between you and them! Don''t embarrass us though, we''d hate to lose regular customers, no matter how perverted they might be."'
							act 'Thank her for the information':
								*clr & cla
								LCworkwork = 1
								LCwork = 1
								minut += 4
								gt 'lakecafe', 'barmensha'
							end
						end
					end
				elseif LCworkwork = 1:
					if LCknowslut = 1 and npc_love['A89'] > 30:
						'Eugene glares at you.'
						'"Did you come to brag about how much of a slut you are, <<$pcs_firstname>>? If you want to whore yourself out, come here on Monday night between 22:00 and 23:00 and show the men here what kind of a person you are. Just don''t lose us any customers."'
						'She turns around and walks away from you.'
						npc_love['A89'] = -5
						act 'Continue':
							minut += 3
							gt 'lakecafe', 'barmensha'
						end
					else
						'"So you''re still interested in that, huh?" she smirks when you mention the special work. "Like I said, our regulars know that we ''arrange meetings'' every Monday between 22:00 and 23:00. If you''re here at that time and want to earn some money using your body, introduce yourself to the person or group you want to service and say ''I''ll be your waitress tonight.'' They''ll know what it means. From what the girls told me, they get paid between 500 and 1,000 <b>₽</b>."'
						act 'Thank her for the reminder':
							minut += 3
							gt 'lakecafe', 'barmensha'
						end
					end
				end
			end
		end
	end
end

if $ARGS[0] = 'Kitchen':
	cla
	*clr
	minut += 180
	LCwork2 += 1
	money += 300
	LCwork2day = daystart
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/bbq/kitchenworkcafe.jpg"></center>'
	'Eugene gives you a warm smile. "That would be great, thanks!" She then hands you a hat and an apron to wear while you work. Once you put them on, you get to work.'
	if rand(1,5) = 1 and LCEugenefirst > 0 and eugene_randy ! daystart:
		eugene_randy = daystart
		*clr & cla
		'Angela leaves as you''re in the middle of chopping vegetables. A few seconds later, Eugene comes in and walks up behind you, leaning against your back. You can feel her breasts against your back and her stiff cock against your ass.'
		'"I seem to have a growing problem, <<$pcs_nickname>>. Could you help me out?"'
		act 'Not today':
			*clr & cla
			npc_rel['A89'] -= 1
			'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big89.jpg"></center>'
			'You shake your head. "Maybe another day. I''m just not in the mood today." you reply.'
			'She lets go of your hand. "Okay, I understand. Maybe some other time." She goes back to work, but you can tell she is disappointed.'
			act 'Continue':
				'You spend the rest of the time washing dishes, cleaning the floors and chopping vegetables. When you''re finished, Eugene gives you your well-earned 300 <b>₽</b>.'
				act 'Finish work': gt 'lakecafe', 'main'
			end
		end
		act 'Follow her into a back room':
			*clr & cla
			npc_rel['A89'] += 1
			'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big89.jpg"></center>'
			'She smiles when you nod. "Okay, how about you follow me and we have some fun?" she says as she grabs your hand and leads you out to the back room.'
			npc_horny['A89'] = 49
			gt 'eugeneev1', 'sex_work'
		end
	else
		'You spend the next three hours washing dishes, cleaning the floors and chopping vegetables. When you''re finished, Eugene gives you your well-earned 300 <b>₽</b>.'
		act 'Finish work': gt 'lakecafe', 'main'
	end
end

if $ARGS[0] = 'bandits':
	menu_off = 1
	*clr & cla
	gs'stat'
	'<center><B><font color=maroon>Criminals</font></B></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/industrial/bbq/bandits.jpg"></center>'
	'A group of tough men, clearly very different from the other visitors this diner usually gets, sit around the table. Their dark clothes and threatening demeanor leave no doubt in your mind: these men are criminals. Fairly well organized, and probably dangerous criminals.'
	'You overheard that they loan people money with abysmal terms. They demand 20% interest, and give you 7 days to repay the debt. Several girls who were unable to repay their debts have disappeared.'
	''
	if workDolg > 0:
		'One of them notices you and says "Hey, you! You know you owe us <B><<workDolg>></B> <b>₽</b>? We want it back, and soon!"'
	else
		'"Are you lost, girl? Fuck off!" one of them grunts menacingly.'
	end
	act 'Leave them alone':gt'lakecafe', 'main'
	act 'Ask to borrow money':
		intinp = input ("How much money do you want to borrow?")
		if intinp <= 0:
			'"You want to borrow... no money? Quit wasting our time!" one of them shouts, rather annoyed at your inability to choose an amount.'
		elseif intinp > 2000000:
			'"Do we look like the National Bank, girl? Don''t be ridiculous!" one of them scoffs.'
		elseif intinp > 0 and intinp <= 2000000:
			*clr & cla
			money += intinp
			workDolg += intinp + (intinp/100)*20
			workDolgDay = 7
			'One of them extends his hand out at you. "Passport. Now."'
			'With your passport in his hand, he makes a few quick phone calls. He writes some stuff down before handing you your passport back, along with your money.'
			'"Listen up, <<$pcs_firstname>> <<$pcs_lastname>>," he grunts. "You have <<workDolgDay>> days to pay back the <<intinp>> <b>₽</b>, plus <<(intinp/100)*20>> <b>₽</b> in interest."'
			'When you nod, he grabs your wrist roughly. "<i>Don''t</i> screw us over! I know everything about you, and I <i>will</i> get my money back, one way or the other..."'
			act 'Promise you''ll pay and leave':gt'lakecafe', 'main'
		end
	end
	if workDolg > 0:
		*clr & cla
		act 'Move away':gt'lakecafe', 'main'
		act 'Promise you''ll pay him on time':
			'"I''ll pay you back on time! I swear!" you plead.'
			'"Talk is cheap, <<$pcs_firstname>> <<$pcs_lastname>>. You have <<workDolgDay>> days, don''t forget!" he shrugs, and turns back to his associates.'
		end
	end
	if workDolg > 0 and money >= workDolg:
		act 'Pay back your debt (<<workDolg>> <b>₽</b>)':
			*clr & cla
			minut += 5
			workDisk = 0
			money -= workDolg
			workDolg = 0
			gs'stat'
			'You pay back the money you owe the criminals. The man who gave you the money seems surprised, but quickly pockets the money.'
			'"Excellent, I knew I could trust you! Pleasure doing business!" he grins, even though it''s fairly obvious he''s lying through his teeth.'
			act 'Leave them alone':gt'lakecafe', 'main'
		end
	end

	if workDolgDay <= 0 and workDolg > 0:
		*clr & cla
		gs 'stat'
		workDisk = 0
		'<center><img <<$set_imgh>> src="images/locations/city/residential/street/bug.jpg"></center>'
		'When two very broad men approach you, you can''t help but notice the distinct outline of pistols underneath their clothes.'
		'They look at you with disdain, and one of them says "You. It''s time you repay your debt."'
		if money >= workDolg:
			money -= workDolg
			workDolg = 0
			'You give the man the amount of money you owe, and he counts it meticulously before he nods to his colleague. "It''s all there."'
			'The other man already had his gun in his hand and reluctantly puts it away. "I guess you''re off the hook, for now. Consider yourself lucky!" he says in a menacing tone.'
			act 'Watch them leave': gt 'lakecafe', 'main'
		else
			if (money + stolmoney + karta) >= workDolg:
				money += stolmoney+karta
				stolmoney = 0
				karta = 0
				money -= workDolg
				workDolg = 0
				'You don''t have the full amount on you, but you tell them that you have the rest at home. "Oh really? Very original! We''re coming with you! I''m not letting you out of my sight for even one second until your debt is paid!" one of the men grunts.'
				'The men follow you to your home, and wait impatiently while you collect the money you owe them. When you produce the full amount, they actually seem a bit surprised.'
				'"Huh. I guess you weren''t lying after all," one says after counting it twice. "Consider your debt paid, miss. Pleasure doing business."'
				act 'Close the door behind them': gt $home_entrance, 'start'
			else
				money += stolmoney + karta
				stolmoney = 0
				karta = 0
				workDolg -= money
				money = 0
				workDolg += 10000
				'"I... I don''t have the money, I''m sorry!" you tell the guys, who roughly grab you by the shoulders the moment you confess.'
				'"Oh, you will be sorry!" one laughs at you. They walk to your apartment with you between them, never even asking for directions.'
				'Once you arrive, one of the men searches your house, piling up all the money you do have, while the other holds you at gunpoint.'
				'"Still not enough, huh?" the man holding you the gun mutters as the other finishes his search. "So, here''s what''s gonna happen. Since you can''t pay your debt and we have to go through all this trouble getting it back, consider your debt increased by another 10,000 <b>₽</b>. Don''t you worry your pretty little head, though. We''re going to give you an alternative way to pay it off."'
				'"Ha! That pretty face will come in handy there!" the other laughs.'
				'Without explaining further, they drag you to a car outside your apartment and throw you into the back seat. About half an hour later, the car pulls over and one of the men tells you to get out. You''re at a sauna building in the city.'
				act 'Get out of the car':
					*clr & cla
					minut += 30
					gs'stat'
					'After one of the criminals makes sure the coast is clear, the two of them pull you out of the car and escort you to a room inside the sauna building. One leaves the room as the other explains your situation. "Until you pay off your debt, we own you! You''ll live and work here until you''ve paid off every last ruble. Any expenses you incur while you are here will be added to your debt. Understood?"'
					'Silence fills the room as he waits for you to acknowledge what he just said. Mortified about what might happen if you don''t, you nod. He decides to paint the picture anyway. "If you try to escape or refuse to work, we''ll put a bullet in your head, chop you up and bury you in the woods in pieces! And that would be a waste, with a pretty face such as yours."'
					'He pinches your cheek and then slaps your face. After looking you in the eyes for a few more seconds to make sure you get the message, he turns around and leaves. You''re all alone now...'
					act 'Look around':gt 'city_sauna', 'saunaroom'
				end
			end
		end
	end
end

--- lakecafe ---------------------------------

