# albinahome
!2022/03/16

!! Albina House Schedule
!! 23 - 07 ... no reply

if $ARGS[0] = 'door_bell':
	act 'Leave': gt 'pav_residential'
	
    if hour = 23 or hour < 7:
		'There are better times for a house call than right now.'
	elseif hour < 9:
		'You push a button on the intercom, and a female voice blasts through.'
		'"What kind of ungodly hour do you call this?! Come back later for a social call!"'
		'That must have been her mother.'
	else
		'You push a button on the intercom and hear a female voice on the other end.'
		'"May I ask who this is?" the voice says.'
		'"It''s <<$pcs_firstname>>," you answer. "I''m a friend of Albina''s."'
		if hour < 17:
			if (kanikuli = 0) and (week < 6):
				'Nobody answers when you buzz the intercom a few times, and you decide to leave.'
			else
				'"Of course, please come in."'
				'The gate buzzes and you hear the click of the latch unlocking.'
				act 'Walk up the driveway': gt 'albinahome', 'maid_greet'
			end
		elseif hour < 21:
			'"Of course, please come in."'
			'The gate buzzes and you hear the click of the latch unlocking.'
			act 'Walk up the driveway': gt 'albinahome', 'maid_greet'
		else	
			'"I''m terribly sorry, but Miss Barlovskaya is not available right now. You might try again later."'
			'The line goes <i>click</i> and the gate remains closed.'
		end
	end
	gs 'stat'
end

if $ARGS[0] = 'maid_greet':
	if AlbinaQW['visiting'] ! daystart:
		!! Entering the house and getting random chances for events/being met by random household member
		AlbinaQW['visiting'] = daystart
		if rand(1,5) = 1:
			gt 'albina_house_events','alb_yoga_start'
		elseif rand(1,4) = 2:
			gt 'albina_sex_scenes','lazar_start'
		else
			!! maid greeting sveta at front door
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/maid.jpg"></center>'
			'The maid answers the door with a polite smile.'
			'"Please make yourself at home Miss <<$pcs_lastname>>," she says, motioning for you to enter and taking your coat.'
			act 'Continue': gt 'albinahome', 'hallway'
		end
	end
end

if $ARGS[0] = 'hallway':
	$loc = 'albinahome'
	$loc_arg = 'hallway'
	$menu_loc = 'albinahome'
	$menu_arg = 'hallway'
	$location_type = 'private'
	menu_off = 0
	frost = 0
	*clr & cla
	minut += 3
	gs 'stat'
	gs 'themes', 'indoors'

	!! For leaving the house or going to the bathroom, no random event chances
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/hallway.jpg"></center>'
	'The foyer is well-appointed with hardwood flooring, numerous arches and tasteful decor. Lighting is sunk into the exquisite staircase with wraparound balconies on either side.'
	'You have been asked not to wander around the house alone, so you''re limited in where you can go.'
	act 'Leave':
		!! AlbinaQW['visiting'] = 0
		minut += 3
		gt 'pav_residential'
	end
	act 'Go to Albina''s bedroom': gt 'albinahome', 'bedroom'
!!	act 'Go to Zoya''s bedroom': gt 'albinahome', 'zoya_room'
	act 'Go to the bathroom': gt 'albinahome', 'downstairs_bathroom'
	act 'Go to the kitchen': gt 'albinahome', 'kitchen'
	act 'Go to the pool': gt 'albinahome', 'pool_side'
end

if $ARGS[0] = 'downstairs_bathroom':
	$loc_arg = 'bathroom'
	$loc = 'albinahome'
	$locM = 'albinahome'
	$locM_arg ='bathroom'
	$menu_loc = 'albinahome'
	$menu_arg = 'bathroom'
	menu_off = 0
	$location_type = 'bathroom'
	*clr & cla
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/bathroom.jpg"></center>'
	'The bathroom is just as well appointed as the rest of the house, with polished marble used throughout its furnishings.'
	*nl
	'There is a shower, toilet, sink, <a href="exec:gt ''mirror'',''start''">mirror</a>, where you can ' + iif(pcs_hairbsh < 1,'<a href="exec:gt ''mirror'',''brush''">brush</a>','brush') + ' your hair, and even a separate bath tub.'
	act 'Return to the hallway':gt 'albinahome', 'hallway'
	dynamic $tampon
	dynamic $quickwash
	dynamic $basin
	if mc_inventory['painkillers'] > 0:
		if pain['total'] > 0 and pain['killer'] = 0:
			act 'Take a painkiller':
				cla
				pain['killer'] += 1
				mc_inventory['painkillers'] -= 1
				pcs_hydra += 20
				gs 'stat'
				*nl
				'You take a painkiller and gulp it down with a glass of water.'
				act 'Finish': gt $loc, $loc_arg
			end
		end
	end
	gs 'din_van', 'prvt_pee'
