glife/locations/fuelstation_carwash.qsrc

# fuelstation_carwash
!2020/10/16/Gwen
! most complete comments for how the code works can be found in 'wash', 'titsFlash', 'runback', and 'punishSpank'
! most other code in here are just variations of those sections

if $ARGS[0] = 'start':
	$loc_arg = 'start'
	$loc = 'fuelstation_carwash'
	$menu_loc = 'fuelstation_carwash'
	$menu_arg = 'start'
	menu_off = 0
	*clr & cla
	! can''t wash cars if have visible cum already
	if (cumloc[6] = 1 or cumloc[7] = 1) or cumloc[11] = 1:
		minut += 5
		pcs_mood -= 5
		gs 'fame', 'pav', 'sex', rand(0, 2)

		'The gas station worker chases you away. "At least wash yourself off first, whore!"'

		act 'Leave': gt 'fuelstation', 'start'
		act 'Go to the toilet': gt 'fuelstation', 'toilet'
	else
		gt 'fuelstation_carwash', 'wash'
	end
end

if $ARGS[0] = 'wash':

	if $region = 'city':
		slut_compare = fame['city_slut']
	elseif $region = 'pav':
		slut_compare = fame['pav_slut']
	end

	! only wearing bimbo or prostitute clothing and looking good can get propositioned by a customer
	if PCloBimbo = 1 or PCloStyle = 4:
		'<center><img <<$set_imgh>> src="images/locations/shared/carwash/bimboclean<<rand(1, 4)>>.jpg"></center>'

		minut += 60
		pcs_mood -= 5
		gs 'sweat', 'add', 2

		if pcs_apprnc >= 60:
			! slightly more money for wearing bimbo or prostitute clothing and looking good too
			'You wash the windows of several cars and earn 100 <b>₽</b>.'
			money += 100

			! min chance of 20 percent; max chance of 80 percent; percent chance scales with fame['city_slut'] or fame['pav_slut']
			! as your reputation increases you will be asked more often
			if rand(1, 100) <= min(max(20, slut_compare), 80):
				'As you finish washing another car, the driver walks up to you to give you a tip. From the way he''s looking at you, it''s obvious he''s interested in something more as well.'
				! starts off with always doing titsQ when rep is low, as rep increases they may skip a question since they know you will do it anyway
				! also different people have different tastes so you wont be asked the same thing in the same order every time by every customer that walks up to you
				carwashscene = rand(1, 100)
				if carwashscene <= min(max(25, slut_compare), 50) and carwashscene >= 25:
					gt 'fuelstation_carwash', 'assQ'
				elseif carwashscene <= min(max(50, slut_compare), 65) and carwashscene >= 50:
					gt 'fuelstation_carwash', 'pussyQ'
				elseif carwashscene <= min(max(65, slut_compare), 85) and carwashscene >= 65:
					gt 'fuelstation_carwash', 'handQ'
				elseif carwashscene <= min(max(85, slut_compare), 100) and carwashscene >= 85:
					gt 'fuelstation_carwash', 'blowQ'
				else
					gt 'fuelstation_carwash', 'titsQ'
				end
			else
				gs 'fuelstation_carwash', 'flash_passing'
			end
		else
			! slightly more money for wearing bimbo or prostitute clothing but not looking too great
			'You wash the windows of several cars and earn 80 <b>₽</b>.'
			money += 80

			gs 'fuelstation_carwash', 'flash_passing'
		end
	else
		minut += 60
		pcs_mood -= 5
		gs 'sweat', 'add', 2
		money += 60

		'<center><img <<$set_imgh>> src="images/locations/shared/carwash/regular<<rand(1, 4)>>.jpg"></center>'

		! normal money just for the car washing
		'You wash the windows of several cars and earn 60 <b>₽</b>.'

		gs 'fuelstation_carwash', 'flash_passing'
	end
end

if $ARGS[0] = 'flash_passing':
	act 'Continue':gt 'fuelstation', 'start'
	if PCloPants > 0 or PCloSkirt > 0:
		if pcs_inhib >= 35: act 'Flash your tits at passing cars': gt 'fuelstation_carwash', 'titsFlash', 'Free', 'Flash'
		if exhibitionist_lvl > 0: act 'Flash your ass at passing cars': gt 'fuelstation_carwash', 'assFlash', 'Free', 'Flash'
		if exhibitionist_lvl > 1: act 'Flash your pussy at passing cars': gt 'fuelstation_carwash', 'pussyFlash', 'Free', 'Flash'
	end
end

if $ARGS[0] = 'titsQ':
	'<center><img <<$set_imgh>> src="images/locations/shared/carwash/bimboclean<<rand(1, 4)>>.jpg"></center>'

	'"Want to earn some more cash, girl? Show me your tits and I''ll give you 50 <b>₽</b>. It''s easy money."'

	! inhibition or exhibitionism requirements needed to accept the offer or just have fun with him
	if exhibitionist_lvl > 0 or pcs_inhib >= 35 or pcs_horny >= 40: act 'Agree': gt 'fuelstation_carwash', 'titsFlash', 'Paid', 'Question'
	act 'Refuse': gt 'fuelstation_carwash', 'refuse'
end

if $ARGS[0] = 'assQ':
	'<center><img <<$set_imgh>> src="images/locations/shared/carwash/bimboclean<<rand(1, 4)>>.jpg"></center>'

	'"What a nice ass you have there. Will 50 <b>₽</b> convince you to show it to me?"'

	! inhibition or exhibitionism requirements needed to accept the offer or just have fun with him
	if exhibitionist_lvl > 0 or pcs_horny >= 60: act 'Agree': gt 'fuelstation_carwash', 'assFlash', 'Paid', 'Question'
	act 'Refuse': gt 'fuelstation_carwash', 'refuse'
