# bedrPar
CLOSE ALL
$metka = ''
$loc = 'bedrPar'
$location_type = 'private'
$locclass = 'bedr'
clr
minut += 1
gs 'stat'
if night_mode = 1:
	fcolor = rgb(255, 255, 255)
	bcolor = rgb(0, 0, 0)
	lcolor = rgb(106, 90, 205)
else
	fcolor = rgb(0, 0, 0)
	bcolor = rgb(255, 255, 255)
	lcolor = rgb(106, 90, 205)
end

if pcs_magik >= 6 and spellbefshild = 1 and tobiQW = 0 and sisterHere < 2:gt 'tobiQW', 'start'

if sisboyday + 1 = daystart and hour = 18:gt'sisterQW','sisboyQW_expel'

'<center><h1><font color="maroon">Your bedroom</font></h1></center>'
! WD: Correct Image path ~ "images/qwest/alter/<<$loc>>.jpg"
'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/home/bedrpar.jpg"></center>'
*nl
'This is the small bedroom you share with your sister, Anya. On one side of the room is a wardrobe that you can use to <a href="exec:gt ''clothing'', ''view_clothing_list'', ''wardrobe''">organize your clothes</a> or <a href="exec:gt ''clothing_QV'', ''list''">pick something to wear</a>. On top of it is a <a href="exec:gt ''clothing'', ''view_clothing_list'', ''store''">suitcase</a> that you could use to store clothes that you don''t wear often. Your <a href="exec:gt ''bed2''">bed</a> is in the corner across from the wardrobe, and your <a href="exec:gt ''stol'' ,''stolPar''">desk</a> is next to it. Your sister''s bed is in the other corner.'
'In the bottom of your wardrobe you have <a href="exec:gt ''shoes'', ''select''">your shoes</a>.'
if budilnikOn = 0:
	'Your <a href="exec:gt ''budilnik'', ''start''">alarm clock</a> is set for <<timer>> hours <<timerM>> minutes and currently turned <a href="exec: budilnikOn = 1 & GT ''<<$loc>>''">off</a>.'
else
	'Your <a href="exec:gt ''budilnik'', ''start''">alarm clock</a> is set for <<timer>> hours <<timerM>> minutes and currently turned <a href="exec: budilnikOn = 0 & GT ''<<$loc>>''">on</a>.'
end

if tabletki > 0 and prezik + prezikcount + preziksabo > 0:
	'Your <a href="exec:gt ''stol'', ''bc''">birth control</a> is hidden in one of your desk drawers, as are your <a href="exec:gt ''stol'', ''bc''">condoms</a>.'
elseif tabletki > 0:
	'Your <a href="exec:gt ''stol'', ''bc''">birth control</a> is hidden in one of your desk drawers.'
elseif prezik + prezikcount + preziksabo > 0:
	'Your <a href="exec:gt ''stol'', ''bc''">condoms</a> are hidden in one of your desk drawers.'
end

if komp = 1:'Your <a href="exec:gorodokKomp = 1 & GT ''Komp'',''start''">laptop</a> is on your desk.'
gorodokKomp = 0

gad = 0
gs 'subkid'
if npc_QW['A33'] > 10:npc_QW['A33'] = 10

gs'dinsister'

if clrbelo <= 4: clrbelo = 5

act 'Exit the room':
	gt'korrPar'
end
if sisboyparty_day + 1 = daystart and sisboyparty = -1 and hour = 22:
	gs'family'
else
	gs'family'

	if rexCarCount >= 9 and sisterHere = 1 and hour < 3 and rexSmsDay ! daystart and smsForRex < 13:
		act 'Send Rex a SMS message':gt 'reks','sms'
	end

	if student > 0 and kursovik < 100:
		act 'Do coursework (1:00)':
			cla
			*clr
			minut += 60
			kursovik += rand(pcs_intel / 20, pcs_intel / 10)

			if kursovik > 100:kursovik = 100

			pcs_mood -= 10
			'<center><img <<$set_imgh>> src="images/pc/activities/study.jpg"></center>'
			'You sit down at the desk and do your coursework, you''ve finished <<kursovik>> percent of it.'

			act 'Leave your desk':gt $curloc
		end
	end

	!!Masturbation, allowed after sister threesome (when sis_watch is used for a message) or sister not here.
	sis_watch = 0

	if pcs_horny >= 50 and (sisboytrio > 0 or sisterHere = 0):
		act 'Masturbate':gt 'selfplay', 'start'
	end

	if pornMagazine > 0:'You have hidden your porn magazines under the mattress of your bed.'
	if (sisboytrio > 0 or sisterHere = 0) and pornMagazine > 0:gs 'events', 'read_porn'

	gs 'events', 'read'

	if tovarL > 0:'You currently have <<tovarL>> trinkets to sell at the station. The maximum you can carry with you is 30.'

	
	if vcard > 0:
		act 'Look at your deck of vintage porn cards':card_deck = 0 & gt 'card'
	end
	if card > 0:
		act 'Look at your deck of new porn cards':card_deck = 1 & gt 'card'
	end

