# lug

if $ARGS[0] = 'start':
	$metka = 'start'
	$loc = 'lug'
	$location_type = 'public_outdoors'
	$menu_loc = 'lug'
	$menu_arg = 'start'
	$locclass = 'park'
	menu_off = 0
	gs'stat'
	'<center><img <<$set_imgh>> src="images/locations/oldtown/park/lug.jpg" ></center>'
	'It''s a small but well maintained meadow with evergreen grass, perfect for laying down to rest, have a picnic or just sunbathe. Mothers with small children regularly visit this place.'

	streetrand = RAND(0,100)
	if streetrand >= 60 and pcs_lover < 3:
		vnerand = RAND(0,300)
		if vnerand <= pcs_apprnc:
			gs'boy'
			'<<$boybody>> <<$boybod>> <<$boyface>> comes up to you. He is wearing <<$boyClo>>'
			'The guy introduces himself as <<$boydesc>> and asks for your telephone number.'

			act 'Tell him your number':
				cla
				gs'boyfrend', 'start'
				stopboy = 0
				'<<$boydesc>> thanks you and leaves.'
				act 'Complete outing':gt'lug', 'start'
			end
		end

	end


	if pavserhom = 0 and psiha = 0 and home_owned[1] = 0:
		temp = RAND(1,100)
		if temp >= 90:
			pcs_horny += 20
			gs'stat'
			'On the path stands a <a href="exec:dynamic $pavserjil">man</a> looking like he is waiting for someone.'
		end
	end

	gs 'kseniyaQW', 'events'

	if pcs_inhib >= 35:
		act 'Flash your tits':
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			cls
			gs 'exhibitionism', 1
			inhib_exp += rand(1,3)
			gs 'flash', 'tits', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'lug', 'start'
		end
	end

	if exhibitionist_lvl > 0:
		act 'Flash your pussy':
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			cls
			gs 'exhibitionism', 3
			gs 'flash', 'pussy', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'lug', 'start'
		end
	end

	act 'Visit the pond':
		set minut += 10
		gt 'lug', 'prut'
	end

	act 'Go toward the park entrance':
		set minut += 5
		gt 'parks', 'start'
	end
	
	gs 'events', 'street_cum'
end


if $ARGS[0] = 'prut':
    cls
    gs'stat'
    $location_type = 'public_outdoors'

    '<center><B>Park Pond</B></center>'
    '<center><img <<$set_imgh>> src="images/locations/oldtown/park/prut.jpg" ></center>'
	'A large and pretty pond near the end of the park, it continues off in to a wooded area.'


    act 'Explore the wooded area':
        set minut += 10
        gt 'lug', 'prut2'
    end

    act 'Return to the small meadow':
        set minut += 10
        gt'lug', 'start'
    end
end

if $ARGS[0] = 'prut2':
    cls
    gs'stat'
    $location_type = 'public_outdoors'

    '<center><B>Woodland Pond</B></center>'
    '<center><img <<$set_imgh>> src="images/locations/oldtown/park/prut2.jpg" ></center>'
	'The pond is still and beautiful here and the trees offer some privacy, it feels quite magical.'
	'There is a large field beyond that is hidden from the tourist trail.'

    act 'Go to the field':
        set minut += 15
        gt 'lug', 'luzhayka'
    end

    act 'Follow the pond back out of the woods':
        set minut += 10
        gt 'lug', 'prut'
    end

	! Setup for teleport circle
	if tpKnown['PushkinPark'] = 1:
		act 'Enter the hidden circle of trees': gt 'treeCircle', 'PushkinPark'
	else
		act 'Investigate a mysterious copse of trees': gt 'treeCircle', 'PushkinPark'
	end

	if MagikDostup ! 1 and rand (1, 4) <= pcs_magik and (hour <=6 or hour >=19):
		if knowsfairy < 1 and fairyskip = 0:
			$metka = 'prut2'
			xgt 'MagEncounterFairy'
		elseif fairyskip = 0:
			act 'Go to where the Fairy may be': xgt 'MagEncounterFairy'
		end
	end

	if temper >= 15 and month >= 5 and month <= 9:
		if pcs_inhib > 30:
			act 'Strip off and skinny dip (1:00)':
				cla
				*clr
				cumspclnt = 4
				gs 'cum_cleanup'
				minut += 60
				pcs_sweat = 10 + rand(0,4)
				pcs_mood += 5
				if pcs_stren < 30: stren_exp += 1
				gs 'exhibitionism', 3
				gs 'clothing', 'strip'
				gs 'underwear', 'remove'
				if pcs_horny >= 80 and pcs_inhib >= 60:
					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/secluded_beach/self/wetpussypants3.jpg"></center>'
					'AS you strip off. A couple of passing men do a double-take and pause a moment to look at your sopping wet panties, probably thinking about what is making you so excited. You don''t care about what they might say or think of you and carry on stripping.'
					'Once you are naked you play around and have fun in the pond, enjoying the feel of the warm water on your body. The clean pond water refreshes and invigorates you.'
				elseif pcs_inhib >= 60:
					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/secluded_beach/dress/undressnudebeach.jpg"></center>'
					'Not caring if anyone is looking at you, you slowly take off your clothes.  You peel off each item like a stripper. Soon, you are completely naked.'
					'You play around and have fun in the pond, enjoying the feel of the warm water on your naked body. The clean pond water refreshes and invigorates you.'
				else
					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/secluded_beach/dress/undressnudebeach.jpg"></center>'
					'You quickly check to see if anyone is watching, and when you''re satisfied no one is paying you undue attention, you take off your clothes.'
					'You play around and have fun in the pond, enjoying the feel of the warm water on your naked body. The clean pond water refreshes and invigorates you.'
				end
				act'Get out and dressed':
					gs 'underwear', 'wear'
					gs 'clothing', 'wear_last_worn'
					gt 'lug', 'prut2'
				end
			end
		else
			'It would be a good place for skinny dipping but you''re too worry about what people would think to do such a thing.'
		end
	end
end

if $ARGS[0] = 'luzhayka':
    cls
    gs'stat'

    '<center><img <<$set_imgh>> src="images/locations/oldtown/park/luzhayka.jpg" ></center>'
	'A quiet hidden field that is well maintained but apart from the occasional grounds keeper you feel like it is all yours.'

    act 'Return to the woodland pond':
        set minut += 15
        gt 'lug', 'prut2'
    end
end

--- lug ---------------------------------

