glife/locations/gad_gpbarn.qsrc

# gad_gpbarn
!2021/05/08

$default_img_path = 'locations/gadukino/'
if $ARGS[0] = '':
	gs 'shortgs', 'setloc', 'gad_gpbarn', ''
	menu_off = 0
	$location_type = 'secluded'
	gs 'miroslava_schedule'

	'<center><h4>Grandparents'' Barn</h4></center>'
	if month >= 4 and month <= 10:
		if hour >= 6 and hour < 22:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/sarai.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/sarai_night.jpg"></center>'
		end
	else
		if hour >= 8 and hour < 18:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/sarai_winter.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/sarai_winter_night.jpg"></center>'
		end
	end
	'Your grandparents'' old barn could hold some valuable items if you spend time searching.'
	'To the left is the new staircase built to convert some of the loft space into a bedroom to afford guests privacy.'
	'The right side of the barn is piled high with various boxes, barrels, and chests of items.'
	'You can store some extra mushrooms and berries here if you don''t want to carry them around all the time.'
	'The left side of the barn has stalls for your grandparents'' horse, cow, and boar.'

	clr
	gs 'stat'

	act 'Go back to the yard': minut += 1 & gt 'gad_gpyard', 'start'
	act 'Go to your room': gt 'gad_gpbarn', 'barn_room'
	if grandpaQW['chore_fetch_firewood'] = 1:
		act 'Gather firewood for Grandpa (0:10)':
			*clr & cla
			if month >= 4 and month <= 10:
				'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/firewood.jpg"></center>'
			else
				'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/firewood_winter.jpg"></center>'
			end
			'You decide to grab the firewood that your grandfather asked for, loading up as much as you can carry.'
			grandpaQW['chore_fetch_firewood'] = 2
			minut += 10
			gs'stat'

			act 'Finish': gt 'gad_gpbarn'
			act 'Return back to your grandfather': minut += 2 & gt 'gad_gphouse', 'grandpa'
		end
	end
	gs 'bicycle', 'gad_gpbarn'
	if (month < 4 or month > 10) or (hour < 9 or hour > 20) or (grandpaQW['chore_feed_horse'] = 1 or grandpaQW['chore_brush_horse'] = 1 or grandpaQW['chore_lead_horse_to_field'] = 1 or grandpaQW['chore_bathe_horse'] = 1):
		act 'Enter the horses stall': gt 'gad_gpbarn', 'horse'
	end
	if (month < 4 or month > 10) or (hour < 9 or hour > 20) or (grandpaQW['chore_feed_cow'] = 1 or grandmaQW['chore_milk_cow'] or grandpaQW['chore_lead_cow_to_field'] = 1 or grandpaQW['chore_herd_cattle'] = 1):
		act 'Enter the cows stall': gt 'gad_gpbarn', 'cow'
	end
	act 'Enter the boars stall': gt 'gad_gpbarn', 'boar'
	act 'Search around in the barn (0:15)': gt 'gad_gpbarn', 'search'
	if mc_inventory['vintage_card'] > 0: act 'View your vintage porn cards': $card_loc = 'gad_gpbarn' & card_deck = 0 & gt 'card'
	if mc_inventory['card'] > 0: act 'View your new porn cards': $card_loc = 'gad_gpbarn' & card_deck = 1 & gt 'card'
	if pcs_horny >= 50:	act 'Masturbate':gt 'selfplay', 'start'
!!	Serpent is not ready yet, so remarking out til then.
!!	if findneck = 1: act 'You hear a scraping noice above you.':gt 'serpent'
end

