# begin
!! SKIP_QSRC2TW
!!2021/04/01
if $ARGS[0] = 'start':
	$loc_arg = 'start'
	$loc = 'begin'
	alarmVars['timerEndH'] = 8
	alarmVars['timerEndM'] = 0
	alarmVars['timerH'] = 6
	alarmVars['timerM'] = 30
	sleepVars['events_active'] = 1
	sleepVars['dreams_active'] = 1

	settingmode = 0
	$checkimg = {
		if $ARGS[0]=$ARGS[2] and $ARGS[1]=$ARGS[3]:
			$result = '<TD><center><img src="images/system/icons/check.png" height="50"></center></TD>'
		else
			$result = '<TD><center><a href="exec:$start_type[''loc''] = ''<<$ARGS[2]>>'' & $start_type[''magic''] = ''<<$ARGS[3]>>'' & gt ''begin'',''start''"><img src="images/system/icons/uncheck.png" height="50"></a></center></TD>'
		end
	}
	gs 'Cheatmenu_din'
	showstat 1
	'<center><b><font color="maroon">CHOOSE GAME START</font></b></center>'
	*nl
	'<center>There are three main start types:'
	'Last year of school (before or after summer holidays);'
	'First year of university;'
	'In the city post graduation from school.'
	*nl
	'For each start type there are 3 options:'
	'Standard;'
	'Magical (Your character will gain magic abilities and learn about a secret magical world);'
	'M2F (As per magic but your character will magically be turned into a girl in the intro).</center>'
	*nl
	*nl
	*nl
	*nl

	'<center><table><TH width="100"><p align="center">Start Type</p></TH><TH width="80"><p align="center">Standard</p></TH><TH width="80"><p align="center">Magical</p></TH><TH width="80"><p align="center">M2F</p></TH>'

	$start_text = '<TR><TD><p align="center">School</p></TD>'

	$start_text += $dyneval($checkimg, $start_type['loc'], $start_type['magic'], 'sg', 'nomagic')
	$start_text += $dyneval($checkimg, $start_type['loc'], $start_type['magic'], 'sg', 'magic')
	$start_text += $dyneval($checkimg, $start_type['loc'], $start_type['magic'], 'sg', 'tg')

	$start_text += '<TR><TD><p align="center">University</p></TD>'

	$start_text += $dyneval($checkimg, $start_type['loc'], $start_type['magic'], 'uni', 'nomagic')
	$start_text += $dyneval($checkimg, $start_type['loc'], $start_type['magic'], 'uni', 'magic')
	$start_text += $dyneval($checkimg, $start_type['loc'], $start_type['magic'], 'uni', 'tg')

	$start_text += '<TR><TD><p align="center">City</p></TD>'

	$start_text += $dyneval($checkimg, $start_type['loc'], $start_type['magic'], 'city', 'nomagic')
	$start_text += $dyneval($checkimg, $start_type['loc'], $start_type['magic'], 'city', 'magic')
	$start_text += $dyneval($checkimg, $start_type['loc'], $start_type['magic'], 'city', 'tg')

	$start_text

	'</table></center>'

	if $start_type['loc'] = 'sg' and $start_type['magic'] ! 'tg':
		act '<center><b>Start</b></center>': gt 'intro_sg', 'start'
	elseif $start_type['magic'] = 'nomagic':
		act '<center><b>Start</b></center>': gt 'intro_' + $start_type['loc'], 'start'
	elseif $start_type['magic'] = 'magic':
		act '<center><b>Start</b></center>': gt 'intro_' + $start_type['loc'] + '_m', 'start'
	elseif $start_type['magic'] = 'tg':
		act '<center><b>Start</b></center>': gt 'intro_' + $start_type['loc'] + '_tg', 'start'
	end

	act '<center><b>Change game settings</b></center>': settingmode = 1 & gs '$menu_setting'
end

if $ARGS[0] = 'warning':
	'<center><b><font color = white>WARNING</font></b></center>'
	*nl
	*nl
	*nl
	*nl
	*nl
	*nl
	'<center><img <<$set_imgh>> src="images/system/1_openings/warning.jpg" ></center>'

	act '<center><b>Continue</b></center>': gt 'begin','real_character'
end

if $ARGS[0] = 'real_character':
	$BACKIMAGE = ''
	cls
	'<center><b><font color = maroon>CHARACTER SELECTION</font></b></center>'
	'<center><img <<$set_imgh>> src="images/system/1_openings/shared/character_creation_1.jpg"></center><center>'
	*nl
	'This game has three ways to display your character''s face:'
	'    1. Dynamically using real images. The result will depend on your hair style and colour or a fixed image of your choice.'
	'    2. To use a fixed image. You can set the path to the image or replace the image "avatar" in the "images" folder of the game with a file of the same name and format (.jpg) and select "Use a fixed image".'
	'    3. Dynamically using generated images. The result will depend on your hair style and colour, eye colour, glasses, makeup, and visible cum'

	'Please note, this choice can be changed in the cheat menu at any time. Only one fixed image can be used at a time and will be the same across all saves.'
	'Your fixed image is your own personal choice, and is based on your personal preferences. By default, the game uses an avatar image from the site wikimedia.org.'

	*nl
	'If you are playing with Quest player for Android, click '
	if Enable_Android = 1:
	   *P '<a href="exec:Enable_Android = 0 & gt ''begin'',''real_character''">Here</a> (Current: <B>Yes</B>)'
	else
	   *P '<a href="exec:Enable_Android = 1 & gt ''begin'',''real_character''">Here</a> (Current: <B>No</B>)'
	end

	'</center>'

	act '<center><b>Use the dynamic profile system</b></center>':
		cls
		gt 'begin', 'start'
	end
	act '<center><b>Use a fixed profile image</b></center>':
		cls
		face_style['type'] = 1
		gt 'begin', 'use_avatar_menu'
	end
	act '<center><b>Use the rendered profile system</b></center>':
		cls
		face_style['type'] = 2
		gt 'begin', 'start'
	end
end

if $ARGS[0] = 'use_avatar_menu':
	$face_style['avatar_path'] = input('Where is the avatar image located? (Leave blank for "images/avatar.jpg")')
	if $face_style['avatar_path'] = '': $face_style['avatar_path'] = 'images/avatar.jpg'

	'You have selected: <<$face_style[''avatar_path'']>>. Is this correct?'

	act 'Yes': gt 'begin', 'start'
	act 'Try again': gt 'begin', 'use_avatar_menu'
	act 'Use a different character': gt 'begin', 'real_character'
end

--- begin ---------------------------------