# clener
if $ARGS[0] = 'start':
	cla
	*clr
	CLOSE ALL
	if sound = 0 and hour >= 8 and hour < 17:PLAY 'sound/office.mp3',30 & PLAY 'sound/office2.mp3',30
	minut += 5
	clr
	gs 'stat'
	fcolor = rgb(0, 0, 0)
	bcolor = rgb(255, 255, 255)
	lcolor = rgb(106, 90, 205)
	'<center><b><font color="maroon">office building</font></b></center>'
	'<center><img src="images/etogame/clener.jpg"></center>'
	'On the walls there are different ads, one of which says:"Cleaner Wanted".'

	if svQW >= 1:
		if hour >= 8 and hour <= 16 and week < 6:
			'The door to the<a href="exec:gt ''torgpred''">Trade Mission</a> is open.'
		else
			'The door of the trade mission is closed and the schedule is visible:Sat and Sun 8:00--16:00'
		end
	end

	if jouryQwNo = 1 and hour = 17:
		'Yuri goes through the corridor (the same office worker who invited you for a walk, but you refused). He looks at you and starts coming closer.'

		act 'Talk to Yuri':
			cla
			minut += 15
			gs 'stat'
			'Yuri walks up to you and says, "<<$name>>, want to grab a cup of coffee?"'

			act 'No':jouryQwNo = 1 & gt 'clener', 'start'

			act 'Drink coffee':
				cls
				minut += 30
				gs 'stat'
				'You go to the café, where Yuri orders coffee. You sit down at the table and begin to drink. Yuri is painfully quiet. He has no sense of humor and is very stiff. Obviously he likes you, but he does not know what to do. When you are done with the coffee Yuri suggests (going with him?).'

				act 'No':jouryQwNo = 1 & gt 'clener', 'start'

				dynamic $youriqwest
			end
		end
	end

	if borodachQW > 0 and borodachSex = 0 and hour >= 19:'The security guard, Sasha, nods at you.'
	if borodachQW > 0 and borodachSex > 0 and hour >= 19:'The security guard, Sasha, smiles and says:"Hi <<$name>>!"'

	if borodachQW > 0 and hour >= 19:
		act 'Approach Sasha':
			cls
			minut += 5
			gs 'stat'

			if borodachSexDay = daystart:'You approach the security guard and say hello. You chat with him a bit, then Sasha has to go on a patrol and you let him go without disrupting him.'

			if borodachSexDay ! daystart:
				'You approach the security guard and say hello. He winks at you, "I stashed a bottle here, I''m sure we''ve both earnt a little break."'

				act 'Join him':
					cla
					minut += 5
					gs 'stat'
					'Sasha takes you into his cubbyhole and pulls out a bottle of vodka from under the table. He then reaches into a drawer and pulls out a piece of liver sausage and some cheese. He pours some of the vodka out into two glasses.'

					act 'Have a drink':
						cla
						'You drink the shitty vodka and it burns your throat. Your throat is on fire and you quickly grabbed some cheese to help soothe it. Sasha casually downs the glass and doesn''t even blink. "Ah, good one."'
						'While you are leaning over to eat the sausage, you feel a light touch as the guard pats you on the ass.'

						act 'Smile':
							cla
							minut += 15
							horny += 10
							gs 'stat'
							'You smile and Sasha pours more vodka, not stopping his caressing of your buttocks.'

							if horny < 50:dynamic $borodachNo2

							dynamic $borodachDrink
						end

						act 'Put your hand on his pants':
							cls
							minut += 15
							horny += 10
							borodachTimes += 1
							gs 'stat'

							picrand = rand(0, 2)

							if picrand = 0:'<center><img src="images/qwest/ohrannik/hj.jpg"></center>'
							if picrand = 1:'<center><img src="images/qwest/ohrannik/hj1.jpg"></center>'
							if picrand = 2:'<center><img src="images/qwest/ohrannik/hj2.jpg"></center>'

							'You put your hand on his crotch and feel his erection harden. Your thin fingers slide over his hardon and find the zipper. You unzip him and get his cock out of his pants. Sasha relaxes on the couch waiting for you to continue what you started.'
							dynamic $ohrhj
							dynamic $ohrbj
						end
					end
				end
			end

			act 'Leave':gt 'clener', 'start'
		end
	end

	if clenerT >= 3 and borodachQW = 0 and hour >= 19:
		'On a chair in front of the guard sits a crossword and he painfully remembers something. He asks you. "Bad ending to the case, and the second letter is I."'

		act 'Reply guard':
			cls
			borodachQW = 1
			'"Fiasco"'
			'The guard smiles. "Exactly I knew PIZDETS couldn''t be the answer.'

			act 'Leave':gt 'clener', 'start'

			act 'Laugh out loud':
				cla
				borodachQW = 2
				'You laugh at the security guard, he smiles and puts aside the crossword. "You must be new, I haven''t seen you before. Cleaning lady work?"'
				'You nod, "Yes, moonlighting, they pay the kind of money that you would not call it work."'
				'"By the way I''m Sasha, and you?'
				'"Your World."'
				'"Very nice. I''ve got a bottle and have a break, Would you join me?'

				act 'Sorry, I have to go':gt 'clener', 'start'

				act 'Why not?':
					cla
					minut += 5
					gs 'stat'
					'Sasha takes you into his cubbyhole and takes out a bottle of vodka from under the table, reached into a drawer and pulls out a piece of liver sausage and some cheese. Takes out a couple of glasses and pours vodka in them.'

					act 'Have a drink':
						cla
						'You drank vodka give zhzhonoy rubber and booze. Breath you perlo of shit and you quickly grabbed cheese zanyuhivat friendship. Sasha habitually slammed the glass and not even pomorschalsya. "Ah, well gone."'
						'While you are leaning to the table and nibbled zanyuhivali, you feel like a hand guard as if by chance, you stroking light touch on the ass.'

						act 'React':
							cla
							minut += 15
							horny += 10
							gs 'stat'
							'"Hey! What are you doing?"'
							'"C''mon, it was accident." Sasha began to mutter pouring more vodka. "Let''s have a drink."'

							if horny < 50:dynamic $borodachNo

							dynamic $borodachDrink
						end

						act 'To pretend not to notice':
							cla
							minut += 15
							horny += 15 + SUB
							gs 'stat'
							'You ate, trying not to pay attention to it, as it was only a casual touch. Sasha poured more vodka and say "Between the first and second glass, not great," he knocks over a glass.'
							if horny < 50:dynamic $borodachNo
							dynamic $borodachDrink
						end
					end
				end
			end
		end
	end

	if clener >= 10 and clenerT = 0:
		act 'Ask for more work':
			cla
			'You ask Boris Ivanovich whether he has more work for you. He says that he needs a cleaner for cleaning the toilets. You can work almost every day. Cleaning toilets for an hour gets you 100 <b>₽</b> immediately in hand.'

			act 'Refuse and leave':gt 'street'

			act 'Agree to work':
				cla
				clenerT = 1
				'You agreed to work.'

				act 'Leave':gt 'clener', 'start'
			end
		end
	end

	if clener = 1:
		act 'Talk about available jobs':
			cla
			'You go into the office that advertised the job. You meet a large man in a jacket. He tells you you can work almost every day. Office cleaning 100 <b>₽</b> per hour, cash.'

			act 'Refuse and leave':gt 'street'

			act 'Agree to work':
				cla
				clener = 2
				'You agreed to work.'

				act 'Leave':gt 'clener', 'start'
			end
		end
	end

	if clener > 1 and clenday ! daystart:
		act 'Mop the floor in the office (1:00)':
			cla
			*clr
			clenday = daystart
			minut += 60
			clener += 1
			manna -= 15
			money += 100
			sweat += 2
			'<center><img src="images/etogame/clener1.jpg"></center>'

			if clener < 5:
				if hour >= 9 and hour <= 16:'You fill a bucket of water and go to the office with a mop. The office staff keeps out of the way while you clean the floor.'
			elseif clener >= 5 and clener < 10:
				if hour >= 9 and hour <= 16:
					jouryQw += 1
					'You fill a bucket of water and go to the office with a mop. The office staff keeps out of the way while you clean the floor. One of the office workers, a man with blond hair and a red face looks at you and tries to hide it, but you feel his burning gaze.'
				end
			elseif clener >= 10:
				if hour >= 9 and hour <= 16 and jouryQw < 7:
					jouryQw += 1
					'You fill a bucket of water and go to the office with a mop. The office staff keeps out of the way while you clean the floor. One of the office workers, a man with blond hair and a red face looks at you and tries to hide it, but you feel his burning gaze.'
				elseif jouryQw = 7 and hour >= 9 and hour <= 16:
					cls
					gs 'stat'
					jouryQw += 1
					'<center><img src="images/etogame/clener1.jpg"></center>'
					'You fill a bucket of water and go to the office with a mop. All the staff are out of the office, except for a red faced blond. He walks up to you and visibly nervous and quiet says. "Hi. My name Yuri. I love you. Can we meet and do something after work?"'

					act 'No':
						cla
						jouryQwNo = 1
						'After the work is complete you go to the commandant of the building Boris Ivanovich. He gives you 100 <b>₽</b> for the work.'

						act 'Leave':gt 'clener', 'start'
					end

					act 'Yes':
						cla
						minut += 15
						gs 'stat'
						'Yuri said that he finishes work now and will meet you at the entrance to the building.'
						'After the work completed you go to the commandant of the building Boris Ivanovich. He gives you 100 <b>₽</b> for the work.'
						'As you leave, there at the entrance to the building Yuri is already waiting for you. He''s pretty emotional and it seems as if he doesn''t know what to do. Not knowing what to say, he blurts out, "Maybe we''ll go to me, the movie''s look, drink champagne, we''ll talk."'

						act 'No':jouryQwNo = 1 & gt 'clener', 'start'

						dynamic $youriqwest
					end

					exit
				end

				if jouryQw > 7 and hour >= 9 and hour <= 16 and jourySex = 0:'You fill a bucket of water and go to the office with a mop. The office staff keeps out of the way while you clean the floor. Yuri looks at you studying every inch of your figure.'
				if jouryQw > 7 and hour >= 9 and hour <= 16 and jourySex > 0:'You fill a bucket of water and go to the office with a mop. The office staff keeps out of the way while you clean the floor. Yuri pretends not to notice you in the office.'
			end

			if hour < 9 or hour > 16:'In the office is unoccupied, you quietly washed the floor and wiped the floor in the office.'

			'After the work is complete you go to the commandant of the building Boris Ivanovich. He gives you 100 <b>₽</b> for the work.'

			act 'Leave':gt 'clener', 'start'
		end
	end

	if clenerT >= 1 and clendayT ! daystart:
		act 'Clean toilets (1:00)':
			cla
			*clr
			clendayT = daystart
			minut += 60
			clenerT += 1
			manna -= 25
			money += 100
			sweat += 3
			'<center><img src="images/etogame/clener2.jpg"></center>'

			if jouryQw > 7 and hour >= 9 and hour <= 16 and jourySex > 0 and jouryResult = 0:
				'You entered the booth and begin to scrub the toilet bowl. The toilet door slams as somebody comes in, you looked out of the booth and saw George. He, too, saw you and came to you. "<<$name>>, do not come to me in the office, well, you know, the team does not understand that I''m meeting with the cleaner."'

				act 'You make me ashamed?':
					cla
					'You come off the toilet and looked into the eyes of Yuri and asked, "You ashamed of me?" Yuri stammered, "Well, not that that would be embarrassed, but you must understand, I am a manager, you lady. We must not be seen together. But I want you to continue on. You know where I live, came to see me after 4 pm."'

					act 'Fuck you':
						cla
						dom += 1
						jouryResult = 1
						'Such behavior has offended you and without hesitation you send Yuri packing. He turned and walked out of the closet.'
						'You washed the floor in the toilet and buffed all the toilets and urinals to a shine. After that you were given 100 <b>₽</b> for his work.'

						act 'Leave':gt 'clener', 'start'
					end

					act 'Okay.':
						cla
						sub += 1
						jouryResult = 10
						'Yuri sees you only as a hole for his member. But you put up with it and agreed to go to his home. Yuri nodded in satisfaction and walked out of the toilet.'
						'You washed the floor in the toilet and buffed all the toilets and urinals to a shine. After that you were given 100 <b>₽</b> for his work.'

						act 'Leave':gt 'clener', 'start'
					end
				end

				exit
			end

			if StasikValera > 0 and SVqw = 0:
				'You cleaned the toilets to a shine at this moment you hear the toilet door as someone walks in, turning around you see a man. You recognise him, it Stasik, with him his friend Valera you met at the beach. Stasik also apparently recognize you and comes up to you, "Hi <<$name>>, you work as a cleaner?"'

				act 'Explain':
					cls
					gs 'stat'
					'<center><img src="images/etogame/clener2.jpg"></center>'
					'You shrug. "I need the money. I earn the money."'
					'Stasik smiles "Well, for an attractive girl I can find a decent part-time job. I just need merchandisers."'

					act 'Further':
						cls
						SVqw = 1
						gs 'stat'
						'<center><img src="images/etogame/clener2.jpg"></center>'
						'You ask about the details. Stasik tells you, "It''s very simple. In northern, central and residential areas are supermarkets. You come to our office to take a job to work, then go to all three stores and arrange our products there, making changes according to the assignment. At the checkout take receipt confirming that that you were at work. Thereafter, head back to our office and we will pay you compensation. 500 <b>₽</b> for a few hours work. No hard labour, what do you say?"'

						act 'Not interested':gt 'clener', 'start'

						act 'I agree':
							cls
							SVqw = 2
							gs 'stat'
							'<center><img src="images/etogame/clener2.jpg"></center>'
							'You agreed and Stas nods, then walks out of the toilet.'

							act 'Leave':gt 'clener', 'start'
						end
					end
				end

				exit
			end

			'You washed the floor in the toilet and polished all the toilets and urinals to a shine. After that you were given 100 <b>₽</b> for your work.'

			act 'Leave':gt 'clener', 'start'
		end
	end

	act 'Leave':gt 'street'
end

--- clener ---------------------------------