if $ARGS[0] = 'search':
	if npc_qw['A221'] > 0 and grigory_barn ! daystart and hour > 8 and hour < 12: gt 'grigory', 'barn'
	*clr & cla
	minut += 15
	gs 'stat'
	if BikeLoc = 0 and rand(0,10) >= 6:
		*clr & cla
		BikeLoc = 1
		gs 'exp_gain', 'observ', 3
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/findbike.jpg"></center>'
		*nl
		'You find an old bicycle in the far corner of the barn. It''s in surprisingly good condition. You pull it out of the barn and clean it up.'
	elseif findbag = 0 and bag = 0 and rand(0,10) >= 7:
		*clr & cla
		findbag = 1
		if findbag = 1: bag = 1
		gs 'exp_gain', 'observ', 3
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/pc/items/gm/purses/5.jpg"></center>'
		*nl
		'In a far corner of the barn, you find a hessian sack filled with mostly junk, but at the bottom, you find a good-quality messenger bag.'
		'You can use this cool-looking bag as a handbag.'
		gm_purses[5] = 1
		$currentpursetype = 'gm'
		currentpursenumber = 5
	elseif mc_inventory['vintage_card'] = 0 and vcard_trash = 0 and rand(0,10) >= 8:
		*clr & cla
		mc_inventory['vintage_card'] = 1
		gs 'exp_gain', 'observ', 3
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/vcards.jpg"></center>'
		*nl
		'"Hmm, what''s this?" You''ve found an unopened deck of vintage adult playing cards still in its original cellophane wrapper.'
	elseif findbraclet = 0 and rand(0,10) >= 9:
		*clr & cla
		findbraclet = 1
		gs 'exp_gain', 'observ', 3
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/bracelet.jpg"></center>'
		*nl
		'While looking through the barn, you spot a metal glint under a wood pile. Upon closer inspection, you see a silver bracelet crafted into a snake''s likeness. Strange, but fantastic that you would find something this valuable in the barn.'
	elseif findbraclet > 0 and findneck = 0 and rand(0,10) >= 10:
		*clr & cla
		findneck = 1
		gs 'exp_gain', 'observ', 3
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/necklace.jpg"></center>'
		*nl
		if $start_type[1] ! 'nomagic':
			'While looking through the barn, your foot goes through a rotten floorboard. You suddenly feel the presence of something magical under the floor. You get on your belly and look through the hole in the floor. You find a small box made of black wood. You pick up the box and see it''s covered in strange writing and glyphs that look like serpents. A feeling of power is coming from within the box. You lift the box''s lid and see a black metal necklace that looks like a coiled snake with ruby eyes. You feel the power coming from the necklace, but it doesn''t feel like any power you have ever felt.'
		else
			'While looking through the barn, your foot goes through a rotten floorboard and gets stuck. As you work your foot free, you glimpse something underneath the floor - a box or something. You get on your belly and look through the hole in the floor. You find a small box made of black wood. You pick up the box and see it''s covered in strange writing and glyphs that look like serpents. The exotic look of the box gives you gooseflesh, and you find yourself holding your breath as you prepare to open the box. You lift the box''s lid and see a black metal necklace that looks like a coiled snake with ruby eyes. You inspect the necklace, watching the light sparkle as it is reflected by the facets on the deep red rubies. You cannot begin to guess what this necklace must be worth.'
		end
	else
		gs 'exp_gain', 'observ', rand(0,1)
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/junk_barn.jpg"></center>'
		*nl
		'In the barn, you find many mouldy magazines, rusty tools and equipment, toys, and dusty, yellowed books. The entire barn reeks of mould and decay.'
	end
	act 'Finish': gt 'gad_gpbarn'
end

if $ARGS[0] = 'horse':
	*clr & cla
	minut += 1
	gs 'stat'

	'<center><h4>Grandparents'' Barn</h4></center>'
	'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/horse.jpg"></center>'
	'Grandfather''s trusted workhorse, Desperado.'

	act 'Leave': minut += 1 & gt 'gad_gpbarn'

	if grandpaQW['chore_feed_horse'] = 1:
		act 'Feed the horse (0:30)':
			*clr & cla
			minut += 30
			grandpaQW['chore_feed_horse'] = 2
			gs 'exp_gain', 'hndiwrk', rand(1,3)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/feed_horse.jpg"></center>'
			'You grab a sack of grain and fill Desperado''s feed bucket. Then, you hang the bucket from his stall and gently pat his nose as he begins to eat.'
			'You watch him eat for a little while before moving on.'

			act 'Finish': gt 'gad_gpbarn','horse'
			act 'Return back to your grandfather': minut += 3 & gt 'gad_gphouse', 'grandpa'
		end
	end
	if grandpaQW['chore_lead_horse_to_field'] = 1:
		act 'Lead the horse to the field (1:00)':
			*clr & cla
			minut += 60
			grandpaQW['chore_lead_horse_to_field'] = 2
			gs 'exp_gain', 'hndiwrk', rand(1,3)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/horse_field.jpg"></center>'
			'You take Desperado by the bridle and lead him to the field. You let him free in the paddock area and watch him run about before moving on.'

			act 'Continue': gt 'gad_field', 'field'
			act 'Return back to your grandfather (0:30)': minut += 30 & gt 'gad_gphouse', 'grandpa'
		end
	end
	if grandpaQW['chore_bathe_horse'] = 1:
		act 'Lead the horse to the river (0:30)':
			*clr & cla
			minut += 30
			grandpaQW['chore_bathe_horse_prog'] = 1
			gs 'exp_gain', 'hndiwrk', rand(1,3)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/horse_field.jpg"></center>'
			'You take Desperado by the bridle and lead him to the river.'

			act 'Continue': gt 'gad_beach', 'start'
		end
	end
	if grandpaQW['chore_bathe_horse'] = 2:
		act 'Return back to your grandfather': minut += 3 & gt 'gad_gphouse', 'grandpa'
	end
	if grandpaQW['chore_brush_horse'] = 1:
		act 'Groom the horse (1:00)':
			*clr & cla
			minut += 60
			grandpaQW['chore_brush_horse'] = 2
			gs 'exp_gain', 'hndiwrk', rand(1,3)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/comb_horse.jpg"></center>'
			'You spend about an hour cleaning and brushing Desperado, scrubbing his coat and brushing his mane and tail. Finally, you are satisfied with the result - he looks as clean and healthy as ever.'

			act 'Finish': gt 'gad_gpbarn','horse'
			act 'Return back to your grandfather': minut += 3 & gt 'gad_gphouse', 'grandpa'
		end
	end
