# grandpahelp

*clr & cla
'<center><img <<$set_imgh>> src="images/locations/gadukino/grandparents/grandpa1.jpg"></center>'
'You walk up to your grandfather and ask if he needs any help. Grandpa thinks for a moment and says:'
menu_off = 1
gs'stat'

if $ARGS[0] = 'start':

	if month <= 4 or month >= 10:
		grandpaQW['help_type'] = rand(0,5)
	elseif month = 5:
		grandpaQW['help_type'] = rand(3,8)
	elseif month = 6 or month = 9:
		grandpaQW['help_type'] = rand(3,12)
	else
		grandpaQW['help_type'] = rand(3,13)
	end

	if grandpaQW['help_type'] = 0:
		'"<<$pcs_nickname>>, could you run out to the barn and bring some firewood for the stove?"'

		grandpaQW['fetch_firewood'] = 1
		act 'Tell him you will go get some in just a bit':gt 'gadhouse', 'grandpa'
		act 'Agree and go to fetch firewood (0:20)':
			*clr & cla
			if month >= 4 and month <= 10:
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/firewood.jpg"></center>'
			else
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/firewood_winter.jpg"></center>'
			end
			'You put on some warm clothes and run over to the barn to collect some firewood. '
			'"I''ve brought some firewood grandfather," you said to your grandfather.'
			'"You are very quick <<$pcs_nickname>>." he replies with a smile. "That''s today''s youth for ya. There is no more work today."'
			grandpaQW['fetch_firewood'] = 0
			minut += 20
			grandmaQW['help'] += 1
			gs'stat'

			act 'Continue':gt 'gadhouse', 'start'
		end
	elseif grandpaQW['help_type'] = 1:
		'"<<$pcs_nickname>>, I need you to go to the barn and feed Desperado."'

		grandpaQW['feed_horse'] = 1
		act 'Tell him that you will get to it in a little bit':gt 'gadhouse', 'grandpa'
		act 'Agree and go to the barn (0:10)':
			*clr & cla
			if month >= 4 and month <= 10:
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
			else
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard_winter.jpg"></center>'
			end
			'You walk over to the barn where Desperado is kept.'
			minut += 10
			gs'stat'

			act 'Continue':gt'gadsarai','horse'
		end
	elseif grandpaQW['help_type'] = 2:
		'"<<$pcs_nickname>>, go to the barn to feed the cows."'

		grandpaQW['feed_cow'] = 1
		act 'Tell him that you will do it in a little while':gt 'gadhouse', 'grandpa'
		act 'Agree and go to the barn (0:10)':
			*clr & cla
			if month >= 4 and month <= 10:
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
			else
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard_winter.jpg"></center>'
			end
			'You walk over to the barn where the cows are kept.'
			minut += 10
			gs'stat'

			act 'Continue':gt'gadsarai','cow'
		end
	elseif grandpaQW['help_type'] = 3:
		gt 'grandpahelp', 'cleanyard'
	elseif grandpaQW['help_type'] = 4:
		gt 'grandpahelp', 'groomhorse'
	elseif grandpaQW['help_type'] = 5:
		gt 'grandpahelp', 'feedhogs'
	elseif grandpaQW['help_type'] = 6 and hour >= 6 and hour < 9:
		gt 'grandpahelp', 'grazehorse'
	elseif grandpaQW['help_type'] = 7 and hour >= 6 and hour < 9:
		gt 'grandpahelp', 'leadcows'
	elseif grandpaQW['help_type'] = 8 and hour >= 6 and hour < 9:
		gt 'grandpahelp', 'grazecows'
	elseif grandpaQW['help_type'] = 9 and temper >= 15 and sunWeather = 1 and week > 5:
		gt 'grandpahelp', 'washhorse'
	elseif grandpaQW['help_type'] >= 10 and grandpaQW['help_type'] < 13 and $grandpaQW['gather_quest'] = '' and ARRSIZE('swimwear') > 0:
		gt 'grandpahelp', 'pickforest'
	elseif grandpaQW['help_type'] = 13 and temper >= 15 and sunWeather = 1 and hour >= 6 and hour < 9:
		'"<<$pcs_nickname>>, we need to help out with hay gathering today. We have to go to the field and help out."'
		'"Okay, grandfather," you replied.'

		grandpaQW['haying_time'] = 1
		act 'Tell him you will meet him there':gt 'gadhouse', 'grandpa'
		act 'Grab a rake and head to the field (0:40)':
			*clr & cla
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_gadfield.jpg"></center>'
			'With the rake in your hand you met up with the other local residents at the field. All the present at the field got assigned to a task. You work hard gathering the hay.'
			minut += 40
			gs'stat'

			act 'Continue':gt'gadfield','field'
		end
	else
		if hour >= 9:
			randmsg = rand(0,5)
			if randmsg = 0:
				'"You can rest today <<$pcs_nickname>>, you don''t need to help me today."'
			elseif randmsg = 1:
				'"You can rest today child, there is nothing to do."'
			elseif randmsg = 2:
				'"You can rest today <<$pcs_nickname>>, there is nothing to do."'
			elseif randmsg = 3:
				'"There''s no work today <<$pcs_nickname>>, go and rest up."'
			elseif randmsg = 4:
				'"You can rest today my dear granddaughter."'
			else
				'"You can take the day off to rest up."'
			end
		else
			randmsg = rand(0,1)
			if randmsg = 0:
				'"You don''t need to help out today <<$pcs_nickname>>."'
			else
				'"You can take the day off."'
			end
		end
		act 'Continue':gt 'gadhouse', 'grandpa'
	end
