# pornstudio
!!2021/07/17

$location_type = 'public_indoors'

if $ARGS[0] = 'start':
	CLOSE ALL
	$loc_arg = 'start'
	$loc = 'pornstudio'
	$menu_loc = 'pornstudio'
	$menu_arg = 'start'
	menu_off = 0
	gs 'pornhist', 'short'
	cls
	minut += 5
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/studia_0.jpg"></center>'

	act 'Leave': gt 'city_redlight', 'start'

	if hour < 10 or hour > 22:
		'The porn studio is currently closed. It is open between 10:00 and 22:00.'
		exit
	end

	'You enter the studio and are greeted by a busy scene of actors, actresses and other studio employees going about their business or chatting to each other. It looks like the manager is in his office.'

	act 'Go to the manager': gt 'pornstudio', 'manager'

	act 'Visit the manager''s PA': gt 'pornstudio', 'pa'

	if bomzQW = 1 and week = 4 and workDisk = 0: act 'Arrive for work': gt 'pornstudio', 'delivery'

	if workDolg > 0 and money >= workDolg:
		act 'Repay your debt':
			cls
			menu_off = 1
			minut += 5
			workDisk = 0
			money -= workDolg
			workDolg = 0
			menu_off = 1
			gs 'stat'
			'You give the money that you owe to the studio.'

			act 'Leave': gt 'pornstudio', 'start'
		end
	elseif workDolg = 0:
		if workDisk = 1 and week = 5:
			act 'Take the disk':
				cls
				menu_off = 1
				minut += 5
				workDisk = 2
				gs 'stat'
				'You are given a thumb drive, and asked if you remember all the instructions. You quietly nod and leave.'
				'As you leave the studio, you hear someone exit a nearby building and start following you.'
				'<font color="magenta"> "Just avoid dark, deserted places and this will blow over."</font> you reassure yourself, and carry on.'

				act 'Leave': gt 'city_redlight', 'start'
			end
		elseif workDisk = 3 and week = 5:
			act 'Give the envelope':
				cls
				menu_off = 1
				minut += 5
				workDisk = 4
				gs 'stat'

				if konvert = 0:
					workDolg = 200000
					workDolgDay = 7
					'Digging through your things, you begin to panic. No envelope. You search again, but to your despair, you can''t find it. You stand there, unable to speak.'
					'The manager grabs his phone and makes a call. You can''t hear exactly what he''s saying because your heart is beating so loud, but he soon hangs up.'
					'"You''re very lucky the boss is in a good mood. He''s given you one week to recover his losses, so you have until next Friday evening to bring me 200,000 <b>₽</b>. Do this and we''re done, you''ll never work for us again. Fail, and bad things will happen to you." he says with a stern look on his face.'
				else
					konvert = 0
					money += 5000
					'You give the envelope to the manager and he gives you 5,000 <b>₽</b>.'
				end

				act 'Leave': gt 'city_redlight', 'start'
			end
		end
	end

	if pfilmNoVenera = 1 and Venera = 0:
		act 'Show your medical certificate':
			cls
			menu_off = 1
			minut += 5
			pfilmNoVenera = 0
			gs 'stat'
			'You hand over your medical certificate showing that you''re STD free. They promise to consider your reinstatement.'

			act 'Leave': gt 'pornstudio', 'start'
		end
	end
end

