# city_residential

! 14-09-22 Added Metro link to navigation line 88

music_loop = 0
CLOSE ALL
$loc_arg = ''
$loc = 'city_residential'
$region = 'city'
$location_type = 'public_outdoors'
$menu_loc = 'city_residential'
$menu_arg = ''
menu_off = 0
killvar '$locclass'

if sound = 0:
	if month >=11 and month <= 12 or month >=1 and month <=3:
		if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/zima.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_night.mp3',30 & PLAY 'sound/zima.mp3',30
	else
		if hour >= 8 and hour <= 23: PLAY 'sound/street2.mp3',30 & PLAY 'sound/street7.mp3',30 & PLAY 'sound/street_leto.mp3',30
		if hour >= 0 and hour <= 7: PLAY 'sound/street_night_leto.mp3' & PLAY 'sound/street_night.mp3',30
	end
end

!all random events move to [street_events], and display them before show location. by illume
if streetevent_hour + 2 < hour:gt'street_event','city_residential', 'main'

'<center><h2>St. Petersburg</h2></center>'
'<center><b>Residential Area</b></center>'
if month >= 11 or month <= 3:
	if daystage = 2 or daystage = 3:
		'<center><img <<$set_imgh>> src="images/locations/city/residential/streetw.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/residential/streetwn.jpg"></center>'
	end
else
	if daystage = 2 or daystage = 3:
		'<center><img <<$set_imgh>> src="images/locations/city/residential/street.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/residential/street_night.jpg"></center>'
	end
end

gs'street_event','city_residential', 'extras'

if opusk > 0 or gnewQW = 5:
	if rand(0,9) = 0:gt 'gopnew', 'start5'
	if func('homes_properties', 'has_access', 'city_apartment'):'Something is written on the wall near the entrance to your building. It reads:<b>"<<$pcs_firstname>> <<$pcs_lastname>> from apartment 69 is a cheap slut!"</b>'
end

gs 'stat'

if gopdeath = 1 and vsehsdaladay ! daystart:
	over = 6
	gt 'gameover'
end

if car > 0 and cardrive = 1 or cardrive = 8:
	if cardrive = 8:
		'<a href="exec: minut += 10 & gs ''carF'', ''start''">Your <<$car>></a> is in your driveway.'
	else
		'<a href="exec:gs ''carF'', ''start''">Your <<$car>></a> is in the parking lot.'
	end
end

if func('homes_properties', 'is_property_of_status', 'owned', 'city_house'):
	'Your <a href="exec: minut += 10 & gs ''city_house_res_misc'', ''fronty''">house</a> is within walking distance.'
	act '<b>Go to your house</b>':
		minut += 10
		gt 'city_house_res_misc', 'fronty'
	end
end

if func('homes_properties', 'has_access', 'city_apartment'):
	act '<b>Go to your apartment</b>':
		gorand = rand(0, 100)

		if (loh > 0 or gnewQW = 7) and gopdolg > 0 and hour >= 20 and gorand >= 80:
			gt 'gopnew', 'start'
		end

		if (opusk > 0 or gnewQW = 5) and hour >= 20 and gorand >= 80 and gopopusday ! daystart:
			gt 'gopnew', 'start'
		end
		minut += 1
		gt 'korr'
	end
end
if hour >= 4 and hour <= 23:
	act 'Walk to the Metro': minut += 5 & gt 'metro', 'start'
end

act 'Walk to the central park (0:20)': minut += 20 & gt 'city_park', 'start'
act 'Walk to the lake': minut += 40 & gt 'city_lake', 'start'

act 'Wait':gs 'obj_din', 'wait'

gs 'taxi'

if hour >= 8 and hour <= 22:'You can see the <a href="exec:$loc = ''city_residential'' & minut += 1 & gt ''kiosk'', ''start''">kiosk</a> selling cigarettes and magazines.'
if Enable_tablemap = 0:
	if katkey = 1:'<a href="exec:gt ''katspalnya'', ''start''">Kat''s</a> apartment'
	if IrinaQW >= 1:'<a href="exec:gt ''city_irinaroom'', ''start''">Irene''s</a> apartment is not far from yours.'
	if hour >= 16 and hour < 22 and dimaQW > 0:'<a href="exec:gt ''city_dima'', ''start''">Dima''s</a> apartment'
	if klofQW >= 2:'<a href="exec:gt ''city_jorahouse'', ''start''">Jora''s</a> apartment'