end

if $ARGS[0] = 'pussyQ':
	'<center><img <<$set_imgh>> src="images/locations/shared/carwash/bimboclean<<rand(1, 4)>>.jpg"></center>'

	'"You look like a cool girl. Let me see your pussy and I''ll give you 50 <b>₽</b>."'

	! inhibition or exhibitionism requirements needed to accept the offer or just have fun with him
	if exhibitionist_lvl > 1 or pcs_horny >= 80: act 'Agree': gt 'fuelstation_carwash', 'pussyFlash', 'Paid', 'Question'
	act 'Refuse': gt 'fuelstation_carwash', 'refuse'
end

if $ARGS[0] = 'handQ':
	'<center><img <<$set_imgh>> src="images/locations/shared/carwash/bimboclean<<rand(1, 4)>>.jpg"></center>'

	'"Could you help me out, girl? It''s getting tight down here in my pants just looking at you. How about you... help me out? I''ll pay you 200 <b>₽</b>."'

	! slut or horny requirements needed to accept the offer or just have fun with him
	if slut_compare >= 25 or pcs_horny >= 25: act 'Give him a handjob': gt 'fuelstation_carwash', 'handjob', 'Paid'
	act 'Refuse': gt 'fuelstation_carwash', 'refuse'
end

if $ARGS[0] = 'blowQ':
	'<center><img <<$set_imgh>> src="images/locations/shared/carwash/bimboclean<<rand(1, 4)>>.jpg"></center>'

	'"Looking hot today, girl! How about you put your mouth to good use? I''ll pay you 200 <b>₽</b>."'

	! slut or horny requirements needed to accept the offer or just have fun with him
	if slut_compare >= 30 or pcs_horny >= 30: act 'Give him a blowjob': gt 'fuelstation_carwash', 'blowjob', 'Paid', 'Question'
	act 'Refuse': gt 'fuelstation_carwash', 'refuse'
end

if $ARGS[0] = 'refuse':
	! just being asked can slowly change your inhibitions which will enable a player to eventually agree to the questions above
	if pcs_inhib < 35: inhib_exp += rand(1, 2)
	pcs_mood += 5
	gs 'stat'

	'<center><video autoplay loop src="images/pc/reactions/no.mp4"></video></center>'

	'You consider his offer, but decide to turn him down and walk away.'

	act 'Go back to washing cars': gt 'fuelstation', 'start'
end

! $ARGS[1] = whether you got paid for this
! $ARGS[2] = whether this act came from a customer question or just flashing for passing cars
if $ARGS[0] = 'titsFlash':
	! chance for using photos or videos
	if rand(1,100) < 50:
		! chance of using old pics since there are so many newer pics to choose from
		if rand(1,100) < 15:
			if PCloPants > 0:
				$flash_image = 'images/locations/shared/carwash/pants/titsflash<<rand(1, 2)>>.jpg'
			else
				$flash_image = 'images/locations/shared/carwash/skirt/titsflash1.jpg'
			end
		else
			! newer photos are more neatly organized into different folders so no looping needed
			!! Let the flash system handle it.
		end
	else
		if PCloPants > 0:
			$flash_video = 'images/locations/shared/carwash/pants/titsflash<<rand(1, 4)>>.mp4'
		elsei
			$flash_video = 'images/locations/shared/carwash/skirt/titsflash<<rand(1, 3)>>.mp4'
		end
	end

	! text differences depending on whether you were paid, whether you are flashing for a customer or for the cars on the road, and what type of clothing you are wearing
	if $ARGS[1] = 'Paid':
		$flash_text[0] = 'You ' + iif(PCloSkirt > 0, 'pull down', 'lift up') + ' your top and show him your breasts for a few seconds.'
		$flash_text[1] = 'You quickly cover up and take your money.'
	else
		if $ARGS[2] = 'Question':
			$flash_text[0] = 'You ' + iif(PCloSkirt > 0, 'pull down', 'lift up')   + ' your top and show him your breasts for a few seconds. You give your breasts a little shake for him.'
			$flash_text[1] = 'You ' + iif(PCloSkirt > 0, 'lift up',   'pull down') + ' your top and cover up.'
		else
			$flash_text[0] = 'You ' + iif(PCloSkirt > 0, 'pull down', 'lift up')   + ' your top and expose your breasts to the road for a few seconds. A few cars pass by and honk in appreciation as you give your breasts a little shake.'
			$flash_text[1] = 'You ' + iif(PCloSkirt > 0, 'lift up',   'pull down') + ' your top and cover up.'
		end
	end

	gs 'flash', 'tits', 'outdoors', 1, 2

	! reputation and money will depend on whether you were paid
	if $ARGS[1] = 'Paid':
		money += 50
		if $region = 'city':
			gs 'fame', 'city', 'prostitute', rand(0, 1)
		elseif $region = 'pav':
			gs 'fame', 'pav', 'prostitute', rand(0, 1)
		end
	end

	if pcs_inhib < 30: inhib_exp += rand(2, 4)
	pcs_mood += 5
	gs 'stat'

	! can only continue with more questions if flashing for a customer
	! also more questions will require either sub or dom or bimbo or horny as well as bimbo or prostitute clothing
	! this has a wide range of requirements so that many different types of characters can still play this content
	!if (bimbolevel >= 1 or pcs_horny >= 5) and (PCloBimbo = 1 or PCloStyle = 4) and $ARGS[2] = 'Question':
	if (bimbolevel >= 1 or pcs_horny >= 5) and (PCloBimbo = 1 or PCloStyle = 4) and $ARGS[2] = 'Question':
		! once again dynamically choosing the next scene to play based on reputation
		carwashscene = rand(1, 100)
		if carwashscene <= min(max(30,slut_compare),60) and carwashscene >= 50:
			act 'Continue': gt 'fuelstation_carwash', 'pussyQ'
		elseif carwashscene <= min(max(60,slut_compare),80) and carwashscene >= 60:
			act 'Continue': gt 'fuelstation_carwash', 'handQ'
		elseif carwashscene <= min(max(80,slut_compare),100) and carwashscene >= 80:
			act 'Continue': gt 'fuelstation_carwash', 'blowQ'
		else
			act 'Continue': gt 'fuelstation_carwash', 'assQ'
		end
	! flashing for cars just allows you to return to the gas station
	else
		act 'Go back to the gas station':
			if $ARGS[1] = 'Paid': slutty += 1
			gt 'fuelstation', 'start'
		end
	end
