# stwork2

if $ARGS[0] = 'strip':
	clr
	gs 'stat'
	'<center><b><font color="maroon">Stage</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripclub1.jpg"></center>'

	if striptip < 10:$pubhot = 'booing you, you hear someone shout, "Get this stupid cow off the stage."'
	if striptip >= 10 and striptip < 20:$pubhot = 'clearly showing discontent with your dancing. They want you off the stage as quickly as possible.'
	if striptip >= 20 and striptip < 30:$pubhot = 'clearly looking bored, drinking and talking among themselves, ignoring you.'
	if striptip >= 30 and striptip < 60:$pubhot = 'sometime looking at you, smiling and enjoy the performance.'
	if striptip >= 60 and striptip < 70:$pubhot = 'watching you with genuine interest while conversing with each other over their beers.'
	if striptip >= 70 and striptip < 80:$pubhot = 'having their attention focused on you.'
	if striptip >= 80 and striptip < 90:$pubhot = 'with strained faces, sweat beading on their foreheads, their arousal clearly showing.'
	if striptip >= 90:$pubhot = 'completely indulged in you. They''re clapping and waving money at you trying to get you attention.'

	'There are men sitting in front of the stage <<$pubhot>>.'

	if hour >= 11 or hour <= 2:
		if stpredmet = 3:lapdance = 0
		if stpredmet > 0:
			if $pantyworntype ! 'none' and $braworntype ! 'none':
				act 'Striptease 15 minutes':
					*clr & cla
					countmoney = 1
					custbooing = 0
					minut += 15
					gs 'sweat', 'add', 15
					fat -= 3
					dancero_exp += rand(2, 4)
					inhib_exp += rand(2,5)
					city_stripping += rand(1,2)

					if stpredmet = 1:gs 'sweat', 'add', 5
					if stpredmet = 0:pcs_hairbsh = 0 & stripdancesum += 1

					striptip = rand(pcs_dancero,100)
					lapdance += striptip

					gs 'stat'
					
					!You either start with underwear and clothes or in underwear. Each has a different picture set.
					if $clothingworntype ! 'nude':
						'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripclo' + rand(1,3) + '.jpg"></center>'
						'You walk up on the stage and hear the music start. The effect is immediate, you start moving seductively around the pole in the center of the stage...'
						gs 'stwork2', 'custboo'
						act 'Take off your top':
							*clr & cla
							'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripclo' + rand(4,5) + '.jpg"></center>'
							if custboo = 0:
								pcs_mood += 5
								'Urged on by the audience you take off your blouse and let it drop to the stage while you keep teasing them.'
							else
								pcs_mood -= 5
								'Ignoring the comments from the audience you take off your blouse and let it drop to the stage while you keep teasing them.'
							end
							gs 'stwork2', 'custboo'
							gs 'stat'
							act 'Take off your skirt':
								*clr & cla
								'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripclo' + rand(6,7) + '.jpg"></center>'
								if custboo = 0:
									pcs_mood += 5
									'The positive responses make you smile even broader as you unzip your skirt and let it drop to your ankles before kicking it off and laying down on the stage, rolling around and looking several customers straight in the eyes. Some of them throw some bills your way and you take care to pay them some extra attention.'
								else
									pcs_mood -= 5
									'The negative comments make you feel a bit uncomfortable as you unzip your skirt and let it drop to your ankles before kicking it off and laying down on the stage, rolling around and looking several customers straight in the eyes.'
								end
								gs 'stwork2', 'custboo'
								gs 'stat'
								if custbooing < 2:
									act 'Show them more':
										*clr & cla
										'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripclo' + rand(9,15) + '.jpg"></center>'
										if custboo = 0:
											pcs_mood += 5
											'The men in the first row go wild when you take off your bra. Shouting "Show your pussy! Show your pussy!"'
											'As you hook your fingers into your panties a few customers start throwing money on the stage. You walk over to one of them and bend over, giving him a great view of your ass as you pull your panties off.'
											'After that you dance as seductively as you can, trying to spread your attention over the audience, but paying extra attention to the ones who give you more money.'
										else
											'The negative comments make you feel a bit uncomfortable as you take off your bra, but as soon as soon as they can see your tits the audience becomes a lot more appreciative.'
											'This gives you the courage to take off your panties as well. Once you are naked some customers start throwing money on the stage.'
											'You dance as seductively as you can, trying to spread your attention over the audience, but paying extra attention to the ones who give you more money.'
										end
										'When the music starts winding down you collect your tips and pick up your clothes, waving a few kisses to your audience before going backstage again.'
										gs 'exhibitionism', 3
										stprivatechance = 1
										gs 'stat'
										act 'Leave the stage': gt 'stwork', 'start'
									end
								else
									act 'Show them more':
										*clr & cla
										'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripclo8.jpg"></center>'
										pcs_mood -= 5
										'Not sure what you could do to please your audience you take off your bra and toss it with the rest of your clothes. Even this doesn''t seem to get any positive responses.'
										'All you can hear is mockery as you try to ignore them and continue your act. The cutting remarks keep coming however and soon you are close to tears.'
										'Before the music stops you start collecting your meager tips and clothes and flee backstage.'
										gs 'exhibitionism', 1
										stprivatechance = 0
										gs 'stat'
										act 'Leave the stage': gt 'stwork', 'start'
									end
								end
							end
						end
					else
						'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripund' + rand(1,3) + '.jpg"></center>'
						'You walk up on the stage and hear the music start. The effect is immediate, you start moving seductively around the pole in the center of the stage...'
						gs 'stwork2', 'custboo'
						act 'Take off your bra':
							*clr & cla
							'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripund' + rand(4,8) + '.jpg"></center>'
							if custboo = 0:
								pcs_mood += 5
								'Urged on by the audience you slowly take off your bra and let it drop to the stage while you keep teasing them.'
							else
								pcs_mood -= 5
								'Ignoring the comments from the audience you slowly take off your bra and let it drop to the stage while you keep teasing them.'
							end
							'You even perform a few easy moves on the pole.'
							gs 'stwork2', 'custboo'
							gs 'exhibitionism', 1
							gs 'stat'
							act 'Take off your panties':
								*clr & cla
								'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripund' + rand(9,12) + '.jpg"></center>'
								if custboo = 0:
									pcs_mood += 5
									'The positive responses make you smile even broader as you playfully drop your panties to your ankles before kicking them off. You look several customers straight in the eyes as you do so. Some of them throw some bills your way and you take care to pay them some extra attention.'
								else
									pcs_mood -= 5
									'The negative comments make you feel a bit uncomfortable as you playfully drop your panties to your ankles before kicking them off. You look several customers straight in the eyes as you do so.'
								end
								gs 'stwork2', 'custboo'
								gs 'exhibitionism', 2
								gs 'stat'
								if custbooing < 2:
									act 'Dance some more':
										*clr & cla
										'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripund' + rand(13,14) + '.jpg"></center>'
										if custboo = 0:
											pcs_mood += 5
											'The men in the first row go wild as soon as you are fully nude. Shouting out their approval. Several of them are tipping generously.'
											'You dance as seductively as you can, trying to spread your attention over the audience, but paying extra attention to the ones who give you more money.'
										else
											'The negative comments make you feel a bit uncomfortable. Not wanting to give up you put all your effort into your dancing. This seems to please some of them and they start tipping you after all.'
											'You dance as seductively as you can, trying to spread your attention over the audience, but paying extra attention to the ones who give you more money.'
										end
										'When the music starts winding down you collect your tips and pick up your clothes, waving a few kisses to your audience before going backstage again.'
										gs 'exhibitionism', 3
										stprivatechance = 1
										gs 'stat'
										act 'Leave the stage': gt 'stwork', 'start'
									end
								else
									act 'Flee the stage':
										*clr & cla
										'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/stripund' + rand(13,14) + '.jpg"></center>'
										pcs_mood -= 5
										'Even being completely naked doesn''t seem to get any positive responses.'
										'All you can hear is mockery as you try to ignore them and continue your act. The cutting remarks keep coming however and soon you are close to tears.'
										'Before the music stops you start collecting your meager tips and clothes and flee backstage.'
										gs 'exhibitionism', 3
										stprivatechance = 0
										gs 'stat'
										act 'Leave the stage': gt 'stwork', 'start'
									end
								end
							end
						end
					end
				end
			end

			act 'Dance around the pole 5 minutes (<<stpredmet>> garments)':
				*clr & cla
				minut += 5
				stpredmet -= 1
				gs 'sweat', 'add', 5
				fat -= 5
				pcs_mood -= rand(4, 8)
				dancpol_exp += rand(2, 4)
				inhib_exp += rand(2,5)
				city_stripping += rand(1,2)
				
				if stpredmet = 1:pcs_hairbsh = 0
				if stpredmet = 0:pcs_makeup = 0 & stripdancesum += 1

				!pcs_hairbsh = 0
				striptip = rand(pcs_dancpol,100)
				lapdance += striptip
				
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/strippole.jpg"></center>'
				'You step up on the stage and the music starts. You grab hold of the pole and acrobatically slide around it while you teasingly undress.'

				if pcs_weight > pcs_hgt - 90:
					vesrand = rand(0, 100)

					if vesrand >= 75:
						'Performing another trick on the pole you can not support your weight and fall flat to the floor. The crowd laughs, "Hey, hippopotamus, stomp back to the swamp where you came from."'
						striptip -= 15
						fingalrand = rand(0, 100)
						if fingalrand >= 75:
							fingal += rand(2, 5)
							gs 'pain', 4, 'cheeks', 'Slam'
							gs 'stat'
							'As you fall, you hit the floor really hard and you can feel a bruise forming on your face.'
						end
					end
					if vesrand >= 50:
						striptip -= rand(5, 10)
						'You overhear some of the customers right next to the stage, "Look at her fat hanging out. Her gut and ass shaking like jelly."'
					end
				end

				gs 'stwork2', 'tipcalculator'

				act 'Continue': gt 'stwork2', 'strip'
			end
		end

		if stpredmet = 0:
			if lapdance >= 150:
				privatrand = rand(0, 100)
				if privatrand >= 50:
					'After you finish dancing, a security guard approaches you and tells you that you have a customer wanting a private show.'
					act '<b>Go perform a private dance</b>': 
						stprivatechance = 0
						gt 'stwork2', 'privatdance'
					end
				end
			end
		end
	else
		'Your shift is over for tonight. Time to head home.'
	end
	
	act 'Leave the stage':gt 'stwork', 'start'