if $ARGS[0] = 'pa':
	*clr & cla
	minut += 5
	$menu_loc = 'pornstudio'
	$menu_arg = 'pa'
	menu_off = 0
	gs 'stat'
	'Inside the small office is a young man sitting at a computer, tapping away at the keyboard.'

	if film = 0:
		'"Who are you? This office is for staff only."'
	else
		'"Hi there, what can I do for you?"'
		if pfilmNO = 0:
			act 'Change your porn name':
				*clr & cla
				menu_off = 1
				gs 'stat'
				'"Is it possible for me to change my stage name?"'
				'"Of course! Just give me a minute to register it in the database. So, what would you like to be called?" he replies.'
				act '"I want to be called..."':
					$pfname = input("Enter the name you want to be known as.")
					if $pfname = '':$pfname = 'Lotta Cox'
					gt 'pornstudio', 'pa'
				end
				act 'Nothing': gt 'pornstudio', 'pa'
			end
		end
		if pfilmSTOP = 0:
			act 'What''s the rating of my videos?':
				cla
				minut += 5
				menu_off = 1
				gs 'stat'

				'"You''ve made <<film>> films."'

				if porn_fame < 10:
					'"Nobody knows your name. You''re one of hundreds of amateur actresses who only play minor roles in big movies. Your own movies sold really cheap."'
				elseif porn_fame < 20:
					'"You''re still unknown, but your name is mentioned in the credits. You''re unlikely to be recognized, and your own movies are still sold cheap."'
				elseif porn_fame < 40:
					'"You''re mentioned here and there, but you still mostly get secondary roles in most of your movies. Your name is slowly emerging and you have your own fanbase."'
				elseif porn_fame < 60:
					'"You''re a minor, but known porn actress. You get the occasional primary role and back cover appearance. Your movies are getting more popular, which means more fans and more money."'
				elseif porn_fame < 80:
					'"You''re a known porn actress who mostly plays primary roles, and you appear on the front cover. Your movies are sold at a decent price, and in big numbers. You may also appear in a variety of adult magazines."'
				else
					'"You''re a famous porn starlet and always play the main role. You''re a brand name, with sex toys and T-shirts among the items sold as part of your own line of merchandise."'
				end

				if porn_fame >= 20:
					ftypecount[0] = pornvag & $ftypecount[0] = 'vaginal'
					ftypecount[1] = pornanal & $ftypecount[1] = 'anal'
					ftypecount[2] = porngasm & $ftypecount[15] = 'orgasm'
					ftypecount[3] = porngang & $ftypecount[3] = 'group sex'
					ftypecount[4] = porncream & $ftypecount[4] = 'creampie'
					ftypecount[5] = pornhole & $ftypecount[5] = 'gloryhole'
					ftypecount[6] = pornbdsm & $ftypecount[6] = 'bdsm'
					ftypecount[7] = pornlesbo & $ftypecount[7] = 'lesbian'
					ftypecount[8] = pornpreg & $ftypecount[8] = 'pregnant'
					ftypecount[9] = pornexhib & $ftypecount[9] = 'public'
					ftypecount[10] = pornmast & $ftypecount[10] = 'masturbation'
					ftypecount[11] = pornbukk & $ftypecount[11] = 'cumshot'
					ftypecount[12] = pornbj & $ftypecount[12] = 'blowjob'
					ftypecount[13] = pornhj & $ftypecount[13] = 'handjob'
					ftypecount[14] = pornswall & $ftypecount[14] = 'cum swallowing'
					k = 1
					:repeating
						c = 14
						:ftypecount
							current = ftypecount[c]
							$current = $ftypecount[c]
							c -= 1
							if current > ftypecount[c]:
								ftypecount[c+1] = ftypecount[c]
								$ftypecount[c+1] = $ftypecount[c]
								ftypecount[c] = current
								$ftypecount[c] = $current
							end
						if c >= k:jump 'ftypecount'
						k += 1
					if k < 14:jump 'repeating'
					if ftypecount[1] = ftypecount[0]:
						if ftypecount[0] = ftypecount[2]:
							'You''re known for your <<$ftypecount[0]>>, <<$ftypecount[1]>> and <<$ftypecount[2]>> scenes.'
						else
							'You''re known for your <<$ftypecount[0]>> and <<$ftypecount[1]>> scenes.'
						end
					else
						'You''re known for your <<$ftypecount[0]>> scenes.'
					end
				end

				if film < 10 and porn_fame < 10:

					'"By the way, if you wanted, I could completely remove them from our systems - for the right price of course." the guy whispers.'

					act 'Tell me more':
						cla
						minut += 5
						films_stop_payment = film * 40000
						gs 'stat'
						'"Seeing as you''re not well known, it''s unlikely anyone would notice. However, to remove them you''d have to cover the loss of the studio''s profits- 40,000 <b>₽</b> per film. That''s a total of <<films_stop_payment>> <b>₽</b>."'
						'"Also, it would piss off your co-stars and director, and likely end your porn career. You should also know that there''s no guarantee that there''s no other copies of your movies out there anyway, so think carefully."'

						if money >= films_stop_payment:
							act 'Remove them':
								minut += 5
								money -= films_stop_payment
								pfilmSTOP = 1
								killvar 'pfilmday'
								killvar 'pornplan'
								killvar 'porntaken'
								killvar 'pornstack'
								killvar 'prodcosttrue'
								killvar 'prodcost'
								film = 0
								gs 'stat'
								'"We never met. Have a nice day, and don''t come back."'

								act 'Leave': gt 'pornstudio', 'start'
							end
						end

						act 'Not interested': gt 'pornstudio', 'start'
					end

					act 'Leave': gt 'pornstudio', 'start'
				end

				act 'Leave': gt 'pornstudio', 'start'
			end
		end

		act 'Leave': gt 'pornstudio', 'start'

	end

	act 'Leave': gt 'pornstudio', 'start'
end

if $ARGS[0] = 'delivery':
	cls
	minut += 15
	menu_off = 1
	gs 'stat'
	'"We made inquiries about you, and everything seems in order. Essentially, we give you a thumb drive, you deliver it to the sauna, they give you an envelope and you bring it to us. Immediately."'
	'"Upon delivery of the envolope, you get 5000 <b>₽</b>. Deliveries are available every Friday, after the studio has opened. If you agree, then visit any Friday, and choose a safe mode of transport."'

	act 'Disagree':bomzQW = -1 & gt 'city_redlight', 'start'

	act 'Agree':
		cls
		minut += 15
		gs 'stat'
		'"We''ll take you this one time. In the future, you''ll have to make your own way because Fridays are getting risky for us. We need to introduce you to our colleagues."'

		act 'Let''s go':
			cls
			workDisk = 1
			minut += 15
			gs 'stat'
			'You climb into a car by the entrance and are driven to the sauna.'

			if saunasex = 1:
				'You recall going to this sauna. You had some pretty energetic sex here.'
			elseif sauna > 0:
				'Oh, it''s the sauna near your home.'
			else
				'This sauna is located near your home. You find it strange that you didn''t notice it before.'
			end

			'You go to the sauna, and are introduced to the local managers. It''s explained to you who you need to deliver to, and are reminded that it is necessary to return the envelope the same day you receive it.'
			'"Don''t forget to use secure transport. We''ll see you on Fridays. <i>Don''t</i> fuck up."'

			act 'Leave':bomzQW = 2 & gt 'city_residential'
		end
	end
end

if $ARGS[0] = 'shower':
	*clr & cla
	$location_type = 'bathroom'
	$loc = 'pornstudio'
	$loc_arg = 'bathroom'
	$locM = 'pornstudio'
	$locM_arg = 'bathroom'
	$menu_loc = 'pornstudio'
	$menu_arg = 'bathroom'
	menu_off = 1
	minut += 5
	pcs_horny += 1
	pcs_makeup = 1
	dynamic $showerdin
	gs 'stat'
	'<center><video autoplay loop src="images/shared/home/bathroom/dush.mp4"></video></center>'
    cumspclnt = 20
	gs 'cum_cleanup'
	'You enter the cubicle, turn the water on and thoroughly wash yourself.'
	if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the shower.'
	
	act 'Look in the mirror': gt 'mirror', 'start'
	act 'Go and see Dimitri': gt 'pornstudio', 'postvideo'
end

if $ARGS[0] = 'bathroom':
	*clr & cla
	minut += 1
	menu_off = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/photo/shower.jpg"></center>'
	'You can freshen up in the mirror or go and see Dimitri about being paid.'

	act 'Look in the mirror': gt 'mirror', 'start'
	act 'Go and see Dimitri': gt 'pornstudio', 'postvideo'
end

