# gadforest_event

$location_type = 'event_outdoors'
gs 'stat'

if $ARGS[0] = 'find_meadow':
	*clr & cla
	menu_off = 1
	'<center><img <<$set_imgh>> src="images/locations/gadukino/meadow/meadow_path.jpg"></center>'
	*nl
	'As you walk through the forest, you notice a small path that runs along some bushes and a small ravine. The path leads away from the well worn tracks you are currently on and into a dense thicket.'

	act 'Ignore it and keep walking':gt 'gadforest', 'forest_edge'
	act 'Follow the path to see where it goes':
		*clr & cla
		meadow = 1
		minut += 10
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/gadukino/meadow/meadow_thicket.jpg"></center>'
		*nl
		'You follow the path to see where it goes, but soon it becomes indistinguishable from the bushes and trees around you.'

		act 'Look around':
			*clr & cla
			minut += 10
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/gadukino/meadow/meadow_trail.jpg"></center>'
			*nl
			'You''re about to return to the edge of the forest, but you spot a small break in the thicket, from the looks of it, it''s no more than an animal trail.'

			act 'Head down the trail':
				*clr & cla
				minut += 10
				gs 'stat'

				'<center><img <<$set_imgh>> src="images/locations/gadukino/meadow/meadow1_<<rand(0,5)>>.jpg"></center>'
				*nl
				'A few minutes later, you reach a majestic meadow filled with wildflowers. Judging by its undisturbed state no one else uses it or has been even been here in a long time.'

				act 'Claim the meadow as your own':
					*clr & cla
					minut += 10
					gs 'stat'

					'<center><img <<$set_imgh>> src="images/locations/gadukino/meadow/meadow1_<<rand(0,5)>>.jpg"></center>'
					*nl
					'You spend some time exploring the meadow and its surroundings. You''re positive no one visits this location. You proclaim the meadow to be your secret hideway all your own.'

					act 'Continue':gt 'meadow', 'start'
				end
			end
		end
	end
end

if $ARGS[0] = 'mira_picking_talk':
	*clr & cla
	menu_off = 1
	minut += 15
	mirapickingtalk = 1
	miratalkday = daystart
	npc_rel['A60'] += 2
	gs 'gadforest', 'bushcraft', 'forest_edge'
	gs 'stat'

	gs 'miroslava','miraclothes'
	*nl
	'"Hi <<$pcs_nickname>>, just wanted to let you know to be careful out here in the forest."'
	'"It is very easy to get lost if you wander away from the forest''s edge. But, the deeper you go into the forest, the more mushrooms and berries you can find."'
	'"Also every morning during the summertime the truck from the city comes to buy mushroms and berries from the local pickers. I don''t bother doing it, but I''m sure you could make some money from that if you wanted to."'
	'"One more warning, I''ve heard some of the other villagers say there are wolves in the forest that come out after dark, so you shouldn''t stay in the forest after sundown."'
	'"That''s one of the reasons why I prefer to walk around the forest''s edge in the morning. It''s much safer in the daylight when more people are around."'

	act 'Continue':gt 'gadforest', 'forest_edge'
end

if $ARGS[0] = 'mira_nude_talk':
	*clr & cla
	menu_off = 1
	minut += 15
	miranudetalk = 1
	miratalkday = daystart
	npc_rel['A60'] += 2
	gs 'gadforest', 'bushcraft', 'forest_edge'
	gs 'stat'

	gs 'miroslava','miraclothes'
	*nl
	'"Hey <<$pcs_nickname>>, guess what I overheard recently, Mira giggles, as she whispers in your ear. Some of the elders in the village were talking about how walking naked in the woods is said to greatly improve your health and mood."'
	'"I don''t know if it''s the fresh air or just being surrounded by nature, but it did make me feel better."'
	'"I may have tried it once, just to see if what they said was true. Maybe we can go together some time?"'

	act 'Continue':gt 'gadforest', 'forest_edge'
end

