glife/locations/stwork.qsrc

# stwork
!!2021/04/15
if $ARGS[0] = 'start':
	$loc = 'stwork'
	$loc_arg = 'start'
	$locM = 'stwork'
	$locM_arg = 'start'
	$sexloc = 'stwork'
	$menu_loc = 'stwork'
	$menu_arg = 'start'
	menu_off = 0
	$location_type = 'private'
	clr
	minut += 5
	stripMir = 1
	gs 'stat'
	gs 'themes', 'indoors'
	killvar '$sexloc'
	CLOSE 'sound/street_club.mp3'
	'<center><b><font color="maroon">Dressing room for strippers</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/backstage' + rand(1,7) + '.jpg"></center>'
	''
	'There are several <a href="exec:gt ''mirror'', ''start''">mirrors</a> hanging on the wall, where you can <a href="exec:gt ''mirror'', ''brush''">brush</a> your hair, and a selection of <a href="exec:gt ''wardrobe'', ''start''">clothes</a> hanging on rails for the girls to dress in.'
	'There are some stairs leading to the <a href="exec:gt ''stwork'', ''stripgirl''">stage</a> where you can head out to perform.'
	if $clothingworntype = 'nude':
		'To the side is a door which overlooks the back yard, used as a staff entrance to save girls from having to deal with scummy customers. Always standing by this entrance is a <a href="exec:gt ''stwork'', ''guard''">security guard</a>, who isn''t going to let you walk outside unless you put some clothes on.'
	else
		'To the side is a <a href="exec:stripMir = 0 & gt ''stripclub'', ''start''">door</a> which overlooks the back yard, used as a staff entrance to save girls from meeting scummy customers. Always standing by this entrance is a <a href="exec:gt ''stwork'', ''guard''">security guard</a> keeping the girls safe.'
	end
	'Near the exit door is a vending machine selling '+iif(money >= 100,'<a href="exec:money -= 100 & gt ''food'', ''snack''">snacks</a>','snacks')+' and a <a href="exec:gt ''beverage'', ''bev_wat''">water cooler</a> which is used heavily by girls coming off stage.'
	'A wooden door leads to the <a href="exec:gt ''stwork'', ''toilet''">staff bathroom</a>.'

	! Tattoos increase your desireability as a stripper
	stripKoef = 0
	if pcs_tattoos['shoulder'] > 0: stripKoef += rand(1, 3)
	if pcs_tattoos['back'] > 0: stripKoef += rand(1, 3)
	if pcs_tattoos['belly'] > 0: stripKoef += rand(1, 3)
	if pcs_tattoos['tramp'] > 0: stripKoef += rand(3, 6)
	if pcs_tattoos['leg'] > 0: stripKoef += rand(1, 3)
	if pcs_tattoos['arm'] > 0: stripKoef += rand(1, 3)
	if pcs_tattoos['side'] > 0: stripKoef += rand(1, 3)
	if countmoney = 1:
		countmoney = 0
		gs 'stwork', 'tipcalculator'
	end

	act 'Exit the club':
		if $clothingworntype ! 'nude':
			gt 'stripclub', 'start'
		else
			msg'<b><font color = red>You need to get dressed.</font></b>'
			gt 'stwork', 'start'
		end
	end
	act 'Go to the staff bathroom':gt 'stwork', 'toilet'
	act 'Change your clothes':gt 'wardrobe', 'start'
	act 'Look in the mirror': gt 'mirror', 'start'
	if money >= 100: act 'Have a snack (0:15) (100 <b>₽</b>)': money -= 100 & gs 'food', 'snack'
	act 'Have a cup of water (0:05)':gs 'beverage', 'bev_wat'

	!! Private dance available
	if stprivatechance > 0:
		stpriv = stripKoef + (pcs_apprnc / 3)
		! Bonus for pole-dancing
		if stprivatechance = 2:
			stpriv += 20
		end
		if stpriv > rand (0, 100):
		*nl
			'One of the bouncers walks up to you, telling you that a customer is waiting for you in one of the private rooms.'
			act 'Perform a private dance':
				stprivatechance = 0
				gt 'stwork2', 'privatdance'
			end
		end
	end

	if 	hour >= 11 or hour <= 2:
		if (mc_inventory['cosmetics'] >= 3 or pcs_makeup >= 4):
			act 'Prepare for your show':
				*clr & cla
				if pcs_sweat >= 20 or (pcs_leghair > 3 or ((pcs_pubes > 3 and pubestyle = 1) or (pubestyle >= 2 and pubestyle <=7) and pcs_pubes > 11)):
					dynamic $showerdin
					minut += 5
					'<h3>Staff Bathroom</h3>'
					'<h5>Shower</h5>'
					'<center><img <<$set_imgh>> src="images/locations/shared/brothel/brothelshower.jpg"></center>'
					dynamic $brit
					*nl
					'After stripping from your clothes, you gather up your towel, washcloth and soap and head to the shower, where you thoroughly wash yourself.'
					if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the shower.'
				end
				if pcs_makeup < 4:
					if mc_inventory['cosmetics'] < 3:
						*nl
						'Once showered, you realize you don''t have enough makeup to go on stage.'
						act 'Go back to the dressing room':gt 'stwork', 'start'
						exit
					end
					gs 'exp_gain', 'makupskl', rand(1,3)
					mc_inventory['cosmetics'] -= 3
					vidageday -= 1
					pcs_makeup = 4
					minut += 5
					'You brush your hair and put on heavy makeup for the customers.'
				end
				pcs_hairbsh = 1
				!!gs 'clothing', 'wear_last_worn'
				!!'You put your clothes back on before heading back onto the stage.'
				if pcs_leghair <= 3:
					if fingal <= 0:
						if strippermission = 0:
							act 'Go to the manager':
								*clr & cla
								'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/stripinspection.jpg"></center>'
								'Before going on stage, you head to the manager''s office for your inspection.'
								if $clothingworntype ! 'nude':
									'"Take off your clothes," he sternly demands.'
									'Once you''re done undressing, he walks up to you and inspects you closely.'
									if pcs_sweat < 20:
										'"Good, you have a clean scent. That is very important in this business."'
										'He briefly runs his hand over your legs.'
										if pcs_leghair <= 3:
											'"Smooth legs. Very good."'
											'He walks around you, looking you up and down from every side.'
											if fingal <= 0:
												'"No bruises. Good. The better you look, the easier it is to make money once you''re on that stage."'
												'"And the last thing. I need to check if you''ve rid yourself of all your pubic hair."'
												'He places his hand on your mound and slowly starts rubbing it, taking a little longer than he did on your legs.'
												'You feel your pussy get a little wet from his touch and hope that he doesn''t notice.'
												gs 'arousal', 'foreplay', 2
												gs 'stat'
												!! This allows different pubic styles but anything from small bush up is still not permitted.
												if (pubestyle = 1 and pcs_pubes <= 3) or lashair = 1:
													strippermission = 1
													'"Very smooth. Good. Looks like you''re ready to get on the stage. You can get to work," he says and ushers you out of his office.'
													stpredmet = 3
													act 'Go back stage': gt 'stwork2', 'strip'
												elseif ((pubestyle >= 2 and pubestyle <=7) or (pubestyle >= 12 and pubestyle <=14)) and pcs_pubes <= 25:
													strippermission = 1
													'"Very cute pubic hair, I''m sure the customers will appreciate it. Now get on stage. You can work," he says and ushers you out of his office.'
													stpredmet = 3
													act 'Go back stage': gt 'stwork2', 'strip'
												else
													'"You need to shave everything off <<$pcs_stagename>>, although a small and cute pubic style is popular at the moment if you feel creative." He smiles and pats you on the ass as he says "Go take care of that and then come back."'
													act 'Go to the dressing room': gt 'stwork', 'start'
												end
											else
												'"I can''t let you up on the stage with a black eye like that. You''ll have to wait until it''s gone. Come back when it''s healed."'
												act 'Go to the dressing room': gt 'stwork', 'start'
											end
										else
											'"Shave your legs! A customer doesn''t want to feel any stubble during a lap dance. Go take care of that and then come back."'
											act 'Go to the dressing room': gt 'stwork', 'start'
										end
									else
										'"Damn it <<$pcs_stagename>>, you stink! Go and take a shower. We can''t have the club smelling like a locker room."'
										act 'Go to the dressing room': gt 'stwork', 'start'
									end
								else
									'You can''t do a striptease if you haven''t got any clothes to strip out of <<$pcs_stagename>>. Find something sexy in the wardrobe first.'
									act 'Go to the dressing room': gt 'stwork', 'start'
								end
							end
						else
							act 'Go back stage':
								stpredmet = 3 & gt 'stwork2', 'strip'
							end
						end
					else
						'You aren''t allowed on stage because of your black eye.'
					end
				else
					'Nobody wants to see a stripper with hairy legs and untrimmed pubes. Have a shave before you go on stage!'
				end
				act 'Leave':gt $loc, $loc_arg
			end
		else
			*nl
			'<font color="red">You don''t have enough make-up to get ready.</font>'
		end
	else
		*nl
		'There are no shows at this time, the stage is open between 11:00 and 2:00.'
	end
	!act '<b>Go back stage</b>':
	!	if hour >= 11 or hour <= 2:
	!		if cumloc[1] = 0 and cumloc[2] = 0 and cumloc[4] = 0 and cumloc[5] = 0 and cumloc[6] = 0 and cumloc[7] = 0 and cumloc[11] = 0 and cumloc[14] = 0:
	!			if pcs_makeup >= 4:
	!				if pcs_hairbsh = 1:
	!					if pcs_sweat < 20:
	!						if pcs_leghair <= 3 and pcs_pubes <= 31:
	!							if fingal <= 0:
	!								stpredmet = 3 & gt 'stwork2', 'strip'
	!							else
	!								'You aren''t allowed on stage due to your black eye.'
	!							end
	!						else
	!							'Nobody wants to see a stripper with hairy legs and untrimmed pubes. Have a shave before you go on stage!'
	!						end
	!					else
	!						'Damn, you stink like a pigsty! Take a shower before going on stage.'
	!					end
	!				else
	!					'The least you can do is brush your hair!'
	!				end
	!			else
	!				'You need to put on very thick makeup if you want people to be impressed by your beauty.'
	!			end
	!		else
	!			'There is some visible semen on your body. Wash yourself before going on stage.'
	!		end
	!	else
	!		'You''re done for today. Time to head home.'
	!	end
	!end