end

if $ARGS[0] = 'custboo':
	if pcs_weight > pcs_hgt - 90:
		vesrand = rand(0, 100)
		if vesrand >= 60:
			striptip -= rand(5, 10)
			custboo = 1
			custbooing += 1
			resprand = rand(0,3)
			if resprand = 0:
				'You overhear some of the customers right next to the stage, "Look at her fat hanging out. Her gut and ass shaking like jelly."'
			elseif resprand = 1:
				'You overhear some of the customers right next to the stage, "What a cow. Someone should roll her off the stage."'
			elseif resprand = 2:
				'You overhear some of the customers right next to the stage, "They should get that fat bitch off the stage and bring on a better looking stripper."'
			elseif resprand = 3:
				'You overhear some of the customers right next to the stage, "Looks like they cater to your tastes too. What was that last fat bitch called again? She weighed more than you, and this girl weighs as much as you two combined."'
			end
		else
			custboo = 0
			resprand = rand(0,1)
			if resprand = 0:
				'A few customers are catcalling. "Get those fat titties out!" You hear one of them yell.'
			elseif resprand = 1:
				'A few customers are catcalling. "Show us some flesh!" You hear one of them yell.'
			end
		end
	else
		custboo = 0
		resprand = rand(0,1)
		if resprand = 0:
			'Several customers are catcalling. They want to see more.'
		elseif resprand = 1:
			'Most of the crowd seems to like what they are seeing. "Show us some more flesh!" You hear one of them yell.'
		end
	end