if $ARGS[0] = 'mira_nude_event':
	*clr & cla
	menu_off = 1
	minut += 15
	miranudetalk = 2
	miratalkday = daystart
	npc_rel['A60'] += 2
	gs 'gadforest', 'bushcraft', 'forest_edge'
	pcs_horny += 10
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/characters/village/mira/miraforest4.jpg"></center>'
	*nl
	'"<<$pcs_nickname>>, do you remember what I told you about walking in the forest? Why don''t we try it out together?" Mira asks.'
	'"You mean walking naked in the woods? you reply."'
	'"Silly, of course that" said Mira. "What do you say?"'
	'"I don''t know Mira." It''s an unexpected offer. On one hand you are a little afraid to do it, but on the other it could be exciting. "But what if someone sees us?"'
	'"Oh, don''t worry, no one will see us." She laughed, spun around and yelled out. "Is anybody here??"'
	'Aside from the chirping birds and some rustling leaves, there was no other sound.'
	'Mira turns back to you, "You see, no one is here. We are all alone."'
	'You hesitantly look around as Mira waits for you reply.'
	'"Well, <<$pcs_nickname>>, come on, make up your mind" Mira said cheerfully and started to mess with your clothes, trying to pull them off.'
	'Finally looking around to make sure no one is around, you decide to...'

	if pcs_inhib < 25:
		gs 'willpower', 'exhib', 'resist', 'easy'
	elseif pcs_inhib > 25 and pcs_inhib < 50:
		gs 'willpower', 'exhib', 'resist'
	elseif pcs_inhib > 50:
		gs 'willpower', 'exhib', 'resist',' hard'
	end
	if will_cost <= pcs_willpwr:
		act 'Resist and keep your clothes on (<<will_cost>> Willpower)':
			*clr & cla
			minut += 5
			pcs_horny += 5
			if pcs_inhib < 50:inhib_exp += rand(1,2)
			npc_rel['A60'] -= 3
			if pcs_inhib < 25:
				gs 'willpower', 'exhib', 'resist', 'easy'
			elseif pcs_inhib > 25 and pcs_inhib < 50:
				gs 'willpower', 'exhib', 'resist'
			elseif pcs_inhib > 50:
				gs 'willpower', 'exhib', 'resist',' hard'
			end
			gs 'willpower', 'pay', 'resist'
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/characters/village/mira/miraforest2.jpg"></center>'
			*nl
			'Mira pouts at you for refusing to undress for a moment then she smiles again, "Alright then, <<$pcs_nickname>>, we can still just go for a normal walk instead."'

			act'Continue':gt 'gadforest','forest_edge'
		end
	else
		act 'Resist and keep your clothes on (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
	end
	act 'Give in to Mira':
		*clr & cla
		minut += 5
		pcs_horny += 10
		if pcs_inhib < 50:inhib_exp += rand(2,4)
		npc_rel['A60'] += 5
		gs 'underwear', 'remove'
		gs 'clothing', 'strip', 'gadforest'
		gs 'exhibitionism', 3
		gs 'stat'

		'<center><img <<$set_imgh>> src="images/characters/village/mira/miraforest5.jpg"></center>'
		*nl
		'Seeing that your resistance has stopped, Mira quickly began to undress you, leaving your clothes in a pile on the forest floor.'

		act'Continue':gt 'gadforest','forest_edge'
	end
end

if $ARGS[0] = 'mushroom_pickers1':
	*clr & cla
	menu_off = 1
	minut += 5
	mushroom_pickersday = daystart
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/mushroom_pickers1.jpg"></center>'
	*nl
	'Wandering through the woods, you notice mushroom pickers from the village. You wonder whether you should look for mushrooms and berries here too, or go someplace else in the forest with less competition.'
	if $clothingworntype = 'nude':
		'You quickly remember you are naked right now and back away from them. It''s a good thing they didn''t see you here, if they did, it would be the talk of the whole village.'
		pcs_horny += 5
		inhib_exp += rand(1,3)
		gs 'stat'
	end

	act 'Continue':gt $loc, $metka
end

if $ARGS[0] = 'mushroom_pickers2':
	*clr & cla
	menu_off = 1
	minut += 5
	mushroom_pickersday = daystart
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/mushroom_pickers2.jpg"></center>'
	*nl
	'On the edge of the forest, you see mushroom pickers from the village going deeper into the forest. You wonder if you should follow them or stay along the edge of the forest where it is safer.'
	if $clothingworntype = 'nude':
		'You quickly remember you are naked right now and back away from them. It''s a good thing they didn''t see you here, if they did, it would be the talk of the whole village.'
		pcs_horny += 5
		inhib_exp += rand(1,3)
		gs 'stat'

		act 'Stay here':gt 'gadforest','forest_edge'
	else
		act 'Stay here':gt 'gadforest','forest_edge'
		act 'Follow them':gt 'gadforest','forest_outskirts'
	end
