glife/locations/music_checks.qsrc

# music_checks

!! Del Parco Storyline Stages
!! ml_delparcoQW['Stage'] = 0 - Storyline hasn''t started yet.
!! ml_delparcoQW['Stage'] = 1 - Sveta declines the offer when they meet while she is busking. Zariyah tells her to visit her office next Friday around 4pm.
!! ml_delparcoQW['Stage'] = 2 - Sveta accepts the offer when they meet while she is busking.  Zariyah tells her to think about it, and that if she changes her mind, just visit her in her office.
!! ml_delparcoQW['Stage'] = 3 -
!! ml_delparcoQW['Stage'] = 4 -
!! ml_delparcoQW['Stage'] = 5 -
!! ml_delparcoQW['Stage'] = 6 -
!! ml_delparcoQW['Stage'] = 7 -
!! ml_delparcoQW['Stage'] = 98 - Sveta declined the offer even after thinking about it. Zariyah gave her a card and asked her to call if she changes her mind.
!!								Story is not over, Sveta can start it any time by calling or visiting Zariyah
!! ml_delparcoQW['Stage'] = 99 - Zariyah met Sveta when Sveta was visibly pregnant and asked her to talk after Sveta gave birth and feels like she is ready for this.
!!								Like with Stage 98, Sveta can continue the story at a later point (after she is not pregnant anymore).
!! ml_delparcoQW['Stage'] = 100 - Zariyah will not do anything with Sveta. Either she decided not to even give her an offer, or she fired Sveta


if $ARGS[0] = 'zariyah_approach':

	if $loc = 'pav_park':
		chance = 75
	else
		ml_approach = (rand(0,100) > 80 and (pcs_instrmusic + pcs_vokal + pcs_perform) >= 120 and pcs_hotcat >= 5 and ml_delparcoQW['stage'] = 0)
	end
	ml_approach = rand(1,100) > chance and (pcs_instrmusic + pcs_vokal + pcs_perform) >= 120 and pcs_hotcat >= 5 and ml_delparcoQW['stage'] = 0

	if ml_approach:
		!! Check for fame: if very 'famous' then she won't ever approach Sveta, doesn't want her associated with Del Parco.
		if fame['pav_slut'] > 250 or fame['pav_prostitute'] > 250 or fame['pav_sex'] > 250 or fame['pav_porn'] > 500 or fame['pav_stripping'] > 500:
			ml_delparcoQW['Stage'] = 100
		!! Check for covered in cum: face, hair, clothes (at least decent amount). If Sveta is in public, visibly covered in cum, she won''t ever approach Sveta,
		!! doesn''t want her associated with Del Parco.
		elseif cumvol[11] > 10 or cumvol[16] > 20 or cumvol[6] > 20 or cumvol[7] > 20:
			ml_delparcoQW['Stage'] = 100
		!! Check for drunk+. If Sveta drunk, very drunk or wasted Zariyah won''t approach her - what for? However, she will still approach her if the next time
		!! she sees Sveta busking and Sveta passes the checks.
		elseif alko > 6:
			ml_approach = 0
			ml_delparcoQW['Zariyah_Trust'] -= 10
		!! Check for stoned: if Sveta is stoned the Zariyah will avoid her for now. But they still can meet.
		elseif drugVars['heroin_high'] > 20:
			ml_approach = 0
			ml_delparcoQW['Zariyah Trust'] -= 20
		end

		!! Less serious checks
		!! Check if Sveta is tipsy
		if alko > 4 and alko < 7:
			ml_delparcoQW['Drinking Rule'] = 1
			ml_delparcoQW['Zariyah Trust'] -= 5
		end

		!! Check if Sveta is high
		if drugVars['weed_high'] > 0:
			ml_delparcoQW['Weed Rule'] = 1
			ml_delparcoQW['Zariyah Trust'] -= 5
		end

		!! Check if Sveta is dressed like a hooker
		if PCloStyle > 3 or PCloStyle2 = 3 or PCloThinness > 4 or PCloTopCut > 3 or PCloSkirt > 4 or PCloPants > 5 or PCloPanties > 0:
			ml_delparcoQW['Outfit Rule'] = 1
			ml_delparcoQW['Zariyah Trust'] -= 5
		end

		!! Check if Sveta is pregnant
		if pregchem > 3450:
			!! If Sveta is visibly pregnant, and also clearly drank alcohol and/or is high and/or is stoned and/or is dressed like a hooker,
			!! Zariyah doesn''t want to do anything with her.
			if alko > 4 or drugVars['weed_high'] > 0 or drugVars['heroin_high'] > 20 or ml_delparcoQW['Outfit Rule'] = 1:
				ml_delparcoQW['Stage'] = 100
			!! If Sveta is visibly pregnant, Zariyah will talk with her and make an offer for after she gave birth. She doesn''t want a pregnant
			!! woman in or close to her third semester as a musician, too risky. But later, sure.
			else
				ml_delparcoQW['Stage'] = 99
			end
		end

		gs 'music_checks', 'check_for_trust'
		if ml_delparcoQW['Stage'] = 100: ml_approach = 0
	end
	killvar 'chance'