end

! $ARGS[1] = whether you got paid for this
! $ARGS[2] = whether this act came from a customer question or just flashing for passing cars
if $ARGS[0] = 'assFlash':
	if rand(1, 100) < 50:
		i = rand(1, 100)
		if i < 10:
			if PCloPants > 0:
				$flash_image = 'images/locations/shared/carwash/pants/assflash1.jpg'
			else
				$flash_image = 'images/locations/shared/carwash/skirt/assflash1.jpg'
			end
		else
			!! Let the flash system handle it
		end
	else
		if PCloPants > 0:
			$flash_video = 'images/locations/shared/carwash/pants/assflash<<rand(1, 3)>>.mp4'
		else
			$flash_video = 'images/locations/shared/carwash/skirt/assflash<<rand(1, 2)>>.mp4'
		end
	end

	if $ARGS[1] = 'Paid':
		$flash_text[0] = 'You ' + iif(PCloSkirt > 0, 'lift your ' + iif(PCloDress = 1, 'dress', 'skirt') + ' up', 'pull your pants down') + ' and show him your ass for a few seconds.'
		$flash_text[1] = 'You quickly cover up and take your money.'
	else
		if $ARGS[2] = 'Question':
			$flash_text[0] = 'You ' + iif(PCloSkirt > 0, 'lift your ' + iif(PCloDress = 1, 'dress', 'skirt') + ' up',   'pull your pants down') + ' and show him your ass for a few seconds. You give your ass a little shake for him before covering up.'
			$flash_text[1] = 'You ' + iif(PCloSkirt > 0, 'pull your ' + iif(PCloDress = 1, 'dress', 'skirt') + ' down', 'pull your pants up')   + ' and cover up.'
		else
			$flash_text[0] = 'You ' + iif(PCloSkirt > 0, 'lift your ' + iif(PCloDress = 1, 'dress', 'skirt') + ' up',   'pull your pants down') + ' and expose your ass to the road for a few seconds. A few cars pass by and honk in appreciation as you give your ass a little shake.'
			$flash_text[1] = 'You ' + iif(PCloSkirt > 0, 'pull your ' + iif(PCloDress = 1, 'dress', 'skirt') + ' down', 'pull your pants up')   + ' and cover up.'
		end
	end

	gs 'flash', 'butt', 'outdoors', 2, 2

	! reputation and money will depend on whether you were paid
	if $ARGS[1] = 'Paid':
		money += 50
		if $region = 'city':
			gs 'fame', 'city', 'prostitute', rand(0, 1)
		elseif $region = 'pav':
			gs 'fame', 'pav', 'prostitute', rand(0, 1)
		end
	end
	if pcs_inhib < 30: inhib_exp += rand(2, 4)
	pcs_mood += 5
	gs 'stat'

	!if (bimbolevel >= 1 or pcs_horny >= 10) and (PCloBimbo = 1 or PCloStyle = 4) and $ARGS[2] = 'Question':
	if (bimbolevel >= 1 or pcs_horny >= 10) and (PCloBimbo = 1 or PCloStyle = 4) and $ARGS[2] = 'Question':
		carwashscene = rand(1, 100)
		if carwashscene <= min(max(50, slut_compare), 75) and carwashscene >= 50:
			act 'Continue': gt 'fuelstation_carwash', 'handQ'
		elseif carwashscene <= min(max(75, slut_compare), 100) and carwashscene >= 75:
			act 'Continue': gt 'fuelstation_carwash', 'blowQ'
		else
			act 'Continue': gt 'fuelstation_carwash', 'pussyQ'
		end
	else
		act 'Go back to the gas station':
			if $ARGS[1] = 'Paid': slutty += 1
			gt 'fuelstation', 'start'
		end
	end
end

