# shulgahome
!============================!
!----FAMILY HUT Shulgin----!
!============================!

CLOSE ALL
$metka = ''
$loc = 'shulgahome'
$location_type = 'event'
!Vasily/Shulga''s dynamic name is randomly chosen in "gopsex"
gs 'stat'
 
!appeal to Sergei Shulgin
if npc_rel['A112'] < 30:$serg_obr = ' uncle' else $serg_obr = ''

'You''re at the door to the Shulgin apartment.'
!Entry conditions:
if week < 6 and hour >= 10 and hour < 16:
	'When you ring the doorbell, no one comes to answer the door. Apparently both '+func('gopsex','hide','Shulga_var_name')+' and Sergey are not at home.'
	if npc_rel['A112'] >=70: 'You could still enter with the key that Sergey gave you.' & act 'Unlock the door and enter':gt 'shulgahall'
elseif hour >= 16 and hour <= 23:
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/serge/serge2.jpg"></center>'
	'When you ring the doorbell,<<$serg_obr>> Sergey comes to answer the door.'
	'"Oh, hello <<$pcs_nickname>>", he shrugs. "If you''re looking for Vasily: he''s not here, and I don''t know when he''ll be back."'
	if npc_rel['A112'] >=30: 'He offers: "You can come in anyway, if you want?"' & act 'Enter':gt 'shulgahall'
elseif hour >= 2 and hour < 5:
	'You move your hand to ring the bell, but stop yourself. It''s too late to go visit them, you''d wake everyone up!'
	if npc_rel['A112'] >=70: 'You could use the key that Sergey gave you to enter the apartment quietly.' & act 'Unlock the door and enter':gt 'shulgahall'
elseif hour >= 5 and hour < 10:
	'You move your hand to ring the bell, but stop yourself. It''s too early, they won''t be out of bed yet.'
	if npc_rel['A112'] >=70: 'You could use the key that Sergey gave you to enter the apartment quietly.' & act 'Unlock the door and enter':gt 'shulgahall'
else
	'The door is opened by '+func('gopsex','hide','Shulga_var_name')+' and you are invited in.' & act 'Enter':gt 'shulgahall'
end

act 'Leave':minut += 1 & gt'pod_ezd','etaj_3'

--- shulgahome ---------------------------------