else
	st_count=0 & $show_table=''
	if katkey = 1:gs'show_table','<a href="exec:gt ''katspalnya'', ''start''">Kat''s</a> apartment','3'
	if IrinaQW >= 1:gs'show_table','<a href="exec:gt ''city_irinaroom'', ''start''">Irene''s</a> apartment is not far from yours.','3'
	if hour >= 16 and hour < 22 and dimaQW > 0:gs'show_table','<a href="exec:gt ''city_dima'', ''start''">Dima''s</a> apartment','3'
	if klofQW >= 2:gs'show_table','<a href="exec:gt ''city_jorahouse'', ''start''">Jora''s</a> apartment','3'
	if hour >= 10 and hour < 22 and lesbiQW = 1:
		gs'show_table','<a href="exec:gt ''lesbidomhouse'', ''start''">Natalya Petrovna''s</a> apartment.', '3'
	elseif lesbiday ! daystart and subdom = 2:
		gs'show_table','<a href="exec:gt ''lesbisubhouse'', ''start''">Your slave''s</a> apartment.','3'
	elseif lesbiday ! daystart and hour >= 8 and hour < 22 and lesbiQW >= 2 and lesbiQW < 13:
		gs'show_table','<a href="exec:gt ''lesbidomhouse'', ''start''">Mistress''s</a> apartment.','3'
	elseif lesbiday ! daystart and hour >= 8 and hour < 22 and lesbiQW >= 13:
		gs'show_table','<a href="exec:gt ''lesbimistress'', ''start''">Mistress''s</a> apartment.','3'
	end
	if st_count > 0 :'<TABLE BORDER=1><<$show_table>></TR></TABLE>'
end

if hour >= 5 and hour <= 23:'The <a href="exec: minut += 1 & gt ''metro'', ''start''">Metro</a> station is a 5 minute walk away.'
if hour >= 8 and hour <= 20:'The <a href="exec: minut += 3 & gt ''shop'', ''start''">supermarket</a> is not far from here.'
if (hour >= 8 and hour <= 20) or preg = 2:
	'The <a href="exec:gt ''city_clinic'', ''start''">clinic</a> is also nearby.'
else
	'The clinic is close. It will open at 08:00.'
end
if hour >= 6 and hour <= 9 and military = 1 and week = 6:
	'There is a <a href="exec:minut += 60 & gt ''Military'', ''start''">military bus</a> waiting on the other side of the street.'
elseif military = 1:
	'The military bus will wait between 06:00 and 09:00 on Saturdays.'
end
if hour >= 8 and hour <= 14 and week ! 1:
	'You could go shopping at the noisy local <a href="exec: minut += 10 & gt ''city_market'', ''start''">marketplace</a>.'
else
	'You could go shopping at the noisy local marketplace, but it''s '+iif(week = 1, 'closed on Mondays.', 'only open between 08:00 and 15:00.')
end
if hour >= 8 and hour <= 15 and week < 6:
	'Near the market is a <a href="exec: minut += 10 & gt ''city_market'', ''tailor''">tailor shop</a> where you can get your clothes resized if needed.'
else	
	'Near the market is a tailor shop where you can get your clothes resized if needed. '+iif(week < 6, 'It closes at 16:00.', 'It''s closed on weekends.')
end
if hour >= 11 and hour < 12 and week > 1 and week < 5 and workKafe['job'] = 1:
	'The side door of <a href="exec: minut += 1 & gt ''city_kafe'', ''work''">"The Roadhouse"</a> is open, allowing employees to enter to begin their shift.'
elseif hour >= 12 and hour <= 22 and week ! 1:
	'In a side alley, next to the uniquely styled diner <a href="exec: minut += 1 & gt ''city_kafe'', ''start''">"The Roadhouse"</a>, you can hear some <a href="exec: minut += 1 & gt ''gopnew'', ''start''">gopniks</a> swearing and laughing.'
