glife/locations/shop.qsrc

# shop
!! This is the supermarket, located in several places

!! Main entrance
if $ARGS[0] = 'start':
	$menu_loc = 'shop'
	$menu_arg = 'start'
	menu_off = 0
	CLOSE ALL
	$location_type = 'public_indoors'
	gs 'themes', 'indoors'
	if sound = 0:PLAY 'sound/shop.mp3',30
	$shoplocation = 'main'
end

if $ARGS[0] = 'start' or $ARGS[0] = 'move': minut += 1

!! Main area
if $shoplocation = 'main':
	if $loc = 'shop': $loc = $loc_bak
	*clr & cla
	'<center><b><font color="maroon">Supermarket</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/shared/store/shop.jpg"></center>'

	if hour < 8 or hour > 20:
		'The supermarket is currently closed.'

		if $loc = 'shop':
			if $loc_bak = 'shop':
				$loc = 'city_trademission'
			else
				$loc = $loc_bak
			end
		end

		act 'Leave the store': minut += 3 & gt $loc
		exit
	end

	'An <a href="exec:$shoplocation = ''ATM'' & gt ''shop'', ''move''">ATM</a>, from which you can withdraw money from your bank account, stands against a wall.'
	'There is a branch of the communications giant <a href="exec:$shoplocation = ''megafon'' & gt ''shop'', ''move''">MegaFon</a>.'
	'A <a href="exec: gs ''noticeboard'',''start''">Public notice board</a>, where you can check various private and official advertisements, is sitting on a nearby wall.'
	'<br>Most of the space in the supermarket is taken up by the <a href="exec:$shoplocation = ''grocery'' & gt ''shop'', ''move''">grocery department</a>, but the store has many smaller departments as well.'
	'These include <a href="exec:$shoplocation=''cosmetics'' & gt ''shop'', ''move''">cosmetics</a>, <a href="exec:$shoplocation = ''hardware'' & gt ''shop'', ''move''">hardware</a>, <a href="exec:$shoplocation = ''clothing'' & gt ''shop'', ''move''">clothing</a> and <a href="exec:$shoplocation = ''tech'' & gt ''shop'', ''move''">household appliances</a>. Not far from the entrance is a <a href="exec:$shoplocation = ''icecream'' & gt ''shop'', ''move''">counter selling ice cream</a>.'

	gs 'stat'
	gs 'themes', 'indoors'
	gs 'family_schedule'

	!! The store in the town and in the altstart only
	if $loc = 'pav_commercial':
		if locat['Anya'] = 7:
			*nl
			'Your sister <a href="exec:$shoplocation = ''Anya'' & gt ''shop'', ''move''">Anya</a> is sitting at the cash register.'
		end
	end

	!! Store in the residential district
	if $loc = 'city_residential':
		if rand(1, 20) = 20:
			if dimaQW = 0:
				'A man is standing by the entrance, looking at you appreciatively.'
				act 'Return the look':gt 'event', 'dima'
			elseif dimaQW = 1:
				'You notice Dima nearby and are frozen with fear. You want to run, but your legs won''t respond.'
				'Your heart thumps in your chest, your vision narrows and you feel faint.'
				act 'Pass out':gt 'event', 'scoreslut1'
			else
				'You meet the same Dima whose friend fucked and abused you. Dima grins confidently. "Hello there..."'

				act 'Hello':
					cla
					'"Come with me. My wife''s away..." he says with a grin.'

					gs 'willpower', 'sex', 'resist'
					if pcs_willpwr < will_cost:
						act 'No (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
					else
						act 'No (<<will_cost>> Willpower)':
							gs 'willpower', 'pay', 'resist'
							gt 'shop', 'start'
						end
					end

					act 'I deserve this':
						*clr & cla

						if rand(1, 2) = 1:
							cla
							'Dima takes you to his house and orders you to lie across the sofa. You get into position and he calls you a bitch before he starts fucking you in the mouth.'
							'<center><img <<$set_imgh>> src="images/locations/city/residential/street/sex/gostdt2.jpg"></center>'
							'Dima finally finishes in your mouth. You obediently swallow and lick the remnants of sperm off his cock.'

							gs 'arousal', 'bj', 10, 'sub', 'deepthroat', 'humiliation'
							gs 'arousal', 'end'
							gs 'cum_call', 'mouth_swallow', 'A169', 1
							gs 'stat'

							act 'Leave': minut += 3 & gt 'city_residential'

						else
							cla
							gs 'pain', 6, 'asscheeks', 'slap'
							spank += 1

							'Dima brings you to his house and begins to kiss and undress you in the hall. Once you''re naked, he takes you to the bathroom.'
							'He unscrews the showerhead and shoves the hose in your ass. You feel the rush of water quickly filling you before Dima sits you on the toilet. After the rough enema, he bends you over and inserts his dick into your ass.'
							'<center><img <<$set_imgh>> src="images/locations/city/residential/street/sex/gostanal2.jpg"></center>'
							'He fucks and slaps your ass for a few minutes before he moans and you feel a warmth filling your ass.'

							gs 'arousal', 'anal', 30, 'sub', 'rough', 'humiliation'
							gs 'arousal', 'end'
							gs 'cum_call', 'anus', 'A169', 1
							gs 'stat'

							act 'Leave': minut += 3 & gt 'city_residential'
						end
					end
				end
			end
		end
	end

	'<br>The store is crowded with shoppers.'

	!! This is connected to the trade mission
	if TorgPredZ > 0:
		!! the location of the shop hasn''t been done today
		if ($loc = 'city_residential' and StreetShopTPday ! daystart) or ($loc = 'city_industrial' and nordShopTPday ! daystart) or ($loc = 'city_mall' and downShopTPday ! daystart):
			act 'Promote products':
				*clr & cla
				if $loc = 'city_residential': StreetShopTPday = daystart
				if $loc = 'city_industrial': nordShopTPday = daystart
				if $loc = 'city_mall': downShopTPday = daystart

				mtprand = rand(40, 130)
				minut += mtprand
				TorgPredZ -= 1
				TorgPredZV += 1
				gs 'stat'

				'<center><img <<$set_imgh>> src="images/locations/shared/store/shop.jpg"></center>'
				'You promote the products for quite a while, and when you finally finish, you go to the cashier and tell them that they sold.'

				act 'Leave': gt 'shop', 'start'
			end

		end
	end

	act 'Leave the store': minut += 3 & gt $loc
	exit
