glife/locations/balkon.qsrc

# balkon
if $ARGS[0] = 'start':
	*clr & cla
	$menu_loc = 'balkon'
	$menu_arg = 'start'
	menu_off = 0
	minut += 1
	gs 'stat'
	'<center><b><font color="maroon">Apartment Balcony</font></b></center>'

	if $clothingworntype = 'nude':
		'<center><img <<$set_imgh>> src="images/locations/city/residential/apartment/balcony_naked1.jpg"></center>'
	elseif $pantyworntype = 'none':
		'<center><img <<$set_imgh>> src="images/locations/city/residential/apartment/balcony_dressed1.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/city/residential/apartment/balcony_underwear1.jpg"></center>'
	end

	'You feel a light breeze as you step out on the balcony, making you feel a little chilly.'

	if hour >= 0 and hour <= 6:
		'It''s dark outside. The street lamps brighten the empty streets below.'
	elseif hour = 7:
		'A new day is dawning outside and the birds are happily chirping.'
	elseif hour >= 8 and hour <= 19:
		'It''s quite nice outside today and the streets are busy.'
	elseif hour >= 20 and hour <= 23:
		'It''s twilight and the street lights are dimly lit. There''s far less movement on the streets.'
	end

	if $clothingworntype = 'nude':
		if sosedBalDay ! daystart:
			if rand(1, 4) = 4:
				'A neighbor from the opposite building is out on his balcony and looking your way. He''s noticed that you''re naked...'
				act 'Look at the neighbor': gt 'balkon2', 'sosed'
			else
				'A neighbor from the opposite building is out on his balcony and looking your way. You feel a little creeped out that he''s following you closely with his gaze.'
			end
		else
			'No one notices that you''re standing naked on your balcony. You feel a little dejected that no one payed you any attention.'
		end
	end

	act 'Return to the living room':
		if $loc = 'sitr': 
			gt 'sitr'
		else
			gt 'sitr2x'
		end
	end
	
	act 'Approach the railing':gt 'balkon2', 'niz'
	
	if mc_inventory['cigarettes'] >= 1: act 'Light a cigarette':gt 'balkon2', 'kurit'
	if mc_inventory['joints'] > 0 and drugVars['weed_high'] = 0: act 'Smoke a joint': minut += 10 & gs 'drugs', 'joint' & gt 'balkon', 'start'
	if pcs_horny >= 50 and pcs_inhib > 30: act 'Masturbate':gt 'balkon2', 'masopt'	
end

--- balkon ---------------------------------