# begin

if $ARGS[0] = 'start':
	$metka = 'start'
	$loc = 'begin'
	gs 'Cheatmenu_din'
	showstat 1
	'<center><b><font color="maroon">CHOOSE GAME START</font></b></center>'
	*nl
	'<b>Transformation Start:</b>'
	'You are Mikhail Kuznetsov, a fairly average, 35 year old businessman who finds an artefact that changes everything about him and his life. Features magic.'
	*nl
	'<b>Schoolgirl Start:</b>'
	'You are a schoolgirl in the most lustful town in Russia. Will you study hard and keep your purity for that special someone or become a sex addicted whore? Or anything in between, the possibilities are endless. No magic.'
	*nl
	'<b>Cursed Schoolgirl Start:</b>'
	'Marvel as we recklessly squish both of the above into one start. You are a schoolgirl who finds the amulet and not much changes, except the magic, actually that''s quite a big change.'
	*nl
	'<b>Cursed Schoolboy Start:</b>'
	'You are Peter Ivanov, a fairly average teenage boy who, while trying to escape a bad situation, ends up in the body of a schoolgirl. Now you have to deal with a new body, new desires, and your new life in the most lustful town in Russia. Features magic.'
	*nl
	'<b>New in Town Start:</b>'
	'You''re controlled by your overbearing mother and can''t take it any more. It is time to find a new life in the city away from her influence. For the first time you can make your own decisions and mistakes. No magic.'
	
	act '<center><b>Transformation Start</b></center>':
		settingmode = 0
		showstat 0
		cla
		act '<center>Show intro (recommended)</center>':
			gt 'preSYS', 'TGStart'
		end
		act '<center>Skip intro (seen it before)</center>':
			tgs_skipinto = 1
			gt 'preSYS', 'TGStart'
		end
	end

	act '<center><b>Schoolgirl Start</b></center>':
		cla
		settingmode = 0
		showstat 0
		MagikDostup = 1
		gt 'preSYS', 'SGStart'
		
	end

	act '<center><b>Cursed Schoolgirl Start</b></center>':
		cla
		settingmode = 0
		showstat 0
		altQS = 1
		gt 'preSYS', 'SGStart'
	end
	
	act '<center><b>Cursed Schoolboy Start</b></center>':
		cla
		settingmode = 0
		showstat 0
		altQS = 1
		csb_start = 1
		gt 'preSYS', 'CSBStart'
	end

	act '<center><b>New in Town Start</b></center>':
		cla
		settingmode = 0
		showstat 0
		MagikDostup = 1
		gt 'preSYS', 'TGStart'
	end
	act '<center><b>Change game settings</b></center>': settingmode = 1 & gs '$menu_setting'
end

if $ARGS[0] = 'warning':
	'<center><b><font color = maroon>WARNING</font></b></center>'
	'<center><img <<$set_imgh>> src="images/system/gl3.jpg" ></center>'
	*nl
	'This game contains, but is not limited to the following:'
	'Pornographic images;'
	'Desriptions of sexual acts;'
	'Rape;'
	'Incest;'
	'Violent assaults;'
	'Backmail for sex;'
	'Drug use;'
	'Extreme character weight (both very skinny and massively obese);'
	'Urination as sexual fetish;'
	'Underage sex 15 - 17 years old (in the text, sexual images used only contain performers 18+ years old);'
	'Theft;'
	'Drug use;'
	'Prostitution;'
	'BDSM;'
	'Kidnap;'
	'Death;'
	'Alcohol abuse.'
	*nl
	'If any of these things upset you or you are under the age of 18 you must not continue.'
	*nl
	'Although many of these things are illegal in various places around the world this is a work of fiction and there are no people actually harmed in the making of this game.'
	'Exhausted and frustrated by the code for sure but no bruises above the neck or below the elbow.'
	'This means that with the exception of rather vague laws in Russia playing this game is not breaking any laws relating to the acts depicted.'
	'Your local laws might be different to those we have checked and if you are worried you should not continue without checking your legal position.'
	
	act 'Continue': gt 'begin','real_character'
