glife/locations/gad_field.qsrc

# gad_field
!2021/05/05
!2024/05/05 - Mira schedule introduced.
!locat['A60'] = Mira''s location. See 'miroslava_schedule'

if $ARGS[0] = 'field':
	gs 'shortgs', 'setloc', 'gad_field', 'field'
	$location_type = 'secluded'
	menu_off = 0
	gs 'miroslava_schedule'
	gs 'gadukino_event', 'sound'
	gs'stat'

	'<center><H4>Field</H4></center>'
	if month >= 4 and month <= 10:
		if hour >= 6 and hour < 22:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadfield.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadfield_night.jpg"></center>'
		end
		if hour >= 9 and hour <= 17 and npc_qw['A221'] = 0: gs 'grigory', 'meet' & exit
	else
		if hour >= 8 and hour < 18:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadfield_winter.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadfield_winter_night.jpg"></center>'
		end
	end

	'A field outside the village.'

	if grigory_flower > 0 and grigory_flower < 10: gt 'grigory', 'flower5'
	if flowerday ! daystart and grigory_flower = 10: gt 'grigory', 'flower6'
	if flowerday ! daystart and grigory_flower > 10: gt 'grigory', 'flower8'
	if hour >= 9 and hour <= 19 and week < 6:'Grandfather''s horse <a href="exec: gt ''gad_field'',''horse''">Desperado</a> is grazing the field.'
	if hour >= 9 and hour <= 19 and grandpaQW['chore_herd_cattle'] = 0:'You notice a large <a href="exec: gt ''gad_field'',''cow''">herd of cows</a> in the middle of the field.'
	if hour >= 6 and hour <= 20 and grandpaQW['chore_herd_cattle'] = 1:'You see the <a href="exec: gt ''gad_field'',''cow''">herd of cows</a> out in the middle of the field.'
	if hour >= 7 and hour <= 20 and grandpaQW['chore_bale_hay'] = 1:'You see a crowd of people working on the field.'

	act 'Head back to the road (0:10)':minut += 10 & gt 'gad_road', 'start'

	if hour >= 7 and hour <= 13 and grandpaQW['chore_bale_hay'] = 1:
		act 'Spend the day helping to bale hay (6:00)':
			gs 'food', 'm_meal'
			*clr & cla
			menu_off = 1

			if npc_rel['A60'] >= 15 and npc_known['A60'] = 1:
				npc_rel['A60'] += 1
				'<center><img <<$set_imgh>> src="images/characters/gadukino/mira/haying_time_mira.jpg"></center>'
				'Most of the village has shown up to help out with the hay. Mira is there too, and you both partake in the activities. You enjoy yourself, and working alongside Mira makes the day fly by. By the end of the day, you are both exhausted but smiling.'
			else
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/haying_time.jpg"></center>'
				'Almost all the villagers have shown up to help with the fresh-cut hay. You spend most of the day working hard and sweating as you help gather the fresh-cut hay. It is difficult, but you get a great workout and end the day feeling exhausted but immensely satisfied.'
			end

			gs 'exercise', 'tier1', 60, 'stren', 'vital'
			minut += 300
			if sunWeather = 1:pcs_tan += 1
			grandpaQW['chore_bale_hay'] = 2
			gs 'exp_gain', 'hndiwrk', rand(0,8)
			gs 'stat'

			act 'Continue': gt 'gad_field', 'field'
			act 'Return back to your grandfather (0:30)': minut += 30 & gt 'gad_gphouse', 'grandpa'
		end
	end

end

if $ARGS[0] = 'horse':
	gs 'shortgs', 'setloc', 'gad_field', 'horse'
	$location_type = 'public_outdoors'
	menu_off = 0

	gs 'gadukino_event', 'sound'
	gs'stat'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/village/horse.jpg"></center>'
	'Your grandfather''s horse, Desperado.'

	act 'Go back to the field': gt 'gad_field', 'field'

	if hour = 19:
		act 'Lead the horse home (1:00)':
			*clr & cla
			menu_off = 1
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/horse_field.jpg"></center>'
			'You spot your grandfather''s horse wandering loose in the field and decide to help by taking Desperado home. Reaching for the harness, you start leading Desperado towards the village.'
			minut += 60
			grandmaQW['help_amount'] += rand(0,1)
			gs 'exp_gain', 'hndiwrk', rand(0,3)
			gs 'stat'

			act 'Continue': gt 'gad_gpbarn', ''
		end
	end
end

