glife/locations/havana_pool.qsrc

# havana_pool

if $ARGS[0] = 'start':
	CLOSE ALL
	gs 'shortgs', 'setloc', 'havana_pool', 'start'
	$location_type = 'public_indoors'
	menu_off = 0
	minut += 5
	gs 'stat'
	gs 'themes', 'indoors'

	'<center><b><font color="maroon">Pool</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/pool/bass.jpg"></center>'
	'You must wear a swimsuit in the pool.'

	if db >= 1 and Goraday ! daystart:act 'Search ZHoru':Goraday = daystart & gt 'city_jorahouse', 'ev42'

	act 'Swim': minut += 5 & gt 'havana_pool', 'a'
	act 'Return to dressing room': gt 'havana', 'dressing_room'
end

if $ARGS[0] = 'a':
	menu_off = 1
	minut += 5
	'<center><b><font color="maroon">Pool</font></b></center>'

	if pcs_magik < 4:
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/pool/bass.jpg"></center>'

	elseif kisameQW = 0:
		'<center><img <<$set_imgh>> src="images/locations/city/citycenter/gym/pool/bass1.jpg"></center>'
		'There''s a professional athlete swimming in the pool. He swims with great speed and is behaving like a fish in water, he walks over to the edge of the pool and in one motion jumps in the water right in front of you. As he looks at you, he grins, showing his shiny white teeth.'

		act 'Observe him':
			*clr & cla
			kisameQW = 1
			minut += 59
			gs 'exercise', 'tier1', 1, 'stren', 'vital'
			pcs_sweat = 10 + rand(0, 4)

			'<center><img <<$set_imgh>> src="images/characters/city/kisame/kisame.jpg"></center>'
			'As he pulls himself out of the pool, he grabs a towel and walks up to you. Smiling he says, "Hi sweetie, my name is Kisame..."'

			act 'Say hello':
				cla
				'"Hi! I''m <<$pcs_nickname>>."'
				'"How about we take a swim together, <<$pcs_nickname>>?"'
				'Before you''re able to answer, Kisame grabs you by the waist and takes a powerful leap into the middle of the pool.'
				if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the water.'
				act 'Next':gt 'kisameQW', 'start'
			end

			gs 'willpower', 'misc', 'resist'
			if pcs_willpwr < will_cost:
				act 'Tell Kisame to fuck off (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
			else
				act 'Tell Kisame to fuck off (<<will_cost>> Willpower)':
					cla
					'"I don''t care who you are, fuck off!"'
					'"That''s not nice!" he replies.'
					'Before you''re able to blink, he grabs you by the waist and throws you into the middle of the pool.'
					'As you surface, you notice Kisame rapidly approaching you...'
					if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the water.'
					gs 'willpower', 'misc', 'resist'
					gs 'willpower', 'pay', 'resist'
					gs 'stat'
					act 'Next': gt 'kisameQW', 'start'
				end
			end
		end

	elseif kisameQW = 1 and KisameDead < 1:
		'<center><img <<$set_imgh>> src="images/characters/city/kisame/kisamev.jpg"></center>'
		'Noticing you observing him, Kisame smiles and tells you, "Hi baby. Want me to fill your hot mouth with my shark-seed?"'

		gs 'willpower', 'bj', 'resist'
		if pcs_willpwr < will_cost:
			act 'Attack Kisame (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		else
			act 'Attack Kisame (<<will_cost>> Willpower)':
				cla
				pcs_horny += 10
				gs 'willpower', 'bj', 'resist'
				gs 'willpower', 'pay', 'resist'
				gs 'stat'
				gs 'boyStat', 'A40'

				gs 'fight','initFight'

				gs 'fight_npcdata', 'kisame'

				gt 'fight', 'start'
			end
		end

		act 'Give him a blowjob under water':
			*clr & cla
			pcs_makeup = 1
			cumspclnt = 10
			gs 'cum_cleanup'
			if pcs_sweat > 15 : pcs_sweat = 10 + rand(0,4)
			pcs_mood += 5

			if pcs_stren < 40:gs 'exp_gain', 'stren', 1 + rand(0, drugVars['steroids_dose']) & gs 'obj_din', 'steroids'		& ! obj_din does not have a steroids sublocation??
			if KisameSex = 0:KisameSex = 1 & Set guy += 1
			gs 'boyStat', 'A40'

			'<center><img <<$set_imgh>> src="images/characters/city/kisame/sex/kisamebj.jpg"></center>'
			'You close your eyes, as Kisame grins and drags you deep into the water. His strong hands press you towards his groin and you wrap your lips around his cock and within seconds Kisame finishes in your mouth.'

			gs 'arousal', 'bj', 2, 'sub'
			gs 'cum_call', 'mouth', 'A40', 1
			gs 'arousal', 'end'
			gs 'stat'

			act 'Get out of the water': gt 'havana_pool', 'start'
		end
	end

	if pcs_stam >= (20 * (10 - sport_clothes_exercise_bonus)) / 2:
		act 'Take a swim (1:00)':
			*clr & cla
			pcs_makeup = 1
			cumspclnt = 10
			gs 'cum_cleanup'
			gs 'exercise', 'tier1', 60, 'stren', 'vital'
			pcs_sweat = 10 + rand(0,4)
			if pcs_inhib < 50:inhib_exp += rand(1,2)
			if func('body_din','pregnancyVisibility') = 0:
				'<center><img <<$set_imgh>> src="images/pc/activities/swim/pool/swim_bikini_<<rand(1,8)>>.jpg"></center>'
			else
				'<center><img <<$set_imgh>> src="images/pc/activities/swim/pool/swim_bikini_preg_<<rand(1,4)>>.jpg"></center>'
			end
			'You take a swim in the pool, which invigorates you, making you feel refreshed.'
			if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the water.'
			act 'Get out of the water': gt 'havana_pool', 'start'
		end
	end

	act 'Leave': gt 'havana_pool', 'start'
end

--- havana_pool ---------------------------------