end

if $ARGS[0] = 'cow':
	*clr & cla
	minut += 1
	gs 'stat'

	'<center><h4>Grandparents'' Barn</h4></center>'
	'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/cow.jpg"></center>'
	*nl
	'Grandma''s favorite animal, the cow, Dawn.'

	act 'Leave': minut += 1 & gt 'gad_gpbarn'

	if grandmaQW['chore_milk_cow'] = 1:
		act 'Milk the cow (0:30)':
			*clr & cla
			minut += 30
			grandmaQW['chore_milk_cow'] = 2
			gs 'exp_gain', 'hndiwrk', rand(1,3)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/milk_cow.jpg"></center>'
			'You start milking Dawn, improving each time you do it.'

			act 'Finish': gt 'gad_gpbarn', 'cow'
			act 'Return back to your grandmother': minut += 3 & gt 'gad_gphouse', 'grandma'
		end
	end
	if grandpaQW['chore_feed_cow'] = 1:
		act 'Feed the cow (0:30)':
			*clr & cla
			minut += 30
			grandpaQW['chore_feed_cow'] = 2
			gs 'exp_gain', 'hndiwrk', rand(1,3)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/feed_cow.jpg"></center>'
			'Dawn is excited about feeding time, shaking her head and doing little cow tippy-taps with her feet. You dump some hay in her trough and watch as she digs in.'

			act 'Finish': gt 'gad_gpbarn','cow'
			act 'Return back to your grandfather': minut += 3 & gt 'gad_gphouse', 'grandpa'
		end
	end
	if grandpaQW['chore_lead_cow_to_field'] = 1 or grandpaQW['chore_herd_cattle'] = 1:
		act 'Lead the cow to the field (1:00)':
			*clr & cla
			minut += 60
			gs 'exp_gain', 'hndiwrk', rand(1,3)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/cow_field.jpg"></center>'
			if grandpaQW['chore_lead_cow_to_field'] = 1:
				'You lead Dawn to the field, where you let the shepherds take over.'
				grandpaQW['chore_lead_cow_to_field'] = 2
			end
			if grandpaQW['chore_herd_cattle'] = 1:'You lead Dawn to the field, where your grandfather awaits you. It''s his turn to keep an eye on the cows..'

			act 'Continue': gt 'gad_field', 'cow'
			if grandpaQW['chore_lead_cow_to_field'] = 2: act 'Return back to your grandfather (0:30)': minut += 30 & gt 'gad_gphouse', 'grandpa'
		end
	end
end

