Girl-Life-Anjuna/locations/gad_gpyard.qsrc

# gad_gpyard
!2024/05/05 - Mira schedule introduced.
!locat['A60'] = Mira''s location. See 'miroslava_schedule'

if $ARGS[0] = 'start':
	music_loop = 0
	gs 'shortgs', 'setloc', 'gad_gpyard', 'start'
	$location_type = 'public_outdoors'
	menu_off = 0
	killvar '$locclass'
	gs 'miroslava_schedule'
	gs 'stat'
	CLOSE ALL
	gs 'gadukino_event', 'sound'

	'<center><h4>Your grandparents'' yard</h4></center>'

	if month >= 4 and month <= 10:
		if hour >= 6 and hour < 22:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/dvor.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/dvor_night.jpg"></center>'
		end
	else
		if hour >= 8 and hour < 18:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/dvor_winter.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/dvor_winter_night.jpg"></center>'
		end
	end
	*nl
	'A fenced yard behind your grandparents'' house. The yard contains a small barn, garden, root cellar, and banya where you can bathe.'

	if $clothingworntype = 'nude':
		*nl
		'You are naked and can only go into your grandparent''s house to get dressed or go to the banya.'
		act 'Enter your grandparents'' house':minut += 1 & gt 'gad_gphouse', 'start'
		act 'Enter the banya': minut += 1 & gt 'gad_gpbath', 'start'
	else
		if grandmaQW['chore_feed_chickens'] = 1 or (hour >= 6 and hour < 20 and month >= 4 and month <= 10):'In the yard there are several <a href="exec:gt ''gad_gpyard'', ''chickens''">chickens</a> running around.'
		if func('homes_properties', 'is_current_home') and hour > 7 and hour < 20 and rex['owned'] = 1:
			if $status['dog'] = '':
				gt 'pet_dog', 'name'
			else
				if rex['gadukino_day'] ! daystart:
					rex['relationship'] += 2
					rex['gadukino_day'] = daystart
				end
				'<br><a href="exec: gt ''pet_dog'', ''gadukino''"><<$rex[''name'']>></a> is running around in the garden.'
			end
		end
	end

	if MiraVars['guest'] = 1: locat['A60'] = 20 & 'Your friend <a href="exec: gt ''miroslava'', ''Start''">Mira</a> stands next to you.'
	!if locat['A60'] ! 20: MiraVars['guest'] = 0

	act '<b>Leave and go into the village</b>':
		if $clothingworntype ! 'nude':	
			minut += 5
			gt 'gadukino'
		else
			msg'<b><font color = red>You need to get dressed.</font></b>'
			gt 'gad_gpyard', 'start'
		end
	end
	if 	grandpaQW['chore_clean_yard'] = 1:
		act 'Clean up the yard for Grandpa (1:00)':
			*clr & cla
			if month >= 4 and month <= 10:
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/clean_yard1.jpg"></center>'
				'Armed with a rake, you begin cleaning the yard. You''re pleased seeing the yard clean. You return the rake to the shed and continue on with your business.'
			else
				'<center><img <<$set_imgh>> src="images/locations/gadukino/village/clean_yard2.jpg"></center>'
				'Armed with a shovel, you begin clearing the yard of snow. You''re pleased with yourself seeing the courtyard is free of snow. You return the shovel to the shed and continue on with your business.'
			end
			minut += 60
			grandpaQW['chore_clean_yard'] = 2
			if month >= 4 and month <= 10:
				fat -= rand(1,3)
				pcs_stam -= 5
				gs 'sweat', 'add', 10
			else
				gs 'exp_gain', 'stren', 1
				fat -= rand(1,5)
				pcs_stam -= 10
				gs 'sweat', 'add', 5
			end
			gs'stat'
			act 'Finish': gt 'gad_gpyard', 'start'
			act 'Return back to your grandfather': minut += 1 & gt 'gad_gphouse', 'grandpa'
		end
	end
	act 'Enter your grandparents'' house': minut += 1 & gt 'gad_gphouse', 'start'
	act 'Enter the banya': minut += 1 & gt 'gad_gpbath', 'start'
	act 'Go to the barn': minut += 1 & gt 'gad_gpbarn'
	act 'Go to the root cellar': minut += 1 & gt 'gad_gpyard', 'root_cellar'
	act 'Go to the garden': minut += 1 & gt 'gad_gpyard', 'garden'

	if grandmaQW['chore_feed_chickens'] = 1 or (hour >= 6 and hour < 20 and month >= 4 and month <= 10):act 'Look at your grandparents'' chickens': gt 'gad_gpyard', 'chickens'

	if rand(1,5) = 1 and hour >= 9 and hour <= 19 and npc_rel['A60'] >= 15 and daystart > MiraVars['emb_day'] and sunWeather = 1 and MiraVars['guestday'] ! daystart and (npc_QW['A63'] < 13 or MiraVars['QW'] >= 10 or MiraVars['had_sex'] > 1) and npc_known['A60'] = 1:
		*clr & cla
		menu_off = 1
		gs 'miroslava', 'miraclothes'
		'You went out into the yard and noticed Mira standing there.'
		'"Oh, <<$pcs_nickname>>, hi. I hope you don''t mind me visiting. I was bored being home alone," she said, smiling.'
		MiraVars['guestday'] = daystart
		minut += 5
		MiraVars['guest'] = 1
		gs 'stat'

		act 'Continue': gt 'gad_gpyard', 'start'
	end


	clothesAtLocation = FUNC('lost_clothes_here',$CURLOC)
	if clothesAtLocation = 1:
		if $clothingworntype = 'nude':
			act 'Get dressed':
				gs 'clothing', 'recover_lost_clothes', 'gad_gpyard', 1
				gs 'underwear', 'wear'
				gt 'gad_gpyard', 'start'
			end
		else
			act 'Pick up your clothes':
				gs 'clothing', 'recover_lost_clothes', 'gad_gpyard'
				'You picked up your clothes.'
				gt 'gad_gpyard', 'start'
			end
		end
	end