end

if $ARGS[0] = 'mushroom_pickers3':
	*clr & cla
	menu_off = 1
	minut += 5
	mushroom_pickersday = daystart
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/mushroom_pickers3.jpg"></center>'
	*nl
	'Wandering through the outskirts of the forest, you notice the mushroom pickers from the village had organized a camp.'
	if $clothingworntype = 'nude':
		'You quickly remember you are naked right now and back away from them. It''s a good thing they didn''t see you here, if they did, it would be the talk of the whole village.'
		pcs_horny += 5
		inhib_exp += rand(1,3)
		gs 'stat'

		act 'Leave them be':gt 'gadforest','forest_outskirts'
	else
		act 'Leave them be':gt 'gadforest','forest_outskirts'
		act 'Say Hello':
			minut += 5
			if pickersQW <= 3:pickersQW += 1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/mushroom_pickers3.jpg"></center>'
			*nl
			if pickersQW < 3:
				'You politely greet them as you are passing by. The men glance at you and respond the same.'
				act 'Leave':gt $loc, $metka
			else
				'You politely greet them as you are passing by. The men look at you and invite you to stop and chat for a bit.'
				act 'Leave':gt $loc, $metka
				act 'Chat':
					*clr & cla
					minut += 10
					gs 'gadforest', 'bushcraft', 'forest_outskirts'
					gs 'stat'

					'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/mushroom_pickers3.jpg"></center>'
					*nl
					pickersrand = rand(0,1)
					if pickersrand = 0:
						'They are very good at finding mushrooms and berries, one of them shows you his basket full of mushrooms and berries. You spend ten minutes talking about the forest and the best places to find mushrooms and berries, before getting up to continue on with your day.'
					elseif pickersrand = 1:
						'One of them asks, "How is your day going?"'
						if boletus + boletus_cooked + bilberry < 5:
							'"Not great today." you answer sadly, showing him your less than full basket.'
							'"Here you go, have a couple of mine." the man says, giving you a couple mushrooms and berries from his basket.'
							'You spend ten minutes talking about the forest and the best places to find mushrooms and berries, before getting up to continue on with your day.'
							boletus += rand(1,2)
							bilberry += rand(1,2)
						else
							'"Pretty well today." you answer happily, showing him your full basket.'
							'You spend ten minutes talking about the forest and the best places to find mushrooms and berries, before getting up to continue on with your day.'
						end
					end
					act 'Leave':gt 'gadforest','forest_outskirts'
				end
			end
		end
	end
end

if $ARGS[0] = 'mushroom':
	*clr & cla
	menu_off = 1
	minut += 5
	foresteventday = daystart
	gs 'gadforest', 'bushcraft', 'forest_center'
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/mushroom0.'+rand(1,3)+'.jpg"></center>'
	*nl
	'Wandering deep in the forest, you stumble upon a clearing full of mushrooms. How lucky!.'

	if boletus + boletus_cooked + bilberry < 5:
		act 'Gather mushrooms':
			*clr & cla
			minut += 60
			if $clothingworntype = 'nude':inhib_exp += rand(1,3)
			boletus += rand(3,5)
			gs 'stat'

			gs 'gadforest', 'picking_clothes', 'forest_center', 'mushroom'
			*nl
			'You begin collecting mushrooms trying to make everything fit in your basket.'

			act 'Continue':gt 'gadforest','forest_center'
		end
	else
		gs 'gadforest', 'picking_clothes_empty', 'forest_center'
		*nl
		'Unfortunately your basket is already full and you cannot carry any more mushrooms.'

		act 'Continue':gt 'gadforest','forest_center'
	end
end