! $ARGS[1] = whether you got paid for this
! $ARGS[2] = whether this act came from a customer question or just flashing for passing cars
if $ARGS[0] = 'pussyFlash':
	!! Flash image is handled the the 'flash' function
	if $ARGS[1] = 'Paid':
		$flash_text[0] = 'You ' + iif(PCloSkirt > 0, 'lift your ' + iif(PCloDress = 1, 'dress', 'skirt') + ' up ', 'pull your pants down') + ' and show him your pussy for a few seconds.'
		$flash_text[1] = 'You quickly cover up and take your money.'
	else
		if $ARGS[2] = 'Question':
			$flash_text[0] = 'You ' + iif(PCloSkirt > 0, 'lift your ' + iif(PCloDress = 1, 'dress', 'skirt') + ' up',   'pull your pants down') + ' and show him your pussy for a few seconds, rubbing your clit a little for him.'
			$flash_text[1] = 'You ' + iif(PCloSkirt > 0, 'pull your ' + iif(PCloDress = 1, 'dress', 'skirt') + ' down', 'pull your pants up')   + ' and cover up.'
		else
			$flash_text[0] = 'You ' + iif(PCloSkirt > 0, 'lift your ' + iif(PCloDress = 1, 'dress', 'skirt') + ' up',   'pull your pants down') + ' and expose your pussy to the road for a few seconds. A few cars pass by and honk in appreciation as you rub your clit a little.'
			$flash_text[1] = 'You ' + iif(PCloSkirt > 0, 'pull your ' + iif(PCloDress = 1, 'dress', 'skirt') + ' down', 'pull your pants up')   + ' and cover up.'
		end
	end

	gs 'flash', 'full', 'outdoors', 3, 2

	! reputation and money will depend on whether you were paid
	if $ARGS[1] = 'Paid':
		money += 50
		if $region = 'city':
			gs 'fame', 'city', 'prostitute', 1
		elseif $region = 'pav':
			gs 'fame', 'pav', 'prostitute', 1
		end
	end

	if pcs_inhib < 40: inhib_exp += rand(4, 6)
	pcs_mood += 5
	gs 'stat'

	!if (bimbolevel >= 1 or pcs_horny >= 15) and (PCloBimbo = 1 or PCloStyle = 4) and $ARGS[2] = 'Question':
	if (bimbolevel >= 1 or pcs_horny >= 15) and (PCloBimbo = 1 or PCloStyle = 4) and $ARGS[2] = 'Question':
		carwashscene = rand(1, 100)
		if carwashscene <= min(max(60, slut_compare), 100) and carwashscene >= 60:
			act 'Continue': gt 'fuelstation_carwash', 'blowQ'
		else
			act 'Continue': gt 'fuelstation_carwash', 'handQ'
		end
	else
		act 'Go back to the gas station':
			if $ARGS[1] = 'Paid': slutty += 1
			gt 'fuelstation', 'start'
		end
	end
end

! $ARGS[1] = whether you got paid for this
if $ARGS[0] = 'handjob':
	! generate random npc for sex
	gs 'npcgeneratec', 0, 'gas station customer', rand(18,40)
	gs 'boyStat', $npclastgenerated

	if $ARGS[1] = 'Paid':
		money += 200
		if $region = 'city':
			gs 'fame', 'city', 'prostitute', 2
		elseif $region = 'pav':
			gs 'fame', 'pav', 'prostitute', 2
		end
	elseif $ARGS[1] = 'Free':
		gs 'fame', 'pav', 'sex', 2
	end
	if pcs_inhib < 50: inhib_exp += rand(6,8)
	pcs_mood += 5
	gs 'stat'

	if rand(1, 100) < 50:
		if rand(0, 1) = 0:
			'<center><img <<$set_imgh>> src="images/shared/sex/handjob/hand.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/shared/sex/handjob/hj.jpg"></center>'
		end
	else
		i = rand(0, 2)
		if i = 0:
			'<center><video autoplay loop src="images/shared/sex/handjob/hj<<i>>.mp4"></video></center>'
		else
			'<center><video autoplay loop src="images/shared/sex/handjob/handjob<<i>>.mp4"></video></center>'
		end
	end

	if $ARGS[1] = 'Paid':
		'You follow him behind the gas station, where you get the promised money. You then kneel down, unzip his pants and start working his shaft with your hands.'
		gs 'arousal', 'hj', 15, 'sub', 'prostitution', 'unknown'
	elseif $ARGS[1] = 'Free':
		'You lead him behind the gas station where you kneel down, unzip his pants and start working his shaft with your hands.'
		gs 'arousal', 'hj', 15, 'dom', 'unknown'
	end
	gs 'stat'

	'After a while, the man starts pulling your head closer to him. "I''ll give you 200 <b>₽</b> if you open that mouth for me."'

	if (bimbolevel >= 1 and pcs_inhib >= 30) or pcs_horny >= 30: act 'Give him a blowjob': gt 'fuelstation_carwash', 'blowjob', 'Paid', 'handjob'
	act 'Keep using your hand': gt 'fuelstation_carwash', 'handjobEndQ'
end