end

if $ARGS[0] = 'cleanyard':
	'"Of course <<$pcs_nickname>>, I need your help in the yard. Bring a garden tool with you."'

	grandpaQW['clean_yard'] = 1
	act 'Tell him that you''ll do it in a minute':gt 'gadhouse', 'grandpa'
	act 'Agree and go clean up the yard (1:00)':
		*clr & cla
		if month >= 4 and month <= 10:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/clean_yard1.jpg"></center>'
			'Armed with a rake, you begin cleaning the yard. You''re pleased seeing the yard clean. You return the rake to the shed and continue on with your business.'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/clean_yard2.jpg"></center>'
			'Armed with a shovel, you begin clearing the yard of snow. You''re pleased with yourself seeing the courtyard is free of snow. You return the shovel to the shed and continue on with your business.'
		end
		minut += 60
		grandpaQW['clean_yard'] = 0
		grandmaQW['help'] += 1
		if month >= 4 and month <= 10:
			fat -= rand(1,3)
		else
			stren_exp += 1
			fat -= rand(1,5)
		end
		gs'stat'

		act 'Go':gt'gaddvor'
	end
end

if $ARGS[0] = 'feedhogs':
	'"<<$pcs_nickname>>, could you go to the barn and feed the hogs."'

	grandpaQW['feed_boar'] = 1
	act 'Tell him you will get to it soon':gt 'gadhouse', 'grandpa'
	act 'Agree and go to the barn (0:10)':
		*clr & cla
		if month >= 4 and month <= 10:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard_winter.jpg"></center>'
		end
		'You walk over to the barn where the hogs are kept.'
		minut += 10
		gs'stat'

		act 'Continue':gt'gadsarai','boar'
	end
end

if $ARGS[0] = 'washhorse':
	'"It''s good weather today. Take Desperado to the river and give him a bath."'

		grandpaQW['horse_river'] = 1
	act 'Tell him you will do it in a little while':gt 'gadhouse', 'grandpa'
	act 'Agree and go to the barn (0:10)':
		*clr & cla
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
		'You walk over to the barn where Desperado is kept.'
		minut += 10
		gs'stat'

		act 'Continue':gt'gadsarai','horse'
	end
end

if $ARGS[0] = 'groomhorse':
	'"Of course <<$pcs_nickname>>, I need your help to groom Desperado."'

	grandpaQW['comb_horse'] = 1
	act 'Tell him you will do it in a bit':gt 'gadhouse', 'grandpa'
	act 'Agree and go to the barn (0:10)':
		*clr & cla
		if month >= 4 and month <= 10:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard_winter.jpg"></center>'
		end
		'You walk over to the barn where Desperado is kept.'
		minut += 10
		gs'stat'

		act 'Continue':gt'gadsarai','horse'
	end
end