elseif hour > 22 or hour <= 3:
	'You can hear the swearing and laughing of some <a href="exec:gt ''gopnew'', ''start''">gopniks</a> in the parking lot of "The Roadhouse" diner.'
else
	'The Roadhouse diner is closed right now. It''s open between 12:00 and 23:00 every day except Monday.'
end
if clener >= 1 and hour >= 7 and hour <= 22:'There''s a small office building where a <a href="exec: minut += 1 & gt ''city_smalloffice'', ''start''">cleaning lady</a> is needed.'

'The city''s large <a href="exec:minut += 20 & gt ''city_park'', ''start''">central park</a> is a 20 minute walk away.'
'The city''s only <a href="exec:minut += 40 & gt ''city_lake'', ''start''">lake</a> is a 40 minute walk away.'
'24 Hour <a href="exec:$loc = ''city_residential'' & gt ''city_pharmacy'', ''start''">Pharmacy</a>.'

if Enable_tablemap = 0:
	if hour >= 10 and hour < 22 and lesbiQW = 1:
		'<a href="exec:gt ''lesbidomhouse'', ''start''">Natalya Petrovna''s</a> apartment.'
	elseif lesbiday ! daystart and subdom = 2:
		'<a href="exec:gt ''lesbisubhouse'', ''start''">Your slave''s</a> apartment.'
	elseif lesbiday ! daystart and hour >= 8 and hour < 22 and lesbiQW >= 2 and lesbiQW < 13:
		'<a href="exec:gt ''lesbidomhouse'', ''start''">Mistress''s</a> apartment.'
	elseif lesbiday ! daystart and hour >= 8 and hour < 22 and lesbiQW >= 13:
		'<a href="exec:gt ''lesbimistress'', ''start''">Mistress''s</a> apartment.'
	end
end

if func('homes_properties', 'has_access', 'city_apartment') = 0:
	'You see several <a href="exec: minut += 1 & gt ''city_trashplace''">trash bins</a> in the courtyard of one of the apartment buildings.'
else
	'You see several <a href="exec: minut += 1 & gt ''city_trashplace''">trash bins</a> in the courtyard of your <a href="exec: gt ''city_apt_building'',''floor_1''">apartment building</a>.'
end

if SNarkPriton > 0:'The <a href="exec:minut += 1 & gt ''city_drugden''">drug house</a> is clearly recognizable by the syringes and trash that lies in front of it.'
if hour >= 8 and hour <= 23 or saunaWorkWhore > 0 or workDisk = 2:'<a href="exec:minut += 10 & gt ''city_sauna''">The sauna</a> is a 10 minute walk away. Rumors say that it''s just a front for a brothel.'

if hour >= 20 or hour <= 4:
	*nl
	'There are prostitutes working near here.'
	if pcs_makeup > 2 and PCloStyle = 4 and pcs_inhib >= 40 and (stat['vaginal'] >  0 or fame['pav_slut'] >= 100):
		act 'Prostitute yourself': gt 'street_walker', 'work'
	elseif pcs_inhib >= 40 and (stat['vaginal'] >  0 or fame['pav_slut'] >= 100):  
		*nl
		'You could work as a prostitute, but you need to wear appropriate clothes and more than a little bit of makeup.'
	else
		*nl
		'You could work as a prostitute, but you aren''t comfortable with the idea.'
	end
end

if booty_call_time['A0'] = daystart:
	i=0
	*nl
	:loopBC
	if booty_call[$fuckbuddy[i]] = daystart and npc_residence[$fuckbuddy[i]] = 3:   
		dynamic(' ''<a href="exec: minut += 2 & gt ''''booty_call_start'''',''''start'''',''''<<$fuckbuddy[i]>>'''' "><<$npc_firstname[$fuckbuddy[i]]>>''''s</a> apartment is nearby.'' ')
	end
	 i +=1
	if i < arrsize('$fuckbuddy') : jump 'loopBC'
end

--- city_residential ---------------------------------

