glife/locations/intro_city.qsrc

# intro_city

gs 'themes', 'indoors'

if $ARGS[0] = 'start':
	$loc = 'intro_city'
	$loc_arg = '2'
	!! Intro to starting city
	!!variables for apartment living
	pcs_hairlng = 100
	*clr & cla
	!!pic of apartment or Gazelle?
	'The big day has finally arrived! Your family piled into your stepfather''s Gazelle pickup and you all traveled from your hometown, Pavlovsk, to St. Petersburg. Today is the day you move into your own apartment and start this new phase of your life.'
	'You think back to your school days and what kind of student you were...'

	if $start_type['magic'] = 'tg':
		act 'Continue': gt 'intro_city', '2'
	else
		act 'Continue': gt 'intro_city_select', 'start'
	end
end

if $ARGS[0] = '2':
!!	Just hair and eye color here for now; the dialog will be update as more options are added
	'<center><b><font color = maroon>CHARACTER CUSTOMIZATION</font></b></center>'
	'<center><b>Allows you to alter hair and eyes, use to match fixed profile picture if in use.</b></center>'
	'<center><img <<$set_imgh>> src="images/system/1_openings/shared/character_creation_2.jpg"></center>'
	'As you look in the mirror, your face comes into focus. While some aspects of your appearance are already set, you can define the others now.'
	'You are fairly tall.'
	*nl
	'<center>Customize your:</center>'
	'<center><a href="exec:gs ''intro_customization'', ''hair''"><img src="images/system/1_openings/shared/icon_hair.png"></a> <a href="exec:gs ''intro_customization'', ''eyes''"><img src="images/system/1_openings/shared/icon_eye.png"></a></center>'
	
	act 'Done': gt 'intro_city', 'vlad_intro'
end

if $ARGS[0] = 'vlad_intro':
	gs 'npc_relationship', 'default_family_friends'
	gs 'intro_initialization'
	gs'stat'
	!! Intro to your stepfather
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big28.jpg"></center>'
	!!basic desc of Vlad, maybe a preset is used somewhere in game already? If not already in the intro (I think it is.)
	'Having spent almost an hour in the cramped truck, you jump out as soon as you arrive. Vladimir gets out and stretches before heading to the back of the Gazelle to start unloading your stuff.'

	act 'Check Kolka': gt 'intro_city', 'kolka_intro'
end

if $ARGS[0] = 'kolka_intro':
	!! Intro to Kolka
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big34.jpg"></center>'
	!!basic desc of Kolka, maybe a preset is used somewhere in game already? If not already in the intro (I think it is.)
	'Your brother, caught up in the excitement of seeing the city, tries to slide past Vladimir unnoticed, but is called back to help unload. He sighs and shuffles his feet before turning around to help.'
	'Giving him an encouraging smile, you thank him for helping. Your effort pays off, his chest puffing out as he starts to help his father.'

	act 'Head inside': gt 'intro_city', 'anya_intro'
end

if $ARGS[0] = 'anya_intro':
	!! Intro to Anya
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big33.jpg"></center>'
	!!basic desc of Anya, maybe a preset is used somewhere in game already? If not already in the intro (I think it is.)
	'Your sister comes up to you, links her arm with yours, and pulls you forward. "Come on, <<$pcs_nickname>>! I want to see this place."'
	'Already knowing the answer, you ask anyway. "Why don''t you have your own apartment then?"'
	'"I''m comfortable where I am right now. When I''m ready, maybe I will."'
	'Rolling your eyes, you let her keep pulling on your arm.'

	act 'Enter the apartment': gt 'intro_city', 'apartment_intro'
end

if $ARGS[0] = 'apartment_intro':
	$temp_nickname = input('<center>What name do you address your mother by?<br>Mother (default), Mum, Mom, Mama, etc.</center>')
	if $temp_nickname ! '':$npc_nickname['A29'] = '<<$temp_nickname>>'
	killvar '$temp_nickname'

	!! Intro to apartment
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/city/residential/apartment/home/korr.jpg"></center>'
	'Once inside you look around, already trying to decide where things should go. Anya sees this, and laughing, drags you through each room to check them out.'
	'By the time you''re done, Kolka and Vladimir have started bringing boxes in. "Your <<$npc_nickname[''A29'']>> is staying outside to keep an eye on your stuff. I don''t think she likes the neighborhood much," he says with a shrug.'
	'You and Anya pick up the boxes they set down and take them to the rooms they were labeled for while your brother and stepfather bring it all inside.'

	act 'Greet <<$npc_nickname[''A29'']>>': gt 'intro_city', 'mom_intro'
end