end

if $ARGS[0] = 'tipcalculator':
	*nl
	'You now have a chance to add up any tips you gained from your last show.'
	!20% chance that tattoos increase tips
	if rand (0, 4) = 0:
		striptip += stripKoef
	end
	if striptip < 25:
		'Nobody even noticed you or your efforts on the stage and it''s no surprise you got nothing for your efforts.'
	elseif striptip < 40:
		'A few people looked at you, but you didn''t receive a single tip.'
	elseif striptip < 55:
		'A few people looked at you, but you didn''t receive any tips.'
	elseif striptip < 70:
		if rand(0,5) = 0:
			'The customers were pleased with your performance, but not enough to tip you.'
		else
			paymoneyrand = rand(3,10) * 2
			money += paymoneyrand
			pcs_mood += rand(1,5)
			gs 'stat'
			'The customers were pleased with your performance. They gave you <<paymoneyrand>> <b>₽</b> in tips.'
		end
	elseif striptip < 90:
		if rand(0,10) = 0:
			'The customers followed your movements between their conversations. You deserved some tips, but luck was against you and you got nothing.'
		else
			paymoneyrand = rand(10,(striptip/5)) * 2
			money += paymoneyrand
			pcs_mood += rand(3,10)
			gs 'stat'
			'The customers followed your movements between their conversations. After counting out your tips, it amounts to <<paymoneyrand>> <b>₽</b>.'
		end
	else
		paymoneyrand = rand(20,striptip)
		money += paymoneyrand
		pcs_mood += rand(5,20)
		gs 'stat'
		'The customers were mesmerized by your dancing and tipped you <<paymoneyrand>> <b>₽</b>.'
	end