! $ARGS[1] = whether you got paid for this
! $ARGS[2] = whether this act came from a customer question or already giving a customer a handjob
if $ARGS[0] = 'blowjob':
	if $ARGS[2] = 'Question':
		gs 'npcgeneratec', 0, 'gas station customer', rand(18, 40)
		gs 'boyStat', $npclastgenerated
	end

	if $ARGS[1] = 'Paid':
		money += 200
		if $region = 'city':
			gs 'fame', 'city', 'prostitute', 2
		elseif $region = 'pav':
			gs 'fame', 'pav', 'prostitute', 2
		end
	elseif $ARGS[1] = 'Free':
		gs 'fame', 'pav', 'sex', 2
	end
	if pcs_inhib < 50: inhib_exp += rand(6, 8)
	pcs_mood += 5
	gs 'stat'

	if rand(1, 100) < 50:
		'<center><img <<$set_imgh>> src="images/locations/shared/carwash/sex/blowjob<<rand(1, 4)>>.jpg"></center>'
	else
		'<center><video autoplay loop src="images/locations/shared/carwash/sex/blowjob<<rand(1, 3)>>.mp4"></video></center>'
	end

	if $ARGS[2] = 'Question':
		if $ARGS[1] = 'Paid':
			'You follow him behind the gas station, where you get the promised money. You then kneel down, unzip his pants and take his dick into your mouth.'
			gs 'arousal', 'bj', 15, 'sub', 'prostitution', 'unknown'
		elseif $ARGS[1] = 'Free':
			'You lead him behind the gas station where kneel down, unzip his pants and take his dick into your mouth.'
			gs 'arousal', 'bj', 15, 'dom', 'unknown'
		end
	elseif $ARGS[2] = 'handjob':
		if $ARGS[1] = 'Paid':
			'You grab the money he tosses at you before taking his dick into your mouth.'
			gs 'arousal', 'bj', 15, 'sub', 'prostitution', 'unknown'
		elseif $ARGS[1] = 'Free':
			'You take his dick into your mouth.'
			gs 'arousal', 'bj', 15, 'dom', 'unknown'
		end
	end
	gs 'stat'

	'After a while, the man starts trying to remove your clothes. "I''ll give you 400 <b>₽</b> if you let me take your pussy."'

	if (bimbolevel >= 1 and pcs_inhib >= 40) or pcs_horny >= 40:
		if stat['think_virgin'] = 1:
			act 'Offer your ass instead': gt 'fuelstation_carwash', 'fuckAnal', 'Paid'
		else
			act 'Offer your pussy': gt 'fuelstation_carwash', 'fuckPussy', 'Paid'
			act 'Offer your ass': gt 'fuelstation_carwash', 'fuckAnal', 'Paid'
		end
	end
	act 'Suck harder to make him cum': gt 'fuelstation_carwash', 'blowjobEndQ'
end

! $ARGS[1] = whether you got paid for this
if $ARGS[0] = 'fuckPussy':
	if $ARGS[1] = 'Paid':
		money += 400
		if $region = 'city':
			gs 'fame', 'city', 'prostitute', 4
		elseif $region = 'pav':
			gs 'fame', 'pav', 'prostitute', 4
		end
	elseif $ARGS[1] = 'Free':
		gs 'fame', 'pav', 'sex', 4
	end
	if pcs_inhib < 60: inhib_exp += rand(14, 16)
	pcs_mood += 10
	gs 'stat'

	if rand(1, 100) < 50:
		'<center><img <<$set_imgh>> src="images/locations/shared/carwash/sex/fuckpussy<<rand(1, 4)>>.jpg"></center>'
	else
		'<center><video autoplay loop src="images/locations/shared/carwash/sex/fuckpussy<<rand(1, 4)>>.mp4"></video></center>'
	end

	if $ARGS[1] = 'Paid':
		'You take the money before bending over and letting the man fuck your pussy.'
		gs 'arousal', 'vaginal', 30, 'sub', 'prostitution', 'unknown'
	elseif $ARGS[1] = 'Free':
		'You bend over and let the man start fucking your pussy.'
		gs 'arousal', 'vaginal', 30, 'dom', 'unknown'
	end
	gs 'stat'

	act 'Continue': gt 'fuelstation_carwash', 'pussyEndQ'
end

! $ARGS[1] = whether you got paid for this
if $ARGS[0] = 'fuckAnal':
	if $ARGS[1] = 'Paid':
		money += 400
		if $region = 'city':
			gs 'fame', 'city', 'prostitute', 4
		elseif $region = 'pav':
			gs 'fame', 'pav', 'prostitute', 4
		end
	elseif $ARGS[1] = 'Free':
		gs 'fame', 'pav', 'sex', 4
	end
	if pcs_inhib < 60: inhib_exp += rand(14, 16)
	pcs_mood += 10
	gs 'stat'

	if rand(1, 100) < 50:
		'<center><img <<$set_imgh>> src="images/locations/shared/carwash/sex/fuckanal<<rand(1, 4)>>.jpg"></center>'
	else
		'<center><video autoplay loop src="images/locations/shared/carwash/sex/fuckanal<<rand(1, 4)>>.mp4"></video></center>'
	end

	gs 'arousal', 'auto_lube', 'anal'
	if $ARGS[1] = 'Paid':
		'You take the money before bending over and letting the man fuck your ass. His cock is still wet with your saliva as it slides inside you.'
		gs 'arousal', 'anal', 30, 'sub', 'prostitution', 'unknown'
	elseif $ARGS[1] = 'Free':
		'You bend over and let the man start fucking your ass. His cock is still wet with your saliva as it slides inside you.'
		gs 'arousal', 'anal', 30, 'dom', 'unknown'
	end
	gs 'stat'

	rapePussyChance = rand(1, 100)
	if rapePussyChance <= min(max(1, slut_compare), 20):
		act 'Continue': gt 'fuelstation_carwash', 'rapePussy'
	else
		act 'Continue': gt 'fuelstation_carwash', 'analEndQ'
	end
end

if $ARGS[0] = 'rapePussy':
	'<center><video autoplay loop src="images/locations/shared/carwash/sex/hardanal<<rand(1, 5)>>.mp4"></video></center>'

	'The man fucks your ass furiously, taking no heed of your painful moans. As you try to move away to limit the depth he can reach in your ass, he slaps your ass hard.'
	'"Stop moving, bitch! Who do you think you are that you can tell me what to do?!" he shouts.'

	if pcs_vag = 0:
		'He gropes your ass, lifts it up and suddenly spots your hymen.'
		'"Wait, you''re a virgin?! Such a tease and still a virgin!"'
		if rand(1, 100) <= min(max(1, slut_compare), 50):
			'"It would have happened sooner or later anyway, virgin slut. Now enjoy and remember this moment; I know I will!"'
			act 'Continue': gt 'fuelstation_carwash', 'rapePussyYes', 'virgin'
		else
			'"Girls like you should not be acting like this! Someone should have taught you a lesson a long time ago."'
			act 'Continue': gt 'fuelstation_carwash', 'punishSpank'
		end
	else
		act 'Continue': gt 'fuelstation_carwash', 'rapePussyYes', 'normal'
	end