end

if $ARGS[0] = 'tipcalculator':
	!20% chance that tattoos increase tips
	if rand (0, 4) = 0:
		striptip += stripKoef
	end
	if striptip < 30:
		'Nobody even noticed you or your efforts on the stage.'
	elseif striptip < 60:
		'A couple of people looked at you but nothing more than that, you didn''t receive a single tip.'
	elseif striptip < 70:
		if payrand = 0: 'A couple of people looked at you but nothing more than that, you didn''t receive any tips.'
	elseif striptip < 80:
		if rand(0,5) = 0:
			'The customers were pleased with your performance. No one tipped you however.'
		else
			paymoneyrand = rand(3,10) * 5
			money += paymoneyrand
			pcs_mood += rand(1,2)
			'The customers were pleased with your performance. They gave you <<paymoneyrand>> <b>₽</b> in tips.'
		end
	elseif striptip < 90:
		if rand(0,10) = 0:
			'The customers followed your movements between their conversations. No one tipped you however.'
		else
			paymoneyrand = rand(10,50) * 5
			money += paymoneyrand
			pcs_mood += rand(1,2)
		'The customers followed your movements between their conversations. After counting out your tips it amounts to <<paymoneyrand>> <b>₽</b>.'
		end
	else
		if rand(0,15) = 0:
			'The customers were mesmerized by your dancing but no one tipped you.'
		else
			paymoneyrand = rand(10,100) * 5
			money += paymoneyrand
			pcs_mood += rand(1,2)
			'The customers were mesmerized by your dancing and have tipped <<paymoneyrand>> <b>₽</b>.'
		end
	end