if $ARGS[0] = 'bilberry':
	*clr & cla
	menu_off = 1
	minut += 5
	foresteventday = daystart
	gs 'gadforest', 'bushcraft', 'forest_center'
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/bilberry'+rand(3,5)+'.jpg"></center>'
	*nl
	'Wandering deep in the forest, you stumble upon a clearing full of berries. How lucky!.'

	if boletus + boletus_cooked + bilberry < 5:
		act 'Gather berries':
			*clr & cla
			minut += 60
			if $clothingworntype = 'nude':inhib_exp += rand(1,3)
			bilberry += rand(3,5)
			gs 'stat'

			gs 'gadforest', 'picking_clothes', 'forest_center', 'berry'
			*nl
			'You begin collecting berries trying to make everything fit in your basket.'

			act 'Continue':gt 'gadforest','forest_center'
		end
	else
		gs 'gadforest', 'picking_clothes_empty', 'forest_center'
		*nl
		'Unfortunately your basket is already full and you cannot carry any more berries.'

		act 'Continue':gt 'gadforest','forest_center'
	end
end

if $ARGS[0] = 'basket':
	*clr & cla
	menu_off = 1
	minut += 5
	foresteventday = daystart
	gs 'gadforest', 'bushcraft', 'forest_center'
	gs 'stat'

	foresteventrand = rand(1,2)
	if foresteventrand = 1:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/basket_boletus.jpg"></center>'
		*nl
		'Wandering in the forest you find a basket full of mushrooms. Strange, someone must have left it here or lost it.'

		if boletus + boletus_cooked + bilberry < 5:
			act 'Steal and empty them into your basket':boletus += 5
		else
			'Unfortunately your basket is already full and you cannot carry any more mushrooms.'
		end
	elseif foresteventrand = 2:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/basket_bilberry.jpg"></center>'
		*nl
		'Wandering in the forest you find a basket full of berries. Strange, someone must have left it here or lost it.'

		if boletus + boletus_cooked + bilberry < 5:
			act 'Steal and empty them into your basket':bilberry += 5
		else
			'Unfortunately your basket is already full and you cannot carry any more berries.'
		end
	end
	act 'Leave the basket alone':gt 'gadforest','forest_center'
end

if $ARGS[0] = 'picnic':
	*clr & cla
	menu_off = 1
	minut += 5
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/picnic1.'+rand(1,4)+'.jpg"></center>'
	'On the edge of the forest you see some people. Apparently they are having a family picnic.'

	if $clothingworntype = 'nude':
		'You quickly remember you are naked right now and back away from them. It''s a good thing they didn''t see you here, if they did, it would be the talk of the whole village.'
		'You shouldn''t be naked right now with this many people in this area of the forest. You''ll either need to get dressed or move to a more secluded area for now.'
		if clothesAtLocation = 1:
			act 'Hide and get dressed':
				*clr & cla
				minut += 5
				gs 'clothing', 'swamp_clothes', 0
				gs 'underwear', 'wear'
				gs 'clothing', 'recover_lost_clothes', 'forest_edge',1
				gs 'stat'

				if PCloSkirt = 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/nudeforest.jpg"></center>'
				if PCloSkirt > 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/nudeforest1.'+rand(1,2)+'.jpg"></center>'
				*nl
				'You change into your clothes before anyone spots you.'

				act 'Continue':gt 'gadforest','forest_edge'
			end
		end
		if meadow > 0:act 'Go to the meadow': minut += 15 & gt 'Meadow'
		act 'Go further into the forest':gt 'gadforest','forest_outskirts'
 	else
		act 'Continue':gt 'gadforest','forest_edge'
	end
end