end

! $ARGS[1] = whether you were a virgin before this or not
if $ARGS[0] = 'rapePussyYes':
	inhib_exp += rand(10, 20)

	'<center><video autoplay loop src="images/locations/shared/carwash/sex/pussytoanal<<rand(1, 3)>>.mp4"></video></center>'

	if $ARGS[1] = 'virgin':
		pcs_mood -= 30
		'He gropes your ass, lifts it up and pushes his dick inside your pussy in one thrust. You feel your hymen break and know your virginity is now gone forever.'
	elseif $ARGS[1] = 'normal':
		pcs_mood -= 20
		'He gropes your ass, lifts it up and pushes his dick inside your pussy in one thrust, all the way to the hilt.'
	end
	gs 'arousal', 'vaginal', 30, 'sub', 'prostitution', 'rough', 'rape', 'unknown'
	gs 'stat'

	act 'Continue': gt 'fuelstation_carwash', 'vaginaCum', 'rape'
end

if $ARGS[0] = 'pussyEndQ':
	'You can feel that the man is about to cum, so you decide to...'

	act 'Let him cum in your pussy': gt 'fuelstation_carwash', 'vaginaCum', 'consensual'
	act 'Let him cum on your face': gt 'fuelstation_carwash', 'blowjobEndFace', 'inside'
	act 'Let him cum in your mouth': gt 'fuelstation_carwash', 'blowjobEndMouth', 'inside'
end

if $ARGS[0] = 'analEndQ':
	'You can feel that the man is about to ejaculate, so you decide to...'

	act 'Let him cum in your ass': gt 'fuelstation_carwash', 'assCum'
	act 'Let him cum on your face': gt 'fuelstation_carwash', 'blowjobEndFace', 'inside'
	act 'Let him cum in your mouth': gt 'fuelstation_carwash', 'blowjobEndMouth', 'inside'
end

! $ARGS[1] = whether this was rape or not
if $ARGS[0] = 'vaginaCum':
	if pcs_inhib < 40: inhib_exp += rand(4, 6)
	pcs_vag += 1
	pain['vaginal'] += 4
	gs 'cum_call', ''
	gs 'stat'

	'<center><video autoplay loop src="images/locations/shared/carwash/sex/cumpussy<<rand(1, 5)>>.mp4"></video></center>'

	if $ARGS[1] = 'consensual':
		pcs_mood += 20
		'You let him cum in your pussy. A pleasant warmth fills your insides as he shoots his load deep inside you. When he pulls out, some of it leaks out of your hole.'
	elseif $ARGS[1] = 'rape':
		pcs_mood -= 20
		'The pounding suddenly stops as he cums inside you. You can feel his cum spurting into you and when he pulls out, some of it leaks out of your hole.'
	end

	gs 'arousal', 'end'
	gs 'stat'

	act 'Go back to the gas station': gt 'fuelstation', 'start'
end

if $ARGS[0] = 'assCum':
	if pcs_inhib < 40: inhib_exp += rand(4, 6)
	minut += 5
	pcs_mood += 10
	pcs_ass += 1
	pain['asshole'] += 1
	gs 'cum_call', 'anus'
	gs 'stat'

	'<center><video autoplay loop src="images/locations/shared/carwash/sex/cumanal<<rand(1, 2)>>.mp4"></video></center>'
	'You let him cum inside your ass. A pleasant warmth fills your insides as he shoots his load deep inside you. When he pulls out, some of it leaks out of you before you can tighten your worn out anus.'
	gs 'arousal', 'end'
	gs 'stat'

	act 'Go back to gas station': gt 'fuelstation', 'start'
end

if $ARGS[0] = 'handjobEndQ':
	'You can feel that the man is about to cum, so you decide to take it...'

	act 'On your face': gt 'fuelstation_carwash', 'blowjobEndFace', 'outside'
	act 'On your hands': gt 'fuelstation_carwash', 'handjobEndHands'
end

if $ARGS[0] = 'handjobEndHands':
	if pcs_inhib < 30: inhib_exp += rand(2, 4)
	pcs_mood += 5
	gs 'cum_call', 'hands'
	gs 'stat'

	if rand(1, 100) < 30:
		'<center><video autoplay loop src="images/shared/sex/cum/handjob/hand0,<<rand(0, 1)>>.mp4"></video></center>'
	else
		'<center><img <<$set_imgh>> src="images/shared/sex/cum/handjob/hand<<rand(1, 2)>>.jpg"></center>'
	end

	'When the man starts cumming, you quickly point his cock away from your face. Your hands are covered in cum by the time he''s done.'

	gs 'arousal', 'end'
	gs 'stat'

	act 'Go back to the gas station': gt 'fuelstation', 'start'
end

if $ARGS[0] = 'blowjobEndQ':
	'You can feel that the man is about to cum, so you decide to take it...'

	act 'On your face': gt 'fuelstation_carwash', 'blowjobEndFace', 'outside'
	act 'In your mouth': gt 'fuelstation_carwash', 'blowjobEndMouth', 'outside'
end