end

if $ARGS[0] = 'stripgirl':
	*clr & cla
	gs 'stat'
	striptalkrand = rand(0, 10)

	if striptalkrand = 0:$striptalk = '"Have you heard about that new girl? She''s really good-looking and all, but she got booed off-stage. Apparently, she was worthless."'
	if striptalkrand = 1:$striptalk = '"I''m telling you, girls with tattoos are a huge turn-on to men."'
	if striptalkrand = 2:$striptalk = '"Working the pole is much more profitable than just dancing. It''s easier to excite the customer, but it also demands more from the person doing it."'
	if striptalkrand = 3:$striptalk = '"Phew, you really have to leave it all out on the stage, getting back all sweaty, with disheveled hair and makeup ruined. The cost in cosmetics is enough to bankrupt you."'
	if striptalkrand = 4:$striptalk = '"Private dances might be guaranteed money, but the real cash is in the ''extras''."'
	if striptalkrand = 5:$striptalk = '"Remember that ugly girl? She got on stage and got booed hard by the customers, but as soon as she started working the pole, their jaws dropped and she made a fortune in tips."'
	if striptalkrand = 6:$striptalk = '"Did I tell you about the time I forgot it was male night? I rushed about getting ready, even broke a nail, only get here and see those bears up on stage!"'
	if striptalkrand = 7:$striptalk = '"That cute security guard was telling me about the problems the girls face with this job. Half of them become whores in the end because the money is better."'
	if striptalkrand = 8:$striptalk = '"There was a fat woman trying to dance on the pole who fell face first on the floor. I thought she''d knocked herself out! You should have seen the black eye she got!"'
	if striptalkrand = 9:$striptalk = '"We had a comedian work here one time. She was a pretty little thing, and she danced well, but jokes don''t earn you any tips here."'
	if striptalkrand = 10:$striptalk = '"I heard about clubs abroad where the tips are so good that the strippers pay for the right to work there."'
	if striptalkrand = 11:$striptalk = '"I''m telling you, doing the occasional porn shoot on one of your days off is a great way to top up your income."'
	'The girls are doing their makeup and hair in the mirror, laughing and gossiping.'
	'<<$striptalk>>'

	act 'Move away':gt 'stwork', 'start'