end


if $shoplocation = 'ATM':
	'<center><b><font color="maroon">ATM</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/shared/store/atm.jpg"></center>'

	if bankAccount = 0:
		'You don''t have a bank account yet!'
	else
		if karta >= bankDebtLimit:
			'You have <<karta - bankDebtLimit>> <b>₽</b> in your account.'
			'You have an overdraft limit of <font color="blue"><<bankDebtLimit>></font>!'
		else
			'You are overdrawn by <font color="red"><<bankDebtLimit - karta>> <b>₽</b></font>.'
			'You have a remaining credit limit of <font color="blue"><<karta>></font>!'
		end

		'<br>ATM Deposit Fee: 100 <b>₽</b>'

		if bankAccount = 1 and money > 0:
			act 'Deposit money into your bank account':
				cla
				menu_off = 1
				minut += 5
				gs 'stat'

				gs 'bank', 'deposit_cash'

				'"Is there anything else I can do for you?"'

				act 'Move away': gt 'shop', 'start'
			end
		end

		if karta <= 0:
			'You have maxed out your overdraft.'
		else
			act 'Withdraw money from the ATM':
				cla
				minut += 5

				kartaOUT = input ("How much money do you want to withdraw?")
				if kartaOUT <= 0 or kartaOUT > karta:
					'<br>Invalid operation.'
				else
					karta -= kartaOUT
					money += kartaOUT
					if karta > bankDebtLimit:
						'<br>You withdraw <<kartaOUT>> <b>₽</b>. You have <<karta - bankDebtLimit>> <b>₽</b> left in your bank account.'
					elseif karta = 0:
						'<br>You withdraw <<kartaOUT>> <b>₽</b>. You have no money left in your bank account.'
					else
						'<br>You withdraw <<kartaOUT>> <b>₽</b>. <font color="red">Your bank account is overdrawn by <b><<bankDebtLimit - karta>> ₽</b>.</font>'
					end
				end

				gs 'stat'
				act 'Move away': gt 'shop', 'start'
			end
		end
	end

	act 'Move away':gt 'shop', 'start'