if $ARGS[0] = 'forest_hunters':
	*clr & cla
	menu_off = 1
	minut += 5
	foresteventday = daystart
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanters.jpg"></center>'
	*nl
	if huntersKnow = 0:'Wandering through the woods you come across some people. Judging by their appearance they must be hunters.'
	if huntersKnow = 1:'Wandering through the woods you see the hunters, Andrei, Sergei and Igor.'

	act 'Leave them alone':gt 'gadforest', $ARGS[1]

	if $clothingworntype ! 'nude':
		act 'Approach the hunters':
			*clr & cla
			if huntersKnow = 0:
				huntersKnow = 1
				gs 'stat'

				'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanters.jpg"></center>'
				*nl
				'You decide to approach the strangers and chat. You never know, maybe they can show you some good places to find mushrooms and berries. After welcoming you, the whole company sat on the ground to rest and chat for a while.'
				'"What''s your name'+iif(pcs_apprnc >= 60,', beautiful','')+'?" one of them asks.'
				'"<<$pcs_nickname>>," you answer.'
				*nl
				if gadriver_gang = 0:
					minut += 30
					gs 'stat'

					'"I''m Andrei," replies the older man, "And these are my friends, from the village, Igor and Sergei."'
					'"By any chance is your last name <<$pcs_lastname>>?" he asked. You looked at him and nodded.'
					'"Don''t be surprised <<$pcs_nickname>>, you look a lot like your mother when she was younger. I ... Hmmm... very good to know, I''m also from Gadukino." said Andrei.'
					*nl
					'After chatting with them for about half an hour, the hunters begin to get up and gather their things.'
					'"Okay <<$pcs_nickname>>, it''s time for us to go." said Andrei.'
					'"If you want, we can bring you to the swamp," he added after a short pause. "From there we have made a path back to the village. We can show it to you if you come with us. Or if you want, you can even stay with us for a bit."'
					act 'Stay in the forest':gt 'gadforest', $ARGS[1]
					act 'Go with them':hunters_here = 1 & minut += 60 & gt 'swamp_yard', 'start'
				else
					minut += 15
					huntersKnowSlut = 1
					huntersRape = 1
					gs 'stat'

					'"What are you doing so far from the village?" asks the older man, looking at you closely, "It''s <<$pcs_nickname>> <<$pcs_lastname>>, the local whore.'
					'You look at him with a mixture of surprise and shock.'
					'"Don''t be surprised, I''m also from Gadukino, and you look just like your mother when she was younger, and apparently you are a whore like her too." he said.'
					'You don''t even remember us. We remember you from that day by the river with Uncle Stepan.'
					'"I''m Andrei, " he added further, "And these are my friends, also from the village, Igor and Sergei."'
					*nl
					if gadriver_gang > 2:'I''m not a whore. I told Uncle Stepan to go to hell! I didn''t want that to happen to me!'
					'"Don''t run away, we won''t hurt you." said Sergei, seeing you jump to your feet.'
					'"I think it''s about time I left" you reply.'
					'You quickly move away from them and only slowing once you can no longer hear them talking.'
					act 'Go back to the forest':gt 'gadforest', $ARGS[1]
				end
			else
				'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanters.jpg"></center>'
				*nl
				'You decide to approach the guys and chat.'

				if huntersKnowSlut = 0:
					minut += 30
					'After chatting with them for about half an hour, the hunters begin to get up and gather their things.'
					'"Okay <<$pcs_nickname>>, it''s time for us to go." said Andrei. "You should pay us another visit some time, ok?"'
					act 'Stay in the forest':gt 'gadforest', $ARGS[1]
					act 'Go with them':hunters_here = 1 & minut += 60 & gt 'swamp_yard', 'start'
				else
					'"Oh, <<$pcs_nickname>>, we were all looking forward to seeing you again" Andrei said with a smile.'
					'"How about you come back with us to our hut, we were just about to head back there anyways."'

					gs 'willpower', 'misc', 'resist', 'hard'
					if will_cost <= pcs_willpwr:
						act 'Stay in the forest  (<<will_cost>> Willpower)':
							gs 'willpower', 'pay', 'resist'
							gs 'stat'
							gt 'gadforest', $ARGS[1]
						end
					else
						act 'Stay in the forest (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
					end
					act 'Go with them':hunters_here = 1 & minut += 60 & gt 'swamp_yard', 'start'
				end
			end
		end
	elseif $clothingworntype = 'nude':
		if huntersKnowSlut = 0 and gadriver_gang = 0:
			act 'Keep walking':
				*clr &cla
				minut += 5
				if huntersKnowSlut = 0:huntersKnowSlut = 1
				pcs_horny += 20
				inhib_exp += rand(1,3)
				gs 'exhibitionism', 3
				gs 'stat'

				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/mitkanudeforest.jpg"></center>'
				*nl
				'You pretend not to notice the hunters and walk right past them, swaying your hips pointedly to maximize the effect. Looking around, you notice that the effect has exceeded your expectations. The men have been stopped in their tracks and are staring at you...'

				act 'Continue':gt 'gadforest', $ARGS[1]
			end
			act 'Hide':
				*clr & cla
				minut += 5
				gs 'stat'

				'<center><img <<$set_imgh>> src="images/locations/gadukino/forest/hiding_woods.jpg"></center>'
				*nl
				'They haven''t noticed you yet, so you quickly hide from sight in a nearby bush. You wait until you can no longer hear them talking to continue on your way.'

				act 'Continue':gt 'gadforest', $ARGS[1]
			end
		else
			'"Oh, <<$pcs_nickname>>, we were all looking forward to seeing you again" Andrei said with a smile.'
			'"How about you come back with us to our hut, we were just about to head back there anyways."'

			gs 'willpower', 'misc', 'resist', 'hard'
			if will_cost <= pcs_willpwr:
				act 'Stay in the forest  (<<will_cost>> Willpower)':
					gs 'willpower', 'pay', 'resist'
					gs 'stat'
					gt 'gadforest', $ARGS[1]
				end
			else
				act 'Stay in the forest (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
			end
			act 'Go with them':hunters_here = 1 & minut += 60 & gt 'swamp_yard', 'start'
		end
	end
