glife/locations/gad_store.qsrc

# gad_store


*clr & cla
gs 'shortgs', 'setloc', 'gad_store', ''
$location_type = 'public_indoors'
menu_off = 0

frost = 0

*pl '<center><h1><font color="maroon">Village Shop</font></h1></center>'
*pl '<center><img <<$set_imgh>> src="images/locations/gadukino/village/market.jpg"></center>'

'You walk into the small shop with four narrow aisles with chest-high shelves full of food and other household goods. There is little variety in the selections, just the most essential products.'
'Slowly you browse the aisles, looking for something to buy.'
*nl
'As you approach the teller, you notice a rack full of magazines, cigarettes, and a few hygienic items.'
*nl
act 'Browse the aisles': gt 'gad_store', 'cart'

act 'Leave the store': minut += 5 & gt 'gadukino'
if grandmaQW['chore_groceries'] = 1:
	act 'Gather the things on Grandma''s list (0:30)':
		*clr & cla
		minut += 30
		gs 'stat'

		grandmaQW['chore_groceries'] = 2
		grandmaQW['help_amount'] += 1

		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/market.jpg"></center>'
		'You take out the list Grandma gave you and begin browsing the shelves for the items she needs. Finally, after about half an hour, you have gotten everything on the list.'
		*nl
		'You take your basket of goods to the teller and explain that you are getting these things for your grandmother.'
		'"Of course! Go ahead and take these on home to her. Tell her I will be by this evening to pick up her payment. I know it''s hard for her to get out anymore..."'

		act 'Thank him and leave': minut += 5 & gt 'gadukino'
		act 'Thank him and take the groceries back to your grandmother (0:10)': minut += 10 & gt 'gad_gphouse', 'grandma'
	end
end


if $ARGS[0] = 'cart':
	$loc_s = 'gad_store'
	$args_s = 'cart'
	*clr & cla

	if hour < 8 or hour > 20:
		'The shop is currently closed.'

		act 'Leave':gt 'gadukino'
		exit
	end

	gs 'item_cart', 'shoppping_aisle', 'gad_store'
	gs 'stat'
	gs 'themes', 'indoors'
	$backimage= 'images/locations/gadukino/village/market.jpg'

	act 'Exit shopping cart': $backimage = '' & gt 'gad_store'
	act 'Leave the store': minut += 5 & gt 'gadukino'
end


--- gad_store ---------------------------------