end

if $shoplocation = 'grocery':
	$loc_s = 'shop'
	$args_s = 'grocery'
	*clr & cla


	if hour < 8 or hour > 20:
		'The grocery department is currently closed.'

		act 'Leave': gt 'shop', 'start'
		exit
	end

	gs 'item_cart', 'shoppping_aisle', 'food'
	gs 'stat'
	gs 'themes', 'indoors'

	$backimage= 'images/locations/shared/store/shop1.jpg'

	act 'Leave the grocery department': gt 'shop', 'start'
	act 'Go to the pet aisle': gt 'shop', 'dog_items'

	if $loc = 'city_mall': gs 'shoplifting', 'city'
end

if $ARGS[0] = 'dog_items':
	*clr & cla
	minut += 1
	menu_off = 1
	$location_type = 'public_indoors'
	gs 'stat'

	'<center><img <<$set_imgh>> src="images/characters/shared/rex/pet_isle.jpg"></center>'
	'You''re currently in the pet aisle, where you can buy food, treats and other things for your dog.'

	act 'Leave': gt 'shop', 'start'

	if $home['current'] ! 'parents_home':
		act 'Buy dog food':
			*clr & cla
			minut += 1
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/characters/shared/rex/dog_food.jpg"></center>'
			'The store sells dog food for 600 <b>₽</b>. Inside each pack is enough food for 20 meals. You have <<objects[''dog_food'']>>.'

			if money < 600:
				'<br>You don''t have enough money to buy food.'
			else
				act 'Buy enough for 20 meals (600 <b>₽</b>, pay cash)':
					money -= 600
					objects['dog_food'] += 20
					gt 'shop', 'dog_items'
				end
			end

			if money >= 1200:
				act 'Buy enough for 40 meals (1200 <b>₽</b>, pay cash)':
					money -= 1200
					objects['dog_food'] += 40
					gt 'shop', 'dog_items'
				end
			end

			if money >= 2400:
				act 'Buy enough for 80 meals (2400 <b>₽</b>, pay cash)':
					money -= 2400
					objects['dog_food'] += 80
					gt 'shop', 'dog_items'
				end
			end
		end
	else
		'<br>You don''t need to buy dog food. Your parents pay for it.'
	end

	act 'Buy some dog treats':
		*clr & cla
		minut += 1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/characters/shared/rex/treat_'+rand(0,2)+'.jpg"></center>'
		'The store sells dog treats for 300 <b>₽</b>. Inside each pack are 20 treats. You have <<objects[''treats'']>>.'

		act 'Go back': gt 'shop', 'dog_items'

		if money < 300:
			'You don''t have enough money to buy a pack.'
		else
			act 'Buy a pack (300 <b>₽</b>, pay cash)':
				money -= 300
				objects['treats'] += 20
				gt 'shop', 'dog_items'
			end
		end
	end

	act 'Buy a chew toy for your dog':
		*clr & cla
		minut += 1
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/characters/shared/rex/chew.jpg"></center>'
		'The store sells a chew toy for 800 <b>₽</b>.'

		act 'Go back': gt 'shop', 'dog_items'

		if money < 800:
			'You don''t have enough money to buy it.'
		else
			act 'Buy one (800 <b>₽</b>, pay cash)':
				money -= 800
				objects['chew'] += 10
				gt 'shop', 'dog_items'
			end
		end
	end

	if objects['toys'] = 0:
		act 'Buy fetch balls':
			*clr & cla
			minut += 1
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/characters/shared/rex/balls.jpg"></center>'
			'The store sells rubber balls for 900 <b>₽</b> that you can use to play fetch with your dog.'

			act 'Go back': gt 'shop', 'dog_items'

			if money < 900:
				'You don''t have enough money to buy them.'
			else
				act 'Buy them (900 <b>₽</b>, pay cash)':
					money -= 900
					objects['toys'] = 1
					gt 'shop', 'dog_items'
				end
			end
		end
	end
end