end
	
if $ARGS[0] = 'real_character':
	cls
	'<center><b><font color = maroon>CHARACTER SELECTION</font></b></center>'
	'<center><img <<$set_imgh>> src="images/pre/shared/character_creation.jpeg"></center>'
	*nl
	'This game offers you the ability to create your own character.'
	'To do this, replace the image "avatar" in the "images" folder of the game with a file of the same name and format JPEG (.jpg). That''s it!'
	'Please note, this choice can only be changed in the cheat menu and in-game changes to hair color, length etc. will not affect the displayed image if you are using a custom one.'
	'This function is made solely to simplify things for those that want to use a custom image without having to sort through hundreds of pictures.'
	'Your selected image is your own personal choice, and is based on your personal preferences. By default, the game uses an avatar image from the site wikimedia.org.'

	*NL 'If you are playing with Quest player for Android, click '
	if Enable_Android = 1:
	   *P '<a href="exec:Enable_Android = 0 & gt ''begin'',''real_character''">Here</a> (Current: <B>Yes</B>)'
	else
	   *P '<a href="exec:Enable_Android = 1 & gt ''begin'',''real_character''">Here</a> (Current: <B>No</B>)'
	end

	act'<center><b>Start a standard character</b></center>':
		cls
		gt 'begin', 'start'
	end
	act'<center><b>Use the avatar system</b></center>':
		cls
		player_avatar = 1
		pcs_eyecol = 1
		pcs_eyesize = 2
		pcs_lashes = 1
		pcs_haircol = 1
		pcs_hairlng = 81
		pcs_lip = 2
		if birthyear = 0: birthyear = 1998
		if birthmonth = 0: birthmonth = 4
		if birthday = 0: birthday = 1
		gt 'begin', 'description_real_character'
	end
end

if $ARGS[0] = 'description_real_character':
	gs 'begin', 'hair'
	gs 'begin', 'lip'
	gs 'begin', 'eyes'
	if birthyear = 0: birthyear = 1998
	if birthmonth = 0: birthmonth = 4
	if birthday = 0: birthday = 1
	cls
	'<center><b><font color = maroon>CHARACTER CUSTOMIZATION</font></b></center>'
	'<center><img HEIGHT = 478 src="images/avatar.jpg"></center>'
	*nl
	'<center>On this screen, you may adjust your character''s description to match your avatar. Please note, at present, hair color and glasses choice may be overridden by the personality choice you make during the game intro.</center>'
	*nl
	'<center>Customize your:</center>'
	!'<center>Your name is <B><i><<$pcs_nickname>> <<$pcs_lastname>></B></i>. (You may change this during the intro, and also at the passport office in-game.)'
	'<center><a href="exec:gs ''begin'', ''hair''"><img src="images/pre/shared/hair icon.png"></a> <a href="exec:gs ''begin'', ''eyes''"><img src="images/pre/shared/eye icon.png"></a> <a href="exec:gs ''begin'', ''lip''"><img src="images/pre/shared/lip icon.png"></a> <a href="exec:gs ''begin'', ''birthday''"><img src="images/pre/shared/birthday icon.png"></a></center>'

	act'<center><b>Done</b></center>': gt 'begin', 'start'
end