if $ARGS[0] = 'manager':
	cls
	minut += 5
	menu_off = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/studia_0.jpg"></center>'
	'You walk into the manager''s office and find Dimitri at his desk.'

	if firstkasting = 0: gt 'pornstudio', 'first'

	if pregchem >= 2688 and pregtalkpornstudio = 0: gt 'pornstudio', 'pregreact'

	if pfilmNoVenera = 1:
	!! Banned from shooting porn due to STD
		'"Why are you here? You''re currently blacklisted while you have an STD. Go get that fixed and show me the medical certificate first."'
	elseif pfilmNO = 1:
	!! Banned from shooting porn
		'"Why are you here? You''re blacklisted and will never work in porn again."'
	elseif pfilmNoVenera = 1:
		'"Did you seek treatment for your STDs? You must bring a certificate proving you are clean."'
	elseif pfilmSTOP = 1:
	!! No longer shooting porn
		'"I''m sorry, I thought you had retired?"'
	elseif ((pfilmday[0] > 0 and hour > 12) or pornmiss = 1) and porndebt <= 20000 and missedshoot = 0:
	!! You missed your shooting time, but you have a chance to work it off
		missedshoot = 1
		pornmiss = 0
		'Dimitri looks agitated as he storms towards you, ready to chew you out.'
		'"Didn''t I tell you not to be late? Where the fuck were you? I''ve wasted a lot of money! I had to pay actors, assistants, the director and the doctor just to sit around on their asses waiting for you! The whole shoot was a bust!"'
		'He manages to cool off a little with the venting of his frustration, and after a deep breath, he continues more calmly.'
		if pfilmday[1] = 0:
			missday = rand(0,3)
			porntaken['1,<<missday>>'] = 0
			act 'Jump in tomorrow':
				prodcost = 0
				pfilmNOPAY = 1
				porntaken['1,<<missday>>'] = 2
				pfilmday[1] = pornplan['1,<<missday>>']
				pornstack += 1
				freefilm = 1
				gt 'pornstudio', 'start'
			end
			'"I''ll give you a chance to make it right. Another actress has gotten sick and cancelled her shoot. If you jump in for her, your debt is cancelled. Or you can work it off, but that will take longer. Of course you can also pay it back, if you have the money. And no, I don''t remember what she was going to shoot. This day has been anything but easy due to you!"'
		else
			'"You know what, you can work it off, but it will take you a while. Of course you can also pay it back, if you have the money."'
		end

		act 'Accept your debt': porndebt += prodcost & gt 'pornstudio', 'start'

		gs 'willpower', 'misc', 'self'
		if will_cost <= pcs_willpwr:
			act 'I quit! (<<will_cost>> Willpower)':
				gs 'willpower', 'pay', 'self'
				'"Fuck this shit, I quit!" you yell before storming out of his office.'
				pfilmNO = 1
				killvar 'porndebt'
				killvar 'pfilmday'
				killvar 'pornplan'
				killvar 'porntaken'
				killvar 'pornnow'
				gt 'pornstudio', 'start'
			end
		else
			act 'I quit! (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
		exit
	elseif porndebt > 20000 and prodcost > 0:
	!! You really fucked up and are banned from shooting porn
		pfilmNO = 1
		killvar 'porndebt'
		killvar 'pfilmday'
		killvar 'pornplan'
		killvar 'porntaken'
		killvar 'pornnow'
		'"You didn''t come to the shoot! You fucked me over again, and you already owed me a lot of money! You took the second chance I gave you and threw it back in my face! I don''t want to work with you anymore. You''re now blacklisted, so get out!"'
	elseif pfilmday[0] > 0 and hour >= 10 and hour <= 12:
	!! You have a porn shoot and are on time
		pornnow = 1
		if hour = 10: '"You''re just in time for your inspection. Off you go now." he says with a smile.'
		if hour = 11: '"You''re late. My patience is not eternal." he says strictly. "Get going to your inspection, quickly!"'
		if hour = 12: '"What the hell? Everyone''s waiting for you! Hurry up and get inspected! Now!"'

		act 'Go for medical check-up': gt 'pornstudio', 'medical', pfilmday[0]
		exit
	elseif film = 0 and pornstack = 0:
	! Your first ever movie offer
		if firstoffer = 0:
			firstoffer = 1
			'"So you''re the new girl? As luck would have it, we''re looking for someone fresh for our next shoot. It''s called ''Girls Jerk Guys #36''."'
			'"For 500 <b>₽</b>, you have to jerk a guy off and have him cum on your tits."'
		else
			'"Hello. Since you''re brand new, all I can offer you is an introductory movie called ''Girls Jerk Guys #36''."'
			'"For 500 <b>₽</b>, you have to jerk a guy off and have him cum on your tits."'
		end

		gs 'willpower', 'exhib', 'self'
		if will_cost <= pcs_willpwr:
			act 'Agree (<<will_cost>> Willpower)':
				cla
				gs 'willpower', 'pay', 'self'
				pornstack += 1
				pfilmday[1] = 1
				gs 'stat'
				'"Cool. We shoot tomorrow, so be here between 10:00 and 11:00. And please, don''t be late."'

				act 'Leave': gt 'pornstudio', 'start'
			end
		else
			act 'Agree (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end

		act 'I don''t think I''m ready': gt 'pornstudio', 'start'
		exit
	elseif film > 0:
		gs 'pornstudio', 'options'
	else
		'Dimitri looks up from his paperwork and greets you. "Hello. Can I help you with something?"'
	end

	if porndebt > 0:
		act 'Ask about your debt': '"Of course. Your current debt to the company is <<porndebt>> <b>₽</b>."'
	end

	act 'Leave': gt 'pornstudio', 'start'
end

