# gad_swamp_yard

gs 'hunter_ambient', 'schedule'
if $ARGS[0] = 'start':
	gs 'shortgs', 'setloc', 'gad_swamp_yard', 'start'
	$location_type = 'secluded'
	menu_off = 0

	hunterscabin = 1

	gs 'gadukino_event', 'sound'
	gs 'stat'

	if lost_girl = 1:
		if daystart > forest_lostday + 1 and rand(forest_lostday - daystart, 30) >= 30 and DayStage = 2:
			gt 'gad_forest_lost', 'rescue', 'ranger', 'gad_swamp_yard'
		end
	end

	'<center><B>The yard in front of the hut</B></center>'
	if month >= 5 and month <= 9:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/'+iif(DayStage < 4,'swamp_yard.jpg','swamp_yard_night.jpg')+'"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/'+iif(DayStage < 4,'swamp_yard_winter.jpg','swamp_yard_winter_night.jpg')+'"></center>'
	end
	*nl


	'Behind the hut, there is a <a href="exec: gt ''gad_swampspring'' ">spring</a>. If you continue further down, there is a small <a href="exec: gt ''gad_backwater'' ">creek</a>  with relatively clean water.'

	if hunters_available = 1:
		if hunters_were_met = 0:
			if hunters_outside = 1:
				'You spot some unfamiliar <a href="exec: gt ''hunters'', ''start'' ">people</a> standing in front of the hut.'
			end
		else
			if hunters_outside = 1:
				if hunters_evening = 1:
					'You hear some gunshots and see <a href="exec: gt ''gad_swamp_yard'', ''shooting_practice'' ">Andrei</a>, not too far in the distance, shooting some bottles.'
					'<a href="exec: gt ''hunters'', ''start'' ">Igor and Sergey</a> are standing in the front yard.'
				else
					if campfire = 1 and hunters_chattime = 0:
						'You see the hunters are sitting by the <a href="exec: gt ''gad_swamp_yard'', ''campfire''">campfire</a>'
					else
						'You notice the <a href="exec: gt ''hunters'', ''start'' ">hunters</a> standing in the front yard.'
					end
				end
			else
				'The camp is quiet, but you can hear the hunters'' voices from the hut.'
			end
		end
	else
		if hunters_were_met = 0:
			'The camp is quiet. There''s nobody here right now, but the camp looks like it is likely in use and not abandoned.'
		else
			if hunters_hunting = 1:
				'The hunters are most likely out hunting for a couple hours. You have the camp to yourself!'
			else
				'The camp is quiet. The hunters are asleep in the hut.'
			end
		end
	end




	act '<b>Go to the swamp</b>': gt 'gad_swamp_yard', 'swamp_escape'
	gs 'bicycle', 'gad_swamp_yard'
	act 'Go into the house':gt 'gad_swamphouse', 'start'

	act 'Approach the firepit': gt 'gad_swamp_yard', 'campfire'
	act 'Visit the spring': gt 'gad_swampspring'
	act 'Visit the creek': gt 'gad_backwater'
	act 'Explore the woods': minut += 10 & gt 'gad_swamp_woods', 'start'


	if hunters_outside = 1 and hunters_available = 1 and rand(1,2) = 1:
		gs 'gad_swamp_yard', 'daytime_flavor_events'
	end
end