end

if $ARGS[0] = 'guard':
	*clr & cla
	gs 'stat'
	if $clothingworntype = 'nude':
		'The bored security guard perks up when you approach him. "Looking good there, <<$pcs_nickname>>."'
		'He doesn''t really have much to say and the conversation quickly turns into an awkward silence.'
	else
		'A bored looking security guard stands by the door. Seeing you, he lazily nods. "Hey <<$pcs_nickname>>."'
	end

	act 'Move away':gt 'stwork', 'start'
end

if $ARGS[0] = 'toilet':
	$location_type = 'bathroom'
	$loc = 'stwork'
	$loc_arg = 'toilet'
	$locM = 'stwork'
	$locM_arg = 'toilet'
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/shared/bathroom/toilet.jpg"></center>'
	*nl
	'You enter a dirty and smelly staff bathroom that''s probably never been cleaned.'
	'There is no mirror, only a grimy shower, toilet and basin.'
	*nl
	if lashair ! 1: 'Your razor will last <b><<mc_inventory[''razor'']>></b> more ' + iif(mc_inventory['razor'] =  1, 'shave', 'shaves') + '. <a href="exec:gs ''din_van'', ''shave_options''">Shave Options</a>'

	act 'Leave the bathroom':gt 'stwork', 'start'
!	if mc_inventory['cosmetics'] >= 3:
!		act 'Have a shower and get ready for work':
!			*clr & cla
!			dynamic $showerdin
!			minut += 10
!			gs 'exp_gain', 'makupskl', rand(1,3)
!			mc_inventory['cosmetics'] -= 3
!			vidageday -= 1
!			pcs_makeup = 4
!			pcs_hairbsh = 1
!			'<h3>Staff Bathroom</h3>'
!			'<h5>Shower</h5>'
!			'<center><img <<$set_imgh>> src="images/locations/shared/brothel/brothelshower.jpg"></center>'
!			*nl
!			'You strip from your clothes and gather up your towel, washcloth and soap before heading to the shower. You wash yourself thoroughly, brush your hair and put on heavy makeup for the customers.'
!			act 'Get out and dry off':gt $loc, $loc_arg
!			dynamic $brit
!		end
!	else
!		'You don''t have enough make-up to get ready.'
!	end
	act 'Have a shower':
		*clr & cla
		dynamic $showerdin
		'<h3>Staff Bathroom</h3>'
		'<h5>Shower</h5>'
		'<center><img <<$set_imgh>> src="images/locations/shared/brothel/brothelshower.jpg"></center>'
		*nl
		'After stripping from your clothes, you gather up your towel, washcloth and soap and head to the shower. You thoroughly wash yourself to be as clean as possible for potential customers.'
		if deodorant_on = 1: gs 'sweat', 'remove_deo' & '<br>Your deodorant gets washed away in the shower.'
		act 'Get out and dry off':gt $loc, $loc_arg
		dynamic $brit
	end

	dynamic $brit
	dynamic $toymanage
	dynamic $enema
	dynamic $tampon
	dynamic $quickwash
	dynamic $basin
	dynamic $publicpan
	gs 'din_van', 'prvt_pee'
end

--- stwork ---------------------------------