if $shoplocation= 'cosmetics':
	$loc_s = 'shop'
	$args_s = 'cosmetics'
	*clr & cla

	if hour < 8 or hour > 20:
		'The cosmetics department is currently closed.'

		act 'Leave': gt 'shop', 'start'
		exit
	end

	gs 'item_cart', 'shoppping_aisle', 'beauty'
	gs 'stat'
	gs 'themes', 'indoors'

	$backimage= 'images/locations/shared/store/shop2.jpg'

	act 'Leave the cosmetics department': gt 'shop', 'start'
	if $loc = 'city_mall': gs 'shoplifting', 'city'
	if $loc = 'pav_commercial':gs 'shoplifting', 'pav'
end


if $shoplocation = 'hardware':
	$loc_s = 'shop'
	$args_s = 'hardware'
	*clr & cla

	if hour < 8 or hour > 20:
		'The hardware department is currently closed.'

		act 'Leave':gt 'shop', 'start'
		exit
	end

	gs 'item_cart', 'shoppping_aisle', 'hardware'
	gs 'stat'
	gs 'themes', 'indoors'

	$backimage= 'images/locations/shared/store/shop3.jpg'

	act 'Leave the hardware department': gt 'shop', 'start'

	if pod_whore_countQW > 15 and paint_blue = 0 and money >= 200:
		act 'Buy paint to cover graffiti (200 <b>₽</b>)':
			money -= 200
			paint_blue = 1
			gt 'shop', '<font color="green">You bought a tin of paint.</font>'
		end
	end
end


if $shoplocation = 'clothing':
	*clr & cla
	'<center><b><font color="maroon">Department of Women''s Clothing</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/shared/store/shop4.jpg"></center>'
	'This department only sells cheap underwear and ice skates.'

	if hour < 8 or hour > 20:
		'The women''s clothing department is currently closed.'

		act 'Leave':gt 'shop', 'start'
		exit

	else
		'Women''s panties and bras 300<b>₽</b> each'
		gs 'stat'
		gs 'themes', 'indoors'

		act 'Leave the women''s clothing department': gt 'shop', 'start'

		act 'View underwear': $shoplocation = 'underwear' & gt 'shop'

		if mc_inventory['ice_skates'] ! 1:
			'A pair of ice-skates are available for 3000 <b>₽</b>.'
			if money >= 3000:
				act 'Buy ice skates (3000 <b>₽</b>)':
					*clr & cla
					money -= 3000
					mc_inventory['ice_skates'] = 1

					'<center><img <<$set_imgh>> src="images/locations/pavlovsk/lake/konki_shop.jpg"></center>'
					'You buy a pair of ice skates.'

					act 'Move away from the counter': gt'shop'
				end
			end
		end

		if mc_inventory['ski'] ! 1:
			'A pair of skis and poles are available for 4000 <b>₽</b>.'
			if money >= 4000:
				act 'Buy skis (4000 <b>₽</b>)':
					*clr & cla
					money -= 4000
					mc_inventory['ski'] = 1

					'<center><img <<$set_imgh>> src="images/pc/activities/ski_buy.jpg"></center>'
					'You buy a pair of skis and poles.'

					act 'Move away from the counter': gt'shop'
				end
			end
		end
	end
end


