# gad_gpbath
!2021/05/05
!2024/05/05 - Mira schedule introduced.
!locat['A60'] = Mira''s location. See 'miroslava_schedule'
CLOSE ALL

if $ARGS[0] = 'start':
	gs 'shortgs', 'setloc', 'gad_gpbath', 'start'
	$location_type = 'bathroom'
	menu_off = 0
	gs 'miroslava_schedule'

	frost = 0
	if banya_underwear = 0:
		if $pantyworntype ! 'none' and $braworntype ! 'none':
			banya_underwear = 1
		else
			banya_underwear = 2
		end
	end
	!!clothesAtLocation = FUNC('lost_clothes_here','gad_gpbath')

	'<center><h4>Bath</h4></center>'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/bana.jpg"></center>'
	'A small room with a low, smoky ceiling, a small stove, a couple of stainless steel water tanks, and a blackened wooden shelf.'
	'Grandma''s enema bulb is hidden behind some stuff on the shelf.'
	'You can check your weight on your grandma''s old mechanical <a href="exec:msg ''<center>Your weight is <<pcs_weight[0]>>.<<pcs_weight[1]>> kg<br>Your body mass index (BMI) is <<pcs_bmi[0]>>.<<pcs_bmi[1]>>.<br><<$bodyVars[''bmi_desc'']>></center>''">scales</a>.'

	gs 'stat'

	gs 'gad_gpbath', 'set_leave_acts'

	if locat['A60'] ! 22:
		gs 'gad_gpbath', 'alone'
	else
		gs 'gad_gpbath', 'with_Mira'
	end
end

if $ARGS[0] = 'set_leave_acts':
	if $clothingworntype ! 'nude':
		act 'Go outside': minut += 1 & gt 'gad_gpyard', 'start'
	else
		act 'Get dressed and leave':
			minut += 1
			menu_off = 1
			!!gs 'clothing', 'recover_lost_clothes', 'gad_gpbath', 1
			gs 'clothing', 'wear_last_worn'
			if banya_underwear = 1: gs 'underwear', 'wear'
			gs 'stat'
			killvar 'banya_underwear'
			gt 'gad_gpyard', 'start'
		end
		act 'Go outside naked':
			*clr & cla
			menu_off = 1
			minut += 1
			inhib_exp += rand(0, 2)
			grandmaQW['nudity_trouble'] += rand(0, 2)
			'<center><img <<$set_imgh>> src="images/locations/gadukino/grandparents/gaddvor_nude.jpg"></center>'
			'It''s undoubtedly risky leaving the bathhouse like this. But, while it''s unlikely anyone saw you go outside naked, there''s a thrill in potentially getting caught.'
			!!gs 'clothing', 'recover_lost_clothes', 'gad_gpbath'
			gs 'arousal', 'flash', 10, 'exhibitionism'
			killvar 'banya_underwear'
			gs 'stat'
			act 'Continue': gt 'gad_gpyard', 'start'
		end

		if ($pantyworntype ! 'none' or $braworntype ! 'none'):
			act 'Go outside in your underwear':
				*clr & cla
				menu_off = 1
				minut += 1
				inhib_exp += rand(0, 1)
				grandmaQW['nudity_trouble'] += rand(0,1)
				'<center><img <<$set_imgh>> src="images/locations/gadukino/grandparents/gaddvor_nude.jpg"></center>'
				'It''s undoubtedly risky leaving the bathhouse like this. But, while it''s unlikely anyone saw you go outside in your underwear, there''s a thrill in potentially getting caught.'
				!!gs 'clothing', 'recover_lost_clothes', 'gad_gpbath'
				gs 'arousal', 'flashlite', 10, 'exhibitionism'
				killvar 'banya_underwear'
				gs 'stat'
				act 'Continue': gt 'gad_gpyard', 'start'
			end
		end
	end
end


