glife/locations/havana_dance.qsrc

# havana_dance

menu_off = 1
minut += 5
gs 'stat'
gs 'themes', 'indoors'

'<center><b><font color="maroon">Dance Studio</font></b></center>'
'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/dance/danceclass.jpg"></center>'
'A big, open room with good lighting and huge mirrors, perfect for improving your dance skills.'

if pcs_energy < 10:
	*nl
	'You are so hungry you can''t even bring yourself to look at the activities available.'
elseif pcs_stam < stammax / 5:
	*nl
	'You are to exhausted you can''t even bring yourself to look at the activities available. Recover your stamina before trying to dance.'
else
	act 'Modern dance class (0:30)':
		*clr & cla
		gs 'exercise', 'tier2', 30, 'agil', 'stren', 'danc'
		abonement -= 1
		if pcs_inhib < 40: inhib_exp += rand(1,2)

		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/dance/moderndance.jpg"></center>'
		if pcs_danc < 100:
			'You study modern dance, which is very popular in the clubs.'
		else
			'The day has finally come, you''ve been working hard, and you realize that you''ve learned everything you can from this class.'
		end

		act 'Leave': gt 'havana', 'dressing_room'
	end

	act 'Burlesque class (0:30)':
		*clr & cla
		gs 'exercise', 'tier2', 15, 'agil', 'stren', 'danc', 'dancero'
		abonement -= 1
		if pcs_inhib < 60: inhib_exp += rand(1, 2)

		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/dance/burlesque.jpg"></center>'
		if pcs_danc < 50:
			gs 'exercise', 'tier2', 15, 'danc'
			'This class isn''t just about taking your clothes off, it''s a difficult dance style and your basics aren''t sufficent. Instead, the teacher helps you with your basic modern dance steps.'
		else
			gs 'exercise', 'tier2', 15, 'dancero'
			'You study the art of burlesque, imaging yourself stripping to the music.'

			if pcs_dancero >= 100: 'You''ve finally managed to master the art of burlesque, there is no need taking this class anymore.'
		end

		act 'Leave': gt 'havana', 'dressing_room'
	end

	if pcs_stren >= 40 or needstrength = 0:
		killvar 'needstrength'
		act 'Pole dance class (0:30)':
			*clr & cla
			gs 'exercise', 'tier2', 15, 'agil', 'stren', 'dancpol'
			abonement -= 1
			if pcs_inhib < 60: inhib_exp += rand(1, 2)
			'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/dance/poledance.jpg"></center>'

			if pcs_dancero < 50 or pcs_stren < 40:
				minut += 15
				gs 'stat'
				'It doesn''t look sensual enough and you bang your head pretty hard on the pole. This is far harder than it looks. It would help if you improved your modern dancing skills or the burlesque one, but you did learn a little.'

				if pcs_stren < 40: 'The instructor tries to be patient with you, but it is clear that you are too weak for this sort of dance.' & needstrength = 1
			else
				gs 'exercise', 'tier2', 15, 'dancpol'
				'You study various acrobatics on the pole.'

				if pcs_dancpol >= 100: 'You''ve already mastered the art of pole dancing, there is nothing more left to teach you.'
			end

			act 'Leave': gt 'havana', 'dressing_room'
		end
	end
end

act 'Leave': gt 'havana', 'dressing_room'


--- havana_dance ---------------------------------