if $ARGS[0] = 'cow':
	gs 'shortgs', 'setloc', 'gad_field', 'cow'
	$location_type = 'secluded'
	menu_off = 0
	gs 'miroslava_schedule'
	gs 'gadukino_event', 'sound'
	gs'stat'
	temp = rand(1,5)

	'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cow.jpg"></center>'
	'The cattle herd is standing in the middle of the field. Some cows are munching on grass, and others just stare idly around.'
	if locat['A60'] = 70: '<a href="exec: gt ''miroslava'', ''start''">Mira</a> is standing next to you.'

	if grandpaQW['chore_herd_cattle'] = 0: act 'Leave them be': gt 'gad_field', 'field'
	if hour = 19 and grandpaQW['chore_herd_cattle'] = 0:
		act 'Lead the cows home (1:00)':
			*clr & cla
			menu_off = 1
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cow_field.jpg"></center>'
			'Seeing the cow herd on the field, you decide to help your grandfather bring the cows home...'
			minut += 60
			grandmaQW['help_amount'] += 1
			gs 'exp_gain', 'hndiwrk', rand(0, 3)
			gs 'stat'

			act 'Continue': gt 'gadukino'
		end
	end
	if grandpaQW['chore_herd_cattle'] = 1:
		if hour < 10:
			act 'Wait until the herd is gathered':
				*clr & cla
				menu_off = 1
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/graze_cow_wait.jpg"></center>'
				if grandpaQW['chore_herd_cattle_experience'] = 0: 'Some time flies by while waiting for the locals to finish bringing their cows to the field.'
				if grandpaQW['chore_herd_cattle_experience'] = 1: 'Some time flies by while waiting for the locals and their children to finish bringing their cows to the field.'

				if hour >= 9:minut += 20
				if hour < 9:minut += 60
				gs 'exp_gain', 'hndiwrk', rand(0, 4)
				gs 'stat'

				act 'Continue': gt 'gad_field', 'cow'
			end
		end
		if hour >= 10 and hour < 13:
			act 'Herd cows with your grandfather (1:00)':
				*clr & cla
				menu_off = 1
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/graze_cow'+rand(1,4)+'.jpg"></center>'
				'You spend an hour herding the cows, watching for stragglers and driving them back to the herd. Then, instead of letting your grandfather do all the work, you roll up your sleeves and try to do most of the work yourself.'

				minut += 60
				if temper >= 25 and sunWeather = 1:
					pcs_hydra -= 12
					pcs_stam -= 8
					gs 'sweat', 'add', 10
				else
					pcs_hydra -= 6
					gs 'sweat', 'add', 5
					pcs_stam -= 5
				end
				grandpaQW['chore_herd_cattle_experience'] = 1
				grandmaQW['help_amount'] += rand(0, 1) / 3
				gs 'exp_gain', 'hndiwrk', rand(0, 3)
				gs 'stat'

				act 'Continue': gt 'gad_field', 'cow'
			end

			gs 'gad_field', 'set_nomira_acts', 1
		end
		if hour >= 13 and hour < 16:
			*clr & cla
			menu_off = 1
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cow_go.jpg"></center>'
			'Looking at his watch, Grandpa turns to you and says, "It''s about lunchtime, which means it''s time to take the herd to the watering hole." So you begin to gather the cows and lead them to the river.'

			if temper >= 25 and sunWeather = 1:
				pcs_hydra -= 12
				pcs_stam -= 8
				gs 'sweat', 'add', 10
			else
				pcs_hydra -= 6
				gs 'sweat', 'add', 5
				pcs_stam -= 5
			end
			grandmaQW['help_amount'] += 1
			minut += 60
			gs 'exp_gain', 'hndiwrk', rand(0, 3)
			gs 'stat'

			act 'Herd the cows nearer to the river (0:15)': minut += 15 & gt 'gad_field', 'cow2'
		end
	end
end


if grandpaQW['chore_herd_cattle'] = 1 and locat['A60'] = 70 and locat['A60_prev'] ! 70:
	*clr & cla
	menu_off = 1
	'<center><img <<$set_imgh>> src="images/characters/gadukino/mira/mira2.jpg"></center>'
	'While keeping an eye on the cow herd, you see Mira in the distance, approaching. You happily wave to her.'
	'"Hi, <<$pcs_nickname>>. I wanted to visit you, and I''ve brought some water with me," she says, nearing you. "Have you missed me?"'
	minut += 5
	npc_rel['A60'] += 1
	gs 'stat'

	MiraVars['follow_time'] = 20 - hour
	act 'Continue':
		pcs_hydra += 40
		if hour < 13:
			gt 'gad_field', 'cow'
		elseif hour < 16:
			gt 'gad_field', 'cow2'
		else
			gt 'gad_field', 'cow3'
		end
	end
end