end

if $ARGS[0] = 'bedroom_event_random':
	!!temp = iif((month < 9) and (month > 5) and (week = 3 or week = 6), rand(1, 12), rand(1,10)) 
	if rand(1,6) = 1:
		!! Lazar Sex Event
		gt 'albina_sex_scenes', 'lazar_start'
	elseif rand(1,5) = 1:
		!! hot tub
		gt 'albina_house_events', 'hot_tub1'
	elseif rand(1,4) = 1 and temper < 10:
		!! swim winter
		gt 'albina_house_events', 'swim_winter1'
	elseif rand(1,3) = 1 and AlbinaQW['studylock'] = 0 and AlbinaQW['flashdrive'] = 0:
		!! laptop event
		gt 'albina_house_events', 'study_door'
	elseif rand(1,2) = 1:
		gt 'albina_house_events','alb_bedroom_shower'
	end
end

if $ARGS[0] = 'bedroom':
	$loc = 'albinahome'
	$loc_arg = 'bedroom'
	$location_type = 'private'
	$locclass = 'bedr'
	$menu_loc = 'albinahome'
	$menu_arg = 'bedroom'
	menu_off = 0
	if AlbinaQW['daily_event'] < daystart:
		AlbinaQW['daily_event'] = daystart
		gs 'albinahome', 'bedroom_event_random'
	elseif AlbinaQW['extra_event'] ! daystart:
		AlbinaQW['extra_event'] = daystart
		if rand(1,10) = 1: 
			gs 'albina_house_events','dancing' 
		elseif rand(1,9) = 1:
			gs 'albina_house_events','ass_too_big'
		end
	end
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	*clr & cla
	if AlbinaQW['albride'] = 3:
		AlbinaQW['albride'] = 4
		'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big23.jpg"></center>'
		'You head up to Albina''s room, and she smiles at you when you walk in. "So you met my mother then? Don''t worry. She''s <i>mostly</i> harmless and actually likes you. So what do you want to do?"'
		act 'Hang out': gt $loc, $loc_arg
	else
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/albinaroom.jpg"></center>'
		'Albina''s bedroom is, in a word, <i>extravagant</i>. The centrepiece is a large double bed covered in soft pillows and a door at the back of the room leads to her en-suite <a href="exec:gt ''albinahome'',''albina_bathroom''">bathroom</a>. There''s even a sliding door leading to a balcony that overlooks the pool. A closet full of expensive-looking clothes is built into one of the walls.'
		'A small <a href="exec:gt ''albina_house_events'',''night_stand''">nightstand</a> rests next to the bed and a <a href="exec:gt ''albina_house_events'',''computer''">laptop</a> is sitting on the desk.'
		act 'Return to the hallway': gt 'albinahome', 'hallway'
		act 'Chat with Albina': gt 'albina_chat', 'chat'
		act 'Talk about video games': gt 'albina_house_events', 'tekken_game'
		act 'Talk about clothes': gt 'albinahome', 'dressing'
!!		if AlbinaQW['SportDay'] ! daystart:
!!			act 'Talk about dancing': gt 'albinahome', 'dancing'
!!		end
	end
end

if $ARGS[0] = 'albina_bathroom':
	$loc_arg = 'bathroom'
	$loc = 'albinahome'
	$locM = 'albinahome'
	$locM_arg ='albina_bathroom'
	$menu_loc = 'albinahome'
	$menu_arg = 'albina_bathroom'
	menu_off = 0
	$location_type = 'bathroom'
	*clr & cla
	minut += 1
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/bathroom.jpg"></center>'
	'Albina''s bathroom.'
	*nl
	'There is a shower, toilet, sink, <a href="exec:gt ''mirror'',''start''">mirror</a>, where you can ' + iif(pcs_hairbsh < 1,'<a href="exec:gt ''mirror'',''brush''">brush</a>','brush') + ' your hair, and even a separate bath tub.'
	!! add a dildo?
	act 'Return to Albina''s room': gt 'albina_chat', 'chat_exit'
	dynamic $tampon
	dynamic $quickwash
	dynamic $basin
	if mc_inventory['painkillers'] > 0:
		if pain['total'] > 0 and pain['killer'] = 0:
			act 'Take a painkiller':
				cla
				pain['killer'] += 1
				mc_inventory['painkillers'] -= 1
				pcs_hydra += 20
				gs 'stat'
				*nl
				'You take a painkiller and gulp it down with a glass of water.'
				act 'Finish': gt $loc, $loc_arg
			end
		end
	end
	gs 'din_van', 'prvt_pee'
