glife/locations/post_office.qsrc

# post_office

if $ARGS[0] = 'leave':
	if $region = 'city':
		gt 'city_center'
	else
		gt 'pav_commercial'
	end
end


if $ARGS[0] = 'start':
	*clr & cla
	$menu_loc = 'post_office'
	$menu_arg = 'start'
	menu_off = 0
	gs 'stat'

	act 'Leave': minut += 3 & gt 'post_office', 'leave'

	if (hour >= 9 and hour <= 10) or (hour >= 15 and hour <=16):

		'<center><b><font color="maroon">Post Office</font></b></center>'
		'<center><img <<$set_imgh>> src="images/locations/shared/postoffice/city.jpg"></center>'
		'It is currently very busy and it looks like you''ll have to wait your turn to get to the counter.'

		act 'Wait in line (0:30)':
			cla
			minut += 30
			gs 'stat'
			gt 'post_office', 'counter'
		end

		if exhibitionist_lvl > 2:
			gs 'willpower', 'exhib', 'self', 'hard'
			if will_cost <= pcs_willpwr:
				act 'Flash both your tits and your pussy to skip the line (<<will_cost>> Willpower)':
					*clr & cla
					gs 'willpower', 'exhib', 'self', 'hard'
					gs 'willpower', 'pay', 'self'
					menu_off = 1
					gs 'flash', 'full', 'inside', 1
					gs 'stat'

					act 'Go to the counter': gt 'post_office', 'counter'
				end
			else
				act 'Flash both your tits and your pussy to skip the line (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
			end
		end

		if exhibitionist_lvl > 1:
			gs 'willpower', 'exhib', 'self'
			if will_cost <= pcs_willpwr:
				act 'Flash your pussy to skip the line (<<will_cost>> Willpower)':
					*clr & cla
					gs 'willpower', 'exhib', 'self'
					gs 'willpower', 'pay', 'self'
					menu_off = 1
					gs 'flash', 'pussy', 'inside', 1
					gs 'stat'

					act 'Go to the counter': gt 'post_office', 'counter'
				end
			else
				act 'Flash your pussy to skip the line (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
			end
		end

		if exhibitionist_lvl > 0 or pcs_inhib >= 45:
			gs 'willpower', 'exhib', 'self', 'easy'
			if will_cost <= pcs_willpwr:
				act 'Flash your tits to skip the line (<<will_cost>> Willpower)':
					*clr & cla
					gs 'willpower', 'exhib', 'self', 'easy'
					gs 'willpower', 'pay', 'self'
					menu_off = 1
					gs 'flash', 'tits', 'inside', 1
					gs 'stat'

					act 'Go to the counter': gt 'post_office', 'counter'
				end
			else
				act 'Flash your tits to skip the line (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
			end
		end

		if exhibitionist_lvl > 0:
			gs 'willpower', 'bj', 'self'
			if will_cost <= pcs_willpwr:
				act 'Offer a blowjob in exchange for jumping the queue (<<will_cost>> Willpower)':
					*clr & cla
					gs 'willpower', 'bj', 'self'
					gs 'willpower', 'pay', 'self'
					menu_off = 1
					if cumloc[11] = 0:
						gs 'npcgeneratec', 0, 'stranger', rand(18,45)
						gs 'boyStat', $npclastgenerated
						inhib_exp += rand(2,5)
						gs 'arousal', 'bj', 10, 'sub'
						gs 'stat'

						act 'Cum on your face':
							*clr & cla
							if pcs_haircol = 0:
								$cum_face_image = 'black/' + rand(1,23)
							elseif pcs_haircol = 1:
								$cum_face_image = 'brown/' + rand(1,31)
							elseif pcs_haircol = 2:
								$cum_face_image = 'red/' + rand(1,19)
							elseif pcs_haircol = 3:
								$cum_face_image = 'blonde/' + rand(1,25)
							else
								$cum_face_image = 'custom/' + rand(1,20)
							end
							'<center><img <<$set_imgh>> src="images/pc/body/cum/cumface/<<$cum_face_image>>.jpg"></center>'
							'The man cums on your face.'
							gs 'cum_call', 'face', 'stranger'
							gs 'arousal', 'end'
							gs 'stat'

							act 'Go to the counter': gt 'post_office', 'counter'
						end

						act 'Cum in your mouth':
							*clr & cla
							'<center><img <<$set_imgh>> src="images/locations/shared/postoffice/sex/cumlip.jpg"></center>'
							'The man cums inside your mouth.'
							gs 'cum_call', 'mouth', 'stranger'
							gs 'arousal', 'end'
							gs 'stat'

							act 'Go to the counter': gt 'post_office', 'counter'
						end

					else
						minut += 5
						gs 'pain', 4, 'tummy', 'hit'
						gs 'stat'
						'<center><video autoplay loop src="images/locations/shared/postoffice/punch.mp4"></video></center>'
						'The man punches you in the gut. "Go away bitch, your face is covered in cum!"'
						'You quickly stagger away.'

						act 'Recover': minut += rand(3, 5) & gt 'post_office', 'leave'
					end
				end
			else
				act 'Offer a blowjob in exchange for jumping the queue (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
			end
		end
	else
		'<center><b><font color="maroon">Post Office</font></b></center>'
		'<center><img <<$set_imgh>> src="images/locations/shared/postoffice/city.jpg"></center>'
		'It is currently quiet and you can walk straight up to the counter.'

		act 'Go to the counter':
			gt 'post_office', 'counter'
		end
	end

	if $region = 'pav': act 'Go to the Postmaster''s office': gt 'post_master', 'start'