if $ARGS[0] = 'cow2':
	gs 'shortgs', 'setloc', 'gad_field', 'cow2'
	$location_type = 'secluded'
	menu_off = 0
	gs 'miroslava_schedule'
	gs 'gadukino_event', 'sound'
	gs'stat'

	'<center><H4>River</H4></center>'
	'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cow_river.jpg"></center>'

	'The cattle herd is near the river. Some cows are munching on grass, some drink from the river, and some just stand or lie around.'

	if locat['A60'] = 70: '<a href="exec: gt ''miroslava'', ''start''">Mira</a> is sitting next to you.'
	if temper >= 15 and sunWeather = 1:'"You can go for a swim if you want, <<$pcs_nickname>>. I''ll keep an eye on the herd," says your grandfather.'

	if grandpaQW['chore_herd_cattle'] = 1:
		if hour < 16:
			act 'Herd cows with your grandfather (1:00)':
				*clr & cla
				menu_off = 1
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/graze_cow'+rand(1,4)+'.jpg"></center>'
				'You spend an hour herding the cows, watching for stragglers and driving them back to the herd. Then, instead of letting your grandfather do all the work, you roll up your sleeves and try to do most of the work yourself.'

				minut += 60
				if temper >= 25 and sunWeather = 1:
					pcs_hydra -= 12
					pcs_stam -= 8
					gs 'sweat', 'add', 10
				else
					pcs_hydra -= 6
					gs 'sweat', 'add', 5
					pcs_stam -= 5
				end
				grandpaQW['chore_herd_cattle_experience'] = 1
				if rand(0,1) = 1:grandmaQW['help_amount'] += rand(0,1)
				gs 'exp_gain', 'hndiwrk', rand(0,3)
				gs 'stat'

				act 'Continue': gt 'gad_field', 'cow2'
			end
			gs 'gad_field', 'set_nomira_acts', 2
		end
		if hour >= 16 and hour < 19:
			*clr & cla
			menu_off = 1
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cow_go.jpg"></center>'
			'Grandpa looks at his watch and says it''s time to drive the herd near the forest. So the two of you begin to gather the herd and guide them toward the woods.'

			minut += 60
			if temper >= 25 and sunWeather = 1:
				pcs_hydra -= 12
				pcs_stam -= 8
				gs 'sweat', 'add', 10
			else
				pcs_hydra -= 6
				gs 'sweat', 'add', 5
				pcs_stam -= 5
			end
			grandmaQW['help_amount'] += rand(0, 3) / 3
			gs 'exp_gain', 'hndiwrk', rand(0, 3)
			gs 'stat'

			act 'Herd the cows nearer to the forest (0:30)': minut += 15 & gt 'gad_field', 'cow3'
		end
	end
end

if $ARGS[0] = 'cow3':
	gs 'shortgs', 'setloc', 'gad_field', 'cow3'
	$location_type = 'secluded'
	menu_off = 0
	gs 'miroslava_schedule'
	gs 'gadukino_event', 'sound'
	gs'stat'

	'<center><H4>Field near the forest</H4></center>'
	'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cow_forest.jpg"></center>'

	'The cattle herd is grazing in a field near the forest.'

	if locat['A60'] = 70: '<a href="exec: gt ''miroslava'', ''start''">Mira</a> is sitting next to you.'

	if grandpaQW['chore_herd_cattle'] = 1:
		if hour < 19:
			act 'Herd cows with your grandfather (1:00)':
				*clr & cla
				menu_off = 1
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/graze_cow'+rand(1,4)+'.jpg"></center>'
				'You spend an hour herding the cows, watching for stragglers and driving them back to the herd. Then, instead of letting your grandfather do all the work, you roll up your sleeves and try to do most of the work yourself.'

				minut += 60
				if temper >= 25 and sunWeather = 1:
					pcs_hydra -= 12
					pcs_stam -= 8
					gs 'sweat', 'add', 10
				else
					pcs_hydra -= 6
					gs 'sweat', 'add', 5
					pcs_stam -= 5
				end
				grandpaQW['chore_herd_cattle_experience'] = 1
				if rand(0,1) = 1:grandmaQW['help_amount'] += rand(0,1)
				gs 'exp_gain', 'hndiwrk', rand(0,3)
				gs 'stat'

				act 'Continue': gt 'gad_field', 'cow3'
			end

			gs 'gad_field', 'set_nomira_acts', 1
		end
		if hour >= 19:
			*clr & cla
			menu_off = 1

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/cow_go_home.jpg"></center>'
			'As sunset approaches, Grandpa says that it is late and time to drive the herd home. So you hurry, gather the cows, and guide them back towards the village.'

			if temper >= 25 and sunWeather = 1:
				pcs_hydra -= 12
				pcs_stam -= 8
				gs 'sweat', 'add', 10
			else
				pcs_hydra -= 6
				gs 'sweat', 'add', 5
				pcs_stam -= 5
			end
			minut += 60
			grandpaQW['chore_herd_cattle'] = 0
			grandmaQW['help_amount'] += 2
			gs 'exp_gain', 'hndiwrk', rand(0,3)
			gs 'stat'

			MiraVars['follower'] = 0
			MiraVars['follow_time'] = 0
			act 'Back to the village': gt 'gadukino'
		end
	end