end

if $ARGS[0] = 'root_cellar':
	*clr & cla
	$loc_arg = 'root_cellar'
	'<center><h4>Root Cellar</h4></center>'
	'<center><img <<$set_imgh>> src="images/locations/gadukino/village/root_cellar.jpg"></center>'
	*nl
	if boletus_stored + bilberry_stored >= 20:
		'Your grandparents'' root cellar is full.'
	elseif boletus_stored + bilberry_stored > 0:
		'Your grandparents'' root cellar is partially full.'
	else
		'Your grandparents'' root cellar is empty.'
	end
	'Even though your grandparents allow you to store extra mushrooms and berries you pick, they reserve the right to use them, too, so you aren''t surprised if any go missing.'
	if boletus_stored > 0: 'You currently are storing <b><<boletus_stored>></b> kg of raw mushrooms.'
	if bilberry_stored > 0: 'You currently are storing <b><<bilberry_stored>></b> kg of raw berries.'
	*nl
	if boletus + boletus_cooked + bilberry >= 5:
		'Your basket is full and you cannot carry more.'
	elseif boletus + boletus_cooked + bilberry > 0:
		'Your basket is partially full.'
	else
		'Your basket is empty.'
	end
	if boletus > 0: 'You currently are carrying <b><<boletus>></b> kg of raw mushrooms.'
	if boletus_cooked > 0: 'You currently are carrying <b><<boletus_cooked>></b> kg of cooked mushrooms.'
	if bilberry > 0: 'You currently are carrying <b><<bilberry>></b> kg of raw berries.'

	act 'Go back to the yard': minut += 1 & gt 'gad_gpyard', 'start'
	if (boletus_stored + bilberry_stored < 20) and (boletus > 0 or bilberry > 0):
		act 'Store as many raw mushrooms and berries that will fit (Max 20 kgs):':
			:store_bb_loop
			if boletus > 0:
				boletus_stored += 1
				boletus -= 1
				if boletus_stored + bilberry_stored < 20: jump 'store_bb_loop'
			end
			if bilberry > 0:
				bilberry_stored += 1
				bilberry -= 1
				if boletus_stored + bilberry_stored < 20: jump 'store_bb_loop'
			end
			gt 'gad_gpyard', 'root_cellar'
		end
		if boletus > 0:
			act 'Store 1 kg of raw mushrooms':
				boletus_stored += 1
				boletus -= 1
				gt 'gad_gpyard', 'root_cellar'
			end
		end
		if bilberry > 0:
			act 'Store 1 kg of raw berries':
				bilberry_stored += 1
				bilberry -= 1
				gt 'gad_gpyard', 'root_cellar'
			end
		end
	end
	if (boletus_stored > 0 or bilberry_stored > 0) and (boletus + boletus_cooked + bilberry < 5):
		act 'Retrieve as many raw mushrooms and berries as you can carry (Max 5 kgs)':
			:retrieve_bb_loop
			if boletus_stored > 0:
				boletus += 1
				boletus_stored -= 1
				if boletus + boletus_cooked + bilberry < 5: jump 'retrieve_bb_loop'
			end
			if bilberry_stored > 0:
				bilberry += 1
				bilberry_stored -= 1
				if boletus + boletus_cooked + bilberry < 5: jump 'retrieve_bb_loop'
			end
			gt 'gad_gpyard', 'root_cellar'
		end
		if (boletus_stored > 0 and grandmaQW['chore_can_mushrooms'] ! 1) or (boletus_stored > 5 and grandmaQW['chore_can_mushrooms'] = 1):
			act 'Retrieve 1 kg of raw mushrooms':
				boletus += 1
				boletus_stored -= 1
				gt 'gad_gpyard', 'root_cellar'
			end
		end
		if (bilberry_stored > 0 and grandmaQW['chore_can_berries'] ! 1) or (bilberry_stored > 5 and grandmaQW['chore_can_berries'] = 1):
			act 'Retrieve 1 kg of raw berries':
				bilberry += 1
				bilberry_stored -= 1
				gt 'gad_gpyard', 'root_cellar'
			end
		end
	end