end

if $ARGS[0] = 'mitka_temporary_event':
	! never had sex with Mitka or not the village whore
	if npc_QW['A63'] = 0 or gadriver_gang >= 3:
		! Mira is already fucking Mitka but not the boys slut yet
		if npc_QW['A60'] >= 2 and npc_QW['A60'] < 11:
			*clr & cla
			minut += 5
			mitkaday = daystart
			MiraLoc = 0
			gs 'stat'

			'<center><b><font color = maroon>Mitka Shkvoryen</font></b></center>'
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/mitka.jpg"></center>'
			*nl
			'While walking through the forest, you meet Mitka. You chat for a bit before saying goodbye. As you begin to walk away, you notice Mira is not with you.'
			'"<<$pcs_nickname>>, you go on, I need to talk to Mitka in private." She says blushing. "He''ll take me home."'
			'"Have fun!" you reply to Mira with a wink.'

			act 'Continue': gt 'gadforest','forest_edge'
			act 'Spy on them':
				! Sveta has not made Mira give her anal virginity to Mitka yet
				if npc_QW['A60'] < 6:
					*clr & cla
					gs 'arousal', 'voyeur', 5
					gs 'stat'

					'<center><img <<$set_imgh>> src="images/characters/village/mira/mirameadowsex.jpg"></center>'
					*nl
					'You decide to follow them from a safe distance. The forest offers plenty of places to hide and you have no trouble staying unseen.'
					'Mira and Mitka talk in whispers, slowly undressing as they walk, but you can''t hear a word they are saying.'

					act 'Watch':
						*clr &cla
						gs 'arousal', 'voyeur', 10
						gs 'stat'

						'<center><img <<$set_imgh>> src="images/characters/village/mira/mirameadowsex1.jpg"></center>'
						*nl
						if npc_QW['A60'] = 2:
							'Eventually, you arrive at your secret meadow. Mira lays down on a blanket in front of Mitka and spreads her legs invitingly. He doesn''t waste a second before he is on top of her her. He positions himself between her legs and starts eagerly slamming his cock roughly into her vagina. Mira certainly seems to be enjoying it though, as she moans and begs for more.'
						else
							'Eventually, you arrive at your not-so-secret meadow. You already know what is about to happen having seen it all before. Mira lays down on a blanket in front of Mitka and spreads her legs invitingly. He doesn''t waste a second before he is on top of her her. He positions himself between her legs and starts eagerly slamming his cock roughly into her vagina. Mira seems to be enjoying it even more than last time, as she moans and begs for more.'
						end

						act 'Continue Watching':
							*clr & cla
							if npc_QW['A60'] = 2:npc_QW['A60'] = 3
							mirasextimes += 1
							gs 'arousal', 'voyeur', 5
							gs 'stat'

							'<center><img <<$set_imgh>> src="images/characters/village/mira/mirameadowsex2.jpg"></center>'
							*nl
							'After a few more minutes Mitka pulls out and cums on her stomach. They rest for a little while and then get dressed and leave to head back to the village.'

							act 'Leave': gt 'gadforest','forest_edge'
						end
					end
				! Sveta has made Mira give her anal virginity to Mitka
				else
					*clr & cla
					gs 'arousal', 'voyeur', 5
					gs 'stat'

					'<center><img <<$set_imgh>> src="images/characters/village/mira/mirameadowsex.jpg"></center>'
					*nl
					'You decide to follow them from a safe distance. The forest offers plenty of places to hide and you have no trouble staying unseen.'
					'Mira and Mitka talk in whispers, slowly undressing as they walk, but you can''t hear a word they are saying.'

					act 'Watch':
						*clr & cla
						gs 'arousal', 'voyeur', 10
						gs 'stat'

						temp_gadf = rand(0,1)
						if temp_gadf = 0:
							'<center><img <<$set_imgh>> src="images/characters/village/mira/sex/mirameadowanal.jpg"></center>'
							*nl
							'Mira is working her ass up and down on Mitka''s hard member, every time she goes down her buttocks slap loudly on his thighs.'
						elseif temp_gadf = 1:
							'<center><img <<$set_imgh>> src="images/characters/village/mira/sex/mirameadowanal1.jpg"></center>'
							*nl
							'Mira is on all fours and moaning loudly as Mitka spreads her asshole with his fingers and then drives his cock all the way in her wide open hole.'
						end

						act 'Continue Watching':
							*clr & cla
							mirasextimes += 1
							gs 'arousal', 'voyeur', 5
							gs 'stat'

							'<center><img <<$set_imgh>> src="images/characters/village/mira/sex/mirameadowanal2.jpg"></center>'
							*nl
							'After a couple of minutes Mitka strongly slaps her ass and Mira quickly turns around, gets on her knees before him and sucks his cock for a few seconds before he shoots his warm cum all over her face.'

							act 'Leave': gt 'gadforest','forest_edge'
						end
					end
				end
			end
		! mira is the boys slut
		elseif npc_QW['A60'] >= 11:
			*clr & cla
			minut += 5
			mitkaday = daystart
			MiraLoc = 0
			gs 'stat'

			'<center><b><font color = maroon>Mitka Shkvoryen</font></b></center>'
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/mitka.jpg"></center>'
			*nl
			'Walking through the forest with Mira, you meet Mitka. Seeing Mira, Mitka grabbed her hand and pulled her into the nearest bush, seeing that Mira is not resisting, you decide not to interfere and mind your own business.'

			act 'Continue': gt 'gadforest','forest_edge'
			act 'Spy on them':
				*clr & cla
				gs 'arousal', 'voyeur', 10
				gs 'stat'

				temp_gadf = rand(0,1)
				if temp_gadf = 0:
					'<center><img <<$set_imgh>> src="images/characters/village/mira/sex/mirameadowanal.jpg"></center>'
					*nl
					'Mira is working her ass up and down on Mitka''s hard member, every time she goes down her buttocks slap loudly on his thighs.'
				elseif temp_gadf = 1:
					'<center><img <<$set_imgh>> src="images/characters/village/mira/sex/mirameadowanal1.jpg"></center>'
					*nl
					'Mira is on all fours and moaning loudly as Mitka spreads her asshole with his fingers and then drives his cock all the way in her wide open hole.'
				end

				act 'Continue Watching':
					*clr & cla
					mirasextimes += 1
					gs 'arousal', 'voyeur', 5
					gs 'stat'

					'<center><img <<$set_imgh>> src="images/characters/village/mira/sex/mirameadowanal2.jpg"></center>'
					*nl
					'After a couple of minutes Mitka strongly slaps her ass and Mira quickly turns around, gets on her knees before him and sucks his cock for a few seconds before he shoots his warm cum all over her face.'

					act 'Leave': gt 'gadforest','forest_edge'
				end
			end
		! Sveta does not know about Mira and Mitka yet or Miras quest is not started yet
		else
			*clr & cla
			minut += 5
			mitkaday = daystart
			gs 'stat'

			'<center><b><font color = maroon>Mitka Shkvoryen</font></b></center>'
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/mitka.jpg"></center>'
			*nl
			'Walking through the forest with Mira, you meet Mitka. You chat for a little while, noticing the interest Mira showed Mitka, before saying goodbye.'

			act 'Continue': gt 'gadforest','forest_edge'
		end
	! Sveta and Mira are both fucking Mitka but don''t know about it
	else
		*clr & cla
		minut += 5
		mitkaday = daystart
		gs 'stat'

		'<center><b><font color = maroon>Mitka Shkvoryen</font></b></center>'
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/mitka.jpg"></center>'
		*nl
		'Walking through the forest with Mira, you meet Mitka. He looks at you both like he is trying to decide something, but must have thought better of it because he continues to just chat normally. You talk for a bit longer before saying goodbye.'

		act 'Continue':gt 'gadforest','forest_edge'
	end
end

--- gadforest_event ---------------------------------