if $ARGS[0] = 'hair':
	cls
	'<center><b><font color = maroon>CHARACTER CUSTOMIZATION</font></b></center>'
	'<center><img HEIGHT = 478 src="images/avatar.jpg"></center>'
	*nl
	if pcs_hairlng <= 1:
		$hair = 'You have <a href="exec:pcs_hairlng = 31 & gs ''begin'', ''hair''">very short</a>,'
	elseif pcs_hairlng <= 31:
		$hair = 'You have <a href="exec:pcs_hairlng = 81 & gs ''begin'', ''hair''">short</a>,'
	elseif pcs_hairlng <= 81:
		$hair = 'You have <a href="exec:pcs_hairlng = 161 & gs ''begin'', ''hair''">chin length</a>,'
	elseif pcs_hairlng <= 161:
		$hair = 'You have <a href="exec:pcs_hairlng = 261 & gs ''begin'', ''hair''">shoulder length</a>,'
	elseif pcs_hairlng <= 261:
		$hair = 'You have <a href="exec:pcs_hairlng = 401 & gs ''begin'', ''hair''">breast length</a>,'
	elseif pcs_hairlng <= 401:
		$hair = 'You have <a href="exec:pcs_hairlng = 601 & gs ''begin'', ''hair''">back length</a>,'
	elseif pcs_hairlng <= 601:
		$hair = 'You have <a href="exec:pcs_hairlng = 801 & gs ''begin'', ''hair''">hip length</a>,'
	elseif pcs_hairlng <= 801:
		$hair = 'You have <a href="exec:pcs_hairlng = 1001 & gs ''begin'', ''hair''">ass length</a>,'
	else
		$hair = 'You have <a href="exec:pcs_hairlng = 1 & gs ''begin'', ''hair''">extremely long</a>,'
	end

	if pcs_haircol = 0 and curly <= 0:$hair += ' <a href="exec:defcurly = 1 & curly = 2147483647 & gs ''begin'', ''hair''">straight</a>, <a href="exec:gs ''begin'', ''pcs_haircol'' & gs ''begin'', ''hair''">black</a> hair.'& $hair2 = 'black hair' & $hair3 = 'black hair'
	if pcs_haircol = 1 and curly <= 0:$hair += ' <a href="exec:defcurly = 1 & curly = 2147483647 & gs ''begin'', ''hair''">straight</a>, <a href="exec:gs ''begin'', ''pcs_haircol'' & gs ''begin'', ''hair''">brown</a> hair.'& $hair2 = 'brown hair' & $hair3 = 'brown hair'
	if pcs_haircol = 2 and curly <= 0:$hair += ' <a href="exec:defcurly = 1 & curly = 2147483647 & gs ''begin'', ''hair''">straight</a>, <a href="exec:gs ''begin'', ''pcs_haircol'' & gs ''begin'', ''hair''">red</a> hair.'& $hair2 = 'Red hair' & $hair3 = 'red hair'
	if pcs_haircol = 3 and curly <= 0:$hair += ' <a href="exec:defcurly = 1 & curly = 2147483647 & gs ''begin'', ''hair''">straight</a>, <a href="exec:gs ''begin'', ''pcs_haircol'' & gs ''begin'', ''hair''">blonde</a> hair.'& $hair2 = 'blond hair' & $hair3 = 'blond hair'
	if pcs_haircol = 0 and curly > 0:$hair += ' <a href="exec:defcurly = 0 & curly = 0 & gs ''begin'', ''hair''">curly</a>, <a href="exec:gs ''begin'', ''pcs_haircol'' & gs ''begin'', ''hair''">black</a> hair.'& $hair2 = 'curls' & $hair3 = 'black curls'
	if pcs_haircol = 1 and curly > 0:$hair += ' <a href="exec:defcurly = 0 & curly = 0 & gs ''begin'', ''hair''">curly</a>, <a href="exec:gs ''begin'', ''pcs_haircol'' & gs ''begin'', ''hair''">brown</a> hair.'& $hair2 = 'curls' & $hair3 = 'brown curls'
	if pcs_haircol = 2 and curly > 0:$hair += ' <a href="exec:defcurly = 0 & curly = 0 & gs ''begin'', ''hair''">curly</a>, <a href="exec:gs ''begin'', ''pcs_haircol'' & gs ''begin'', ''hair''">red</a> hair.'& $hair2 = 'curls' & $hair3 = 'red hair'
	if pcs_haircol = 3 and curly > 0:$hair += ' <a href="exec:defcurly = 0 & curly = 0 & gs ''begin'', ''hair''">curly</a>, <a href="exec:gs ''begin'', ''pcs_haircol'' & gs ''begin'', ''hair''">blonde</a> hair.' &$hair2 = 'curls' & $hair3 = 'blond curls'
	'<center>Adjust your hair to match your avatar. Please note that, at present, hair choices are overridden by your starting personality choice (e.g. volleyball players will always have straight blond hair).</center>'
	*nl
	nathcol = pcs_haircol
	if player_avatar = 1:
		if avatar_hair = 1:
			'<center>Please note that this choice is given only once and you will not be able to change it without starting a new game!</center>'
			'<center>You have <i><<$av_hair>>.</i> <a href="exec:avatar_hair = 0 & gs ''begin'', ''hair''">Revert to default</a>.</center>'
		else
			'<center><i><<$hair>></i> You may also <a href="exec:gs ''begin'', ''hair_input'' & gs ''begin'', ''hair''">manually enter a description</a></center>.'
		end
	end
	if $start_type = 'sgs':
		act'<center><b>Done</b></center>': gt 'preCUST', 'SGStart'
	else
		act'<center><b>Done</b></center>': gt 'begin', 'description_real_character'
	end