!! Women''s clothing underwear viewer
if $shoplocation = 'underwear':
	*clr & cla
	if $loc ! 'shop': $loc_bak = $loc
	$loc = 'shop'
	'<center><B>Click on an item to view details</B></center>'

	if gm_panties[7] = 0: *p '<a href="exec:gt ''panties'', ''view_panty_item'', ''shop'', ''gm'', 7, 300"><img src="images/pc/items/gm/panties/7.jpg" 	height="150" /></a>'
	if gm_panties[9] = 0: *p '<a href="exec:gt ''panties'', ''view_panty_item'', ''shop'', ''gm'', 9, 300"><img src="images/pc/items/gm/panties/9.jpg" 	height="150" /></a>'
	if gm_panties[12] = 0: *p '<a href="exec:gt ''panties'', ''view_panty_item'', ''shop'', ''gm'', 12, 300"><img src="images/pc/items/gm/panties/12.jpg" 	height="150" /></a>'
	if gm_panties[21] = 0: *p '<a href="exec:gt ''panties'', ''view_panty_item'', ''shop'', ''gm'', 21, 300"><img src="images/pc/items/gm/panties/21.jpg" 	height="150" /></a>'
	if gm_panties[37] = 0: *p '<a href="exec:gt ''panties'', ''view_panty_item'', ''shop'', ''gm'', 37, 300"><img src="images/pc/items/gm/panties/37.jpg" 	height="150" /></a>'
	*nl
	if gm_bras[11] = 0: *p '<a href="exec:gt ''bras'', ''view_bra_item'', ''shop'', ''gm'', 11, 300"><img src="images/pc/items/gm/bras/11.jpg" 	height="150" /></a>'
	if gm_bras[12] = 0: *p '<a href="exec:gt ''bras'', ''view_bra_item'', ''shop'', ''gm'', 12, 300"><img src="images/pc/items/gm/bras/12.jpg" 	height="150" /></a>'
	if gm_bras[16] = 0: *p '<a href="exec:gt ''bras'', ''view_bra_item'', ''shop'', ''gm'', 16, 300"><img src="images/pc/items/gm/bras/16.jpg" 	height="150" /></a>'
	if gm_bras[18] = 0: *p '<a href="exec:gt ''bras'', ''view_bra_item'', ''shop'', ''gm'', 18, 300"><img src="images/pc/items/gm/bras/18.jpg" 	height="150" /></a>'

	act 'Return':
		$loc = $loc_bak
		$shoplocation = 'clothing'
		gt 'shop'
	end
end


!! Household appliances
if $shoplocation = 'tech':
	$loc_s = 'shop'
	$args_s = 'tech'
	*clr & cla

	if hour < 8 or hour > 20:
		'The household appliance department is currently closed.'

		act 'Leave': $backimage= '' & gt 'shop', 'start'
		exit
	end

	gs 'item_cart', 'shoppping_aisle', 'tech'
	gs 'stat'
	gs 'themes', 'indoors'
	$backimage= 'images/locations/shared/store/shop5.jpg'

	!! mc_inventory['tech_game_ds'] and mc_inventory['tech_webcam'] need a mc_inventory['tech_computer'] requirement
	!! also for some reason mc_inventory['tech_webcam'] doesn't work.
	!! It shows up as an item and you can put it into the item cart but buying it doesn't increase the value of mc_inventory['tech_webcam'].
	!!also having a Plasma TV shows up as having 2 TVs since I couldn''t change TV = 2 to a new variables without changing a lot of code and text.


	act 'Leave the appliance department': $backimage= '' & gt 'shop', 'start'
end


!! Ice cream counter
if $shoplocation = 'icecream':
	'<center><img <<$set_imgh>> src="images/shared/store/icecreamcounter.jpg"></center>'
	'Ice cream is available for 50 <b>₽</b>.'
	act 'Move away from the counter':gt 'shop', 'start'
	if money >= 50:
		act 'Buy ice cream':
			*clr & cla
			money -= 50
			fat += 3
			pcs_mood += 50
			pcs_hydra += 60
			pcs_energy += 30
			cumspclnt = 2
			gs 'cum_cleanup'
			pcs_breath = 0
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/shared/food/icecreem.jpg"></center>'
			'You buy some ice cream and eat it.'

			act 'Move away from the counter':gt 'shop', 'start'
		end
	end
end


