# rex_party

!introductions
if $ARGS[0] = 'start':
    CLOSE ALL

    !set event variables
    sisterQW['partycount'] += 1
	sisterQW['party'] = 2
	sisboyparty = 1
	sisboypartyQW += 1
	alkoParty = 0
	party_girls_talk = 0
	girls_smoke = 0
	party_dj = 0
	dj_beer = 0
	dj_thank = 0
	dj_bad = 0
	dj_boobs = 0
	party_boys_drink = 0
	Rex_save = 0
	party_boys_in = 0
	rex_talk = 0
	rex_sex = 0
	drunk_sveta = 0
	iralenasleep = 0
	sister_party_dom = 0
    lastUpdatedHour = -1 & !This variable is used to update event every hour
    numberOfEvents = 2 & !This variable is used to update event every hour


	$location_type = 'event'
	gs 'themes', 'indoors'
	$loc_arg = 'start'
	$loc = 'rex_party'
	$menu_loc = 'rex_party'
	$menu_arg = 'start'
	menu_off = 0
	cls
    minut += 15
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/reksparty_1_' + rand(1,5) + '.jpg"></center>'
	'You arrive at Rex''s apartment for the weekend party. Going inside with the others, the loud music drowns out any noise from outside. As soon as you are inside, several boys immediately start offering you drinks.'
	act 'Drink':
		cls
		minut += 5
		alkoParty += 1
		gs 'drugs', 'alcohol', 'vodka'
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/reksparty_2_' + rand(1,4) + '.jpg"></center>'
		'In all this mess, you are unable to find a clean cup and are handed a full bottle of booze. Clinking glasses with the bottle, you put your lips to its mouth and turn it up, gulping down several swigs of strong drink, noticing the effects almost at once.'
		'The party has just begun. You can still walk through the apartment and find something to do.'
		act 'Move away': gt 'rex_party', 'RexRoom'
	end
end

if $ARGS[0] = 'RexRoom':
    $loc_arg = 'RexRoom'
    $menu_arg = 'RexRoom'
	cls
	minut += 5
	gs 'stat'

    gs $loc, 'EventUpdate'
    '<center><b><font color = maroon>Rex''s Room</font></b></center>'
    !gs $loc, 'RexRoomEvent<<eventNumber>>'
    gs 'rex_party', 'Event<<eventNumber>>', 'RexRoom'

    act 'Go to the living room': gt 'rex_party', 'LivingRoom'
end

if $ARGS[0] = 'LivingRoom':
    $loc_arg = 'LivingRoom'
    $menu_arg = 'LivingRoom'
	cla & *clr
	minut += 5
	gs 'stat'

    gs $loc, 'EventUpdate'
    '<center><b><font color = maroon>Living room</font></b></center>'
    gs 'rex_party', 'Event<<eventNumber>>', 'LivingRoom'

    act 'Go to Rex''s room': gt 'rex_party', 'RexRoom'
    act 'Go to the kitchen': gt 'rex_party', 'Kitchen'
    act 'Go to the Toilet': gt 'rex_party', 'Toilet'
    act 'Leave Rex''s home': gt 'pav_commercial'
end

if $ARGS[0] = 'Kitchen':
    $loc_arg = 'Kitchen'
    $menu_arg = 'Kitchen'
	cla & *clr
	minut += 5
	gs 'stat'

    gs $loc, 'EventUpdate'
    '<center><b><font color = maroon>Kitchen room</font></b></center>'
    '<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/kuh.jpg"></center>'
    gs 'rex_party', 'Event<<eventNumber>>', 'Kitchen'

    act 'Go to the living room': gt 'rex_party', 'LivingRoom'
end

if $ARGS[0] = 'Toilet':
	$loc = 'rex_party'
	$loc_arg = 'Toilet'
	$menu_arg = 'Toilet'
	$locM = 'rex_party'
	$locM_arg = 'Toilet'

	cla & *clr
	minut += 5
	gs 'stat'
   
	if alko > 3 and rand(1,100) <= 30: gt 'rex_party_sexEvents', 'toilet_sex_events'
	'<center><b><font color = maroon>Toilet</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/toilet.jpg"></center>'

	'Here you can wash your face, freshen up or touch up your make-up at <a href="exec: gt ''mirror'', ''start''">mirrors</a>.'
	!if pcs_horny > 50:'Feeling yourself ready to burst with desire, you can''t take it anymore and begin to <a href="exec: gt ''rex_party_sexEvents'', ''toilet_mast''">masturbate</a>.'
	act 'Go to the living room': gt 'rex_party', 'LivingRoom'
	if cumloc[11] = 1 or cumloc[12] = 1:
		act 'Clean the sperm from your face (0:10)':
			cla
			*clr
			pcs_makeup = 1
			cumspclnt = 9
			gs 'cum_cleanup'
			cumspclnt = 13
			gs 'cum_cleanup'
			if pcs_sweat > 19 : pcs_sweat -= 5
			minut += 10
			'<center><img <<$set_imgh>> src="images/pc/activities/facewash.jpg"></center>'
			*nl
			'You clean your face and get rid of any trace of cum.'

			act 'Move away': gt 'rex_party', 'Toilet'
		end
    end
end

if $ARGS[0] = 'EventUpdate':
    if alko < 3: 
        eventNumber = 1
    else
        eventNumber = 2
    end

    !{
        if lastUpdatedHour = -1 or lastUpdatedHour ! hour:
            lastUpdatedHour = hour
            eventNumber = rand(1,numberOfEvents)
        end
    }
    
end