end

if $ARGS[0] = 'pcs_haircol':
	pcs_haircol += 1
	if pcs_haircol > 3: pcs_haircol = 0
end

if $ARGS[0] = 'hair_input':
	avatar_hair = 1
	$av_hair = input("Enter a description of your hair:")
end

if $ARGS[0] = 'lip':
	cls
	'<center><b><font color = maroon>CHARACTER CUSTOMIZATION</font></b></center>'
	'<center><img HEIGHT = 478 src="images/avatar.jpg"></center>'
	*nl
	if pcs_lip = 0:$pcs_lip = 'you have thin<<$pcs_lipbalm>> lips.' & $liptalk = 'thin lips' & $liptalk2 = 'thin lips' & $liptalk3 = 'thin lips'
	if pcs_lip = 1:$pcs_lip = 'You have normal<<$pcs_lipbalm>> lips.' & $liptalk = 'soft lips' & $liptalk2 = 'delicate lips' & $liptalk3 = 'tender lips'
	if pcs_lip = 2:$pcs_lip = 'You have plump<<$pcs_lipbalm>> lips.' & $liptalk = 'plump lips' & $liptalk2 = 'plump lips' & $liptalk3 = 'plump lips'
	if pcs_lip = 3:$pcs_lip = 'You have large,<<$pcs_lipbalm>> full lips.' & $liptalk = 'full lips' & $liptalk2 = 'plump lips' & $liptalk3 = 'full lips'
	if pcs_lip = 4:$pcs_lip = 'You have huge, thick<<$pcs_lipbalm>> lips.' & $liptalk = 'thick lips' & $liptalk2 = 'thick lips' & $liptalk3 = 'thick lips'
	'<center>Adjust the size of your lips to match your <a href="exec:view''images/avatar.jpg''">image</a>:</center>'
	*nl
	'<center><i><<$pcs_lip>></i></center>'
	*nl
	if pcs_lip < 4:'<center><a href="exec:pcs_lip += 1 & gs ''begin'', ''lip''">Bigger lips</a></center>'
	if pcs_lip > 0:'<center><a href="exec:pcs_lip -= 1 & gs ''begin'', ''lip''">Smaller lips</a></center>'
	act'<center><b>Done</b></center>': gt'begin','description_real_character'
end