if $ARGS[0] = 'alone':
	if week >= 6:
		if hour >= 12 and hour <= 18:
			'You put the wood into the stove to feed the fire. The banya will be ready to use around 19:00.'
		elseif hour > 18 and hour < 22:
			'The banya is now ready.'

			if banaday ! daystart:
				act 'Relax in the banya (2:00)':
					cls
					menu_off = 1
					minut += 120
					pcs_sweat = rand(0,5)
					noshampoo = 1
					dynamic $showerdin
					pcs_hairbsh = 0
					pcs_makeup = 1
					if $clothingworntype ! 'nude': gs 'clothing', 'strip'
					if $pantyworntype ! 'none' and $braworntype ! 'none': gs 'underwear', 'remove'

					banaday = daystart

					if frost > 0:frost = 0

					if sauna_daystart ! daystart:
						sauna_daystart = daystart
						pcs_skin += rand(2,4)
						pcs_willpwr += 3
					end

					gs 'stat'

					'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/par.jpg"></center>'
					'You strip, sit down and relax. Then, after a proper banya session, you pick up a bucket filled with cold water, pour it over yourself, and head over to the shower. You feel like a completely new person.'
					if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the water.'
					act 'Finish': gt 'gad_gpbath', 'start'
				end
			end
		else
			'The banya is not in use at this time. However, it is available between 19:00 and 22:00 during the weekend.'
		end
	elseif week < 6:
		'The banya is not used during the week. However, it is usually ready to use from 19:00 during the weekend.'
	end
	*nl

	if mc_inventory['shampoo'] > 0 or (locat['Fam_inGad'] = 1 and func('homes_properties', 'has_access', 'parents_home')):
		act 'Wash your body (0:25)':
			*clr & cla
			menu_off = 1
			minut += 25
			if locat['Fam_inGad'] = 1 and func('homes_properties', 'has_access', 'parents_home'): noshampoo = 1
			dynamic $showerdin
			if frost > 0:frost = 0
			!!gs 'clothing', 'strip', 'gad_gpbath'
			gs 'clothing', 'strip_all'
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/mit.jpg"></center>'
			'You lather up your washcloth and start scrubbing your body. Next, you rinse off the soap and begin to lather your hair with shampoo. After rinsing off the shampoo, you feel completely clean.'
			if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the water.'

			act 'Finish': gt 'gad_gpbath', 'start'
		end
	else
		'<font color="red">You''ve run out of shampoo and will have to buy some more before you can wash.</font>'
	end

	gs 'din_van', 'private'

	!! This should all be contained in din_van
	!{
	dynamic $bteeth
	gs 'din_van', 'prvt_pee'
	dynamic $tampon

	if $clothingworntype ! 'nude':
		act 'Remove clothes':
			minut += 1
			!!gs 'clothing', 'strip', 'gad_gpbath'
			gs 'clothing', 'strip'
			gs 'stat'
			gt 'gad_gpbath', 'start'
		end
	end

	dynamic $wearpan
	dynamic $removepan
	dynamic $basin

	if mc_inventory['painkillers'] > 0:
		$pluralS = 's'
		if mc_inventory['painkillers'] = 1:$pluralS = ''
		'You have <b><<mc_inventory[''painkillers'']>></b> painkiller<<$pluralS>>.'
		if pain['total'] > 0 and pain['killer'] = 0:
			act 'Take a painkiller':
				cla
				menu_off = 1
				gs 'drugs', 'painkiller'
				pcs_hydra += 20
				gs 'stat'

				*nl
				'You take a painkiller and gulp it down with a glass of water.'

				act 'Finish': gt 'gad_gpbath', 'start'
			end
		end
	end
	if lashair ! 1 and mc_inventory['razor'] > 0:'Your razor will last <b><<mc_inventory[''razor'']>></b> more shaves. <a href="exec:gs ''din_van'', ''shave_options''">Shave Options</a>.'
	'There''s a small shaving <a href="exec:gt ''mirror'', ''start''">mirror</a> on the window sill, which you can use to ' +iif(pcs_hairbsh < 1,'<a href="exec:gt ''mirror'',''brush''">brush</a>','brush') + ' your hair.'

	!WD: heal chafe
	if mc_inventory['chafing_cream']>0:'On a shelf is a tube of ointment for chafing, which will be enough for <b><<mc_inventory[''chafing_cream'']>></b> applications.'

	if mc_inventory['tampons'] =  0 and mc_inventory['sanitary_pads'] = 0:
		'<b><font color="red">You have no tampons left.</font></b>'
	elseif mc_inventory['tampons'] =  1:
		'<font color="red">You have only <b><<mc_inventory[''tampons'']>></b> tampon left.</font>'
	else
		'You have <b><<mc_inventory[''tampons'']>></b> tampons.'
	end
	if mc_inventory['sanitary_pads'] = 0 and mc_inventory['tampons'] =  0:
		'<b><font color="red">You have no pads left.</font></b>'
	elseif mc_inventory['sanitary_pads'] = 1:
		'<font color="red">You have only <b><<mc_inventory[''sanitary_pads'']>></b> pads left.</font>'
	else
		'You have <b><<mc_inventory[''sanitary_pads'']>></b> pads.'
	end

	if mc_inventory['breastcream'] > 0:
		'<a href="exec: gs ''drugs'', ''breastcream'' & gt ''gad_gpbath'', ''start''">Apply breast cream.</a> Uses left: <<mc_inventory[''breastcream'']>>.'
	end

	if (cumloc[6] = 1 or cumloc[7] = 1):
		act 'Rinse the cum stains off your clothes in lukewarm water (0:10)':
			cla
			menu_off = 1
			cumspclnt = 6
			gs 'cum_cleanup'
			minut += 10
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/shared/sex/cum/frotsp.jpg"></center>'
			'You scrub all the cum from your clothes.'

			act 'Finish': gt 'gad_gpbath', 'start'
		end
	end

	dynamic $brit

	!!breast pump is now in the menu, not on the screen
	if mc_inventory['breast_pump'] > 0 and bp_unbox >= 1:
		act 'Use breast pump':
			gt 'lact_bp', 'bp_milking'
		end
	elseif mc_inventory['breast_pump'] > 0 and bp_unbox <= 0:
		'<a href="exec: gt ''lact_bp'', ''bp_unbox_event''">Unbox</a> your breast pump'
	elseif mc_inventory['breast_pump'] <= 0:
		gs 'lact_bp', 'massage'
	end

	dynamic $toymanage
	dynamic $enema

	if mc_inventory['chafing_cream'] > 0 and mosol > 0 and mosal_time <= totminut:
		act 'Rub ointment onto your pussy (0:05)':
			cla
			menu_off = 1
			mosal_time = totminut + 600
			minut += 5
			mc_inventory['chafing_cream'] -= 1
			mosol -= 5
			gs 'stat'
			'You take a tube of cream and rub it onto your itchy vulva.'

			act 'Finish': gt 'gad_gpbath', 'start'
		end
	end
	}