end

if $ARGS[0] = 'privatdance':
	*clr & cla
	minut += 30
	money += 400
	if pcs_sweat < 30 : gs 'sweat', 'add', 10
	pcs_hairbsh = 0
	pcs_makeup = 0
	fat -= 5
	pcs_mood += rand(2,6)
	dancero_exp += rand(2, 4)
	stripdancesum += 1

	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/privatstrip.jpg"></center>'
	'You walk over to a smaller private room where you put on some music before the customer walks in. As the customer walks in you tell him to sit down and enjoy the show. You spend half an hour showing off your dancing skills, and every time you grind against him you can feel his rock hard cock.'

	stprrand = rand(0,15)
	if stprrand = 0:
		gt 'stwork2', 'pr1'
	elseif stprrand = 1:
		gt 'stwork2', 'pr2'
	elseif stprrand = 2:
		gt 'stwork2', 'pr3'
	end

	act 'Return to the locker room':gt 'stwork', 'start'
end

if $ARGS[0] = 'pr1':
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/pr1.jpg"></center>'
	'Just as you start to dance, you hear a knock on the door. His friends are waiting outside wanting to join in on the dance. Feeling trapped you agree and start dancing, after a while they tell you to stop and ask if you''re willing to go all the way for 4000 <b>₽</b>.'

	act 'Reject them':gt 'stwork', 'start'

	act 'Agree':
		gang += 1
		guy += 4
		killvar '$boy'
		i=rand(18,40)
		gs 'npcgeneratec', 0, 'Private dance Client', i
		gs 'boyStat', $npclastgenerated
		gs 'npcgeneratec', 0, 'Friend of Client', i
		gs 'boyStat', $npclastgenerated,'1'
		gs 'npcgeneratec', 0, 'Friend of Client', i
		gs 'boyStat', $npclastgenerated,'2'
		gs 'npcgeneratec', 0, 'Friend of Client', i
		gs 'boyStat', $npclastgenerated,'3'
		picrand = 12
		money += 4000
		$sexloc = 'stwork'
		gt 'paysex', 'var'
	end
end

if $ARGS[0] = 'pr2':
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/pr2.jpg"></center>'
	'The man you''re dancing is mesmerized by you and can''t stop touching himself, after a while he asks you if he can fuck you for 2000 <b>₽</b>.'
	
	gs 'willpower', 'sex', 'resist', 'hard'
	if will_cost <= pcs_willpwr:
		act 'Reject him (<<will_cost>> Willpower)':
			gs 'willpower', 'pay', 'resist'
			gs 'stat'
			gt 'stwork', 'start'
		end
	else
		act 'Reject him (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
	end	

	act 'Agree':
		guy += 1
		picrand = 39
		money += 2000
		$sexloc = 'stwork'
		xgt 'sex', 'var'
	end
end

if $ARGS[0] = 'pr3':
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/stripclub/pr3.jpg"></center>'
	'It''s a bit different dancing for a woman, it''s not often you have the pleasure doing that so you''re feeling a bit more frisky than usual. As you finish the dance she gives you an kiss and you start making out. She stops and offers you 1000 <b>₽</b> to continue on.'

	gs 'willpower', 'sex', 'resist', 'hard'
	if will_cost <= pcs_willpwr:	
		act 'Reject her (<<will_cost>> Willpower)':
			gs 'willpower', 'pay', 'resist'
			gs 'stat'
			gt 'stwork', 'start'
		end
	else
		act 'Reject her (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
	end	

	act 'Agree':
		girl += 1
		lesbian += 1
		picrand = 18
		money += 1000
		$sexloc = 'stwork'
		xgt 'lezbsex', 'var'
	end
end

--- stwork2 ---------------------------------