end

if $ARGS[0] = 'chickens':
	*clr & cla
	$loc_arg = 'chickens'
	'<center><img <<$set_imgh>> src="images/locations/gadukino/village/chickens1.jpg"></center>'
	'Ordinary chickens clucking about their pen.'
	minut += 1
	gs 'stat'

	act 'Leave': gt 'gad_gpyard', 'start'
	!job Granny
	if grandmaQW['chore_feed_chickens'] = 1:
		act 'Feed the chickens':
			*clr & cla
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/chickens2.jpg"></center>'
			'You decide to feed the chickens. You pick up a bucket full of bird''s seed and grain mix and toss it on the ground. They immediately rush over and start to greedily eat. You watch them for a bit before you go about your business.'
			minut += 30
			grandmaQW['chore_feed_chickens'] = 2
			gs 'exp_gain', 'hndiwrk', rand(0,3)
			gs 'stat'

			act 'Finish': gt 'gad_gpyard', 'start'
			act 'Return back to your grandmother': minut += 1 & gt 'gad_gphouse', 'grandma'
		end
	end
end


if $ARGS[0] = 'garden':
	$location_type = 'secluded'
	gs 'shortgs', 'setloc', 'gad_gpyard', 'garden'
	menu_off = 0
	gs 'gadukino_event', 'sound'
	gs 'miroslava_schedule'
	gs 'stat'
	!gs'time'

	if month >= 4 and month <= 10:
		if hour >= 6 and hour < 21:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/garden.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/garden_night.jpg"></center>'
		end
	else
		if hour >= 8 and hour < 18:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/garden_winter.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/garden_winter_night.jpg"></center>'
		end
	end

	'A large vegetable garden that your grandparents are very proud of.'
	if month >= 4 and month <= 10:
		'There is also a small land plot is dedicated to growing <a href="exec: gt ''gad_gpyard'', ''strawberry'' ">strawberries</a> and a <a href="exec: gt ''gad_gpyard'',''fruit_garden'' ">fruit tree orchard</a>.'
	else
		'There is also a small plot of land dedicated to growing strawberries and a small fruit tree orchard, but they are not in season right now.'
	end

	act 'Go back to the yard': minut += 1 & gt 'gad_gpyard', 'start'

	!job Granny
	if grandmaQW['chore_work_in_garden'] = 1:
		act 'Work in the garden (3:00)':
			*clr & cla
			menu_off = 1
			minut += 180
			gs 'sweat', 'add', 10
			grandmaQW['chore_work_in_garden'] = 2
			gs 'exp_gain', 'stren', 1
			fat -= rand(1,5)
			gs 'exp_gain', 'hndiwrk', rand(3,9)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/work_garden'+rand(1,5)+'.jpg"></center>'
			'You spend some time doing some gardening.'
			act 'Finish': gt 'gad_gpyard', 'garden'
			act 'Return back to your grandmother': minut += 2 & gt 'gad_gphouse', 'grandma'
		end
	end
	!job Granny
	if grandmaQW['chore_water_garden'] = 1:
		act 'Water the plants (1:00)':
			*clr & cla
			menu_off = 1
			gs 'sweat', 'add', 10
			minut += 60
			grandmaQW['chore_water_garden'] = 2
			gs 'exp_gain', 'vital', 1
			fat -= rand(1,2)
			gs 'exp_gain', 'hndiwrk', rand(0,3)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/water_garden.jpg"></center>'
			'You spend an hour watering the garden.'
			act 'Finish': gt 'gad_gpyard', 'garden'
			act 'Return back to your grandmother': minut += 1 & gt 'gad_gphouse', 'grandma'
		end
	end
	!job Granny
	if grandmaQW['chore_harvest_garden'] = 1:
		act 'Harvest (3:00)':
			*clr & cla
			menu_off = 1
			minut += 180
			gs 'sweat', 'add', 10
			grandmaQW['chore_harvest_garden'] = 2
			gs 'exp_gain', 'stren', 1
			fat -= rand(1,3)
			gs 'exp_gain', 'hndiwrk', rand(3,9)
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/harvest_garden'+rand(1,5)+'.jpg"></center>'
			'You spend a few hours harvesting vegetables in the garden.'
			act 'Finish': gt 'gad_gpyard', 'garden'
			act 'Return back to your grandmother': minut += 1 & gt 'gad_gphouse', 'grandma'
		end
	end