if $ARGS[0] = 'eyes':
	cls
	'<center><b><font color = maroon>CHARACTER CUSTOMIZATION</font></b></center>'
	if player_avatar = 1:
		'<center><img HEIGHT = 478 src="images/avatar.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="<<FUNC(''$face_image'')>>"></center>'
	end
	*nl
	if pcs_eyecol = 0:$pcs_eyecol = 'brown' & $glacol2 = 'brown'
	if pcs_eyecol = 1:$pcs_eyecol = 'gray' & $glacol2 = 'gray'
	if pcs_eyecol = 2:$pcs_eyecol = 'green' & $glacol2 = 'green'
	if pcs_eyecol = 3:$pcs_eyecol = 'blue' & $glacol2 = 'blue'
	if glass <= 0:$glass = '' & glassvnesh = 0
	if glass = 1:$glass = ' You wear silly glasses in a cheap frame.' & glassvnesh = 10
	if pcs_lashes > 2:pcs_lashes = 2
	if pcs_lashes = 0:$pcs_lashes = 'with short eyelashes'
	if pcs_lashes = 1:$pcs_lashes = 'with normal eyelashes'
	if pcs_lashes = 2:$pcs_lashes = 'with long eyelashes'
	if pcs_eyesize > 3:pcs_eyesize = 3
	if pcs_eyesize = 0:$glaza = 'You have small <a href="exec:gs ''begin'', ''eye color'' & gs ''begin'', ''eyes''"><<$pcs_eyecol>></a> eyes, <<$pcs_lashes>>.<<$glass>>' & $glaza2 = '<<$pcs_eyecol>> eyes' & $glaza3 = '<<$glacol2>> eyes'
	if pcs_eyesize = 1:$glaza = 'You have expressive <a href="exec:gs ''begin'', ''eye color'' & gs ''begin'', ''eyes''"><<$pcs_eyecol>></a> eyes, <<$pcs_lashes>>.<<$glass>>' & $glaza2 = 'expressive <<$pcs_eyecol>> eyes' & $glaza3 = 'expressive <<$glacol2>> eyes'
	if pcs_eyesize = 2:$glaza = 'You have large <a href="exec:gs ''begin'', ''eye color'' & gs ''begin'', ''eyes''"><<$pcs_eyecol>></a> eyes, <<$pcs_lashes>>.<<$glass>>' & $glaza2 = 'big <<$pcs_eyecol>> eyes' & $glaza3 = 'high <<$glacol2>> eyes'
	if pcs_eyesize = 3:$glaza = 'You have huge <a href="exec:gs ''begin'', ''eye color'' & gs ''begin'', ''eyes''"><<$pcs_eyecol>></a> eyes, <<$pcs_lashes>>.<<$glass>>' & $glaza2 = 'great <<$pcs_eyecol>> eyes' & $glaza3 = 'great <<$glacol2>> eyes'

	if player_avatar = 1:
		'<center>Adjust your eyes and eyelashes to match your avatar. Please note, glasses choice may be overridden by your starting personality choice (e.g. bookworms/nerds will always start with glasses).</center>'
	else
		'<center>Please note, glasses choice may be overridden by your starting personality choice (e.g. bookworms/nerds will always start with glasses).</center>'
	end	
	*nl
	'<center><i><<$glaza>></i></center>'
	*nl
	if pcs_lashes < 2:'<center><a href="exec:pcs_lashes += 1 & gs ''begin'', ''eyes''">Lengthen lashes</a></center>'
	if pcs_lashes > 0:'<center><a href="exec:pcs_lashes -= 1 & gs ''begin'', ''eyes''">Shorten lashes</a></center>'
	if pcs_eyesize < 3:'<center><a href="exec:pcs_eyesize += 1 & gs ''begin'', ''eyes''">Larger eyes</a></center>'
	if pcs_eyesize > 0:'<center><a href="exec:pcs_eyesize -= 1 & gs ''begin'', ''eyes''">Smaller eyes</a></center>'
	if glass = 0:'<center><a href="exec:glass = 1 & gs ''begin'', ''eyes''">Wear glasses</a></center>'
	if glass = 1:'<center><a href="exec:glass = 0 & gs ''begin'', ''eyes''">Remove glasses</a></center>'

	if player_avatar = 1:
		act'<center><b>Done</b></center>': gt'begin','description_real_character'
	elseif $start_type = 'nt':
		act'<center><b>Done</b></center>': gt 'preCUST', 'NTStart2'
	elseif $start_type = 'sgs':
		act'<center><b>Done</b></center>': gt 'preCUST', 'SGStart'
	else
		act'<center><b>Done</b></center>': gt 'preCUST', 'TGStart'
	end
end

if $ARGS[0] = 'eye color':
	pcs_eyecol += 1
	if pcs_eyecol > 3: pcs_eyecol = 0
end