end

if $ARGS[0] = 'counter':
	*clr & cla
	$menu_loc = 'post_office'
	$menu_arg = 'counter'
	menu_off = 0
	'<center><b><font color="maroon">Counter</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/shared/postoffice/counter.jpg"></center>'
	'There''s nothing interesting happening. It''s rather boring here.'

	act 'Leave': minut += 3 & gt 'post_office', 'leave'

	if bankAccount = 1 and money > 0:
		act 'Deposit money into your bank account':
			cla
			menu_off = 1
			minut += 5
			gs 'stat'

			gs 'bank', 'deposit_cash'

			'"Is there anything else I can do for you?"'

			act 'Leave the post office': minut += 3 & gt 'post_office', 'leave'
			act 'Yes': gt 'post_office', 'counter'
		end
	end

	if policeQW['legal_fine'] > 0:
		act 'Pay your fine(s)':
			menu_off = 1
			gs 'stat'
			fineIN = input ('How much do you want to pay off?')

			if fineIN <= 0 or fineIN > money:
				'Invalid operation.'

			elseif fineIN >= policeQW['legal_fine']:
				money -= policeQW['legal_fine']
				policeQW['legal_fine'] = 0
				policeQW['missed_fine_deadlines'] = 0
				policeQW['fine_deadline'] = 0
				policeQW['arrest_gameover_flag'] = 0
				'<br>You pay the full amount of your outstanding fine(s) to the cashier and they print out a receipt to say that it''s paid off.'

			else
				policeQW['legal_fine'] -= fineIN
				money -= fineIN
				'<br>You pay <<fineIN>> <b>₽</b> of your legal fine(s). You have <<policeQW[''legal_fine'']>> <b>₽</b> still outstanding.'
			end
			killvar 'fineIN'
		end

		if money >= policeQW['legal_fine']:
			act 'Pay off your fine(s)':
				*clr & cla
				menu_off = 1
				money -= policeQW['legal_fine']
				policeQW['legal_fine'] = 0
				policeQW['missed_fine_deadlines'] = 0
				policeQW['fine_deadline'] = 0
				policeQW['arrest_gameover_flag'] = 0
				gs 'stat'
				'<center><b><font color="maroon">Counter</font></b></center>'
				'<center><img <<$set_imgh>> src="images/locations/shared/postoffice/counter.jpg"></center>'
				'You pay the full amount of your outstanding fine(s) to the cashier and they print out a receipt to say that it''s paid off.'

				act 'Done': gt 'post_office', 'counter'
			end
		end
	end

	if used_pattest > 0:
		act 'Send paternity test (20,000 <b>₽</b>)':
			menu_off = 1
			if money >= 20000:
				dynamic $send_test
				*clr & cla
				gs 'stat'
				'You pay the fee for the testing, then mail your used paternity test to the lab in Saint Petersburg with the copy of your receipt of payment. You will get answer by SMS within a week.'
			else
				'Unfortunately, you have no money to submit the test. They would just throw it out without the receipt of payment.'
			end
			act 'Done': gt 'post_office', 'counter'
		end
	end

	act 'Check received mail':
		*clr & cla
		menu_off = 1
		gs 'stat'
		minut += 5
		if mail[$region] <= 0 and mail['all'] <= 0:
			'You have no mail.'
		else
			'You have mail.'
			act 'Pickup your mail': gt 'post_office', 'pickup_mail'
		end

		'"Is there anything else I can do for you?"'

		act 'Yes': gt 'post_office', 'counter'
		act 'Leave the post office': minut += 3 & gt 'post_office', 'leave'
	end

	i = 0

