glife/locations/_body_image.qsrc

# $body_image
!This function will return url of image, and set additional texts to $body_image_msg
!for example, you can   VIEW func('$body_image', 'body')   to view body image in popup window, and
!pl $body_image_msg     to display extra texts


$body_image_msg = ''

if $ARGS[0] = 'body':
	$body_image_msg += 'You are <<pcs_hgt>>cm tall and <<$bodyVars[''desc'']>>.'
	$result = $bodyVars['img']
end

if $ARGS[0] = 'tits':
	$body_image_msg += 'Your breasts would be considered an EU <<$titsize>>.'
	$result = 'images/pc/body/tits/t<<tits>>.jpg'
end

if $ARGS[0] = 'pubes' or $ARGS[0] = 'pussy':
	$result = 'images/pc/body/pussy/'

	if ARGS[1] ! 0: temp_pubes = ARGS[1]		else temp_pubes = pcs_pubes
	if ARGS[2] ! 0: temp_pubecol = ARGS[2]		else temp_pubecol = pcs_pubecol[2]
	if ARGS[3] ! 0: temp_pubestyle = ARGS[3]	else temp_pubestyle = pubestyle

	if temp_pubecol = 0:
		$temp_pubecol = 'black'
	elseif temp_pubecol = 1:
		$temp_pubecol = 'brunette'
	elseif temp_pubecol = 2:
		$temp_pubecol = 'ginger'
	elseif temp_pubecol = 3:
		$temp_pubecol = 'blonde'
	elseif temp_pubecol = 4:
		$temp_pubecol = 'red'
	elseif temp_pubecol = 5:
		$temp_pubecol = 'blue'
	elseif temp_pubecol = 6:
		$temp_pubecol = 'green'
	elseif temp_pubecol = 7:
		$temp_pubecol = 'pink'
	elseif temp_pubecol = 8:
		$temp_pubecol = 'purple'
	end

	if temp_pubes ! 0:
		if temp_pubes <= 3:
			$result += 'hair/pussy'
		elseif temp_pubes <= 10:
			$result += 'hair/stubble'
		elseif temp_pubes <= 15:
			$result += 'hair/very_short'
		elseif temp_pubes <= 25:
			if temp_pubestyle = 2:
				$result += 'shave/<<$temp_pubecol>>_v'
			elseif temp_pubestyle = 3:
				$result += 'shave/<<$temp_pubecol>>_triangle'
			elseif temp_pubestyle = 4:
				$result += 'shave/<<$temp_pubecol>>_landing'
			elseif temp_pubestyle = 5:
				$result += 'shave/<<$temp_pubecol>>_heart'
			elseif temp_pubestyle = 6:
				$result += 'shave/<<$temp_pubecol>>_flame'
			elseif temp_pubestyle = 7:
				$result += 'shave/<<$temp_pubecol>>_cross'
			elseif temp_pubestyle = 8:
				$result += 'shave/<<$temp_pubecol>>_trimmed'
			elseif temp_pubestyle = 12:
				$result += 'shave/<<$temp_pubecol>>_mini'
			else
				$result += 'hair/<<$temp_pubecol>>_small'
			end
		elseif temp_pubes <= 35:
			$result += 'hair/<<$temp_pubecol>>_mid'
		else
			$result += 'hair/<<$temp_pubecol>>_full'
		end
	else
		$result += 'hair/pussy'
	end

	killvar 'temp_pubes' & killvar 'temp_pubecol' & killvar 'temp_pubestyle'

	$result += '.jpg'
end

if $ARGS[0] = 'ass' or $ARGS[0] = 'butt':
	$result = 'images/pc/body/ass/'

	if bodyVars['butt_silicone'] > 0:
		$result += '9s.jpg'
		!$body_image_msg += 'Through the use of implants, you have given yourself a jiggly bubble <a href="exec:view''<<$result>>''">butt</a>.'

	!natural butt
	elseif pcs_buttsize <= 7:
		$result += '1.jpg'
		!$body_image_msg = 'Your <a href="exec:view''<<$result>>''">ass</a> is square and as flat as a plank.'
	elseif pcs_buttsize <= 14:
		$result += '2.jpg'
		!$body_image_msg = 'Your <a href="exec:view''<<$result>>''">ass</a> is square but not completely flat.'
	elseif pcs_buttsize <= 21:
		$result += '3.jpg'
		!$body_image_msg = 'You have an average, feminine looking <a href="exec:view''<<$result>>''">ass</a>.'
	elseif pcs_buttsize <= 29:
		$result += '4.jpg'
		!$body_image_msg = 'You have an above-average, feminine looking <a href="exec:view''<<$result>>''">ass</a>.'
	elseif pcs_buttsize <= 36:
		$result += '5.jpg'
		!$body_image_msg = 'Your <a href="exec:view''<<$result>>''">ass</a> is bigger, rounder and firmer than average.'
	elseif pcs_buttsize <= 44:
		$result += '6.jpg'
		!$body_image_msg = 'Your ample <a href="exec:view''<<$result>>''">ass</a> is bigger, rounder and firmer than most.'
	elseif pcs_buttsize <= 51:
		$result += '7.jpg'
		!$body_image_msg = 'You have a heart-shaped <a href="exec:view''<<$result>>''">butt</a> that jiggles as you walk.'
	elseif pcs_buttsize <= 59:
		$result += '8.jpg'
		!$body_image_msg = 'You have a large heart-shaped <a href="exec:view''<<$result>>''">butt</a> that jiggles and sways as you walk.'
	else
		$result += '9.jpg'
		!$body_image_msg = 'You have a large bubble <a href="exec:view''<<$result>>''">butt</a> that jiggles and sways as you walk.'
	end
end