! $ARGS[1] = whether his cock was inside or outside of you before he cums on your face
if $ARGS[0] = 'blowjobEndFace':
	if pcs_inhib < 30: inhib_exp += rand(2, 4)
	pcs_mood += 5
	gs 'cum_call', 'face'
	gs 'stat'

	if rand(1, 100) < 30:
		'<center><video autoplay loop src="images/locations/shared/carwash/sex/cumface<<rand(1,2)>>.mp4"></video></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/shared/carwash/sex/cumface<<rand(1,4)>>.jpg"></center>'
	end

	if $ARGS[1] = 'outside':
		'When the man starts cumming, you quickly point his cock towards your face. Your face is covered in cum by the time he''s done.'
	elseif $ARGS[1] = 'inside':
		'When the man starts cumming, you quickly take his cock out of your mouth and point it towards your face. Your face is covered in cum by the time he''s done.'
	end

	gs 'arousal', 'end'
	gs 'stat'

	act 'Go back to the gas station': gt 'fuelstation', 'start'
end

! $ARGS[1] = whether his cock was inside or outside of you before he cums in your mouth
if $ARGS[0] = 'blowjobEndMouth':
	gs 'cum_call', 'mouth', $boy
	gs 'stat'

	if rand(1, 100) < 60:
		'<center><img <<$set_imgh>> src="images/locations/shared/carwash/sex/cummouth<<rand(1, 4)>>.jpg"></center>'
	else
		'<center><video autoplay loop src="images/locations/shared/carwash/sex/cummouth1.mp4"></video></center>'
	end

	if $ARGS[1] = 'outside':
		'When the man starts cumming, you quickly open your mouth while keeping his cock aimed at your tongue, giving him a good view of the cum as it flies inside your mouth.'
	elseif $ARGS[1] = 'inside':
		'When the man starts cumming, you quickly take his cock out of your mouth and aim it at your tongue, giving him a good view of the cum as it flies inside your mouth.'
	end

	*nl
	'Your mouth is full of cum. You decide to...'
	gs 'arousal', 'end'
	gs 'stat'
	act 'Swallow it': gt 'fuelstation_carwash', 'blowjobEndMouthSwallow'
	act 'Spit it out': gt 'fuelstation_carwash', 'blowjobEndMouthSpit'
end

if $ARGS[0] = 'blowjobEndMouthSwallow':
	if pcs_inhib < 40: inhib_exp += rand(4, 6)
	swallow += 1
	pcs_mood += 10
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/shared/carwash/sex/swallow<<rand(1, 4)>>.jpg"></center>'
	'You gulp down the mouthful of cum and present your tongue to him.'
	'The man smiles and slaps you mildly on the face. "What a nice young slut you are. Next time I need a refill, I''ll be sure to stop by."'
	stat['swallow'] += 1
	gs 'arousal', 'end'
	gs 'stat'

	act 'Go back to the gas station': gt 'fuelstation', 'start'
end

if $ARGS[0] = 'blowjobEndMouthSpit':
	if pcs_inhib < 30: inhib_exp += rand(2, 4)
	gs 'stat'

	if rand(1, 100) > 50:
		'<center><img <<$set_imgh>> src="images/locations/shared/carwash/sex/spit<<rand(1, 3)>>.jpg"></center>'
	else
		'<center><video autoplay loop src="images/locations/shared/carwash/sex/spit1.mp4"></video></center>'
	end

	'You spit the cum out between the legs of your customer.'
	'His face darkens. "What, my cum isn''t good enough for you to swallow? I''ll teach you, bitch!"'
	'He moves closer to you with an angry scowl on his face...'

	act 'Run back to the gas station': gt 'fuelstation_carwash', 'runback'
end

if $ARGS[0] = 'runback':
	! runSuccess uses a simpler version of the formula used with carwashscene
	! just based on strength and agility; uses whichever is higher to try and run away
	! min 25 percent chance; max 75 percent chance for this initial getaway
	if rand(1, 100) <= min(max(25, pcs_stren, pcs_agil), 75):
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/turn_back.jpg"></center>'
		'You manage to escape his grasp and take a quick look behind you to make sure he''s not following you before heading back to the gas station.'
		gs 'arousal', 'end'
		gs 'stat'
		act 'Escape': gt 'fuelstation', 'start'
	else
		pain['cheeks'] += 2
		pain['head'] += 2
		pain['mouth'] += 2
		pain['neck'] += 4

		'<center><video autoplay loop src="images/locations/shared/carwash/sex/punishbeatface.mp4"></video></center>'
		'You aren''t quick enough and he catches you. He pushes you down and starts to slap across the face.'
		gs 'arousal', 'end'
		gs 'stat'

		act 'Endure his punishment': gt 'fuelstation_carwash', 'punish'
		! gave doms the choice to fight back as long as they have some energy related stat with something left even if they lost the roll for runSuccess
		! these values are based off of the cheat menu values for players who turn off these stats as they can never go below 35
		gs 'willpower', 'skill', 'resist', 'stren_lvl'
		will_cost = (will_cost * 3) / 2
		if pcs_willpwr < will_cost:
			act 'Push him off and escape (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		else
			act 'Push him off and escape (<<will_cost>> Willpower)':
				gs 'willpower', 'pay', 'resist'
				gt 'fuelstation_carwash', 'fight'
			end
		end
	end
end

if $ARGS[0] = 'fight':
	! maybe at some point this could be an actual fight but with the state of the combat logic is in this will just be left to drain a stat to escape
	! these values are based off of the cheat menu values for players who turn off these stats as they can never go below 35
	pcs_energy = max(0, pcs_energy - 35)
	pcs_hydra = max(0, pcs_hydra - 35)

	gs 'arousal', 'end'
	gs 'stat'

	gt 'fuelstation', 'start'