if $ARGS[0] = 'birthday':
	cls
	'<center><b><font color = maroon>CHARACTER CUSTOMIZATION</font></b></center>'
	if csb_start ! 1:
		if player_avatar = 1:
			'<center><img HEIGHT = 478 src="images/avatar.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="<<FUNC(''$face_image'')>>"></center>'
		end
	else
		'<center><img <<$set_imgh>> src="images/pre/csb/petercsb.jpg"></center>'
	end
	'<center>Choose your date of birth:</center>'
	*nl
	if birthyear = 0: birthyear = 1998
	if birthmonth = 0: birthmonth = 4
	if birthday = 0: birthday = 1

	if birthmonth = 2:
		if ((birthyear mod 4 = 0) and (birthyear mod 100 ! 0)) or (birthyear mod 400 = 0): 
			monthdays = 29
		else
			monthdays = 28
		end
	elseif birthmonth = 4 or birthmonth = 6 or birthmonth = 9 or birthmonth = 11:
		monthdays = 30
	else
		monthdays = 31
	end

	if birthmonth > 12: birthmonth = 12
	if birthmonth < 1: birthmonth = 1
	if birthday < 1: birthday = 1
	if birthday > monthdays: birthday = monthdays

	if birthday < 10 and birthmonth < 10:
		'<center>Your birthday: <B>0<<birthmonth>>/0<<birthday>></B> (MM/DD)</center>'
	elseif birthday < 10 and birthmonth >= 10:
		'<center>Your birthday: <B><<birthmonth>>/0<<birthday>></B> (MM/DD)</center>'
	elseif birthday >= 10 and birthmonth < 10:
		'<center>Your birthday: <B>0<<birthmonth>>/<<birthday>></B> (MM/DD)</center>'
	elseif birthday >= 10 and birthmonth >= 10:
		'<center>Your birthday: <B><<birthmonth>>/<<birthday>></B> (MM/DD)</center>'
	end

	*nl
	'<center><a href="exec:birthday += 5 & gs ''begin'', ''birthday''">+5 Days</a></center>'
	'<center><a href="exec:birthday += 1 & gs ''begin'', ''birthday''">+1 Day</a></center>'
	'<center><a href="exec:birthday -= 1 & gs ''begin'', ''birthday''">-1 Day</a></center>'
	'<center><a href="exec:birthday -= 5 & gs ''begin'', ''birthday''">-5 Days</a></center>'
	'<center><a href="exec:birthmonth = 1 & gs ''begin'', ''birthday''">January</a></center>'
	'<center><a href="exec:birthmonth = 2 & gs ''begin'', ''birthday''">February</a></center>'
	'<center><a href="exec:birthmonth = 3 & gs ''begin'', ''birthday''">March</a></center>'
	'<center><a href="exec:birthmonth = 4 & gs ''begin'', ''birthday''">April</a></center>'
	'<center><a href="exec:birthmonth = 5 & gs ''begin'', ''birthday''">May</a></center>'
	'<center><a href="exec:birthmonth = 6 & gs ''begin'', ''birthday''">June</a></center>'
	'<center><a href="exec:birthmonth = 7 & gs ''begin'', ''birthday''">July</a></center>'
	'<center><a href="exec:birthmonth = 8 & gs ''begin'', ''birthday''">August</a></center>'
	'<center><a href="exec:birthmonth = 9 & gs ''begin'', ''birthday''">September</a></center>'
	'<center><a href="exec:birthmonth = 10 & gs ''begin'', ''birthday''">October</a></center>'
	'<center><a href="exec:birthmonth = 11 & gs ''begin'', ''birthday''">November</a></center>'
	'<center><a href="exec:birthmonth = 12 & gs ''begin'', ''birthday''">December</a></center>'

	if csb_start ! 1:
		if player_avatar = 1:
			act'<center><b>Done</b></center>': gt 'begin', 'description_real_character'
		else
			act'<center><b>Done</b></center>': gt 'preSYS', 'SGStart2'
		end
	else
		act'<center><b>Done</b></center>': gt 'preSys', 'CSBStart'
	end
end

--- begin ---------------------------------