if $ARGS[0] = 'coat':
	if $coatworntype = 'none':
		$body_image_msg += 'You will not wear a coat outside.'
		$body_image_msg += '<br>Your health will suffer if you don''t wear a coat in the winter.'
		$result = ''
	else
		$body_image_msg += 'Your current coat is <<$coatworntype>> no.<<coatwornnumber>>.<br>'
		!make sure to sync these with [outdoors]~364
		if PCoatWarm = 1:
			$body_image_msg += 'It''ll keep you fairly warm down to -10C.'
		elseif PCoatWarm = 2:
			$body_image_msg += 'It will handle temperatures down to -20C.'
		elseif PCoatWarm = 3:
			$body_image_msg += 'You will be nice and warm even in the depths of winter.'
		end
		$result = 'images/pc/items/<<$coatworntype>>/coats/<<coatwornnumber>>.jpg'
	end
end

if $ARGS[0] = 'clothes':
	if $clothingworntype = 'nude' and towel = 1 and $pantyworntype = 'none':
		$result = 'images/pc/body/towel.jpg'
		$body_image_msg += 'You are only wearing a towel'
	elseif $clothingworntype = 'nude' and robe = 1:
		$result = 'images/pc/body/robe.jpg'
		$body_image_msg += 'You are only wearing a robe'
	elseif $clothingworntype = 'nude' and $pantyworntype ! 'none':
		$result = 'images/pc/body/nude.jpg'
		$body_image_msg += 'You are only wearing panties'
	elseif $clothingworntype = 'nude' and $pantyworntype = 'none':
		$result = 'images/pc/body/nude1.jpg'
		$body_image_msg += 'You are completely naked.'
	elseif $clothingworntype = 'misc_outfits' and clothingwornnumber = 1:
		$result = func('$clothing_image', $clothingworntype, clothingwornnumber)
		$body_image_msg += 'You are wearing a hessian sack the hunters gave you.'
	else
		$result = func('$clothing_image', $clothingworntype, clothingwornnumber)
		$body_image_msg += 'You are wearing ' + func('$short_description', $clothingworntype) + '<<clothingwornnumber>>.'
		if PClobimbo = 1:$body_image_msg += '<br>You are dressed like a bimbo.'
		if $clothingworntype ! 'coat' and PCloswimwear = 0:
			gs 'clothing_attributes', $clothingworntype, clothingwornnumber
			gs 'clothing_descriptions'
			$body_image_msg += '<br><<$description>>'
		else
			if $clothingworntype = 'danilovich_swimsuit':
				gs '$attributes_danilovich_swim_one', $clothingworntype, clothingwornnumber
			elseif $clothingworntype = 'scandalicious_swimsuit':
				gs '$attributes_scandalicious_swim_one', $clothingworntype, clothingwornnumber
			elseif $clothingworntype = 'scandalicious_bikinis':
				gs '$attributes_scandalicious_swim_two', $clothingworntype, clothingwornnumber
			elseif $clothingworntype = 'allure_swimsuit':
				gs '$attributes_allure_swim_one', $clothingworntype, clothingwornnumber
			elseif $clothingworntype = 'allure_bikinis':
				gs '$attributes_allure_swim_two', $clothingworntype, clothingwornnumber
			elseif $clothingworntype = 'nerdvana_swimsuit':
				gs '$attributes_nerdvana_swim_one', $clothingworntype, clothingwornnumber
			elseif $clothingworntype = 'nerdvana_bikinis':
				gs '$attributes_nerdvana_swim_two', $clothingworntype, clothingwornnumber
			end
			$body_image_msg += $swimwear_description
		end

		if $clothingworntype = 'gm_maid' or PCloStyle2 = 1:
			$body_image_msg += '<br>This outfit is considered to be a maid uniform.'
		elseif $clothingworntype = 'gm_server' or PCloStyle2 = 2:
			$body_image_msg += '<br>This outfit is a server uniform, suitable for jobs that require one.'
		elseif $clothingworntype = 'eroto_strip' or PCloStyle2 = 3:
			$body_image_msg += '<br>This is a stripper outfit.'
		end
	end
end

if $ARGS[0] = 'panties':
	if $pantyworntype = 'none':
		$body_image_msg += 'You are not wearing any panties.'
		$result = func('$body_image', 'pussy')
	else
		$result = func('$panty_image', $pantyworntype, pantywornnumber)
		$body_image_msg += 'You are wearing <<$pantyworntype>> panty no. <<pantywornnumber>>'
	end
end

if $ARGS[0] = 'bra':
	if $braworntype = 'none':
		$body_image_msg += 'You are not wearing a bra. '
		$result = func('$body_image', 'tits')
	else
		$body_image_msg += 'You are wearing <<$braworntype>> bra no. <<brawornnumber>>. Your breasts would be considered an EU <<$titsize>>'
		$result = func('$bra_image', $braworntype, brawornnumber)
	end
end

if $ARGS[0] = 'bodysuit':
	if $braworntype = 'none':
		$body_image_msg += 'You are not wearing a bodysuit. '
		$result = func('$body_image', 'tits')
	else
		$body_image_msg += 'You are wearing <<$bodysuitworntype>> bodysuit <<bodysuitwornnumber>>. Your breasts would be considered an EU <<$titsize>>'
		$result = func('$pcs_outfit_image', $bodysuitworntype+'_bodysuits', bodysuitwornnumber)
	end
end

if $ARGS[0] = 'shoes':
	if $clothingworntype = 'nude' or $shoeworntype = 'none':
		$result = 'images/pc/body/feet.jpg'
	else
		$body_image_msg += 'You are wearing ' + func('$shoe_description', $shoeworntype) + '<<shoewornnumber>>.'
		$result = func('$shoe_image', $shoeworntype, shoewornnumber)
	end
end


--- $body_image ---------------------------------