if $ARGS[0] = 'options':
	'"Let''s see what I have on offer for you."'
	if film < 5:
		fmulti = 100
	elseif film < 10:
		fmulti = 120
	elseif film < 15:
		fmulti = 140
	elseif film < 25:
		fmulti = 160
	elseif film < 50:
		fmulti = 180
	elseif film >= 50:
		fmulti = 200
	end

	act 'Filter by date':
		$selection = {
			*clr
			'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/studia_0.jpg"></center>'
			'<font color="grey">The selected days will not be displayed</font><br>'
			m1 = month
			d1 = day + 1
			if monthsend[m1] < d1: m1 += 1 & d1 = 1
			if m1 > 12: m1 = 1
			w2 = week + 1
			if w2 > 7: w2 = 1
			p1 = 1
			w1 = 1
			:monthloop
				*p '<Table border=0 cellpadding=1><TR><TH colspan=7><b><i><font size=6 color="brown"><<$monthName[m1]>></font></i></b></TH></TR>'
				*p '<TR align="center"><TH>   Monday    </TH><TH>   Tuesday   </TH><TH>Wednesday</TH><TH>  Thursday   </TH><TH>     Friday     </TH><TH>  Saturday   </TH><TH>    Sunday    </TH></TR>'
				:weekloop
					selected[p1] = p1
					if w1 = 1:*p '<TR>'
					!making sure that the date and the day of the week are in the correct position
					if w2 ! 1:
						if w2 = 7:
							w1 = 7 & *p '<TD></TD><TD></TD><TD></TD><TD></TD><TD></TD><TD></TD>'
						elseif w2 = 6:
							w1 = 6 & *p '<TD></TD><TD></TD><TD></TD><TD></TD><TD></TD>'
						elseif w2 = 5:
							w1 = 5 & *p '<TD></TD><TD></TD><TD></TD><TD></TD>'
						elseif w2 = 4:
							w1 = 4 & *p '<TD></TD><TD></TD><TD></TD>'
						elseif w2 = 3:
							w1 = 3 & *p '<TD></TD><TD></TD>'
						else
							w1 = 2 & *p '<TD></TD>'
						end
						w2 = 1
					end
					!selectable day display comes
					if inversefilter = 1:
						if datefilter['<<selected[p1]>>'] = 1:
							datefilter['<<selected[p1]>>'] = 0
						else
							datefilter['<<selected[p1]>>'] = 1
						end
					end

					if m1 = 1 and d1 >= 1 and d1 <= 8:nh1 = 1
					if m1 = 2 and d1 = 23:nh1 = 1
					if m1 = 3 and d1 = 8:nh1 = 1
					if m1 = 5 and (d1 = 1 or d1 = 2):nh1 = 1
					if m1 = 5 and d1 = 9:nh1 = 1
					if m1 = 6 and (d1 = 12 or d1 = 13):nh1 = 1
					if m1 = 11 and d1 = 4:nh1 = 1

					if nh1 = 1:
						$option = '<font color="red"><del><b><<d1>><b></del></font>'
					elseif pfilmday[p1] > 0:
						$option = '<font color="green"><<d1>></font>'
					elseif datefilter['<<selected[p1]>>'] = 1 or (weekdayfilter = 1 and w1 < 6) or (weekendfilter = 1 and w1 >= 6):
						$option = '<font color="grey"><del><<d1>></del></font>'
					else
						$option = '<a href="exec:datefilter[''<<selected[p1]>>''] = 1 & dynamic $selection"><font color="black"><<d1>></font></a>'
					end
					killvar 'nh1'
					*p '<TD align="center"><font size=5><<$option>></font></TD>'
					!preparing for next day
					d1 += 1
					p1 += 1
					w1 += 1
			!we have to check the end of the month too
			if monthsend[m1] < d1:
				!Oh-oh, this is the next month already!
				*p '</TR></TABLE><br>'
				if w1 = 8: w1 = 1
				w2 = w1
				w1 = 1
				m1 += 1
				if m1 > 12: m1 = 1
				d1 = 1
				!does it necessary to display the next month?
				if p1 < 50:jump 'monthloop'
			else
				!the next day is still the same month
				if p1 < 50:
					!the next day have to be displayed
					if w1 = 8: *p '</TR>' & w1 = 1
					jump 'weekloop'
				else
					!the next day does not have to be displayed
					*p '</TR></TABLE><br>'
				end
			end
			inversefilter = 0
			''
			if weekdayfilter = 0:
				$weekdayfilter = '<a href="exec:weekdayfilter = 1 & dynamic $selection">Remove weekdays</a>'
			else
				$weekdayfilter = '<a href="exec:weekdayfilter = 0 & dynamic $selection">Restore weekdays</a>'
			end
			if weekendfilter = 0:
				$weekendfilter = '<a href="exec:weekendfilter = 1 & dynamic $selection">Remove weekends</a>'
			else
				$weekendfilter = '<a href="exec:weekendfilter = 0 & dynamic $selection">Restore weekends</a>'
			end
			*p '<<$weekdayfilter>>  <<$weekendfilter>>  <a href="exec:inversefilter = 1 & dynamic $selection">Inverse selection</a><br>'
			*p '<a href="exec:killvar ''datefilter'' & killvar ''selected'' & weekdayfilter = 0 & weekendfilter = 0 & dynamic $selection">Clear date filters</a>'
		}
		dynamic $selection
	end