!	if card > 0:
!		if card > 1:
!			act 'Look at your deck of vintage porn cards':gt 'card'
!		elseif card = 2:
!			act 'Look at your deck of new porn cards':gt 'card'
!		elseif card = 1 and card = 2:
!			act 'Look at your deck of vintage porn cards':gt 'card'
!			act 'Look at your deck of new porn cards':gt 'card'			
!		end
!	end

	if dur > 0:'You have hidden <<dur>> doses of Pale Lady.'

	if dur > 0 and narkday ! daystart:
		act 'Use some Pale Lady (0:05)':
			cla
			*clr
			minut += 5
			narkday = daystart
			pcs_health = pcs_vital * 10 + pcs_stren * 5
			pcs_willpwr = pcs_intel * 5 + pcs_sprt * 5
			pcs_mood = 100
			pcs_horny = 100
			nark += 10
			dur -= 1
			'<center><img <<$set_imgh>> src="images/shared/drugs/dur.jpg"></center>'
			'You snort some Pale Lady, feeling dizzy for just a moment. After that you feel fantastic, and incredibly horny.'

			act 'Continue':gt $curloc
		end
	end
end

if tanga = 0:
	act 'Wear underwear':
		cla
		tanga = 1
		gt $curloc
	end
elseif tanga = 1:
	act 'Take off your underwear':
		cla
		tanga = 0
		gt $curloc
	end
end

gs 'exercise', 'start'

if gobelen>0:'You have <<gobelen>> completed tapestries.'
if pcs_sewng >= 40 and tkan > 0:'You have enough fabric for <<tkan>> lessons.'
if pcs_sewng >= 40 and tkan <= 0:'You do not have any fabric.'
if pcs_sewng >= 80:
	if newgobelen = 0 and tkan > 0:
		act'Start a new tapestry':
			cls
			tkan -= 1
			newgobelen = 1
			minut += 15
			gs'stat'
			'You spend 15 minutes at the embroidery frame, preparing the fabric and outlining the pattern for the tapestry.'
			act'Set the tapestry aside':gt $curloc
		end
	end
	if newgobelen>=1:
		'Your tapestry is <<newgobelen/10>> percent finished.'
		act'Work on the tapestry for an hour':
			cls
			minut+=60
			sewng_exp += rand(pcs_intel/10, pcs_intel/5)
			gobramax = (pcs_sewng - 70) * 6
			gobramin = (pcs_sewng - 70) * 2
			newgobelen += rand(gobramin,gobramax)
			gs'stat'
			if newgobelen < 1000:'You spent an hour working on your tapestry, which is now <<newgobelen/10>> percent finished.'
				if newgobelen >= 1000:
				newgobelen = 0
				gobelen += 1
				'Your work on the tapestry is done.'
			end
			act'Set the tapestry aside':gt $curloc
		end
	end
end
if pcs_sleep <= 80:
	if succubusQW = 2:
		act 'Undress and go to sleep':
			if $clothingworntype ! 'nude': gs 'clothing', 'strip'
			gt 'bed2', 'succhoice'
		end
	else
		act 'Undress and go to sleep':
			if disable_autosave = 0:
				if StoryLine = 0:
					savegame 'autosave.sav'
				else
					savegame 'autosave_alt.sav'
				end
			end
			if $clothingworntype ! 'nude': gs 'clothing', 'strip'
			if magf2bdo = 2:
				gt 'bed2', 'magbstchoice'
			else
				gt 'bed2', 'sleep'
			end
		end
	end
end

--- bedrPar ---------------------------------