if $ARGS[0] = 'mom_intro':
	!! Intro to Mom - answer sets relationship level
	*clr & cla
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big29.jpg"></center>'
	'Your <<$npc_nickname[''A29'']>> finally comes inside, carrying food she made ahead of time for everyone.'
	'"<<$pcs_nickname>>, this is a pretty rough neighborhood. You need to be really careful of those boys outside. The sooner university starts and you can get out of here, the better. I don''t know why you couldn''t just wait until summer ended to move to the city."'
	act 'Tell her what she wants to hear':
		gs 'npc_relationship', 'set', 'A29', 50
		*clr & cla
		'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big29.jpg"></center>'
		'"Everything will be fine, <<$npc_nickname[''A29'']>>. I''ll look into university prices and decide then."'
		'She gives you a hug before going to the kitchen to start preparing lunch.'

		act 'Have lunch': gt 'intro_city', 'lunch_break'
	end
	act 'Snap at her':
		gs 'npc_relationship', 'set', 'A29', 30
		*clr & cla
		'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big29.jpg"></center>'
		'"Just stop <<$npc_nickname[''A29'']>>! I''m an adult now, and I''ll do whatever I want with whoever I want!"'
		'Her eyes flash in anger, but she doesn''t say anything. She then heads into the kitchen to prepare lunch.'

		act 'Have lunch': gt 'intro_city', 'lunch_break'
	end
	act 'Appreciate her concern':
		gs 'npc_relationship', 'set', 'A29', 70
		*clr & cla
		'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big29.jpg"></center>'
		'"I know, don''t worry so much <<$npc_nickname[''A29'']>>. I''ll be very careful, I promise. It''s only for a few months."'
		'She gives you a hug before going to the kitchen to prepare lunch.'

		act 'Have lunch': gt 'intro_city', 'lunch_break'
	end
end

if $ARGS[0] = 'lunch_break':
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/dinnerhome.jpg"></center>'
	if npc_rel['A29'] >= 60:
		'<<$npc_nickname[''A29'']>> hands you a plate with a big smile as you all sit down at your kitchen table.'
	elseif npc_rel['A29'] <= 30:
		'Lunch is a little tense at first, but everyone is used to you and your <<$npc_nickname[''A29'']>> fighting.'
	else
		'<<$npc_nickname[''A29'']>> hands out plates of food as you all sit down at your kitchen table.'
	end
	'Before long, you''re all laughing and joking with each other as you eat. You''re still looking forward to being on your own, but you know times like this will become pretty rare once they head home.'
	'Once everyone is finished and <<$npc_nickname[''A29'']>> clears up, they all prepare to say goodbye.'

	act 'Say goodbye to your family': gt 'intro_city', 'family_goodbye'
end

if $ARGS[0] = 'family_goodbye':
	!! Say goodbye to your family
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/city/residential/apartment/home/korr.jpg"></center>'
	'Anya gives a hug and congratulates you on getting your own place. Your brother gives you an awkward hug and whispers to text him what it''s like living on your own.'
	'Vladimir then comes over and hugs you too, telling you how proud he is to be your stepfather and to call if you need anything.'
	if npc_rel['A29'] >= 60:
		'Your <<$npc_nickname[''A29'']>> finishes what she''s doing and comes over, tears in her eyes. Wrapping you in a hug, she again reminds you to stay away from the boys outside before joining the rest of the family by the door.'
	elseif npc_rel['A29'] <= 30:
		'Your <<$npc_nickname[''A29'']>> finishes what she''s doing and gives you an awkward hug, apologising for fighting with you before joining the rest of the family by the door.'
	else
		'Your <<$npc_nickname[''A29'']>> finishes what she''s doing and comes over and gives you a hug, again reminding you to stay away from the boys outside before joining the rest of the family by the door.'
	end
	*nl
	'They all wave and head out, leaving you alone for the first time. You spend some time unpacking your stuff before you stop and stretch, deciding you can finish later.'

	if $start_type['magic'] = 'nomagic':
		act 'Continue': gt 'intro_city', 'welcome_intro'
	elseif $start_type['magic'] = 'tg':
		act 'Continue': gt 'intro_city_tg', 'welcome_intro'
	else
		act 'Continue': gt 'intro_city_m', 'welcome_intro'
	end
end

if $ARGS[0] = 'welcome_intro':
	gs 'intro_initialization_city'
	!! Welcome to Girl Life speech
	showstat 1
	showobjs 1
	gs 'obj_din', 'old'
	*clr & cla
	'<center><img <<$set_imgh>> src="images/system/1_openings/5_city/city_start.jpg"></center>'
	'Welcome to Girl Life. You are finally free of your parents and ready to face all the freedoms and challenges that entails. Your options are nearly unlimited and now it''s time to go out and discover them all.'
	'Don''t forget to enroll in university during August if that''s a goal you want to pursue.'

	act 'Start the game': gt 'korr'
end


--- intro_city ---------------------------------