!{	act 'Filter by tag':
		$displaytag = {
			*clr
			'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/studia_0.jpg"></center>'
			'<font color="grey">The selected tags will not be displayed</font><br><br>Currenty filtered tags: <font color="green"><<$tagfilter>></font>'
			if flag_tag[1] = 0: '<a href="exec:$tagfilter += ''hetero '' & flag_tag[1] = 1 & dynamic $displaytag">heterosexual</a>'
			if flag_tag[2] = 0: '<a href="exec:$tagfilter += ''lesbian '' & flag_tag[2] = 1 & dynamic $displaytag">lesbian</a>'
			if flag_tag[3] = 0: '<a href="exec:$tagfilter += ''threesome '' & flag_tag[3] = 1 & dynamic $displaytag">threesome</a>'
			if flag_tag[4] = 0: '<a href="exec:$tagfilter += ''gangbang '' & flag_tag[4] = 1 & dynamic $displaytag">gangbang</a>'
			if flag_tag[5] = 0: '<a href="exec:$tagfilter += ''facial '' & flag_tag[5] = 1 & dynamic $displaytag">facial</a>'
			if flag_tag[6] = 0: '<a href="exec:$tagfilter += ''vaginal '' & flag_tag[6] = 1 & dynamic $displaytag">vaginal</a>'
			if flag_tag[7] = 0: '<a href="exec:$tagfilter += ''anal '' & flag_tag[7] = 1 & dynamic $displaytag">anal</a>'
			if flag_tag[8] = 0: '<a href="exec:$tagfilter += ''blowjob '' & flag_tag[8] = 1 & dynamic $displaytag">blowjob</a>'
			if flag_tag[9] = 0: '<a href="exec:$tagfilter += ''handjob '' & flag_tag[9] = 1 & dynamic $displaytag">handjob</a>'
			if flag_tag[10] = 0: '<a href="exec:$tagfilter += ''cumshot '' & flag_tag[10] = 1 & dynamic $displaytag">cumshot</a>'
			if flag_tag[11] = 0: '<a href="exec:$tagfilter += ''swallowing '' & flag_tag[11] = 1 & dynamic $displaytag">swallowing</a>'
			if flag_tag[12] = 0: '<a href="exec:$tagfilter += ''DP '' & flag_tag[12] = 1 & dynamic $displaytag">DP</a>'
			if flag_tag[13] = 0: '<a href="exec:$tagfilter += ''creampie '' & flag_tag[13] = 1 & dynamic $displaytag">creampie</a>'
			''
			'<a href="exec:killvar ''$tagfilter'' & killvar ''flag_tag'' & dynamic $displaytag">Clear date filters</a>'
		}
		dynamic $displaytag
	end
}
	act 'Filter by participants':
		$displaynum = {
			*clr
			'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/studia_0.jpg"></center>'
			'<font color="grey">The movies above the selected number of partners will not be displayed</color><br>'
			if ppnum = 1:
				$pp1 = '<b><font color="red" size=8>1</font></b>'
			else
				$pp1 = '<a href="exec:ppnum = 1 & dynamic $displaynum"><font size=8 color="black">1</font></a>'
			end
			if ppnum = 2:
				$pp2 = '<b><font color="red" size=8>2</font></b>'
			else
				$pp2 = '<a href="exec:ppnum = 2 & dynamic $displaynum"><font size=8 color="black">2</font></a>'
			end
			if ppnum = 3:
				$pp3 = '<b><font color="red" size=8>3</font></b>'
			else
				$pp3 = '<a href="exec:ppnum = 3 & dynamic $displaynum"><font size=8 color="black">3</font></a>'
			end
			if ppnum = 4:
				$pp4 = '<b><font color="red" size=8>4</font></b>'
			else
				$pp4 = '<a href="exec:ppnum = 4 & dynamic $displaynum"><font size=8 color="black">4</font></a>'
			end
			if ppnum = 5:
				$pp5 = '<b><font color="red" size=8>5</font></b>'
			else
				$pp5 = '<a href="exec:ppnum = 5 & dynamic $displaynum"><font size=8 color="black">5</font></a>'
			end
			'<Table border=0 cellspacing=10><TR><TH><<$pp1>></TH><TH><<$pp2>></TH><TH><<$pp3>></TH><TH><<$pp4>></TH><TH><<$pp5>></TH></TR>'
			''
			'<a href="exec:killvar ''ppnum'' & dynamic $displaynum">Clear participant limitations</a>'
		}
		dynamic $displaynum
	end

	act 'Porn production schedule':
		$contracting = {
			*clr
			'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/studia_0.jpg"></center>'
			''
			d1 = day
			w1 = week
			m1 = month
			counter = 1
			$pornofday = ''
			:pornopt
				killvar 'nh1'
				pcount[counter] = counter
				w1 += 1
				if w1 > 7:w1 = 1
				d1 += 1
				if monthsend[m1] < d1: m1 += 1 & d1 = 1
				if m1 > 12: m1 = 1

				if m1 = 1 and d1 >= 1 and d1 <= 8:nh1 = 1
				if m1 = 2 and d1 = 23:nh1 = 1
				if m1 = 3 and d1 = 8:nh1 = 1
				if m1 = 5 and (d1 = 1 or d1 = 2):nh1 = 1
				if m1 = 5 and d1 = 9:nh1 = 1
				if m1 = 6 and (d1 = 12 or d1 = 13):nh1 = 1
				if m1 = 11 and d1 = 4:nh1 = 1

				if (weekdayfilter = 1 and w1 >= 6) or (weekendfilter = 1 and w1 < 6) or (weekdayfilter = 0 and weekendfilter = 0) or nh1 = 1:
					if datefilter['<<selected[counter]>>'] = 0:
						if nh1 = 1:
							$pornofday = '<i><b>National holiday, no shootings!</b></i><br>'
						else
							porns = 0
							:pornplanloop
								dynamic $pornfilmdesc, pornplan['<<counter>>,<<porns>>']
								if (pfactor <= ppnum) or (ppnum = 0):
									if porntaken['<<counter>>,<<porns>>'] = 2:
										$pornofday += '<font color="green"><b><<$porndesc[pornplan[''<<counter>>,<<porns>>'']]>></b> - <i>Already contracted</i></font><br>'
									elseif pfilmday[counter] > 0 and porntaken['<<counter>>,<<porns>>'] = 0:
										$pornofday += '<font color="grey"><<$porndesc[pornplan[''<<counter>>,<<porns>>'']]>></font><br>'
									elseif porntaken['<<counter>>,<<porns>>'] = 1:
										$pornofday += '<font color="red"><<$porndesc[pornplan[''<<counter>>,<<porns>>'']]>> - <i>Taken by someone else</i></font><br>'
									elseif porntaken['<<counter>>,<<porns>>'] = 3:
										$pornofday += '<font color="red"><<$porndesc[pornplan[''<<counter>>,<<porns>>'']]>> - <i>You don''t fit the role</i></font><br>'
									elseif pornstack < 10 and porntaken['<<counter>>,<<porns>>'] = 0:
										$pornofday += '<a href="exec:pornstack += 1 & porntaken[''<<counter>>,<<porns>>''] = 2 & pfilmday[<<pcount[counter]>>] = pornplan[''<<counter>>,<<porns>>''] & gs ''stat'' & dynamic $contracting"><<$porndesc[pornplan[''<<counter>>,<<porns>>'']]>></a><br>'
									else
										$pornofday += '<font color="grey"><<$porndesc[pornplan[''<<counter>>,<<porns>>'']]>></font><br>'
									end
								end
							if porns < 3: porns += 1 & jump 'pornplanloop'
						end
						if $pornofday ! '':
							'<<$monthName[m1]>> <<d1>>, <<$week[w1]>>: '
							'<<$pornofday>>'
							$pornofday = ''
						end
					end
				end
			if counter < 29:
				counter += 1
				jump 'pornopt'
			end
		}
		dynamic $contracting
	end

	if pornstack > 1 or (freefilm = 0 and pornstack > 0):
		act 'Cancel a contract':
			$canceling = {
				*clr
				'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/studia_0.jpg"></center>'
				d1 = day
				w1 = week
				m1 = month
				i = 1
				:nopornopt
					pcount[i] = i
					w1 += 1
					if w1 > 7:w1 = 1
					d1 += 1
					if monthsend[m1] < d1: m1 += 1 & d1 = 1
					if (pfilmday[i] = 1 and freefilm = 0) or pfilmday[i] > 1: '<<$monthName[m1]>> <<d1>>, <<$week[w1]>>: '
					porns = 0
					:nopornplanloop
						if porntaken['<<i>>,<<porns>>'] = 2: '<a href="exec:pornstack -= 1 & porntaken[''<<i>>,<<porns>>''] = 0 & pfilmday[<<pcount[i]>>] = 0 & gs ''stat'' & dynamic $canceling"><<$porndesc[pornplan[''<<i>>,<<porns>>'']]>></a>'
					if porns < 3: porns += 1 & jump 'nopornplanloop'
				if i < 49:
					i += 1
					jump 'nopornopt'
				end
			}
			dynamic $canceling
		end
	end

	act 'Leave':
		killvar 'ppnum'
		killvar 'displaynum'
		killvar 'displaytext'
		killvar 'displayimage'
		killvar '$pp1'
		killvar '$pp2'
		killvar '$pp3'
		killvar '$pp4'
		killvar '$pp5'
		killvar 'displaytag'
		killvar 'flag_tag'
		killvar 'selection'
		killvar 'datefilter'
		killvar 'selected'
		killvar 'option'
		killvar 'tagfilter'
		killvar 'contracting'
		killvar 'pcount'
		killvar 'weekdayfilter'
		killvar 'weekendfilter'
		gt 'pornstudio', 'start'
	end