end


if $ARGS[0] = 'check_if_fired':
 !! Check for fame: if very 'famous' then she won't ever approach Sveta, doesn't want her associated with Del Parco.
	if fame['pav_sex'] > 150:
		ml_delparcoQW['Sveta Sex'] = 1
		ml_delparcoQW['Stage'] = 100
	elseif fame['pav_prostitute'] > 150:
		ml_delparcoQW['Sveta Prostitute'] = 1
		ml_delparcoQW['Stage'] = 100
	elseif fame['pav_porn'] > 500:
		ml_delparcoQW['Sveta Porn'] = 1
		ml_delparcoQW['Stage'] = 100
	elseif fame['pav_stripping'] > 500:
		ml_delparcoQW['Sveta Stripper'] = 1
		ml_delparcoQW['Stage'] = 100
	!! Check for covered in cum: face, hair, clothes (at least decent amount). If Sveta is shows up to a gig covered in cum, Zariyah will fire her on the spot.
	!! TODO: Will add something here, if she is caught and raped in the park before the gig it makes sense that she goes to Zariyah to call the police. That will be a separate scene.
	elseif cumvol[11] > 10 or cumvol[16] > 20 or cumvol[6] > 20 or cumvol[7] > 20:
		ml_delparcoQW['Stage'] = 100
	!! Check for drunk+. If Sveta shows up to perform drunk, very drunk or wasted Zariyah will fire her because she is unreliable.
	elseif alko > 6:
		ml_delparcoQW['Sveta Drunk'] = 1
		ml_delparcoQW['Stage'] = 100
	!! Check for stoned: if Sveta shows up to perform stoned, Zariyah will fire her because she is unreliable.
	elseif drugVars['heroin_high'] > 20:
		ml_delparcoQW['Sveta Stoned'] = 1
		ml_delparcoQW['Stage'] = 100
	end
end

if $ARGS[0] = 'check_if_can_perform':
	!! Less serious checks
	!! Check if Sveta is tipsy
	if alko > 4 and alko < 7:
		ml_delparcoQW['Drinking Rule'] = 1
		ml_delparcoQW['Zariyah Trust'] -= 10
		ml_perform = 0
	end

	!! Check if Sveta is high
	if drugVars['weed_high'] > 0:
		ml_delparcoQW['Weed Rule'] = 1
		ml_delparcoQW['Zariyah Trust'] -= 10
		ml_perform = 0
	end

	!! Check if Sveta is dressed like a hooker
	if PCloStyle > 3 or PCloStyle2 = 3 or PCloThinness > 4 or PCloTopCut > 3 or PCloSkirt > 4 or PCloPants > 5 or PCloPanties > 0:
		ml_delparcoQW['Outfit Rule'] = 1
		ml_delparcoQW['Zariyah Trust'] -= 10
		ml_perform = 0
	end
end

if $ARGS[0] = 'check_for_trust':
	!! Check for Zariyah''s trust level. If it is 0 or less, then the story is over. So if she sees Sveta drunk or stoned several times, she won''t make an offer.
	if ml_delparcoQW['Zariyah Trust'] <= 0:
		ml_delparcoQW['Stage'] = 100
	end
end


if $ARGS[0] = 'reset_checks':
	ml_delparcoQW['Drinking Rule'] = 1
	ml_delparcoQW['Weed Rule'] = 1
	ml_delparcoQW['Outfit Rule'] = 1
end


--- music_checks ---------------------------------