glife/locations/gargazel.qsrc

# gargazel

CLOSE ALL
$loc_arg = $ARGS[0]
$loc = 'gargazel'
$menu_loc = 'gargazel'
$menu_arg = ''
menu_off = 0
$location_type = 'secluded'
fatherdrunk = 0
clr
gs 'family_schedule'
gs 'stat'
'<center><h4>Garage</h4></center>'

if locat['Stepdad'] = 9:
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/garage/gargazel.jpg"></center>'
	'A large garage that belongs to your stepfather. He spends time in there working on his beloved Gazelle pickup truck whenever he can in the late afternoons and evenings. You can tell the door is not locked, he''s probably in there now.'
else
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/resident/apartment/garage/gargazel_empty.jpg"></center>'
	'A large garage that belongs to your stepfather. He spends time in there working on his beloved Gazelle pickup truck whenever he can in the late afternoons and evenings. Right now the garage is closed, and the door is locked with a large padlock.'
end

if locat['Stepdad'] = 9:
	if fatherdrunk = 1:
		'Your <a href="exec:gt ''garfather''">stepfather and uncle Misha</a> are in the garage, drinking vodka.'
	else
		'Your <a href="exec:gt ''garfather''">stepfather</a> is in the garage, working on his Gazelle pickup truck.'
	end
end

act 'Leave the garage':minut += 5 & gt 'pav_complex', 'garages'

if YouCanGar > 0:
	'You have stored <<mc_inventory[''trinkets_garage'']>> trinkets in the garage currently. Your stepfather allowed you to store some things in his garage but doesn''t want you taking up all his space, he has allowed you to store up to 100 trinkets here. The garage is not very easily accessible; if you want to sell the trinkets at the station, you will have to bring them back home first.'

	if mc_inventory['trinkets_home'] >= 30:
		'You already have too much stored at home and do not have any more space.'
	elseif mc_inventory['trinkets_home'] < 30:
		trinkets_can_take = 30 - mc_inventory['trinkets_home']
		'You can bring <<trinkets_can_take>> trinkets home and store them somewhere, until you have time to collect and sell them at the train station.'

		if mc_inventory['trinkets_garage'] > 0:
			if mc_inventory['trinkets_garage'] >= trinkets_can_take:
				act 'Move <<trinkets_can_take>> trinkets to your home':
					cls
					menu_off = 1
					minut += 60
					mc_inventory['trinkets_home'] += trinkets_can_take
					mc_inventory['trinkets_garage'] -= trinkets_can_take
					gs 'stat'
					'You spend an hour gathering your trinkets from various places, bringing them home and hiding them there.'

					act 'Continue':gt $curloc
				end
			end

			if mc_inventory['trinkets_garage'] < trinkets_can_take:
				act 'Collect <<mc_inventory[''trinkets_garage'']>> trinkets to take with you':
					cls
					menu_off = 1
					minut += 30
					mc_inventory['trinkets_home'] += mc_inventory['trinkets_garage']
					mc_inventory['trinkets_garage'] = 0
					gs 'stat'
					'You spend half an hour gathering your trinkets from various places in the garage, putting them in a bag so you can go sell them at the station.'

					act 'Continue':gt $curloc
				end
			end
		end
	end
end

--- gargazel ---------------------------------