end

if $ARGS[0] = 'first':
	cls
	menu_off = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/casting/casting0.jpg"></center>'
	'You sit down on the sofa and greet the manager. "I see it''s your first time with us. So, you want to be a porn star?'

	if pcs_inhib < 40 and (money <= 500 and karta <= 500 and func('homes_properties', 'get_accessible_property_count') = 0) or (narkoman = 1 or SLomka > 0):
		'While you don''t feel confident enough showing off your body, you''re desperate for money, and are willing to do anything to earn it.'
		act 'Continue': gt 'pornstudio', 'yes'
	elseif pcs_inhib < 40:
		'You don''t feel confident enough to start a career in porn. You should gain some confidence showing off your body first.'
		act 'Leave': gt 'pornstudio', 'start'
	else
		act 'Continue': gt 'pornstudio', 'yes'
	end
end

if $ARGS[0] = 'yes':
	cls
	menu_off = 1
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/casting/casting0.jpg"></center>'
	'You sit down on the sofa and greet the manager. "I see it''s your first time with us. So, you want to be a porn star?"'
	act 'Yes':
		cla
		minut += 5
		gs 'stat'
		'You confirm your enthusiasm to be in porn and he nods. "Let''s see your papers. You are 18 or older, yes?"'
		if age >= 18:
			'"Yes, I am." you answer, handing him your passport.'
			'"All right then. First we''ll need to do a casting. Take off your clothes and let me see your body."'
		elseif fakepassport = 1:
			'"Yes, I am." you answer, handing him your fake passport.'
			'You see him frown as he checks your passport with suspicion.'
			'"Well, I guess everything is in order. First we''ll need to do a casting. Take off your clothes and let me see your body."'
		else
			'"Nearly..." you plead.'
			'"Right... Here''s my card. Come back when you''re old enough, kid."'
			fakepassport = 2
			act 'Leave': gt 'pornstudio', 'start'
			exit
		end

		act 'Make excuses and leave': gt 'pornstudio', 'start'

		gs 'willpower', 'exhib', 'self'
		if will_cost <= pcs_willpwr:
			act 'Undress (<<will_cost>> Willpower)':
				cla & *clr
				gs 'willpower', 'pay', 'self'
				minut += 5
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/casting/casting1.jpg"></center>'
				'You undress as he gets up from his chair and walks towards you. "Lie down on the couch and spread your legs."'
                
				act 'Grab your clothes and run out': gt 'pornstudio', 'start'

				act 'Lie down':
					cla & *clr
					minut += 5
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/casting/casting2.jpg"></center>'
					'You lie down on the sofa and spread your legs. The manager takes a few pictures on his phone, explaining that they''re for your portfolio. After that, he asks you to kneel.'

					act 'Kneel':
						cla & *clr
						minut += 5
						gs 'stat'
						'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/casting/casting3.jpg"></center>'
						'You get up from the sofa and kneel in front of him as he pulls out his sizeable cock. You admire it for a few seconds before slowly sucking on his tip. He takes more pictures as he says "Now suck."'

						act 'Suck his dick':
							cla & *clr
							minut += 5
							gs 'stat'
							'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/casting/casting4.jpg"></center>'
							'You take his shaft into your mouth and begin to suck it as he takes a few more pictures.'

							act 'Finish him':
								cla & *clr
								minut += 5
								gs 'stat'
								'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/casting/casting5.jpg"></center>'
								'You take his dick deep into your throat while trying to look as sexy as possible. Meanwhile, he fondles your breast with his free hand.'
								'After a few minutes, he pulls his dick out of your mouth. "Finish me off!" he curtly orders. You quickly jerk him off and soon a thick load of cum is covering your face. He takes some last photos of you before returning to his desk and offering you wipes. You quickly clean yourself, get dressed and sit down.'
								'"You can call me Dimitri. You''re going to need a stage name.'

								act 'Choose your name':
									cla & *clr
									firstkasting = 1
									$pfname = input ("What will your porn name be?")

									if $pfname <= 0:$pfname = '<<$pcs_nickname>> BimboStar'

									'"<<$pfname>>, wonderful name. Now listen. Before shooting starts, you have to pass a medical examination. If we find any sign of a sexually transmitted disease, you''re out, no exceptions."'
									'"There we go, you''re now registered. We''re quite big in the industry, shooting about four films a day, so you can choose what you to be in. Anal or gangbang, it''s your choice, just remember to take care of your health. If you get sick or something, just cancel the shoot. You can do this up to the day of the shooting."'
									'"Come see me when you want a contract. And welcome to the world of pornography...<<$pfname>>."'

									act 'Continue': gt 'pornstudio', 'start'
								end
							end
						end
					end
				end
			end
		else
			act 'Undress (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
	end
