glife/locations/city_experimental_trials.qsrc

# city_experimental_trials

!!2023/09/20
!! Content reused from the medical experiment mod by pchs and julzor.
!! Inspiration taken from Clean Slate: https://tfgames.site/index.php?module=viewgame&id=2247



$loc = 'city_experimental_trials'
$location_type = 'private'
$locM = 'city_experimental_trials'

$doc1 = 'Doctor Sokolnikov'
$doc2 = 'Doctor Ivanov'



if $ARGS[0] = 'front_desk' or $ARGS[0] = '':
	menu_off = 0
	$menu_loc = 'city_experimental_trials'
	$menu_arg = 'front_desk'
	$loc_arg = 'front_desk'
	minut += 2
	gs 'stat'

	temp_rand = rand(0,3)
	if temp_rand <= 1 or experimentQW['signed'] = 0:
		'<center><img <<$set_imgh>> src="images\locations\city\residential\clinic\experiments\desk1.jpg"></center>'
		*nl
		'A young woman, dressed in office clothes and wearing glasses, is sitting behind a desk.'

	elseif temp_rand <= 2:
		'<center><img <<$set_imgh>> src="images\locations\city\residential\clinic\experiments\nurse1.jpg"></center>'
		*nl
		'A young nurse is sitting behind a desk.'

	else
		'<center><img <<$set_imgh>> src="images\locations\city\residential\clinic\experiments\nurse2.jpg"></center>'
		*nl
		'An elderly nurse is sitting behind a desk.'
	end

	killvar 'temp_rand'

	if experimentQW['signed'] ! 0:
		'She looks up as you walk in and warmly welcomes you inside. "Hello Miss <<$pcs_lastname>>, how can I help you today?"'

		act 'Leave': gt 'city_clinic', 'start'

		if $experimentQW['trial_active'] = '':
			act 'Ask which clinical trials are available': gt 'city_experimental_trials_list', 'see_trials'
		else
			if experimentQW['trial_duration'] > 0:
				*nl
				'You are already taking part in a clinical trial.'
			else
				act 'Report your findings':
					cla
					*nl
					if pcs_intel < 50:
						'You report your experience in as much detail as you can.'
						'"Thank you for your participation, it is invaluable to our research."'
					else
						'You report your experience in great detail, noting the various side effects that you''ve noticed.'
						'"Thank you so much for your help! You''ve helped us advance our research greatly!"'
						if rand(0,2) = 0:
							temp_tip = 10 * (pcs_intel  * rand(1,3) / 10)
							'"I think your dedication should be rewarded," she adds and hands you various notes adding up to ₽<<temp_tip>>.'
							money += temp_tip
							killvar 'temp_tip'
						end
					end

					$experimentQW['trial_active'] = ''
					act 'Continue': gt 'city_experimental_trials', 'front_desk'
				end
			end
		end

		if experimentQW['times_participated_0'] >= 2 or experimentQW['times_participated_1'] ! 0 or experimentQW['times_participated_2'] ! 0 or experimentQW['times_participated_3'] ! 0 or experimentQW['times_participated_4'] ! 0:
			*nl
			'You also spot a small pharmaceutical stand to the side.'
			act 'Go to the experimental pharmacy': gt 'city_experimental_trials_pharmacy', 'counter'
		end


	else
		'She looks up as you walk in and warmely welcomes you inside. "Hello miss, how can I help you?"'
		'"I read an advert that you''re looking for people to test new treatments? And that you compensate the subjects for it?" you reply.'
		'"We are at the forefront of medical research, and you could help us push the boundaries of modern medicine. Your contribution will help save countless lives. If you want to apply, please read and fill in this form."'
		'She hands over a clipboard.'
		*nl

		if pcs_intel < 10:
			'The form is filled with legal jargon, but you''re pretty sure that you''ll be paid to be experimented on and that these trials won''t harm your health.'
		elseif pcs_intel < 50:
			'The form is filled with a lot of legal jargon, but you manage to grasp the important parts.'
			'The clinic will pay you to take an experimental treatment and any consequences are yours to bear, but they do guarantee your safety.'
		elseif pcs_intel < 90:
			'The form explains that you''ll get paid to take part in testing experimental treatments.'
			'The clinic is not liable for any of the consequences, but they will not jeopardize your general health.'
			'Finally you are prohibited from disclosing the methods and results of the treatments to anybody not affiliated with the clinic.'
		else
			'The form is filled with complicated legal jargon intended to confuse the reader, but your sharp mind pierces the veil.'
			'You will get paid when you take part in testing experimental treatments which can result in permanent changes to your body and mind.'
			'You are solely responsible in dealing with those consequences and you may not reveal the contents nor results of the treatments. If you do so, then you can be sued for an exorbitant amount of money.'
			'Finally, reading between the lines, you also manage to grasp that some of these experiments aren''t fully ethical.'
		end

		*nl

		'At the bottom of the document is an area where you need to write down your full name, age and add your signature.'

		act 'Sign the document':
			experimentQW['signed'] = 1
			*clr & cla
			'<center><img <<$set_imgh>> src="images\locations\city\residential\clinic\experiments\desk1.jpg"></center>'
			*nl
			'You hand the signed document back to the woman.'
			'"Thank you Miss... <<$pcs_lastname>>," she says as she looks it over. "We''ll add you to our database and you can enter our various trials. The contract you signed is legally binding, so you''re not allowed to discuss your experiences with anybody outside of this clinic."'
			'"It''s to protect our proprietary technology," she adds, seemingly having noticed the look on your face. "If you talk about what happens here, then you can leak our discoveries. Everything will be fine so long as you keep this to yourself."'

			act 'Return to the front desk': gt 'city_experimental_trials', 'front_desk'
		end

		act 'Put the contract down and leave': gt 'city_clinic', 'start'
	end
end



killvar '$doc1'
killvar '$doc2'

--- city_experimental_trials ---------------------------------