end

if $ARGS[0] = 'with_Mira':
	!125st
	act 'Undress and bathe with Mira':
		*clr & cla
		menu_off = 1
		!!gs 'clothing', 'strip', 'gad_gpbath'
		gs 'clothing', 'strip_all'
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/characters/gadukino/mira/miraban.jpg"></center>'
		'While you undress, you notice Mira removing her panties from the corner of your eye.'

		gs 'arousal', 'erotic_nudity', 5
		gs 'stat'

		act 'Watch Mira clean herself':
			*clr & cla
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/characters/gadukino/mira/miraban1.jpg"></center>'
			'You feel the hot steam penetrate into your pores while you blissfully watch Mira lather up. She sometimes throws at you short glances and smiles hesitantly in response...'
			gs 'arousal', 'erotic_nudity', 5
			gs 'stat'
			act 'Steam':
				*clr & cla
				noshampoo = 1
				dynamic $showerdin
				pcs_hairbsh = 0
				pcs_makeup = 1

				! WD: Missing Var ~ 'banaday'
				banaday = daystart
				if frost > 0:frost = 0
				pcs_skin += 5

				gs 'stat'
				'<center><img <<$set_imgh>> src="images/characters/gadukino/mira/miraban2.jpg"></center>'
				'Mira finally finishes lathering herself; you take the loofah and lather yourself from head to toe. You enjoy yourselves in the warm bath, relaxing in each other''s company, occasionally exchanging meaningless anecdotes...'
				if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the water.'
				gs 'arousal', 'erotic_nudity', 25
				gs 'arousal', 'end'
				gs 'stat'

				gs 'gad_gpbath', 'set_leave_acts'
			end
		end
	end
end

--- gad_gpbath ---------------------------------