if $ARGS[0] = 'Event1':
    if $ARGS[1] = 'RexRoom':
        '<center><b><font color = maroon>Rex''s Room</font></b></center>'
        '<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/reksparty_1_' + rand(1,5) + '.jpg"></center>'
        'You sit at a table and drink with your friends. Sitting to one side of you sharing a bottle as always are <a href="exec: gt ''rex_party_smallEvents'', ''lena''">Lena</a> who is always fun, her slightly more reserved friend <a href="exec: gt ''rex_party_smallEvents'', ''ira''">Ira</a>, and always upbeat <a href="exec: gt ''rex_party_smallEvents'', ''rex''">Rex</a>.'
        'To your other side sits your sister <a href="exec: gt ''rex_party_smallEvents'', ''anya''">Anya</a>, drinking already, and <a href="exec: gt ''rex_party_smallEvents'', ''roma''">Roma</a>, who himself sits just a bit away looking more serious than normal, plus lots of <a href="exec: gt ''rex_party_smallEvents'', ''party_girls''">girls</a> and <a href="exec: gt ''rex_party_smallEvents'', ''party_boys''">guys</a> you barely know.'
        'One of the guys offers you a bottle to <a href="exec: gt ''rex_party_smallEvents'', ''party_drink''">drink</a> from as he says, "A little more to set the mood."'
    end
    if $ARGS[1] = 'LivingRoom':
        '<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/reksparty_3.jpg"></center>'
        'This is a large living room. Hardly anyone is here, most are all still sitting in the other room talking and drinking. Only one <a href="exec: gt ''rex_party_smallEvents'', ''dj''">guy</a> is in here tinkering with a turntable.'
    end
    if $ARGS[1] = 'Kitchen':
        'The kitchen is spacious, but kinda dirty. The kitchen table is covered in cans and bottles of beer as well as 5ths of booze. You can grab any bottle you want and <a href="exec: gt ''rex_party_smallEvents'', ''party_drink''">drink</a>.'
        if party_dj =1 and dj_beer < 1:'You grab two bottle for the <a href="exec: gt ''rex_party_smallEvents'', ''dj_take_beer''">DJ and his friend</a>.'
    end
end

if $ARGS[0] = 'Event2':
    if $ARGS[1] = 'RexRoom':
        '<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/reksparty_party_home_1_' + rand(1,5) + '.jpg"></center>'
        'After a while, everyone gets up to go dance and drink. Only a few <a href="exec: gt ''rex_party_smallEvents'', ''party_girls''">girls</a> are left in the room, but they are fun to hang out and gossip with.'
        iif(party_girls_talk >= 2,'You <a href="exec: gt ''rex_party_smallEvents'', ''talk''">chat</a> and gossip with them. One of the girls pulls out some marijuana and invites all of you to <a href="exec: gt ''rex_party_smallEvents'', ''smoke''">have a smoke</a>.', 'You <a href="exec: gt ''rex_party_smallEvents'', ''talk''">chat</a> and gossip with them.')
        if pcs_mood = 100 and pcs_horny >= 50 and girls_smoke > 1:
            'All the girls are in a good mood, and several of them excitedly pull you with them to have some <a href="exec: gt ''rex_party_smallEvents'', ''fun''">fun</a>.'
        end
    end
    if $ARGS[1] = 'LivingRoom':
        '<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/rekshome/party/reksparty_4_' + rand(1,8) + '.jpg"></center>'
        'The party is in full swing. In one corner. a <a href="exec: gt ''rex_party_smallEvents'', ''dj''">guy</a>, the party DJ, is spinning beats at the turntable. You want to give it a try and <a href="exec: gt ''rex_party_smallEvents'', ''dance''">spin some beats</a>.'
        '<a href="exec: gt ''rex_party_smallEvents'', ''roma''">Roma</a> and <a href="exec: gt ''rex_party_smallEvents'', ''anya''">Anya</a> are locked together having fun dancing.'
        if Rex_Love = 0:'<a href="exec: gt ''rex_party_smallEvents'', ''rex''">Rex</a> is having fun dancing with some <a href="exec: gt ''rex_party_smallEvents'', ''party_girls''">girls</a>.'
        if Rex_Love = 1:'You are dancing with some <a href="exec: gt ''rex_party_smallEvents'', ''party_girls''">girls</a> and <a href="exec: gt ''rex_party_smallEvents'', ''rex''">Rex</a>, who looks at you with loving eyes.'
        '<a href="exec: gt ''rex_party_smallEvents'', ''ira_lena_livingRoom''">Lena</a> and <a href="exec: gt ''rex_party_smallEvents'', ''ira_lena_livingRoom''">Ira</a> are having fun in the company of drunken <a href="exec: gt ''rex_party_smallEvents'', ''party_boys''">guys</a>.'
    end

    if $ARGS[1] = 'Kitchen':
        'The kitchen is spacious, but kinda dirty. The kitchen table is covered in cans and bottles of beer as well as 5ths of booze. You can grab any bottle you want and <a href="exec: gt ''rex_party_smallEvents'', ''party_drink''">drink</a>.'
        if party_dj =1 and dj_beer < 1:'You grab two bottle for the <a href="exec: gt ''rex_party_smallEvents'', ''dj_take_beer''">DJ and his friend</a>.'
        'Some <a href="exec: gt ''rex_party_smallEvents'', ''party_boys''">guys</a> bang their empty drinks down on the table. Refilling, they offer a cup to you and try to get you to <a href="exec: gt ''rex_party_smallEvents'', ''kitchen_boy_drink''">drink</a> with them.'
    end
end
--- rex_party ---------------------------------