end

if $ARGS[0] = 'strawberry':
	gs 'shortgs', 'setloc', 'gad_gpyard', 'strawberry'
	menu_off = 0
	gs 'gadukino_event', 'sound'
	gs 'stat'
	!gs'time'

	if month = 6 or month = 7:
		if hour >= 6 and hour < 21:
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/strawberry1.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/strawberry_night.jpg"></center>'
		end
	else
		if hour >= 6 and hour < 21:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/strawberry2.jpg"></center>'
		else
			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/strawberry_night.jpg"></center>'
		end
	end

	'It''s strawberry season, you approach the field where the strawberries grow, searching for some ripe strawberries.'

	act 'Go back to the garden': minut += 1 & gt 'gad_gpyard', 'garden'

	if month >= 7 and month <= 9 and strawberriesday ! daystart:
		act 'Eat some strawberries (1:00)':
			*clr & cla
			menu_off = 1
			strawberriesday = daystart
			minut += 60
			pcs_mood += 10
			pcs_hydra += 40
			pcs_energy += 15
			cumspclnt = 2 & gs 'cum_cleanup' & pcs_breath = 0
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/eat_strawberries.jpg"></center>'
			'You spend some time wandering through the plot searching for ripe strawberries. You walk along, picking off the ones that you find and popping them in your mouth.'

			act 'Finish': gt 'gad_gpyard', 'strawberry'
		end
	end
	!job Granny
	if grandmaQW['chore_collect_strawberries'] = 1:
		act 'Collect strawberries (3:00)':
			*clr & cla
			menu_off = 1
			minut += 180
			gs 'sweat', 'add', 10
			grandmaQW['chore_collect_strawberries'] = 2
			gs 'exp_gain', 'agil', 1
			fat -= 1
			gs 'exp_gain', 'hndiwrk', rand(3,9)
			gs 'stat'

			if PCloSkirt = 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/village/collect_strawberries.jpg"></center>'
			if PCloSkirt > 0 and $pantyworntype ! 'none':'<center><img <<$set_imgh>> src="images/locations/gadukino/village/collect_strawberries_ski.jpg"></center>'
			if PCloSkirt > 0 and $pantyworntype = 'none':'<center><img <<$set_imgh>> src="images/locations/gadukino/village/collect_strawberries_tanga.jpg"></center>'
			'You wander through the plot for several hours, collecting ripe strawberries and placing them in the basket.'

			act 'Finish': gt 'gad_gpyard', 'strawberry'
			act 'Return back to your grandmother': minut += 3 & gt 'gad_gphouse', 'grandma'
		end
	end