end


if $ARGS[0] = 'kitchen':
	$locM_arg = 'kitchen'
	$locM = 'albinahome'
	$loc_arg = 'kitchen'
	$loc = 'albinahome'
	$menu_loc = 'albinahome'
	$menu_arg = 'kitchen'
	$location_type = 'indoors'
	menu_off = 0
	CLOSE ALL
	*clr & cla
	minut += 1
	$locclass = 'kitr'
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/albina/home/kitchen.jpg"></center>'
	'Albina''s kitchen.'
	gs 'kit_din'
	act 'Back to the hall': gt 'albinahome', 'hallway'
	act 'Go to Albina''s bedroom': gt 'albinahome', 'bedroom'
!!	act 'Go to Zoya''s bedroom': gt 'albinahome', 'zoya_room'
	act 'Go to the bathroom': gt 'albinahome', 'downstairs_bathroom'
	act 'Go to the pool': gt 'albinahome', 'pool_side'
end

if $ARGS[0] = 'pool_side':
	if AlbinaQW['daily_event'] ! daystart and rand(1,2) = 1 and temper > 20 and daystage >= 2 and daystage <= 4:
		AlbinaQW['daily_event'] = daystart
		if week < 6:
			!! Albina sunbathing
			gt 'albina_house_events', 'alb_sunbathe_1'
		else
			if rand(1,2) = 1:
				!! Mom Event
				gt 'albina_mother_events', 'zoya_sunbathing_solo'
			else
				!! Mom Albina Event
				gt 'albina_mother_events', 'zoya_sunbathing_albina'
			end
		end
	end
	*clr & cla
	minut += 1
	gs 'stat'
	if month >= 11 or month <= 3:
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/pool.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/pool_winter.jpg"></center>'
	end
	'Albina''s pool.'
	act 'Back to the hall': gt 'albinahome', 'hallway'
	act 'Go to Albina''s bedroom': gt 'albinahome', 'bedroom'
!!	act 'Go to Zoya''s bedroom': gt 'albinahome', 'zoya_room'
	act 'Go to the bathroom': gt 'albinahome', 'downstairs_bathroom'
	act 'Go to the kitchen': gt 'albinahome', 'kitchen'
end

if $ARGS[0] = 'dancing':
	*clr & cla
	menu_off = 1
	gs 'stat'
	if AlbinaQW['SportHome']  = 0:
		'<center><video autoplay loop src="images/locations/pavlovsk/resident/albinahome/train.mp4"></video></center>'
		'Albina is training in her room, doing some stretching exercises.'
		'She''s wearing skin-tight yoga pants that show off her toned body quite well.'
		act 'Ask why she doesn''t train at the gym':
			*clr & cla
			AlbinaQW['SportHome']  = 1
			minut += 15
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big23.jpg"></center>'
			'"I don''t like the sweaty perverts at the gym staring at my ass, so I prefer training at home instead," she replies.'
			'You can''t help but stare at her firm, shapely rear as she says that, and she grins at you.'
			'"Eyes up here, <<$pcs_nickname>>! Anyway, if you want, I could teach you about stripping and pole dancing?"'
			act 'No thanks': AlbinaQW['SportDay'] = daystart & gt 'albinahome', 'bedroom'
			act 'Teach me stripping': gt 'albinahome', 'stripping'
			act 'Teach me poledancing': gt 'albinahome', 'poledancing'
		end
	else
		'<center><video autoplay loop src="images/locations/pavlovsk/resident/albinahome/train.mp4"></video></center>'
		'Albina is training in her room, doing some stretching exercises.'
		'She smiles at you. "Well? Want me to teach you some things?"'
		act 'No thanks': AlbinaQW['SportDay'] = daystart & gt 'albinahome', 'bedroom'
		act 'Teach me stripping': gt 'albinahome', 'stripping'
		act 'Teach me poledancing': gt 'albinahome', 'poledancing'
	end