!!{	*pl '<center><table align="center">'

	:loopcard

	if i = 0:
		n = 5
		price = 60
		$buy_link = '<a' + iif(money >= 60, ' href="exec: gs ''$buy_item'', <<n>>, ''hours of internet access'', <<price>>, ''internet'', ''post_office''">buy ','>buy ') +'</a>'
	elseif i = 1:
		n = 10
		price = 115
		$buy_link = '<a' + iif(money >= 115, ' href="exec: gs ''$buy_item'', <<n>>, ''hours of internet access'', <<price>>, ''internet'', ''post_office''">buy ','>buy ') +'</a>'
	elseif i = 2:
		n = 20
		price = 220
		$buy_link = '<a' + iif(money >= 220, ' href="exec: gs ''$buy_item'', <<n>>, ''hours of internet access'', <<price>>, ''internet'', ''post_office''">buy ','>buy ') +'</a>'
	elseif i = 3:
		n = 50
		price = 520
		$buy_link = '<a' + iif(money >= 520, ' href="exec: gs ''$buy_item'', <<n>>, ''hours of internet access'', <<price>>, ''internet'', ''post_office''">buy ','>buy ') +'</a>'
	end

	i += 1

	'<tr><td align="center"><<n>> hour internet card </td><td align="right">(you have <<internet>> hours of internet access) </td><td align="right"><<$buy_link>> </td><td align="left">for <<price>> <b>₽</b></td></tr>'

	if i < 4: jump 'loopcard'

	'</table></center>'

	if money > 0:
		act 'Put the money on the phone':
			cla
			menu_off = 1
			minut += 5
			obmennik = input ("How much <b>₽</b> do you want to deposit?")

			if obmennik <= 0:
				'<center><br><b>Invalid operation.</b></center>'
				act 'Return': gt 'post_office', 'counter'
			else
				if money < obmennik:
					'<center><br>You do not have <b><<obmennik>></b> <b>₽</b>.</center>'
					act 'Return': gt 'post_office', 'counter'
				end

				if money >= obmennik:
					set balans = balans + obmennik
					set money = money - obmennik
					clr
					gs 'stat'
					'<center><br>You put <b><<obmennik>></b> <b>₽</b> to the account.</center>'

					'"Is there anything else I can do for you?"'

					act 'Yes': gt 'post_office', 'counter'
					act 'Leave the post office': gt 'post_office', 'counter'
				end
			end
		end
	end
}
!!{	Might use for the city branch, but seems ott for Pav
	if askWork = 0 and $region = 'pav':
		act 'Ask for work':
			*clr & cla
			askWork += 1
			minut += 5
			gs 'stat'
			'You approach the counter and greet the girl there. "Excuse me, I hear you''re looking for postal workers?"'
			'She nods understandingly. "We''re looking for new workers and I''d hire you in an instant, but unfortunately it''s not up to me. You should go see Oleg Koltsov, the postmaster. He''s usually in his office between 12:00 and 14:00. I bet he''ll hire you! Good luck when you see him!"'
			act 'Step away from the counter': gt 'post_office', 'start'
		end
	end
}
end

if $ARGS[0] = 'pickup_mail':
	'<center><img src="images/locations/shared/postoffice/worker.jpg"></center>'

	if mail[$region] > 0 or mail['all'] > 0:
		'You have <<mail[$region] + mail[''all'']>> pieces of mail left to pickup.'
	else
		'You have collected all your mail.'
	end

	gs 'blackmailer', 'set_post_act'

	act 'Go back': gt 'post_office', 'counter'
	act 'Leave': minut += 3 & gt 'post_office', 'leave'

end



!! Not used for Pav, maybe use for city?
!! Not used currently
if $ARGS[0] = 'post_off':
	*clr & cla
	menu_off = 1
	minut += 30
	gs 'stat'
	'<center><b><font color="maroon">Postmaster Office</font></b></center>'
	!!'<center><img src="images/system/image_needed.png"></center>'
	'An older man sits behind a desk, busy with some paperwork. He''s dressed quite sharply for his position.'

	act 'Exit office': gt 'post_office', 'start'

	if post_wrk = 0:
		act 'Ask for work':
			*clr & cla
			minut += 15
			gs 'stat'
			!!Placeholder text
			'You approach the man''s desk, but he doesn''t look up from his work. With a soft voice, you carefully try to get his attention. "Umm... Excuse me?"'
			'He looks up at you. "Oh I''m sorry, I didn''t hear you come in. Hello, I''m Oleg Koltsov, postmaster at this post office. Is there a problem?"'
			'You smile and shake your head. "No, no problem. I''m actually looking for a job. I hear you''re looking for workers?"'
			'You can feel his eyes exploring your body for a second before he responds. "Yes, we are! We currently only have a part-time vacancy, for sorting the mail. You would be working between these and these hours, give or take. Does that sound good to you?"'

			act '"Sorry, not interested"':
				*clr & cla
				gs 'stat'
				'"I need to think about it if it''s okay?" you reply.'
				'"Sure. Come back when you''ve made up your mind."'

				act 'Exit office': gt 'post_office', 'start'
			end

			act '"That sounds great!"':
				*clr & cla
				post_wrk += 1
				gs 'stat'
				!!Placeholder text
				'You beam. "That sounds fantastic, thank you so much!"'
				'Oleg gives you a friendly smile, happy to have found another potential worker. He quickly writes some of your personal data down.'
				'"If you want to work a shift, you need to be here between this time. There''s no point in you getting changed just for 20 minutes of work."'
				'You give him a handshake as you get ready to leave. "Okay. Thank you sir!"'

				act 'Exit office': gt 'post_office', 'start'
			end
		end
	end
end

--- post_office ---------------------------------