# sportShop
if $ARGS[0] = 'start':
	cla
	clr
	*clr
	minut += 5
	gs 'stat'
	fcolor = rgb(0, 0, 0)
	bcolor = rgb(255, 255, 255)
	lcolor = rgb(106, 90, 205)
	'<center><b><font color="maroon">Sporting goods store</font></b></center>'
	'<center><img src="images/etogame/sportshop.jpg"></center>'

	act 'Leave':
		cla
		minut += 5
		gt 'torgcentr'
	end

	act 'In the women''s clothing department':
		cla
		minut += 5
		gt 'sportshop', 'clo'
	end

	if skak = 0 and money >= 500:
		act 'Buy rope (500 rubles)':
			cla
			minut += 5
			money -= 500
			skak = 1

			act 'Pick up a package':gt 'sportshop', 'start'
		end
	end

	if obruch = 0 and money >= 1500:
		act 'Buy hoop (1,500 rubles)':
			cla
			minut += 5
			money -= 1500
			obruch = 1

			act 'Pick up a package':gt 'sportshop', 'start'
		end
	end

	if bookYog = 0 and money >= 1500:
		act 'Buy benefits of yoga (1,500 rubles)':
			cla
			minut += 5
			money -= 1500
			bookYog = 1

			act 'Pick up a package':gt 'sportshop', 'start'
		end
	end

	!!!WD: Doesn''t exists anymore in 1.0.5
	if remsitr = 1 and treadmill = 0 and money >= 5000:
		act 'Treadmill 5000 rubles':
			cla
			minut += 5
			money -= 5000
			treadmill = 1
			'The attendant informed that they can send it directly to your house.'

			act 'Give the address':gt 'sportshop', 'start'
		end
	end
	!!!
end

if $ARGS[0] = 'clo':
	$metka = $ARGS[0]
	$loc = $CURLOC
	$metkaM = $ARGS[0]
	$locM = $CURLOC
	cla
	clr
	*clr
	mag = 1
	minut += 5
	gs 'stat'
	fcolor = rgb(0, 0, 0)
	bcolor = rgb(255, 255, 255)
	lcolor = rgb(106, 90, 205)
	'<center><b><font color="maroon">Department of women''s clothing.</font></b></center>'
	'<center><img src="images/etogame/sportshop.jpg"></center>'
	'All clothing costs 4,000 rubles, sportswear dimensionless.'

	act 'Get out of the department':
		cla
		minut += 5
		gt 'sportshop', 'start'
	end
	
	if money >= 4000:
		i = 1
		:loopyoga
			if yoga[i] = 0:dynamic 'act ''Look at sportswear <<i>>'':gt ''clothing'', ''view_clothing_item'', ''shop'', ''yoga'', <<i>>, 4000'
			i += 1
		if i <= 18:jump 'loopyoga'
	end
end

--- sportShop ---------------------------------