if $ARGS[0] = 'grazehorse':
	'"<<$pcs_nickname>>, take Desperado to the field, my legs hurt so I need to rest for a bit. I''ll retrieve the horse up in the evening."'

	grandpaQW['horse_field'] = 1
	act 'Tell him you will do it soon':gt 'gadhouse', 'grandpa'
	act 'Agree and go to the barn (0:10)':
		*clr & cla
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
		'You walk over to the barn where Desperado is kept.'
		minut += 10
		gs'stat'

		act 'Continue':& gt'gadsarai','horse'
	end
end

if $ARGS[0] = 'grazecows':
	if grandpaQW['graze_cow_exp'] = 0: 
		'"<<$pcs_nickname>>, we need to let the cows graze on the field today. Grab something to eat and lead the herd to the field. I''ll meet you there."'
	else
		'"<<$pcs_nickname>>, it''s our turn to look out for the cows grazing on the field today. So grab something to eat quickly, and stop by the field where the herd is. I''ll bring them back home."'
	end

	grandpaQW['graze_cow'] = 1
	act 'Tell him you will meet him there':gt 'gadhouse', 'grandpa'
	act 'Agree and go to the field (0:40)':
		*clr & cla
		if grandpaQW['graze_cow_exp'] = 0:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
			'You take a little nibble of a sandwich and go to the shed where the herd is. Your grandmother put a sandwich and a bottle of water in the bag for lunch.'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cow_go_field.jpg"></center>'
			'You have a quick bite and go to the field where the village herd is. Your grandmother put a sandwich and a bottle of water in the bag for lunch.'
		end
		pcs_mood += 20
		pcs_health += 10
		minut += 40
		if bottle = 0: bottle = 1
		if buterbrod = 0: buterbrod = 1
		gs'stat'

		act 'Continue':gt'gadfield','cow'
	end
end

if $ARGS[0] = 'leadcows':
	'"I have sore feet today, <<$pcs_nickname>>. My dear granddaughter, could you lead the cows on the field and tell the herders to drive them home at the end of the day."'

	grandpaQW['cow_field'] = 1
	act 'Tell him you will soon':gt 'gadhouse', 'grandpa'
	act 'Agree and go to the barn (0:10)':
		*clr & cla
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/go_yard.jpg"></center>'
		'You walk over to the barn where the cows are kept.'
		minut += 10
		gs'stat'

		act 'Continue':gt'gadsarai','cow'
	end
end

if $ARGS[0] = 'pickforest':
	if grandpaQW['help_type'] = 10:
		$grandpaQW['gather_quest'] = 'mushroom'
		grandpaQW['mushroom_qty'] = rand(2,3)
		'"<<$pcs_nickname>>, could you go to the forest and pick mushrooms? I''m craving fried mushrooms."'
		'"How much should I pick, grandpa?", you ask.'
		'"<<grandpaQW[''mushroom_qty'']>> kg will be enough," grandfather replies. "Be careful so you don''t get lost."'
	elseif grandpaQW['help_type'] = 11:
		$grandpaQW['gather_quest'] = 'berry'
		grandpaQW['berry_qty'] = rand(3,5)
		'"<<$pcs_nickname>>, could you go to the forest to pick some berries? Grandma wants to make homemade fruit jam."'
		'"How much should I pick, grandpa?" you ask.'
		'"<<grandpaQW[''berry_qty'']>> kg will be enough," grandfather replies. "Just be careful so you don''t get lost."'
	elseif grandpaQW['help_type'] = 12:
		$grandpaQW['gather_quest'] = 'both'
		grandpaQW['mushroom_qty'] = rand(1,2)
		grandpaQW['berry_qty'] = rand(2,3)
		'"<<$pcs_nickname>>, can you go to the forest and pick some berries and mushrooms? Your grandmother wants to make a mushroom soup, and has a craving for some fresh berries."'
		'"How much should I pick, grandpa?"'
		'"<<grandpaQW[''mushroom_qty'']>> kg mushrooms and <<grandpaQW[''berry_qty'']>> kg of berries will be enough," grandfather replies. "Just don''t get lost."'
	end
	act 'Tell him you will go get some soon':gt 'gadhouse', 'grandpa'
	act 'Agree and go to the forest (1:00)':
		*clr & cla
		if hour >= 6 and hour < 22:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad_night.jpg"></center>'
		end
		'You agree to help your grandfather, grabbing a basket and setting out on the road to the forest.'
		minut += 60
		act 'Continue': gt 'gadforest', '1'
	end
end

--- grandpahelp ---------------------------------