if $ARGS[0] = 'boar':
	*clr & cla
	minut += 1
	gs 'stat'

	'<center><h4>Grandparents'' Barn</h4></center>'
	'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/boar.jpg"></center>'
	'One of your grandparents'' dearest possessions, the boar, Nickle.'

	act 'Leave':minut += 1 & gt 'gad_gpbarn'

	if grandpaQW['chore_feed_boar'] = 1:
		act 'Feed the hog (0:30)':
			*clr & cla
			minut += 30
			grandpaQW['chore_feed_boar'] = 2
			gs 'exp_gain', 'hndiwrk', rand(1,3)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/gp_dacha/feed_boar.jpg"></center>'
			'You grab the feed bag and fill Nickle''s trough. You stand there and watch for a few minutes as he eats like a... well, like a pig.'

			act 'Finish': gt 'gad_gpbarn','boar'
			act 'Return back to your grandfather': minut += 3 & gt 'gad_gphouse', 'grandpa'
		end
	end
end

if $ARGS[0] = 'barn_room':
	$location_type = 'private'
	$setloc['StageTitle'] = 'Guest Room'
	$setloc['StageImage'] =   '<<$default_img_path>>village/gad_room.jpg'
	gs 'shortgs', 'setloc', 'gad_gpbarn', $ARGS[0]
	gs 'miroslava_schedule'
	gs 'themes', 'indoors'
	gs 'stat'
	gs 'themes', 'indoors'
	gs 'stat'
	gs 'core_library', 'stage_title'
	gs 'music_actions', 'clear_restrictions'

	act '<b>Leave and go to the yard</b>':
		if $clothingworntype ! 'nude':
			minut += 5
			gt 'gad_gpyard', 'start'
		else
			msg'<b><font color = red>You need to get dressed.</font></b>'
			gt $loc, $loc_arg
		end
	end
	act '<b>Leave and enter the dacha</b>':
		if $clothingworntype ! 'nude':
			minut += 5
			gt 'gad_gphouse', 'entry'
		else
			msg'<b><font color = red>You need to get dressed.</font></b>'
			gt $loc, $loc_arg
		end
	end

	'A small rustic loft space converted from your grandparents barn. A pair of sleeping pallets of dubious comfort is laid out for guests. The room walls are whitewashed with some clothes lines to dry your clothes with some farming tools. It''s not much to look at but it''s somewhere you can call home and have some privacy.'

	!! Activities - basic only. There is no internet so laptop is consigned to grandparents only. Room is too small for exercise, use yard or forest meadow.
	gs 'library_functions', 'set_home_read_acts'
	act 'Relax on your bed': gt 'bed', 'start'
	if pcs_horny >= 50:
		act 'Masturbate':gt 'selfplay', 'start'
	end

	if mc_inventory['vintage_card'] > 0: act 'View your vintage porn cards': card_deck = 0 & gt 'card'
	if mc_inventory['card'] > 0: act 'View your new porn cards': card_deck = 1 & gt 'card'
	gs 'music_actions', 'start'


	!! Activities End
	!! TODO: if winter create task for chopping wood for log stove.
	!! act 'light log stove': gt 'gad_gpbarn', 'log_stove'

	!! Game functions
	'At the foot of your bed is a small <a href="exec:gt ''wardrobe'', ''start''">chest</a> containing some of your clothes.'

	'<table><tr><td valign="top">'
	func('alarmclock', 'base_alarmclock_text')

	if mc_inventory['contraceptive_pill'] > 0 and mc_inventory['equipped_condoms'] + mc_inventory['normal_condoms'] + mc_inventory['sabotaged_condoms'] > 0:
		'Your <a href="exec:gt ''stol'', ''bc''">birth control</a> are hidden a small nook, as are your <a href="exec:gt ''stol'', ''bc''">condoms</a>.'
	elseif mc_inventory['contraceptive_pill'] > 0:
		'Your <a href="exec:gt ''stol'', ''bc''">birth control</a> are hidden in a small box under your pallet.'
	elseif mc_inventory['equipped_condoms'] + mc_inventory['normal_condoms'] + mc_inventory['sabotaged_condoms'] > 0:
		'Your <a href="exec:gt ''stol'', ''bc''">condoms</a> are hidden behind a loose brick.'
	end

	if $start_type['loc'] = 'sg' and SchoolAtestat = 0 and week = 6 and hour > 4 and hour < 9 and detention_set = 1 and detention_warning ! daystart:
		detention_warning = daystart
		msg 'You have detention this morning and must be at school before 09:00.'
	end

	if mc_inventory['tech_computer'] = 1: 'Your <a href="exec: gt ''Komp'',''start''">computer</a> is on your desk.'
end

if $ARGS[0] = 'log_stove':
	!! simple iron stove that requires wood logs. Make it a task to fill and light in winter.
end
--- gad_gpbarn ---------------------------------