end




if $ARGS[0] = 'set_nomira_acts':
	if locat['A60'] ! 70:
		if ARGS[1] = 1:
			act 'Go for a run in the field (1:00)':
				*clr & cla
				menu_off = 1
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/graze_cow_run.jpg"></center>'
				'Since the cows are all behaving, you spend some time jogging around the field.'

				frost = 0
				minut += 60
				fat -= 5
				gs 'exp_gain', 'run', 1
				gs 'sweat', 'add', 10
				pcs_mood += 5
				pcs_stam -= 8
				if temper >= 25 and sunWeather = 1:
					pcs_hydra -= 24
					gs 'sweat', 'add', 12
				else
					pcs_hydra -= 18
					gs 'sweat', 'add', 10
				end
				gs 'stat'

				act 'Continue': gt $loc, $loc_arg
			end
			if temper >= 15 and sunWeather = 1:
				if pcs_sleep < 40:
					act 'Take a nap (1:00)':
						*clr & cla
						menu_off = 1
						'<center><img <<$set_imgh>> src="images/locations/gadukino/village/graze_cow_lying.jpg"></center>'
						'You feel drowsy watching the cows stand around, so you lie down on the grass. You doze off and wake up about an hour later.'

						if temper >= 25: pcs_hydra -= 12
						gs 'sleep_simple', 'nap', 1

						act 'Continue': gt $loc, $loc_arg
					end
				end
				act 'Pick flowers (1:00)':
					*clr & cla
					menu_off = 1
					'<center><img <<$set_imgh>> src="images/locations/gadukino/village/graze_cow_flowers.jpg"></center>'
					'Keeping one eye on the cattle, you spend an hour wandering the field, picking flowers.'
					minut += 60
					pcs_mood += 20
					pcs_stam -= 4
					if temper >= 25:
						pcs_hydra -= 8
						gs 'sweat', 'add', 5
					else
						pcs_hydra -= 5
						gs 'sweat', 'add', 3
					end
					gs 'stat'

					act 'Continue': gt $loc, $loc_arg
				end
			end
		elseif ARGS[1] = 2:
			if temper >= 15 and sunWeather = 1:
				if pcs_stam >= (5 * (10 - sport_clothes_exercise_bonus)) / 2:
					act 'Swim (0:15)':
						*clr & cla
						menu_off = 1
						'<center><img <<$set_imgh>> src="images/locations/gadukino/village/graze_cow_river.jpg"></center>'
						'You spend a few minutes splashing around in the river, which feels cool and refreshing.'
						if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the water.'
						cumspclnt = 4 & gs 'cum_cleanup'
						pcs_stam -= 3
						pcs_mood += 5
						if willday_swim ! daystart: willday_swim = daystart & pcs_willpwr += 1
						gs 'exercise', 'tier1', 15, 'stren'
						gs 'stat'

						act 'Continue': gt 'gad_field', 'cow2'
					end
				end
			end
		end

		act 'Tan (0:30)':
			*clr & cla
			menu_off = 1
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/graze_cow_sun.jpg"></center>'
			'You lie down to sunbathe by the river while Grandpa looks after the herd.'
			minut += 30
			gs 'sweat', 'add', 10
			pcs_mood += 5
			pcs_tan += 1
			gs 'stat'

			act 'Continue': gt $loc, $loc_arg
		end

		act 'Read a book (1:00)':
			*clr & cla
			menu_off = 1
			gs 'library_functions', 'read_book'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/graze_cow_book'+rand(1,2)+'.jpg"></center>'
			if temper >= 25: pcs_hydra -= 12
			if pcs_nerd > 0:
				pcs_mood = 100
				if pcs_stren > 1: stren_deg -= 1
				if pcs_vital > 5: vital_deg -= 1
				'You start reading a book you brought with you. You are so engrossed in the story you forget about the time.'
			else
				pcs_mood += 10
				'While reading the book, time flies by because you are really engaged in the plot.'
			end
			gs 'stat'

			act 'Close the book': gt $loc, $loc_arg
		end
	end
end




--- gad_field ---------------------------------