glife/locations/pav_library.qsrc

# pav_library

!2021/10/05
!2023/09/11 Loan update by Anjuna

menu_off = 0

if $ARGS[0] = '':
	gs 'shortgs', 'setloc', 'pav_library', ''
	$location_type = 'public_indoors'
	frost = 0
	gs 'stat'

	gs 'themes', 'indoors'

	'<center><b><font color="maroon">Community center library</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/library/gdkbibl.jpg"></center>'
	'For such a small town, the library is surprisingly large, containing many interesting books on a wide variety of subjects.'

	if mid($start_type,1,2) = 'sg' and kanikuli = 0 and week < 6 and nerdstudynight['day'] ! daystart and hour > 14 and SchoolAtestat = 0:
		'The nerds are sitting at a table studying together.'
	end

	if mid($start_type,1,2) = 'sg' and kanikuli = 0 and week > 5 and hour >= 12 and hour < 14:
		if nataliaQW['library_day_check'] ! daystart:
			nataliaQW['library_day_check'] = daystart
			if rand(0,3) = 0: nataliaQW['library_day'] = daystart
		end
		if nataliaQW['library_day'] = daystart:
			'You see your classmate <a href="exec: gt ''natalia_pavlova'',''library''">Natalia Pavlova</a> sitting alone at one of the tables.'
		end
	end

	act 'Leave': gt 'pav_commcenter'
	act 'Go to the toilets': gt 'gdktoilet', 'start'

	if nerd_game['game_day'] = daystart and hour = 19: act 'Wait for game night to start': minut = 60 & gt 'pav_library'
	if nerd_game['game_day'] = daystart and hour = 20: act 'Join the nerds': gt 'nerd_game_night', 'game'

	if hour <= 7 or hour >= 18:
		'The library is closed.'
		exit
	end

	'Between the bookshelves are some tables which can be used for studying. Some of them have <a href="exec: gs ''internet_mobile'', ''get_access'', ''free'', ''noporn'',''nocamshow'' & gs ''internet_mobile'', ''add_limitation'', ''general-text'', ''On this public computer all adult content sites are blocked'' & gt ''Komp'',''start''">computers</a> for public use.'
	if lernHome > 0: 'You could do your homework with the help of one of the computers.'

	act 'Read a book': gt 'pav_library', 'read'
	act 'Borrow a book': gt 'pav_library', 'loan'

	act 'Study for an hour':
		*clr & cla
		menu_off = 1
		gs 'library_functions', 'read_book'
		lern += rand(1, 3)
		grupvalue[3] += 2
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/pc/items/accessories/books/learning' + rand(1,3) + '.jpg"></center>'
		'You read several books that should help you with your school work, you feel that you learned something today.'
		act 'Put the book back': gt 'pav_library'
	end

	if lernhome > 0:
		gs 'willpower', 'chore', 'self', iif(grupTipe = 4 and pcs_traits['nerd_status'] = 0, 'hard', iif(pcs_traits['nerd_status'] > 0, 'easy', 'medium'))
		if pcs_traits['nerd_status'] = 2: will_cost = will_cost / 2
		if pcs_willpwr < will_cost and pcs_traits['nerd_status'] < 3:
			act 'Do your homework (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
		else
			act 'Do your homework (1:00' + iif(pcs_traits['nerd_status'] = 3, '', ' and <<will_cost>> Willpower')+')':
				*clr & cla
				minut += 60
				pcs_mood += 5 * pcs_traits['nerd_status']
				lern += 1

				gs 'willpower', 'chore', 'self', iif(grupTipe = 4, 'hard', iif(pcs_traits['nerd_status'] > 0, 'easy', 'medium'))
				if pcs_traits['nerd_status'] = 2: will_cost = will_cost / 2
				if pcs_traits['nerd_status'] < 3: gs 'willpower', 'pay', 'self'
				gs 'stat'
				gs 'grades', 'homework', 'school', 'yes', 1, 0, 0

				'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/library/homework.jpg"></center>'
				'You sit down at one of the tables with a computer and use it to help you do your homework.'
				'After an hour, you''ve '+iif(lernHome = 0, 'completed', 'done a part of')+' your homework.'

				act 'Get up from the table': gt 'pav_library'
			end
		end
	end

	if mid($start_type,1,2) = 'sg' and kanikuli = 0 and week < 6 and nerdstudynight['day'] ! daystart and hour > 14 and SchoolAtestat = 0 and SchoolBlock = 0 and (class['school_grades_above_40'] + class['school_grades_above_70'] + class['school_grades_above_90'] <= 20 or grupTipe = 3):
		act 'Join the nerd''s study group': gt 'pav_library_nerdstudy', 'nerd_study_night'
	end
end

if $ARGS[0] = 'read':
	gs 'shortgs', 'setloc', 'pav_library', 'read'

	'<center><b><font color="maroon">Community center library</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/library/gdkbibl.jpg"></center>'

	act 'Leave': gt 'pav_commcenter'

	if hour >= 18:
		!! Note find stern librarian image
		'The librarian finds you still reading and shooshes you out of the library'
		exit
	end

	act 'Go back': gt 'pav_library'
	gs 'library_functions', 'set_library_read_acts'
end

if $ARGS[0] = 'loan':
	gs 'shortgs', 'setloc', 'pav_library', 'loan'

	'<center><b><font color="maroon">Community center library</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/library/gdkbibl.jpg"></center>'

	act 'Leave': gt 'pav_commcenter'

	if hour >= 18:
		'The library is closing for the night.'
		exit
	end

	act 'Go back': gt 'pav_library'
	gs 'library_functions', 'set_loan_acts'
end

--- pav_library ---------------------------------