glife/locations/music_delparco.qsrc

# music_delparco

if $ARGS[0] = 'talkwithzariyah':
!!	TODO: Some small talk and a description here plus some paragraph depending on where the quest stands
	'You ask the first waitress about Zariyah, and she directs you to the office. As you approach, she waves at you through the open door, signaling to enter "Yes, yes Ruslan, don''t worry about it. No, I have to go, talk later."'
	if ml_delparcoQW['Stage'] = 1:
		'She puts down the phone "<<$pcs_nickname>>, so glad that you came. How are you? Did you think about the offer?" she smiles at you as you sit down.'
		act 'Accept the offer to play at Del Parco': gt 'music_delparco', 'delparco_accept'
	!!	act 'Decline the offer': gt 'mod_musiclife_delparco', 'delparco_decline'
	elseif ml_delparcoQW['Stage'] = 2:
		'She puts down the phone "<<$pcs_nickname>>, so glad that you came. How are you? Did you come to talk about the offer?" she smiles at you as you sit down.'
		act 'Discuss the live music with': gt 'music_delparco', 'firstdiscussion'
	end
	act 'Leave': gt 'cafe_parco', 'start'
end

if $ARGS[0] = 'delparco_accept':
	ml_venues['del_parco'] = 1
	ml_delparcoQW['Stage'] = 2
!!	TODO: Better scene.
	'You accept.'
	*nl
	'(Warning - the event is unfinished, so there is lack of pictures and the text is simplified)'
    act 'Discuss the live music with': gt 'music_delparco', 'firstdiscussion'
	act 'Leave': gt 'cafe_parco', 'start'
end


if $ARGS[0] = 'firstdiscussion':
	if (week + 2 <= 7):
		ml_answerdeadline = week + 2
	else
		ml_answerdeadline = week - 5
	end

!!	TODO: Obviously, blahblah is not proper text.
	*nl
	'You take a seat facing Zariyah "I thought about it a bit more and, yes, I would like to do it just need to know a bit more. I never really did anything like this."'
	'She nods and picks up a pen "I understand, <<$pcs_nickname>>. Well, it''s not like playing in an arena or anything. We just need someone to play on Fridays. It would be half an hour, but it''s not background music, you play songs."'
	'She wiggles the pen, writing down some of what she say "And we would pay you. It''s not a lot of money, but we pay you 800 rubles. And we would like to start two weeks from now at 8 in the evening."'
	'You think for a moment. 800 rubles is way more than you can get anywhere else in Pavlovsk. On the other hand, 30 minutes is quite a few songs, and you will have to practice a lot in the beginning to do it.'
	*nl
	act 'Accept the offer':
		*clr & cla
		ml_delparcoQW['Stage'] = 4
		'"I would love to do it!" you almost bite your tongue as you stop, but the fact that someone asks you to play is a first step to your dream. You almost couldn''t contain yourself.'
		'"Excellent!" Zariyah smiles at you, and pushes the paper she was writing on towards you "Everything is there. Don''t forget, two weeks from now, Friday at 8pm, so please be here latest half past seven.
		Trust me, you will need the time to set yourself up. And then every Friday if it works out."'
		ml_gigday['delparco'] = daystart + 19 - week
		ml_gighour['delparco'] = 19
		ml_gigfee['delparco'] = 800

		killvar 'ml_answerdeadline'

		act 'Leave': gt 'cafe_parco', 'start'
	end

	act 'Ask for some time':
		*clr & cla
		ml_delparcoQW['Stage'] = 3
		ml_delparcoQW['Next Date'] = daystart + 2
		ml_delparcooriginaldate = daystart
		'"I have to think, I want to make sure that I can do it. It''s a big commitment and I don''t want to, you know... not do it right."'
		'Zariyah nods "Ok, <<$pcs_nickname>>, but please, let me know by <<$week[''ml_answerdeadline'']>>."'

		killvar 'ml_answerdeadline'

		act 'Leave': gt 'cafe_parco', 'start'
	end


end

if $ARGS[0] = 'acceptafterthinking':

	offset = (daystart-ml_delparcooriginaldate)
	ml_gigday['delparco'] = daystart + 19 - offset - week
	ml_gighour['delparco'] = 19
	ml_gigfee['delparco'] = 800
	ml_delparco['performance'] = 50
	ml_delparcoQW['Stage'] = 4

	'"I would love to do it!" you almost bite your tongue as you stop, but the fact that someone asks you to play is a first step to your dream. You almost couldn''t contain yourself.'
	'"Excellent!" Zariyah smiles at you, and pushes the paper she was writing on towards you "Everything is there. Don''t forget, two weeks from now, Friday at 8pm, so please be here latest half past seven.
	Trust me, you will need the time to set yourself up. And then every Friday if it works out."'

	killvar 'offset'
	killvar 'ml_delparcooriginaldate'
	act 'Leave': gt 'cafe_parco', 'start'
end

if $ARGS[0] = 'eveningshow':
	minut += 60
	ml_correction_chance = ml_performance['set_quality'] + ((pcs_hotcat - 5)*3) + (pcs_perform/10)
	ml_success = rand(0,100)
	gs 'exp_gain', 'instrmusic', rand(1,2)
	gs 'exp_gain', 'vokal', rand(1,2)
	ml_performance['performed_minutes'] += 30
	ml_performance['total_time_performed'] += 30

!!	if perform_lvl < 45 = rand(1,3):
		'<center><video autoplay loop src="images/pc/activities/music/GigPlaceHolder.mp4"></video></center>'
	!!TODO: More scene, on set up, arriving, etc.
		if ml_success < ml_performance['set_quality']:
			ml_delparco['performance'] += 10
			gs 'fame', 'pav', 'music', rand(1,5)
			pcs_mood += 15
			'You played with no issues playing everything as it was meant to be.'
		elseif ml_success < ml_correction_chance:
			ml_delparco['performance'] += 5
			gs 'fame', 'pav', 'music', rand(1,3)
			'You made some mistakes and forgot the lyrics in some places, but you were able to compensate by your performance and yes, your looks.'
			pcs_mood += 5
		elseif ml_success < ml_correction_chance + 10:
			gs 'fame', 'pav', 'music', rand(-2,0)
			pcs_mood -= 5
			'You made quite a few mistakes and forgot the lyrics in places, and even though you tried your best to compensate by your performance and your looks, you could see that people have noticed them. '
			'You will have to practice even more and rehearse your songs before your next gig.'
		else
			ml_delparco['performance'] -= 20
			gs 'fame', 'pav', 'music', rand(-10,-5)
			pcs_mood -= 15
			'Today definitely wasn''t your day. You bombed, there is no better word for it. While you lasted your 30 minutes, you could see on the audience that they didn''t really enjoy it, even though they politely clapped at the end.'
			'You will have to do some serious practicing if you want to have another chance to perform.'
		end
!!	end
	*nl
	'(The event is unfinished - do not complain about quality - report only serious bugs)'


	act 'Leave': gt 'cafe_parco', 'start'
end

--- music_delparco ---------------------------------