end


if $ARGS[0] = 'fruit_garden':
	gs 'shortgs', 'setloc', 'gad_gpyard', 'fruit_garden'
	menu_off = 0
	gs 'gadukino_event', 'sound'
	cls
	gs'stat'
	!gs'time'

	if hour >= 6 and hour < 21:
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/fruit_garden.jpg"></center>'
	else
		'<center><img <<$set_imgh>> src="images/locations/gadukino/village/fruit_garden_night.jpg"></center>'
	end

	'There are apples and pears growing in the fruit orchard.'

	act 'Go back to the garden': minut += 1 & gt 'gad_gpyard', 'garden'

	if month >= 7 and month <= 9 and fruitday ! daystart:
		act 'Eat the fruit (1:00)':
			*clr & cla
			menu_off = 1
			fruitday = daystart
			minut += 60
			pcs_mood += 10
			pcs_hydra += 20
			pcs_energy += 30
			cumspclnt = 2 & gs 'cum_cleanup' & pcs_breath = 0
			gs 'stat'

			'<center><img <<$set_imgh>> src="images/locations/gadukino/village/eat_fruit.jpg"></center>'
			'You spend some time wandering around the orchard munching on the ripe fruit.'

			act 'Finish': gt 'gad_gpyard', 'fruit_garden'
		end
	end
	!job Granny
	if grandmaQW['chore_collect_fruit'] = 1:
		act 'Collect fruit (3:00)':
			*clr & cla
			menu_off = 1
			minut += 180
			gs 'sweat', 'add', 10
			grandmaQW['chore_collect_fruit'] = 2
			gs 'exp_gain', 'agil', 1
			fat -= rand(1,3)
			gs 'exp_gain', 'hndiwrk', rand(3,9)
			gs 'stat'

			if PCloSkirt = 0:'<center><img <<$set_imgh>> src="images/locations/gadukino/village/fruit_collect.jpg"></center>'
			if PCloSkirt > 0 and $pantyworntype ! 'none':'<center><img <<$set_imgh>> src="images/locations/gadukino/village/fruit_collect_ski.jpg"></center>'
			if PCloSkirt > 0 and $pantyworntype = 'none':'<center><img <<$set_imgh>> src="images/locations/gadukino/village/fruit_collect_tanga.jpg"></center>'
			'You walk around the orchard and pick the ripe fruit hanging from the trees.'

			act 'Finish': gt 'gad_gpyard', 'fruit_garden'
			act 'Return back to your grandmother': minut += 3 & gt 'gad_gphouse', 'grandma'
		end
	end