end

if $ARGS[0] = 'medical':
	*clr & cla
	menu_off = 1
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/exam.jpg"></center>'
	minut += 5
	gs 'stat'
	'You enter the office where the doctor is waiting. He quickly snaps on a pair of rubber gloves and tells you to undress.'
	'You remove your clothes and sit on the gynecological chair. The doctor comes up to you and starts the check up. After a thorough inspection, he takes a blood sample.'
	'"It will be about half an hour before the tests are finished. They will tell us if you have caught something."'

	act 'Wait':
		cla
		minut += 30
		gs 'stat'
		'...'
		'...'
		if venera > 0:
			'"Your analysis shows you have an STD." the doctor tells you as he calls Dimitri to the office.' 
			gs 'pav_clinic', 'std_check'

			'Once he arrives, Dimitri looks at the test results.'
			if venera = 1 and GerpesOnce = 1 and Gerpes < 3:
				'"Since your herpes is in remission and you don''t have other STDs, you may film today."'
			else
				'"Sorry, but as long as you have an STD, you cannot make films."'
				pfilmNoVenera = 1
				gs 'pornschedule', 'pornmiss'
				act 'Leave': gt 'pornstudio', 'start'
			end
		else
			'"Very good, you are clean. You can go to the dressing room."'
		end

		if pfilmNoVenera = 0:
			act 'Go to the dressing room':
				pf = ARGS[1]
				dynamic $pornfilmdesc, pf
				gs 'pornfilm', 'pornactor'
				gs 'pornfilm', 'pornactress'
				*clr & cla
				'<center><img width=700 src="images/locations/city/redlight/studio_porn/makeup.jpg"></center>'
				minut += 30
				cumspclnt = 20
				gs 'cum_cleanup'
				pcs_sweat = 0
				pcs_hairbsh = 1
				pcs_makeup = 4
				pcs_lipbalm += 8
				pcs_breath = 1
				gs 'stat'
				'A skinny white-haired woman is waiting for you in the dressing room.'
				'You take a thorough shower before getting an enema. You then get your hair and make-up done.'

				act 'Go to the set': gt 'pornfilm', '<<pf>>'
			end
		end
	end
end

if $ARGS[0] = 'postvideo':
	cls
	menu_off = 1
	minut += 30
	pf = pfilmday[0]
	pfilmday[0] = 0
	pornstack -= 1
	pornnow = 0
	if film < 5:
		fmulti = 25
	elseif film < 10:
		fmulti = 30
	elseif film < 15:
		fmulti = 35
	elseif film < 25:
		fmulti = 40
	elseif film < 50:
		fmulti = 45
	elseif film >= 50:
		fmulti = 50
	end

	film += 1
	if film = 1:
		$porntitle[film] = 'Girls Jerk Guys #36 - <<$pfname>>'
		$pornfilmstory[film] = '<<$pfname>>''s debut into the world of porn. Watch as she jerks off <<$pactor[1]>> and lets him cum all over her tits.'
	else
		if $pstory = '' and editpornname = 1:
			$pornfilmstory[film] = input('You can enter the story of the porn movie. This action can be done only once, but you can choose to do it later! (Just hit Enter/Esc when blank)<br>Tags of the current movie: <font color=#541717 size=2><<$pfilmtags>></font>')
		else
			$pornfilmstory[film] = $pstory
		end
		if editpornname = 1:
			$porntitle[film] = input("Enter the name of the porn movie. <i>This action can be done only once, but you can choose to do it later! (Just hit Enter/Esc when blank)</i>")
		end
	end

	if pfilmNOPAY = 0:
		pfcash = pcash * fmulti
		money += pfcash
		'Dimitri counts <<pfcash>> <b>₽</b> out for your film and wishes good luck.'
	else
		pfilmNOPAY = 0
		pfcash = 0
		'You have fulfilled your obligation and made the film for free.'
	end
	pornfilmYear[film] = year
	pornfilmMonth[film] = month
	pornfilmDay[film] = day
	porndaystart[film] = daystart
	pornfilmType[film] = pf
	pornfilmCash[film] = pfcash
	pornfilmActAge[film] = age
	pornfilmAppAge[film] = vidage
	pornfilmpregchem[film] = pregchem
	pornfilmacting[film] = acting+orgasmbonus+pcs_intel/10
	dynamic $pornfilmdesc, pf
	killvar 'orgasmbonus'
	if pornfilmacting[film] >= 90:
		porn_fame += 3
	elseif pornfilmacting[film] >= 75:
		porn_fame += 2
	elseif pornfilmacting[film] >= 60:
		porn_fame += 1
	end
	if hotcat >= 9:
		porn_fame += 3
	elseif hotcat >= 7:
		porn_fame += 2
	elseif hotcat >= 5:
		porn_fame += 1
	end
	pornfilmvnesh[film] = hotcat

	acting += actbonus

	if pfType ! 0:
		unprotfilm = -1
		if succubusflag = 1:
!!			May add a check to clear unprotfilm based on sucpcinfo (the PC knows Succubae are immune to STD''s)
			if pfcash > 0:
				$tmp = '"I almost can''t believe they paid me <<pfcash>><b>₽</b> for such a wonderful meal!"'
			else
				$tmp = '"And they think I''m doing this for free. If only they knew they were paying me in another way..."'
			end
			'You let slip a satisfied smirk and think to yourself, <<$tmp>>'
		elseif knowpreg = 0 and thinkpreg = 0 and pillcon2 < 1000:
			pornDanger[film] = 1