if $ARGS[0] = 'campfire':
	!TODO: Add mechanic so that fire slowly goes through wood and extinguishes when there is no more left
	cla & *clr
	$loc = 'gad_swamp_yard'
	$loc_arg = 'campfire'
	menu_off = 1
	gs 'hunter_ambient', 'schedule'
	gs 'stat'

	act 'Move away': gt 'gad_swamp_yard', 'start'

	if campfire = 1:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/'+iif(DayStage = 2,'campfire_day.jpg','campfire_night.jpg')+'"></center>'
		*nl
		'A nice, warm campfire you can sit and relax by. You can use it for cooking something or heating up some water to bathe.'
		'You can also put it out with the bucket if there is enough water.'

		if hunters_breakfast = 1 or hunters_lunch = 1:
			*clr
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hanters1.jpg"></center>'
			*nl
			'The hunters also sit around the campfire, talking and joking about all kinds of stuff before heading out hunting.'

			act 'Chat (0:30)':
				gt 'hunter_interactions', 'chat_with_hunters'
			end

			!TODO: Flesh out the learning content here
			act 'Ask for some survival tips (0:10)':
				cla
				hunter_lessons += 1
				if hunter_collective_opinion > 25 and hunter_lessons <= 10:
					hunter_collective_opinion -= 1
					gs 'exp_gain', 'bushcraft', 1
					minut += 10
					*nl
					'The hunters talk to you about some of their experiences when they first started out.'
				else
					if hunter_lessons > 10 and hunter_sexual_comfort > 25:
						!TODO: Prototype implementation for the creekside event, to be revamped
						'Sergei tells you to go by the creek for the next lesson about how to scope the area for a hunt.'
						hunter_lessons -= 8
						gs 'stat'

						act 'Further': gt 'hunter_favors', 'creekside_gangbang_request'
					else
						minut += 20
						'The hunters do not even bother to answer you. Instead, you sit quietly for twenty minutes before getting on to other business.'
					end
				end

				act 'Further': gt 'gad_swamp_yard', 'campfire'
			end
		end

		if hunters_drink = 1:
			*clr
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/fireside_drink.jpg"></center>'
			*nl
			'The hunters are drinking and chatting loudly. You can join them for a chat or maybe a drink or two if you like.'
			act 'Chat (0:30)':
				gt 'hunter_interactions', 'chat_with_hunters'
			end

			act 'Ask them for a drink':
				gt 'hunter_interactions', 'join_drinking'
			end
		end

		if bucket >= 3:
			act 'Put out the fire':
				cla & *clr
				'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/campfire_put_out.jpg"></center>'
				*nl
				'You pour some water to extinguish the campfire.'
				campfire = 0
				minut += 5
				bucket -= 3

				act 'Further': gt 'gad_swamp_yard', 'campfire'
			end
		end
		if bucket > 0:
			if boletus > 0 and mushroom_soup = 0: act 'Cook some mushroom soup (0:30)': gs 'hunter_favors', 'mushroom_soup'
			if raw_meat > 0 and meat_stew = 0: act 'Cook some meat stew (1:00)': gs 'hunter_favors', 'meat_stew'
		end

		if bucket >= 5 and hotwater = 0:
			act 'Heat up water (0:30)':
				*clr & cla
				'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/hotwater.jpg"></center>'
				minut += 30
				bucket -= 5
				hotwater = 1
				water_heated += 1
				*nl
				if water_heated > 5 and (pcs_inhib < 85 or hunter_sexual_comfort > 25):
					'"It is too tedious to keep heating up water", you think to yourself.'
				else
					'With the now-heated water, you can bathe yourself in the tub.'
				end
				gs 'stat'

				act 'Continue': gt 'gad_swamp_yard', 'campfire'
			end
		end

		act 'Eat a meal':
			cla
			act 'Return': gt 'gad_swamp_yard', 'campfire'
			act 'Eat jerky and trail mix':gt 'food', 'jerky'
			if meat_stew > 0:
				act 'Eat meat stew':
					gs 'food', 'meat_stew'
					meat_stew -= 1
					*nl
					if meat_stew > 0:
						'There''s <<meat_stew>> '+iif(meat_stew > 1, 'servings','serving')+' of stew left in the pot'
					else
						'You have finished the last of the stew. The pot is empty.'
					end
				end
			end
			if mushroom_soup > 0:
				act 'Eat mushroom soup':
					gs 'food', 'mush_soup'
					mushroom_soup -= 1
					if mushroom_soup > 0:
						'There''s <<mushroom_soup>> '+iif(mushroom_soup > 1, 'servings','serving')+' of soup left in the pot'
					else
						'You have finished the last of the soup, and the pot is empty.'
					end
				end
			end
			if bilberry > 0:
				act 'Eat berries':gt 'food','bilberry'
			end
		end
		if alko > 8:
			gt 'hunter_interactions', 'drunken_blackout'
		end
	else
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/'+iif(DayStage = 2,'campfire_out_day.jpg','campfire_out_night.jpg')+'"></center>'
		*nl
		'You can use this firepit to light a fire if you have some firewood available.'
		!TODO: Tie fire lighting to bushcraft, make hunters do it on their schedule or with Sveta asking
		if firewood >= 10 and campfire = 0:
			act 'Light fire':
				cla & *clr
				'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/'+iif($clothingworntype ! 'nude','campfire_light.jpg','campfire_light_nude.jpg')+'"></center>'
				'You use some chopped wood, dry branches and twigs to light a campfire in the firepit.'
				firewood -= 10
				campfire = 1
				minut += 15

				act 'Further': gt 'gad_swamp_yard', 'campfire'
			end
		elseif firewood < 10 and campfire = 0:
			*nl
			'There is some wood and twigs by the pit but not enough to light a new fire. You will probably need to collect branches, chop some or ask a hunter to do so.'
		end
	end