end

if $ARGS[0] = 'stripping':
	*clr & cla
	AlbinaQW['SportDay'] = daystart
	npc_rel['A23'] += 1
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/stripdance.jpg"></center>'
	if pcs_inhib < 60:inhib_exp += rand(2,3)

	if pcs_danc >= 40:
		gs 'exercise', 'tier2', 120, 'agil', 'dancero'
		gs 'stat'
		'"Okay, we need some space. Follow me."'
		'She leads you down to the home gym, where she teaches you how to passionately dance to the music while stripping.'

		if pcs_dancero >= 100:'You don''t learn anything new since you already know everything she can teach you.'
	else
		gs 'exercise', 'tier3', 120, 'agil', 'danc'
		gs 'stat'
		'A striptease is too complex for you. You''re not able to dance and strip at the same time. Albina recommends that you start with learning to dance first.'
	end
	gs 'albinahome', 'post_workout_shower'
	act 'Rest': gt 'albinahome', 'bedroom'
end

if $ARGS[0] = 'poledancing':
	*clr & cla
	AlbinaQW['SportDay'] = daystart
	npc_rel['A23'] += 1
	if pcs_stren >= 40 and pcs_dancero > 50:
		if pcs_inhib < 60:inhib_exp += rand(2,3)
		gs 'exercise', 'tier2', 120, 'stren', 'vital', 'dancpol'
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/poledance.jpg"></center>'
		'Albina leads you to the home gym, where she teaches various acrobatic moves on the pole. The two of you greatly enjoy yourselves.'
		if pcs_dancpol >= 100: 'You didn''t learn anything new since you already know everything she can teach you.'
		gs 'albinahome', 'post_workout_shower'
		act 'Rest': gt 'albinahome', 'bedroom'
	elseif pcs_stren < 40 and pcs_dancero > 50:
		'You try your best to follow Albina''s instructions, but end up smacking your head on the pole instead and falling to the floor.'
		'You''re flat on your back and see Albina kneeling over you. "Are you okay, <<$pcs_nickname>>? It looks like you''re still too weak for pole dancing, so we need to develop your strength instead."'
		'You nod at her, and she pulls you to your feet before checking your head. "It might bruise, but otherwise, you look fine."'
		act 'Develop strength (2:00)':
			*clr & cla
			gs 'exercise', 'tier2', 120, 'stren', 'vital'
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/stren.jpg"></center>'
			'Albina shows you how to develop your strength using various exercises.'
			'You wonder if these exercises are how she has such a great-looking ass.'
			gs 'albinahome', 'post_workout_shower'
			act 'Rest': gt 'albinahome', 'bedroom'
		end
	else
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/stripdance.jpg"></center>'
		if pcs_inhib < 60:inhib_exp += rand(2,3)
		'Albina grins. "You still can''t strip well enough for pole dancing. We should practice that first."'
		if pcs_danc >= 40:
			gs 'exercise', 'tier2', 120, 'agil', 'dancero'
			gs 'stat'
			'Albina teaches you how to passionately dance to the music while stripping.'

			if pcs_dancero >= 100: 'You don''t learn anything new since you already know everything she can teach you.'
		else
			gs 'exercise', 'tier3', 120, 'agil', 'danc'
			gs 'stat'
			'A striptease is too complex for you. You''re not able to dance and strip at the same time. Albina recommends that you start with learning to dance first.'
		end
		gs 'albinahome', 'post_workout_shower'
		act 'Rest': gt 'albinahome', 'bedroom'
	end
end

if $ARGS[0] = 'post_workout_shower':
	'"You''re looking a little sweaty there, <<$pcs_nickname>>. You should go and have a shower. Mama wouldn''t like it if you got sweat marks all over the furniture. Meet me in my bedroom when you''re done."'
	dynamic $shower
end

if $ARGS[0] = 'dressing':
	act 'Try on some clothes':
		*clr & cla
		minut += 60
		pcs_mood += 10
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/albinahome/dressing.jpg"></center>'
		'You and Albina open her vast wardrobe and begin digging into her various clothes.'
		'As you rummage around in her wardrobe, you are amazed by how many different clothes she owns. Her wardrobe seems like a bottomless pit filled with dresses, skirts, leggings, jeans and other expensive-looking clothes.'
		'The two of you end up spending an hour trying on various different outfits.'
		act 'Finish': gt 'albinahome', 'bedroom'
	end
end




--- albinahome ---------------------------------