end

if $ARGS[0] = 'punish':
	! once again punishType uses the same logic as carwashscene for dynamic choices
	punishType = rand(1, 100)
	if punishType <= min(max(50,slut_compare),75) and punishType >= 50:
		gt 'fuelstation_carwash', 'punishAnal'
	elseif punishType <= min(max(75,slut_compare),100) and punishType >= 75:
		gt 'fuelstation_carwash', 'punishPussyQ'
	else
		gt 'fuelstation_carwash', 'punishSpank'
	end
end

if $ARGS[0] = 'punishSpank':
	pcs_horny = 0
	pcs_mood -= 10
	inhib_exp += rand(2, 4)
	pain['asscheeks'] += 5
	gs 'stat'

	'<center><video autoplay loop src="images/locations/shared/carwash/sex/punishspank.mp4"></video></center>'
	'The angry man drags you to a more secluded area, bends you over and starts to spank your ass very hard.'
	'After twenty minutes of ruthless punishment, he finally stops and you crawl away with your ass burning.'
	gs 'arousal', 'foreplay', 15, 'sub', 'rough', 'unknown'
	gs 'arousal', 'end'
	gs 'stat'
	gs 'fuelstation_carwash', 'punishEnd'
end

if $ARGS[0] = 'punishAnal':
	pcs_horny = 0
	pcs_mood -= 20
	pain['asshole'] += 6
	inhib_exp += rand(5, 10)
	gs 'cum_call', 'anus'
	gs 'stat'

	'<center><video autoplay loop src="images/locations/shared/carwash/sex/punishanal<<rand(1, 3)>>.mp4"></video></center>'
	'The angry man drags you to a more secluded area, bends you over and sticks a finger in your ass.'
	'Your anus fully exposed, he starts fucking it ruthlessly.'
	'After half an hour of rough assfucking, he releases his grip on you so you can finally crawl away, your aching ass sore from the brutal penetration.'
	gs 'arousal', 'anal', 30, 'sub', 'rough', 'rape', 'unknown'
	gs 'arousal', 'end'
	gs 'stat'
	gs 'fuelstation_carwash', 'punishEnd'
end

if $ARGS[0] = 'punishPussyQ':
	'The angry man drags you to a more secluded area where he bends you over and starts rubbing your pussy.'

	if pcs_vag = 0:
		'"Wait, you''re a virgin?! Such a slutty tease and you''re still a virgin?"'

		penetrate = rand (1, 100)
		if penetrate <= min(max(50,slut_compare),75) and penetrate >= 50:
			'"I''ll spare your virginity, but you''re still getting fucked. Sluts have more than one hole for a reason, right?"'

			act 'Endure it': gt 'fuelstation_carwash', 'punishAnal'
		elseif penetrate <= min(max(75,slut_compare),100) and penetrate >= 75:
			'"This makes it even better! I haven''t had a virgin in forever! I''m going to enjoy your tears, slut."'

			act 'Endure it': gt 'fuelstation_carwash', 'punishPussy', 'virgin'
		else
			'"Someone should have done this a long time ago, but I''ll spare you penetration this time!"'

			act 'Endure it': gt 'fuelstation_carwash', 'punishSpank'
		end
	else
		'"Let''s try what you''ve been teasing, you ungrateful whore!"'
		act 'Endure it': gt 'fuelstation_carwash', 'punishPussy', 'normal'
	end
end

! $ARGS[1] = whether you were a virgin before this or not
if $ARGS[0] = 'punishPussy':
	pcs_horny = 0
	pain['vaginal'] += 4
	inhib_exp += rand(5, 10)
	gs 'cum_call', ''
	gs 'stat'

	'<center><video autoplay loop src="images/locations/shared/carwash/sex/punishpussy<<rand(1, 5)>>.mp4"></video></center>'

	if $ARGS[1] = 'virgin':
		'Your pussy fully exposed, he slowly inserts his cock inside you. He pushes right up against your hymen, savoring the moment. Suddenly, you feel your hymen break and know your virginity is now gone forever.'
		pcs_mood -= 40
	elseif $ARGS[1] = 'normal':
		'Your pussy fully exposed, he starts ruthlessly fucking it.'
		pcs_mood -= 20
	end
	'After half an hour, he releases his grip on you so you can finally crawl away, your aching pussy sore from the brutal penetration.'

	gs 'arousal', 'vaginal', 30, 'sub', 'rough', 'rape', 'unknown'
	gs 'arousal', 'end'
	gs 'stat'
	gs 'fuelstation_carwash', 'punishEnd'
end

!! SM it was too hard to get abducted so remove old check against strength/agility, now only checks against slut reputation
!! minimum chance of 1% maximum chance of 90% to be abducted
if $ARGS[0] = 'punishEnd':
	if rand(1, 100) <= min(max(1, slut_compare), 180):
		'Your perpetrator isn''t done with you, however.'
		'He catches you again, drags you to his car and pushes you into the trunk...'
		'You have a feeling this won''t go well for you...'
		act 'Cry for help': gt 'abduction', 'start'
	else
		'Your perpetrator stands up and just watches as you crawl away in pain.'
		'He turns around and calmly walks away, leaving you alone.'
		act 'Escape': gt 'fuelstation', 'start'
	end
end







!! cleanup
killvar 'carwashscene'
killvar 'punishType'
killvar 'penetrate'



--- fuelstation_carwash ---------------------------------