end

if $ARGS[0] = 'shooting_practice':
	if $ARGS[1] = '':
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/andrei_shooting.jpg"></center>'
		'You approach Andrei shooting some bottles with his pistol. You think maybe he can teach you a few tricks.'

		act 'Ask if you can shoot too':
			if hunter_collective_opinion > 50 and rand(1,4) = 1:
				cla & *clr
				'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/andrei_shooting.jpg"></center>'
				'"Sure thing! But, say, how about we spice it up a bit? If you can hit that bottle over there in one shot, I will do anything you want," says Andrei.'
				'"And what if I cannot?" you ask.'
				'"Well, in that case, you get to do anything I ask for. So it is only fair, right?" he asks with a smirk.'
				'"I guess it is," you respond, slightly blushing, thinking about what Andrei could ask you to do.'

				act 'Take the bet':
					cla & *clr
					'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/'+iif($clothingworntype ! 'nude','shooting.jpg','shooting_nude.jpg')+'"></center>'
					*nl 'You line up your sights and aim at the bottle. You inhale and hold your breath before...'
					hunter_collective_opinion += 6
					gs 'stat'

					act 'Pull the trigger': gt 'hunter_interactions', 'shooting_bet'
				end

				act 'Refuse':
					cla
					'Not liking the odds of likely spending the day naked or worse, "Maybe some other time," you respond before walking away.'
					hunter_collective_opinion -= 2
					gs 'stat'

					act 'Further': gt 'gad_swamp_yard', 'start'
				end
			elseif hunter_collective_opinion > 35:
				gt 'gad_swamp_yard', 'shooting_practice', 'practice'
			else
				if hunter_sexual_comfort > 20:
					gt 'gad_swamp_yard', 'shooting_practice', 'andrei_request'
				else
					cla & *clr
					'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/andrei_shooting.jpg"></center>'
					'You try to get Andrei''s attention, but he ignores you. Finally, when you keep trying, he waves his hand to gesture for you to go away.'
					act 'Further': gt 'gad_swamp_yard', 'start'
				end
			end
		end

		act 'Walk away': gt 'gad_swamp_yard', 'start'

	elseif $ARGS[1] = 'practice':
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/'+iif($clothingworntype ! 'nude','shooting.jpg','shooting_nude.jpg')+'"></center>'
		*nl '"Alright, I will show you a few tricks while you try," says Andrei. You spend about an hour practicing your shooting under Andrei''s guidance.'
		minut += 60
		gs 'exp_gain', 'shoot', 2
		gs 'stat'

		act 'Walk away': gt 'gad_swamp_yard', 'start'

	elseif $ARGS[1] = 'andrei_request':
		'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/andrei_shooting.jpg"></center>'
		'"You see, these bullets don''t come free," says Andrei. "My time looking over your shoulder also doesn''t come free. So you gotta pay me back somehow."'
		'"What do you mean?" you ask, with a vague idea of where this is going.'

		if $clothingworntype = 'nude':
			'"Since you are all naked, might as well let me fuck your little pussy right here," he says, "then I will let you shoot a bit."'
			!TODO: if pcs_inhib < x
			act 'Let him fuck you': gt 'hunter_interactions', 'andrei_quick_fuck'
		else
			andrei_shooting_request = rand(1,4)
			if andrei_shooting_request = 1:
				'"I want you to show me your tits. Just lift your top and let me have a good look at them. You can shoot the rifle then."'
				act 'Flash your tits':
					cla & *clr
					'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/shooting_tit_flash.jpg"></center>'
					'You lift your top and expose your tits to Andrei for a minute. You then cover up and ask, "Enough payment for a lesson?"'
					'"I''d appreciate a more extended look, but I will take it," responds Andrei'
					hunter_sexual_comfort += 3
					gs 'arousal', 'flashlite', 3
					gs 'arousal', 'end'
					gs 'stat'

					act 'Further': gt 'gad_swamp_yard', 'shooting_practice', 'practice'
				end
			elseif andrei_shooting_request = 2:
				'"I want you to show me your pussy. Go sit on that log and lift up your bottom. You can shoot the rifle then."'
				act 'Flash your pussy':
					cla & *clr
					'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/shooting_pussy_flash.jpg"></center>'
					'You lift your bottom and expose your pussy to Andrei for a minute. You then cover up and ask, "Enough payment for a lesson?"'
					'"I''d appreciate a longer look, but I will take it," responds Andrei'
					hunter_sexual_comfort += 5
					gs 'arousal', 'flashlite', 5
					gs 'arousal', 'end'
					gs 'stat'

					act 'Further': gt 'gad_swamp_yard', 'shooting_practice', 'practice'
				end
			elseif andrei_shooting_request = 3:
				'"I want you to take off all your clothes. Then hand them all to me. If you want to shoot my rifle, you have to be in your birthday suit."'
				act 'Strip naked':
					cla & *clr

					'You slowly take off your clothes one by one until you are completely naked in front of Andrei.'
					'You look at the ground and blush as he stares at your exposed tits, ass and pussy. You cannot help but feel your pussy moisten.'
					'"This naked look suits you better, do you know that?" says Andrei. He ogles your body for a few more minutes before handing you the rifle.'
					hunter_sexual_comfort += 7
					gs 'clothing', 'strip_all', 'gad_swamphouse'
					gs 'arousal', 'flash', 10, 'exhibitionism'
					gs 'arousal', 'end'
					gs 'stat'

					act 'Further': gt 'gad_swamp_yard', 'shooting_practice', 'practice'
				end
			elseif andrei_shooting_request = 4:
				'"Seeing a young, pretty thing like you prancing around gives me a boner. I want you to suck my dick," demands Andrei.'
				act 'Suck his dick':
					cla & *clr
					'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/shooting_bj.jpg"></center>'
					'You kneel down obediently and start sucking his dick until you feel him cumming down your throat. You make sure to catch every drop.'
					'"Now that''s a good girl. Good girls get to shoot the rifle," says Andrei.'
					hunter_sexual_comfort += 8
					gs 'boyStat', 'A172'
					gs 'arousal', 'bj', 15, 'sub', 'exhibitionism'
					gs 'cum_call', 'mouth_swallow', 'A172', 1
					gs 'arousal', 'end'
					gs 'stat'

					act 'Further': gt 'gad_swamp_yard', 'shooting_practice', 'practice'
				end
			end
		end

		act 'Walk away': gt 'gad_swamp_yard', 'start'
	end