end




if $ARGS[0] = 'cikl':
	!! vovan, from 1.2.5
	hunters_check = 0
	mushroom_pickers = 0
	mira_go_river = 0
	forestpicnic = 0

	!! new grandparent chore stuff, for 0.8.0
	if gadstay = 1 and lost_girl = 0:
		if daystart > (grandmaQW['last_day_helped'] + 3) and daystart > (grandpaQW['last_day_helped'] + 3):
			if (daystart - grandmaQW['last_day_helped']) <= (daystart - grandpaQW['last_day_helped']):
				'You haven''t helped your grandparents with any chores in <<daystart - grandmaQW[''last_day_helped'']>> days. You should help out more often to stay on your grandparents'' good side.'
			else
				'You haven''t helped your grandparents with any chores in <<daystart - grandpaQW[''last_day_helped'']>> days. You should help out more often to stay on your grandparents'' good side.'
			end
			grandmaQW['help_amount'] -= 1
		end
	end

	!! disappointing grandma
	if grandmaQW['chore_clean_floor'] = 1 or grandmaQW['chore_clean_floor'] = 2:
		grandmaQW['chore_clean_floor'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_wash_clothes'] = 1 or grandmaQW['chore_wash_clothes'] = 2:
		grandmaQW['chore_wash_clothes'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_milk_cow'] = 1 or grandmaQW['chore_milk_cow'] = 2:
		grandmaQW['chore_milk_cow'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_groceries'] = 1 or grandmaQW['chore_groceries'] = 2:
		grandmaQW['chore_groceries'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_can_mushrooms'] = 1 or grandmaQW['chore_can_mushrooms'] = 2:
		grandmaQW['chore_can_mushrooms'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_can_berries'] = 1 or grandmaQW['chore_can_berries'] = 2:
		grandmaQW['chore_can_berries'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_can_veggies'] = 1 or grandmaQW['chore_can_veggies'] = 2:
		grandmaQW['chore_can_veggies'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_feed_chickens'] = 1 or grandmaQW['chore_feed_chickens'] = 2:
		grandmaQW['chore_feed_chickens'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_work_in_garden'] = 1 or grandmaQW['chore_work_in_garden'] = 2:
		grandmaQW['chore_work_in_garden'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_water_garden'] = 1 or grandmaQW['chore_water_garden'] = 2:
		grandmaQW['chore_water_garden'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_collect_strawberries'] = 1 or grandmaQW['chore_collect_strawberries'] = 2:
		grandmaQW['chore_collect_strawberries'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_collect_fruit'] = 1 or grandmaQW['chore_collect_fruit'] = 2:
		grandmaQW['chore_collect_fruit'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_harvest_garden'] = 1 or grandmaQW['chore_harvest_garden'] = 2:
		grandmaQW['chore_harvest_garden'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_gather_mushrooms'] = 1 or grandmaQW['chore_gather_mushrooms'] = 2:
		grandmaQW['disappointment'] = 2
	elseif grandmaQW['chore_gather_mushrooms'] = 1 or grandmaQW['chore_gather_mushrooms'] = 2 and grandmaQW['disappointment'] = 2:
		grandmaQW['chore_gather_mushrooms'] = 0
		grandmaQW['chore_mushroom_quantity'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_gather_berries'] = 1 or grandmaQW['chore_gather_berries'] = 2:
		grandmaQW['disappointment'] = 2
	elseif grandmaQW['chore_gather_berries'] = 1 or grandmaQW['chore_gather_berries'] = 2 and grandmaQW['disappointment'] = 2:
		grandmaQW['chore_gather_berries'] = 0
		grandmaQW['chore_berry_quantity'] = 0
		grandmaQW['disappointment'] = 1
	elseif grandmaQW['chore_gather_both'] = 1 or grandmaQW['chore_gather_both'] = 2:
		grandmaQW['disappointment'] = 2
	elseif grandmaQW['chore_gather_both'] = 1 or grandmaQW['chore_gather_both'] = 2 and grandmaQW['disappointment'] = 2:
		grandmaQW['chore_gather_both'] = 0
		grandmaQW['chore_mushroom_quantity'] = 0
		grandmaQW['chore_berry_quantity'] = 0
		grandmaQW['disappointment'] = 1
	end

	!! disappointing grandpa
	if grandpaQW['chore_fetch_firewood'] = 1 or grandpaQW['chore_fetch_firewood'] = 2:
		grandpaQW['chore_fetch_firewood'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_feed_horse'] = 1 or grandpaQW['chore_feed_horse'] = 2:
		grandpaQW['chore_feed_horse'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_feed_cow'] = 1 or grandpaQW['chore_feed_cow'] = 2:
		grandpaQW['chore_feed_cow'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_clean_yard'] = 1 or grandpaQW['chore_clean_yard'] = 2:
		grandpaQW['chore_clean_yard'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_feed_boar'] = 1 or grandpaQW['chore_feed_boar'] = 2:
		grandpaQW['chore_feed_boar'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_bathe_horse'] = 1 or grandpaQW['chore_bathe_horse'] = 2:
		grandpaQW['chore_bathe_horse'] = 0
		grandpaQW['chore_bathe_horse_prog'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_brush_horse'] = 1 or grandpaQW['chore_brush_horse'] = 2:
		grandpaQW['chore_brush_horse'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_lead_horse_to_field'] = 1 or grandpaQW['chore_lead_horse_to_field'] = 2:
		grandpaQW['chore_lead_horse_to_field'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_herd_cattle'] = 1 or grandpaQW['chore_herd_cattle'] = 2:
		grandpaQW['chore_herd_cattle'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_lead_cow_to_field'] = 1 or grandpaQW['chore_lead_cow_to_field'] = 2:
		grandpaQW['chore_lead_cow_to_field'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_gather_mushrooms'] = 1 or grandpaQW['chore_gather_mushrooms'] = 2:
		grandpaQW['disappointment'] = 2
	elseif grandpaQW['chore_gather_mushrooms'] = 1 or grandpaQW['chore_gather_mushrooms'] = 2 and grandpaQW['disappointment'] = 2:
		grandpaQW['chore_gather_mushrooms'] = 0
		grandpaQW['chore_mushroom_quantity'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_gather_berries'] = 1 or grandpaQW['chore_gather_berries'] = 2:
		grandpaQW['disappointment'] = 2
	elseif grandpaQW['chore_gather_berries'] = 1 or grandpaQW['chore_gather_berries'] = 2 and grandpaQW['disappointment'] = 2:
		grandpaQW['chore_gather_berries'] = 0
		grandpaQW['chore_berry_quantity'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_gather_both'] = 1 or grandpaQW['chore_gather_both'] = 2:
		grandpaQW['disappointment'] = 2
	elseif grandpaQW['chore_gather_both'] = 1 or grandpaQW['chore_gather_both'] = 2 and grandpaQW['disappointment'] = 2:
		grandpaQW['chore_gather_both'] = 0
		grandpaQW['chore_mushroom_quantity'] = 0
		grandpaQW['chore_berry_quantity'] = 0
		grandpaQW['disappointment'] = 1
	elseif grandpaQW['chore_bale_hay'] = 1 or grandpaQW['chore_bale_hay'] = 2:
		grandpaQW['chore_bale_hay'] = 0
		grandpaQW['disappointment'] = 1
	end

	!! grandparents use root cellar
	if boletus_stored > 0: boletus_stored -= rand(0,1)
	if bilberry_stored > 0: bilberry_stored -= rand(0,1)
	if boletus_stored < 0: boletus_stored = 0
	if bilberry_stored < 0: bilberry_stored = 0
	!! end of new grandparent chore stuff, for 0.8.0

	if catout ! 0: catout = 0
	if feedcat ! 0: feedcat = 0

end

--- gad_gpyard ---------------------------------