if $shoplocation = 'megafon':
	*clr & cla
	minut+=3
	gs'stat'

	'<center><b><font color = maroon>MegaFon shop</font></b></center>'
	'<center><img src="images/system/phone/megafon2.jpg" ></center>'

	$tables = '<center><table>'
	$tablec = '</table></center>'
	if bankAccount = 0: '<center><h4>You need a valid bank account to buy monthly contracts.</h4></center>'
	$title = '<center><h4>Home Internet Subscription</h4></cemter>'
	price = 900
	if $home['current'] = 'parents_home':
		$line = '<tr><td align="center">Your parents are paying for the internet at home, and you can''t take out a second internet subscription for the same address</td></tr>'

	elseif property['internet_enabled'] = 0:
		$line = '<tr><td align="center">You can''t buy an internet subscription for <<$home[''display'']>></td></tr>'

	elseif subscription[$home['current']] = 1:
		$temp_home = '<<$home[''current'']>>-date'
		$line = '<tr><td align="center">You have an active internet subscription at <<$home[''display'']>> that will renew next month on day <<subscription[$temp_home]>> for <<price>> <b>₽</b></td></tr>'
		killvar '$temp_home'

	else
		$line = '<tr><td style="padding-left: 10px; padding-right: 10px; align: left; ">Monthly internet subscription for <<price>><b>₽</b> at your <<$home[''display'']>>. Automatically renews every month</td>'

		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		elseif karta >= price:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''buy_subscription'', ''<<$home[''current'']>>'', <<price>>, 0 & minut += 30 & karta -= <<price>> & gs ''stat'' & gt ''shop'' ">Pay with Card</a></td></tr>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient balance</td></tr>'
		end
	end

	'<<$title>><<$tables>><<$line>><<$tablec>>'

	killvar 'line'
	killvar 'title'

	!! "Returns":
	!! $property_code[], $property_name[], $property_status[], property__is_current_home[]
	!! $property_stat values: 'rented', 'owned', 'tenants', 'no access'
	gs 'homes_properties', 'get_internet_enabled_properties', 'home', 'hasaccess'
	count = ARRSIZE('$property_name')
	if count > 0:
		:propertyloop
			if property__is_current_home[i] = 0:
				$title = '<center><h4>Internet Subscription for your other properties</h4></center>'
				if $property_status[i] = 'tenants':
					$line += '<tr><td align="center">You have rented out the <<LCASE($property_name[i])>> and you don''t have to buy internet for our tenants.</td></tr>'

				elseif subscription[$property_code[i]] = 0:
					$line += '<tr><td style="padding-left: 10px; padding-right: 10px; align: left; ">Monthly internet subscription for <<price>> <b>₽</b> at <<LCASE($property_name[i])>>. Automatically renews every month</td>'
					if bankAccount = 0:
						$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
					elseif karta >= price:
						$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''buy_subscription'', ''<<$property_code[i]>>'', <<price>>, 0 & minut += 30 & karta -= <<price>> & gs ''stat'' & gt ''shop'' ">Pay with card</a></td></tr>'
					else
						$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient balance</td></tr>'
					end

				elseif subscription[$property_code[i]] > 0:
					$line += '<tr><td align="center">You have an active internet subscription for the <<LCASE($property_name[i])>> that will renew next month on day <<subscription[''<<$property_code[i]>>-date'']>> for <<price>> <b>₽</b></td></tr>'
				end
			end
			killvar '$property'

			i += 1
		if i < count: jump 'propertyloop'

		gs 'homes_properties', 'clean_up_property_data'
		killvar 'i' & killvar 'count'
		if $title ! '' : '<<$title>><<$tables>><<$line>><<$tablec>>'
		killvar 'line' & killvar 'title'

	end

	$title = '<center><h4>Mobile Internet Subscription</h4></center>'
	price = 1200
	if subscription['mobile'] = 1:
		$line = '<tr><td align="center">You have an active mobile internet subscription that will renew next month on day <<subscription[''mobile-date'']>> for <<price>><b>₽</b></td></tr>'

	else
		if subscription['metered_mobile'] > 0:
			!! Every 12 minutes gives back 1 ₽
			discount = subscription['metered_mobile'] / 12
			discount_left = max(price - discount, 0)
			$line = '<tr><td align="center">You still a have <b><<subscription[''metered_mobile'']>> ₽</b> balance for your metered mobile internet which gives you a <<discount>> <b>₽</b> discount</td></tr>'
		end
		$line += '<tr><td style="padding-left: 10px; padding-right: 10px; align: left; ">Monthly mobile internet subscription for'+iif(discount > 0, ' <s><<price>></s><<price-discount>>', ' <<price>>')+'<b>₽</b>. Automatically renews every month</td>'

		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		else
			if karta < (price - discount):
				$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient funds</td></tr>'
			else
				$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''buy_subscription'', ''mobile'', <<price>>, <<discount_left>> & gs ''internet_mobile'', ''cancel_subscription'', ''metered_mobile'' & minut += 30 & karta -= <<price-discount>> & gs ''stat'' & gt ''shop'' ">Pay with card</a></td></tr>'
			end
		end
	end

	'<<$title>><<$tables>><<$line>><<$tablec>>'

	killvar 'line'
	killvar 'title'

	$title = '<center><h4>Metered Internet</h4></center>'

	if  subscription['mobile'] = 1:
		$line = '<tr><td align="center">You have an active mobile internet subscription for unlimited use, you can''t buy extra minutes </td></tr>'
		$line += '<tr><td align="left"><b>300 minutes</b> (5 hours) of mobile internet for 80 <b>₽</b></td></tr>'
		$line += '<tr><td align="left"><b>600 minutes</b> (10 hours) of mobile internet for 155 <b>₽</b></td></tr>'
		$line += '<tr><td align="left"><b>1200 minutes</b> (20 hours) of mobile internet for 295 <b>₽</b></td></tr>'
		$line += '<tr><td align="left"><b>3000 minutes</b> (50 hours) of mobile internet for 695 <b>₽</b></td></tr>'

	else
		$line = '<tr><td style="padding-left: 10px; padding-right: 10px; align: left; "><b>300 minutes</b> (5 hours) of mobile internet for 80<b>₽</b></td>'

		if money > 80:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_mobile'', 300 & money -= 80 & minut += 10 & gt ''shop'' ">Pay with cash</a></td>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Not enough cash</td>'
		end

		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		elseif karta >= 80:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_mobile'', 300 & karta -= 80 & minut += 10 & gt ''shop'' ">Pay with card</a></td></tr>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient balance</td></tr>'
		end

		$line += '<tr><td style="padding-left: 10px; padding-right: 10px; align: left; "><b>600 minutes</b> (10 hours) of mobile internet for 155<b>₽</b></td>'

		if money > 155:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_mobile'', 600 & money -= 155 & minut += 10 & gt ''shop'' ">Pay with cash</a></td>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Not enough cash</td>'
		end

		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		elseif karta >= 155:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_mobile'', 600 & karta -= 155 & minut += 10 & gt ''shop'' ">Pay with card</a></td></tr>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient balance</td></tr>'
		end

		$line += '<tr><td style="padding-left: 10px; padding-right: 10px; align: left; "><b>1200 minutes</b> (20 hours) of mobile internet for 295<b>₽</b></td>'

		if money > 295:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_mobile'', 1200 & money -= 295 & minut += 10 & gt ''shop'' ">Pay with cash</a></td>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Not enough cash</td>'
		end

		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		elseif karta >= 295:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_mobile'', 1200 & karta -= 295 & minut += 10 & gt ''shop'' ">Pay with card</a></td></tr>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient balance</td></tr>'
		end

		$line += '<tr><td style="padding-left: 10px; padding-right: 10px; align: left; "><b>3000 minutes</b> (50 hours) of mobile internet for 695<b>₽</b></td>'

		if money > 695:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_mobile'', 3000 & money -= 695 & minut += 10 & gt ''shop'' ">Pay with cash</a></td>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Not enough cash</td>'
		end

		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		elseif karta >= 695:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_mobile'', 3000 & karta -= 695 & minut += 10 & gt ''shop'' ">Pay with card</a></td></tr>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient balance</td></tr>'
		end
	end

	'<<$title>><<$tables>><<$line>><<$tablec>>'

	killvar 'line'
	killvar 'title'

	'<center>You have <b><<subscription[''metered_mobile'']>></b> minutes for mobile internet use</center>'

	$title = '<center><h4>Mobile Calls and Texts</h4></center>'
	price = 800
	if subscription['monthly_calls'] = 1:
		$line += '<tr><td align="center">You have an active mobile subscription that will renew next month on day <<subscription[''monthly_calls-date'']>> for <<price>> <b>₽</b></td></tr>'
	else
		if subscription['metered_calls'] > 0:
			discount = subscription['metered_calls'] / 2
			discount_left = max(price - discount, 0)
			$line += '<tr><td align="center">You have <b><<subscription[''metered_calls'']>>₽</b> for mobile calls and text messages which gives you a <<discount>> <b>₽</b> discount</td></tr>'
		end
		$line += '<tr><td style="padding-left: 10px; padding-right: 10px; align: left;">Monthly mobile subscription that allows you to make calls and send text messages for'+iif(discount > 0, '<b><s><<price>></s></b> <span color="red"><b><<price-discount>></b></span>', ' <b><<price>></b>')+'<b>₽</b> Automatically renews every month</td>'


		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		else
			if karta < (price - discount):
				$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient funds</td></tr>'
			else
				$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''buy_subscription'', ''monthly_calls'', <<price>>, <<discount_left>> & gs ''internet_mobile'', ''cancel_subscription'', ''metered_calls'' & minut += 30 & karta -= <<price>> & gs ''stat'' & gt ''shop'' ">Pay with card</a></td></tr>'
			end
		end
	end
	'<<$title>><<$tables>><<$line>><<$tablec>>'
	killvar 'title'
	killvar 'line'

	$title = '<center><h4>Metered Calls and Texts</h4></center>'

	if subscription['monthly_calls'] = 1:
		$line += '<tr><td>You have an active mobile subscription with unlimited minutes and texts, you can''t buy extra minutes</td></tr>'

	else
		$line += '<tr><td style="padding-left: 10px; padding-right: 10px; align: left;">60<b>₽</b> call pack for your mobile phone that gives you 60 minutes of calltime and 120 text messages</td>'

		if money >= 60:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_calls'', 60, 120 & money -= 60 & minut += 10 & gt ''shop'' ">Pay with cash</a></td>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Not enough cash</td>'
		end

		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		elseif bankAccount = 1 and karta >= 60:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_calls'', 60, 120 & karta -= 60 & minut += 10 & gt ''shop'' ">Pay with card</a></td></tr>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient balance</td></tr>'
		end

		$line += '<tr><td style="padding-left: 10px; padding-right: 10px; align: left;">115<b>₽</b> call pack for your mobile phone that gives you 120 minutes of calltime and 240 text messages</td>'

		if money >= 115:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_calls'', 120, 240 & money -= 115 & minut += 10 & gt ''shop'' ">Pay with cash</a></td>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Not enough cash</td>'
		end

		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		elseif bankAccount = 1 and karta >= 115:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_calls'', 120, 240 & karta -= 115 & minut += 10 & gt ''shop'' ">Pay with card</a></td></tr>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient balance</td></tr>'
		end

		$line += '<tr><td style="padding-left: 10px; padding-right: 10px; align: left;">170<b>₽</b> call pack for your mobile phone that gives you 180 minutes of calltime and 360 text messages</td>'
		if money >= 170:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_calls'', 180, 360 & money -= 170 & minut += 10 & gt ''shop'' ">Pay with cash</a></td>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Not enough cash</td>'
		end

		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		elseif bankAccount = 1 and karta >= 170:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_calls'', 180, 360 & karta -= 170 & minut += 10 & gt ''shop'' ">Pay with card</a></td></tr>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient balance</td></tr>'
		end

		$line += '<tr><td style="padding-left: 10px; padding-right: 10px; align: left;">225<b>₽</b> call pack for your mobile phone that gives you 240 minutes of calltime and 480 text messages</td>'

		if money >= 225:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_calls'', 240, 480 & money -= 225 & minut += 10 & gt ''shop'' ">Pay with cash</a></td>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Not enough cash</td>'
		end

		if bankAccount = 0:
			$line += '<td style="padding-left: 10px; padding-right: 10px;">No bank account</td></tr>'
		elseif bankAccount = 1 and karta >= 225:
			$line += '<td style="padding-left: 10px; padding-right: 10px;"><a href="exec: gs ''internet_mobile'', ''top_up_metered'', ''metered_calls'', 240, 480 & karta -=225 & minut += 10 & gt ''shop'' ">Pay with card</a></td></tr>'
		else
			$line += '<td style="padding-left: 10px; padding-right: 10px;">Insufficient balance</td></tr>'
		end
	end

	'<<$title>><<$tables>><<$line>><<$tablec>>'
	'<center>You have <b><<subscription[''metered_calls'']>> minutes</b> for mobile calls and <<subscription[''sms_limit'']>> text messages</center>'

	killvar 'title'
	killvar 'line'
	killvar 'discount'
	killvar 'discount_left'
	killvar 'price'

	act 'Return to the supermarket': gt 'shop','start'
end

if $shoplocation = 'Anya':
	cla
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/resident/anya/anyabusywork.jpg"></center>'
	gs 'sister_chat', 'checks'
	'"Don''t disturb me at work, <<$pcs_nickname>>! Can''t you see that I have customers?"'
	act 'Move away': gt 'shop','start'
end

--- shop ---------------------------------