!!			Left "ppreg" pending its eventual use
			if ppreg = 0:
				if pfcash > 0:
					$tmp = ' Was <<pfcash>> <b>₽</b> worth the risk of getting impregnated by a seedy porn actor you''ll probably never see again?'
				else
					$tmp = 'You didn''t even get paid to risk pregnancy! You''ll likely never see the guy again.'
				end
				'With a growing sense of horror, you realize that you aren''t on the shot and have no idea when you last took a birth control pill.<<$tmp>>'
			else
				!{If she has birth control and deliberately isn''t using it, obviously she wants to get pregnant or just doesn''t care.}
				if pfcash > 0:
					$tmp = 'Either way, <<pfcash>> <b>₽</b> will definitely help make a better life for you and your baby if you end up pregnant.'
				else
					$tmp = 'The fact that you weren''t even paid to take this risk excites you more than you''d like to admit.'
				end
				'From the moment you stepped onto the set, you kept thinking about how you were completely unprotected during this shoot. You aren''t sure if you''re afraid of the consequences or excited by them.<<$tmp>>'
				pcs_horny += 10
			end
		end
		killvar '$tmp'
	end

	if pfactor = 50:
		$pornfilmActor[film] = 'Fifty fans of'
	else
!!		dynamic $pornactor
		$pornfilmActor[film] = ''
		pact = pfactor
		:pornactortext
			if pact > 1:
				$pornfilmActor[film] += $pactor[pact]+', '
			else
				$pornfilmActor[film] += $pactor[pact]
			end
			pact -= 1
		if pact > 0:jump 'pornactortext'
	end

	if film < 10:
		filmkoef = 10
	elseif film < 25:
		filmkoef = 5
	else
		filmkoef = 0
	end

	pfcash = 0
	gs 'stat'

	act 'Leave': gt 'pornstudio', 'start'
end

if $ARGS[0] = '1':
	$loc_arg = $ARGS[0]
	$loc = 'pornstudio'

	minut = minut + 5
	clr
	menu_off = 1
	gs'stat'

	'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/pierre_1.jpg"></center>'
	'You''ve come to the studio, looking for someone - anything that you think can help you.'
	'You approach a man, who introduces himself as Dimitri.'

	act 'State the purpose of your visit':
		*clr & cla
		minut += 60
        '<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/pierre_2.jpg"></center>'
		'Dimitri smiles. "New actresses are always welcome, but if they''re terrible, the studio won''t take them. The auditions are made public, so remember that if you ever consider it."'
		'"I''ll tell you everything else under one condition - you have to undress."'

		act 'Undress':
			*clr & cla
			'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/casting_3.jpg"></center>'
			'You strip out of your clothes. Once you''re nude, Dimitri smiles and starts his tour.'
			'"We start with the casting auditions. As I said, if you''re terrible, then you have no hope. This can be overlooked if you have an attractive appearance, however."'

			act 'Continue':
				*clr & cla
				'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/model_0.jpg"></center>'
				'"Then a girl is chosen for the lead role. Only the most attractive of girls are chosen."'
				
				act 'Continue':
					*clr & cla
					'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/film_0.jpg"></center>'
					'"Then she shoots the scenes, an interesting and exciting process that can take hours. The films we shoot...'
					
					act 'Continue':
						*clr & cla
						'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/dvd-disx.jpg"></center>'
						'He pulls a DVD off the top of a nearby stack. "Are how we make money."'

						act 'How and where is it all sold?':
							*clr & cla
							'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/pierre_2.jpg"></center>'
							'"We mostly sell it digitally on our premium websites, but we have guys at the sauna in the residential area and in the sex shop for those who want to buy physically.' 
							'We''re thinking of moving in on the university as well- and not just selling our films there. We could possibly shoot a few films on campus. There''s a huge market for young college students and we want a slice."'

							act 'Is that legal?':
								*clr & cla
								'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/ment_0.jpg"></center>'
								'"It doesn''t matter since we bribe the cops. Maybe in the future you''ll be able to help us with that? In the meantime, I''ve told you everything you need to know."'

								act 'I understand':
									*clr & cla
									pornstudio = 3

									'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/pierre_2.jpg"></center>'
									'"Good girl. Now leave and stop wasting my time."'
                                    gt 'pornstudio', 'start'
								end
							end
						end
					end
				end
			end
		end
	end
end

if $ARGS[0] = '2':
	$loc_arg = $ARGS[0]
	$loc = 'pornstudio'
	menu_off = 1

	clr
	! WD: Fix Uninitialised ~ 'carrf' to 'carrar'
	carrar = RAND(40, 100)
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/city/redlight/studio_porn/casting_<<rand(1,6)>>.jpg"></center>'

	'You spend eight hours posing in a variety of sexy underwear for the casting director.'

	minut += 120
	gs 'stat'
	minut += 120
	gs 'stat'
	minut += 120
	gs 'stat'
	minut += 120
	gs 'stat'

	if pcs_apprnc < carrar:
		'"You don''t have what it takes. Sorry."'
	elseif pcs_apprnc >= carrar:
		actr = 1

		'You get the role.'
	end

	act 'Finish':
		gt 'pornstudio','start'
	end
end

if $ARGS[0] = '3':
	$loc_arg = $ARGS[0]
	$loc = 'pornstudio'

	clr
	actr = 0
	gs 'stat'
	gt 'bdsm'
end

if $ARGS[0] = 'pregreact':
	'"Wow. I''m surprised you still want to do the shoot considering how far along you are. The good news is, we''ve been looking into appealing to people with different fetishes, so this is the perfect opportunity to start marketing to pregnancy fetishists. However, this is also going to change the shoots you can do."' 
	'"You see, this is more of a niche thing and not something we can really use for wide appeal. You can still work, but only on specific pregnancy shoots, so you might not get the same amount of work you got before. Don''t worry though, if we can find a way to make money off of you, we definitely will." the manager ends with a smile.'
	act 'Continue': pregtalkpornstudio = 1 & gt 'pornstudio', 'manager'
end

--- pornstudio ---------------------------------
