glife/locations/gad_road.qsrc

# gad_road
!2024/05/05 - Mira schedule introduced.
!locat['A60'] = Mira''s location. See 'miroslava_schedule'

if $ARGS[0] = 'start':
	gs 'shortgs', 'setloc', 'gad_road', 'start'
	$location_type = 'public_outdoors'
	menu_off = 0
	gs 'miroslava_schedule'
	CLOSE ALL
	gs 'gadukino_event', 'sound'
	gs'stat'

	'<center><H4>Forest road</H4></center>'

	if month >= 4 and month <= 10:
		if hour >= 6 and hour < 22:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad_night.jpg"></center>'
		end
	else
		if hour >= 8 and hour < 18:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad_winter.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadroad_winter_night.jpg"></center>'
		end
	end
	*nl
	'A dirt road leading to the outskirts of Gadukino. You are surrounded by grainfields where the grains appear, reaching all the way to the heavens.'
	'The forest '+iif(gad_meadow_found = 1, 'and meadow ', '')+'can be found further down the road, away from the village.'
	*nl
	! 10% chance of meeting Mitka once per day on the road when Sveta is not the village boys slut or whole villages whore
	if rand(0, 9) = 0 and GadBoy['first_drink'] > 0 and GadBoy['mitka_day'] ! daystart and hour >= 17 and hour < 20 and (npc_QW['A63'] < 11 or GadBoy['river_gang'] > 2):
		'<a href="exec:gt ''mitka''">Mitka</a> is smoking near the road, he smiles at you as you walk by.'
	! Meet the boys to drink with them at 20 if Sveta has been invited by Mitka already
	elseif GadBoy['first_drink'] > 0 and hour = 20 and alko < 10 and GadBoy['drinkday'] ! daystart:
		'<a href="exec:gt ''gad_road'', ''drinking_invite''">Mitka, Kolyamba, and Vasyan</a> are walking down the road towards the woods, drinking moonshine and talking loudly.'
	! If Sveta is late to go drink with the boys if she already knows where the trailer is she can still get there
	elseif GadBoy['first_drink'] = 2 and hour > 20 and alko < 10 and GadBoy['drinkday'] ! daystart:
		! if Sveta did not bring Mira with her and Mira has met the boys already then there is a 50% chance she will show up too

		if locat['A60'] = 42:
			if MiraVars['QW'] >= 16 and GadBoy['river_gang'] = 2:
				'You can go drink with Mira, Mitka, Kolyamba and Vasyan at their <a href="exec:gt ''mitkabuh_group''">trailer</a> hidden in the woods.'
			else
				'You can go drink with Mira, Mitka, Kolyamba and Vasyan at their <a href="exec:gt ''mitkabuh''">trailer</a> hidden in the woods.'
			end
		else
			'You can go drink with Mitka, Kolyamba and Vasyan at their <a href="exec:gt ''mitkabuh''">trailer</a> hidden in the woods.'
		end
	end

	act 'Walk to the bus station (0:01)': minut += 1 & gt 'bus', 'gadukino'
	act 'Walk to Gadukino (0:10)': minut += 10 & gt 'gadukino'
	act 'Walk down to the river (0:10)': minut += 10 & gt 'gad_river', 'start'
	act 'Walk to the fields (0:10)': minut += 10 & gt 'gad_field', 'field'
	act 'Walk into the woods (0:15)': minut += 15 & gt 'gad_forest', 'forest_edge'

	if hour >= 6 and hour < 22:
		if PCloSport = 0:
			'You could go for a run here if you were wearing sports clothes and shoes.'
		else
			if pcs_energy >= 5 and pcs_stam >= stammax / 5:
				act 'Go for a run (1:00)':
					*clr & cla
					menu_off = 1
					gs 'exercise', 'tier1', 60, 'run'

					if month <= 3 or month >= 11:
						'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadbeg4.jpg"></center>'
					elseif month=9 or month=10 or month=4 or month=5:
						'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadbeg3.jpg"></center>'
					else
						if strenbuf >= pcs_mass['body']:
							'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadbeg1.jpg"></center>'
						else
							'<center><img <<$set_imgh>> src="images/locations/gadukino/village/gadbeg2.jpg"></center>'
						end
					end
					'You run for an hour enjoying the scenery.'

					act 'Finish': gt 'gad_road', 'start'
				end
			elseif pcs_stam >= stammax / 5:
				act 'Go for a run (1:00)': '<br><font color="red">You are so hungry you cannot face going for a run.</font>'
			else
				act 'Go for a run (1:00)': '<br><font color="red">You are to exhausted to do this. Recover your stamina before trying to go for a run.</font>'
			end
		end
	end
end

if $ARGS[0] = 'drinking_invite':
	gs 'shortgs', 'setloc', 'gad_road', 'drinking_invite'
	$location_type = 'secluded'
	menu_off = 1
	gs 'miroslava_schedule'
	minut += 5
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/locations/gadukino/village/drunk.jpg"></center>'
	'You quickly catch up to the boys who have already started drinking.'
	! Sveta has never been drinking with Mitka before
	if GadBoy['first_drink'] = 1:
		'Mitka is the first to greet you, "Hey <<$pcs_nickname>>, glad you decided to join us today!"'
		'Kolyamba and Vasyan nod in agreement as they look you over.'
		'"We know this great spot in the woods to hang out. No one ever bothers us there."'
	else
		'Mitka is the first to greet you, "Hey <<$pcs_nickname>>, glad you decided to join us today!"'
		'Kolyamba and Vasyan nod in agreement as they look you over.'
	end
	'Mitka asks, "Are you ready to go?"'

	! if Sveta came here to kick off Miras quest then she cannot leave otherwise Sveta is free to decline the offer
	if MiraVars['QW'] > 0 or locat['A60'] ! 42:
		gs 'willpower', 'drink', 'resist'
		if will_cost <= pcs_willpwr:
			act 'No thanks, not tonight. (<<will_cost>> Willpower)':
				gs 'willpower', 'drink', 'resist'
				gs 'willpower', 'pay', 'resist'
				gs 'stat'

				gt 'gad_road', 'start'
			end
		else
			act 'No thanks, not tonight. (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		end
	end

	! if Sveta did not bring Mira with her and Mira has met the boys already then there is a 50% chance she will show up too
	if locat['A60'] = 42 and locat['A60_prev'] ! 42 and MiraVars['follow_time'] = 0:
		'Just as the words leave Mitka''s mouth, Mira comes bounding around the corner.'
		'"Hey guys, thanks for the invite! <<$pcs_nickname>> is here, too, awesome! Let''s go!"'
	end

	if locat['A60'] = 42:
		! Mira is here and both her and Sveta are the town whores
		! mitkabuh_group has the drinking events for group sex for 2 girls and 3 boys
		if MiraVars['QW'] >= 16 and GadBoy['river_gang'] = 2:
			act 'Go with them': minut += 15 & gt 'mitkabuh_group'

		! Mira is here and neither or only 1 out 2 of them is the town whore
		! mitkabuh has the drinking events for group sex for 1 girl and 3 boys or no sex at all if quest is not far enough along
		else
			act 'Go with them': minut += 15 & gt 'mitkabuh'
		end
	! Mira is not here so Sveta goes by herself
	else
		act 'Go with them': minut += 15 & gt 'mitkabuh'
	end
end

--- gad_road ---------------------------------