end

if $ARGS[0] = 'swamp_escape':
	!add chance to swamped by illume
	if hunters_available = 1 and hunters_outside = 1:
		if hour >= 6 and hour < 21:
			minut += 5
			if rand(0, 9) = 0: gt 'gad_swamp', 'start' else gt 'gad_swamp','stuck'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/hunters/handshelp.jpg"></center>' & !! instead igorhanter.jpg
			'As you start moving into the swamp, Igor calls after you.'

			!TODO: Different line depending on opinion and slut
			'"<<$pcs_nickname>>, where are you going? You will get stuck in there!'
			gs 'stat'

			act 'Turn back':gt 'gad_swamp_yard','start'
			act 'Ignore him and keep going':
				minut += 5

				!TODO: Add skill clothing and temp check here instead of praying to RNGesus
				if rand(0, 9) = 0: gt 'gad_swamp', 'start' else gt 'gad_swamp','stuck'
			end
		end
	else
		minut += 5
		!TODO: Here too, also see how to avoid duplicating. Maybe create a child event node?
		if (hour >= 6 and hour < 21) or rand(0, 9) < 3: gt 'gad_swamp', 'start' else gt 'gad_swamp', 'stuck'
	end
end

if $ARGS[0] = 'daytime_flavor_events':
	gs 'hunter_ambient', 'schedule'
	if rand(1,30) = 1 and hunters_available > 0:
		gt 'hunter_interactions', 'skirt_breeze'
	elseif rand(1,10) = 1 and hunters_available > 0:
		gt 'hunter_favors', 'housekeeping_request'
	elseif rand(1,12) = 1 and hunters_available > 0:
		gt 'hunter_ambient' , 'yard_convo'
	elseif rand(1, hunter_sexual_comfort / 4 + 2) = 1 and hunters_available > 0:
		gt 'hunter_interactions', 'naked_encounter'
	elseif rand(1,15) = 1 and hunters_available > 0:
		gt 'hunter_ambient', 'bring_food'
	end
end

--- gad_swamp_yard ---------------------------------