# cikl
day += 1
daystart += 1
week += 1
hour -= 24

if BuyHous = 2 and ArendHouseSL <= 0:ArendHouseSL = 0 & BuyHous = 0 & housr = 0
if BuyHous = 2 and ArendHouseSL > 0:ArendHouseSL -= 1

vidageday -= 1
if workDolgDay > 0:workDolgDay -= 1
if QWdogreiqTimer > 0:QWdogreiqTimer -= 1
if husband > 0:husbanday += 1
if husband > 10 and husbanday > 0:husband -= 15
if fingal > 0:fingal -= 1

if husbandMark = 1 and husband <= 10:
	husbizvradd = 0
	husbharmin = 0
	husbandMark = 0
	husband = 0
	divorced += 1

	if KFOnLineReaga > 0:KFOnLineReaga -= 1

	'<b><font color="red">Your husband has filed for a divorce.</font></b>'
end

if year_start ! year and katjaPreg = 0 and month >= 2:katjaPreg = 1

!Clothing stock and price randomizers
Clothingstock = rand (0,23)
i = 1
:loopprice
Clothingstock[i] = rand (0,500)
i += 1
if i <= 147:jump 'loopprice'

!!SECTION: Bimbo (daily status update checks)
if bimbo < 0:
	bimbo = 0
elseif bimbo < 10:
	bimbolevel = 0
	bimbo -= 1
elseif bimbo < 20:
	bimbolevel = 1
elseif bimbo < 30:
	bimbolevel = 2
elseif bimbo < 40:
	bimbolevel = 3
else
	if succubusflag = 1:
		bimbolevel = 4
	else
		bimbolevel = 3
	end
end
if bimbo >= 50:bimbo = 50

!!Bimbo levels. They use custom variables so they wont permanently change character stats
if bimbolevel = 0:bimbobeauty = 0 and bimbostupidity = 0
if bimbolevel = 1:bimbobeauty = (vnesh / 10) and bimbostupidity = (intel / 6)
if bimbolevel = 2:bimbobeauty = (vnesh / 6) and bimbostupidity = (intel / 4)
if bimbolevel = 3:bimbobeauty = (vnesh / 5) and bimbostupidity = (intel / 3)
if bimbolevel = 4:bimbobeauty = (vnesh / 4) and bimbostupidity = (intel / 3)

if bimbocl = 1:
	bimbocl = 0
	bimbo += 2
end
!!Checks how often sex has occured in the last 24 hours and for drops in bimbo score, for calculating withdrawal
if bimbolevel >= 1:
	bimbo += ((sex + bj + anal) - snapshotX) - 3
	if snapshotY - bimbo <= 1 or bimbo > 40:
		bimbowithdrawal = 0
	else
		bimbowithdrawal += 1
	end
end
snapshotX = (sex + bj + anal)
snapshotY = bimbo


if curly > 0:curly -= 1

! WD: Added daily reduction of braids for Maruda Hair Mod
if hbraids > 0:hbraids -= 1


sweat += 1

if tan > 0:tan -= 1

if tabletkishot <= 0: pillcon -= 1000
if pillcon < 0:	pillcon = 0

if tabletkicheck = 2:
	if tabletkishot ! 0:
		cycle = 1
		mesec = 0
		if rand(0,1000) = 1000:
			EggRH = rand(20,80)
		else
			EggRH = 0
		end
		FocH = EggRH
	end
	if tabletkishot <= 0:
		'The chemicals regulating your fertility cycle are wearing off.'
		pillcon -= 29000
		tabletkicheck = 0
	elseif tabletkishot > 1 and tabletkishot < 5:
		'You are due for a birth control shot. If you do not get one, you might get pregnant.'
	elseif tabletkishot = 1:
		'Your birth control shot will wear off tomorrow.'
	end
	tabletkishot -= 1
end

tabletkipd += tabletkipi
tabletkipi = 0
tabletkipt = 0
if tabletkicheck = 1:
	if tabletki <= 0:
		tabletkicheck = 0
		'You are out of birth control pills.'
		tabletkipi = -5
	elseif tabletki < 5:
		'You are running out of birth control pills. You only have a few left.'
	end
end

if tabletkicheck = 1 and tabletkichday < daystart:
	tabletkichday = daystart
	tabletkimm = ((100-(willpower / (intel * 5 + will * 5))) + (100-(manna / (intel * magik + magik * 100 + vital * 10 + rikudo))))
	if son < 10:
		tabletkimm += (100- (son * 10))
	end
	if willpower < ((intel * 5 + will * 5) * 25 / 100):
		tabletkimm = tabletkimm * 4
	elseif manna < ((intel * magik + magik * 100 + vital * 10 + rikudo) * 10 / 100):
		tabletkimm = tabletkimm * 2
	end
	tabletkiap = tabletkimm
	tabletkiap += (((100-intel)*4)+((100-will)*2)+((50-age)*3))
	tabletkiap -= ((kid*30)+(abort*2)+(tabletkipd*(age/10)))
	temprand = rand(0,(200+(tabletkimm-(will*3))))
	if temprand = 0:
		tabletkioddp = 1
	end
	tabletkiap += temprand
	if tabletkiap < 600:
		if tabletkipd > -10:
			if willpower < ((intel * 5 + will * 5) * 25 / 100):
				'You stare at your bottle of birth control pills. You know you should take one, but you can''t quite work up enough effort to care.'
			elseif manna < ((intel * magik + magik * 100 + vital * 10 + rikudo) * 10 / 100):
				'You stare at your bottle of birth control pills, but don''t open it.'
			elseif son < 10:
				'You fumble with the cap on your birth control pills, trying to get it open. You finally give up, too tired to manage it.'
			else
				'You just realized you forgot to take your birth control pill today.'
			end
		end
		tabletkipt = 2
		tabletkipi = -4
	else
		if tabletkiap < 650:
			temprand = rand(0,5)
		else
			temprand = rand(0,1000)
		end
		if temprand = 0:
			temprand = rand(0,1)
			if temprand = 0:
				tabletki -= 1
				skinvan += 1
				tabletkipt = -2
				tabletkipi = 1
			else
				tabletkipt = 3
				tabletkipi = -3
			end
			if tabletkipd > -10:
				'You find yourself holding the bottle of birth control pills. You cannot remember if you took one or not.'
			end
			if tabletkipd > 10:
				if rand(0,9) = 0:
					if tabletkipt < 0:
						'You don''t think you have taken it today.'
					else
						'You think you have taken it today.'
					end
				else
					if tabletkipt > 0:
						'You don''t think you have taken it today.'
					else
						'You think you have taken it today.'
					end
				end
			end
		else
			'You take your birth control pill for the day.'
			tabletki -= 1
			skinvan += 1
			if tabletkioddp = 0:
				pillcon += ((pillcon+15000)/40)+1000
				if pillcon > 40000: pillcon = 40000
			else
				if vitaminday ! daystart:
					vitaminday = daystart
					skinvan += 1
				end
			end
			tabletkiday = daystart
			tabletkipt = 0
			tabletkipi = 0
		end
	end		
end

if skinvan >= 20:skinvan -= 20 & skin += 1

if lashair ! 1:
	leghair += 1
	lobok += 1
end

if suhbelo > 0:suhbelo2 = suhbelo & suhbelo = 0

if fbreath = 1:fbreath = 0

if cheatNoEat = 1:fat += 15

manna -= 10

if beg >= 2000:
	beg -= 4
elseif beg >= 1500:
	beg -= 3
elseif beg >= 1000:
	beg -= 2
elseif beg >= 100:
	beg -= 1
end

!'
if salo > fat:
	salo -= 1
	fat += 1
else
	salo += 1
	fat -= 1
end

if strenbuf > stren:strenbuf -= 1
if strenbuf < stren:strenbuf += 1
if vitalbuf > vital:vitalbuf -= 1
if vitalbuf < vital:vitalbuf += 1
if agilbuf > agil:agilbuf -= 1
if agilbuf < agil:agilbuf += 1
'!

!STD check
if SifacOnce = 1:Sifilis += 1
if GerpesOnce = 1:Gerpes += 1
if TriperOnce = 1:Triper += 1
if KandidozOnce = 1:Kandidoz += 1

VeneraN = 0

if VeneraOnce > 0:VeneraOnce = 0
if SifacOnce = 1:VeneraN += 1
if GerpesOnce = 1:VeneraN += 1
if TriperOnce = 1:VeneraN += 1

Venera = VeneraN

!Appearance age
if vidageday <= 0:
	vidageday = 360
	vidage += 1
end

if anus > 1 and ashrink > 0 and analplugIN = 0:
	if anusK < 0:anusK = 0
	if anusK < ashrinkdays:anusK += 1
	if anusK >= ashrinkdays:anus -= ashrink & anusK = 0
	if anus < 0: anus = 0
end
if vagina > 10 and vshrink > 0:
	if vaginaK < 0:vaginaK = 0
	if vaginaK < vshrinkdays:vaginaK += 1
	if vaginaK >= vshrinkdays:vaginaK = 0 & vagina -= vshrink
end

lipkoef -= 1
!!!!!!!!!!!!
!!!jobs!!!
!!!!!!!!!!!!
if Enable_autotampon = 0 and isprok = 1:isprok = 0 & 'You threw away your used tampon.'
if Enable_autotampon = 0 and isprokp = 1:isprokp = 0 & 'You threw away your used sanitary pad.'

if preg = 1 and pregtime < 280:
	pregtime += 1

	if pregtimes = 0:pregtimes = 1
elseif preg = 1 and pregtime = 280 and hourpreg ! hour:
	hourpreg = hour
	'<center><b>A sharp pain runs through your stomach, and something flows down your legs. Snap, your water broke! You have to get to the clinic fast!</b></center>'
elseif preg = 1 and pregtime > 280:
	cla
	*clr
	over = 4
	'<center><b>A horrible pain shoots through your body.</b></center>'
	xgt 'gameover'
	exit
end

if StoryLine = 0 or altQS = 1:
	if horny < 100:horny += vagina
else
	if vagina = 0:
		razeba = 0

		if horny > 0 and horny <= 50:horny -= 10
		if horny > 50:horny -= 25
	elseif vagina > 0:
		if pregtimes = 0:
			if age < 18:
				razeba = 1

				if horny > 0 and horny <= 50:horny -= 5
				if horny > 50 and horny < 80:horny -= 10
				if horny >= 80:horny -= 20
			elseif age >= 18 and age < 21:
				razeba = 2

				if horny > 0 and horny <= 50:horny -= 1
				if horny > 50 and horny < 80:horny -= 5
				if horny >= 80:horny -= 10
			elseif age >= 21 and age < 25:
				razeba = 3

				if horny > 0 and horny <= 50:horny += 1
				if horny > 50 and horny < 80:horny -= 1
				if horny >= 80:horny -= 5
			elseif age >= 25 and age < 30:
				razeba = 4

				if horny > 0 and horny <= 50:horny += 5
				if horny > 50 and horny < 80:horny += 1
				if horny >= 80:horny -= 5
			elseif age >= 30:
				razeba = 5

				if horny > 0 and horny <= 50:horny += 10
				if horny > 50 and horny < 80:horny += 5
				if horny >= 80:horny += 1
			end
		elseif pregtimes > 0:
			if preg = 0:
				razeba = 5

				if horny > 0 and horny <= 50:horny += 10
				if horny > 50 and horny < 80:horny += 5
				if horny >= 80:horny += 1
			elseif preg > 0:
				razeba = 6

				if horny < 100:horny += pregtime / 10
			end
		end
	end
end

if horny < 0:horny = 0

if musle >= salo and stren >= 10 and vital >= 10 and dounspell = 0:
	!!Fall muscularity
	if downmusl >= 5:
		downmusl = 0
		stren -= 1
		vital -= 1
		fat += 4
		salo += 4
	else
		downmusl += 1
	end
end

!counter for Dimka avoidance
if nodimka = 1:
	nodimkaK += 1
	if dimaRudeBlock = 1: nodimka = 0
end

!!! Maruda Hair Mod
!!! Max. Hair length 600mm, or 60cm, which should be somewhere in the lower back area.
!!! Hair grows 1mm each day, it takes 20 months (1 month = 30 days) to regrow the hair from 0.
if hairlength < 601:hairlength += 1

if hscrunch > 0:
	hscrunchrand = rand(1, 100)

	if hscrunchrand <= 8:hscrunch -= 1
end
!!! Maruda Hair Mod

gs 'starenie'

if nark > 60:
	nark = 60
elseif nark > 30:
	nark -= 3
elseif nark > 0:
	nark -= 1
end

if pregtime > 10:fat += 1
if kanicont > 0:kanicont -= 1 & !kanicont countdown. set and display in [stat]

if nippain = 2:
	if nippainday + 5 < daystart:
		$nippain = 'You are constantly reminded of the sharp pain from your nipples.'
		nippain = 1
		nippainday = daystart
	elseif nippainday + 5 >= daystart:
		$nippain = 'You are constantly reminded of the sharp pain from your nipples.'
	end
elseif nippain = 1:
	if nippainday + 5 < daystart:
		$nippain = ''
		nippain = 0
	elseif nippainday + 5 >= daystart:
		$nippain = 'Your nipples are a little sore.'
	end
end

if painpub = 2:
	if painpubday + 5 < daystart:
		$painpub = 'Your vulva is painfully sore.'
		painpub = 1
		painpubday = daystart
	elseif painpubday + 5 >= daystart:
		$painpub = 'Your vulva is painfully sore.'
	end
elseif painpub = 1:
	if painpubday + 5 < daystart:
		$painpub = ''
		painpub = 0
		painpubday = daystart
	elseif painpubday + 5 >= daystart:
		$painpub = 'Your vulva is a little sore.'
	end
end

prezikProver += 1
if pirs_pain_ton > 0:pirs_pain_ton -= 1
if brow > 0 and browper = 0:brow -= 1
if shorthair = 1:
	shorthairday += 1
	if shorthairday >= 45:shorthairday = 0 & shorthair = 0
end

if KatjaOTN > 0:
	if KatjaHorny > 0 and KatjaLust < 40:KatjaHorny -= rand(1, 3)
	if KatjaLust >= 40:KatjaHorny += rand(1, 3)
	if KatjaHorny < 0:KatjaHorny = 0
	if KatjaHorny >= 100:KatjaHorny = 0 & KatjaMastr += 1 & KatjaLust += 1
end

if trenerepa > 20:trenerepa -= 1

if birthday = day and birthmonth = month:
	!!birthday
	age += 1
	vidage += 1
end

!!!!!!!!!!!!!!!
!!!generation!!!
!!!!!!!!!!!!!!!
if NPCnum < 290:
	NPCnow = NPCnum
	NPCnum += rand(1, 3)
	gs 'npc'
elseif NPCnum < 300:
	NPCnow = NPCnum
	NPCnum += 1
	gs 'npc'
end

!!!!!!!!!!!!!!!
if kanikuli = 0:Suspeh -= 1
dmishaevent = 0

if Gspravka <= 0 and GspravkaT = 1:GspravkaT = 0 & Gspravka = 0
if GspravkaT = 1:Gspravka -= 1
if IvanPodstavaQW = 2 and PodpiskaNeviezd = 30:IvanPodstavaQW = 3
if IvanPodstavaQW = 2 and PodpiskaNeviezd > 0 and PodpiskaNeviezd < 30:PodpiskaNeviezd += 1

if salo > (fat + 40):
	salo -= 3
	fat += 3
elseif salo > (fat + 20):
	salo -= 1
	fat += 1
elseif salo > (fat + 10):
	fatD2roll = rand(0,1)
	salo -= fatD2roll
	fat += fatD2roll
end

if fat > (salo + 40):
	salo += 3
	fat -= 3
elseif fat > (salo + 20):
	salo += 1
	fat -= 1
elseif fat > (salo + 10):
	fatD2roll = rand(0,1)
	salo += fatD2roll
	fat -= fatD2roll
end

if salo > 240:
	salo = 240
	elseif salo > 180:
	salo -= 3
elseif salo > 120:
	salo -= 2
elseif salo > 60:
	salo -= 1
elseif salo < 30: 
	salo += 3
elseif salo < 60:
	salo += 2
end

if fat > 240:
	fat = 240
elseif fat > 180:
	fat -= 3
elseif fat > 120:
	fat -= 2
elseif fat > 60:
	fat -= 1
elseif fat < 30:
	fat += 3
elseif fat < 60:
	fat += 2
end

if strenbuf > 90:
	strenbuf -= 2
elseif strenbuf > 80:
	strenbuf -= 1
end

if vitalbuf > 90:
	vitalbuf -= 2
elseif vitalbuf > 80:
	vitalbuf -= 1
end

if strenbuf > stren:strenbuf -= 1
if strenbuf < stren:strenbuf += 1
if vitalbuf > vital:vitalbuf -= 1
if vitalbuf < vital:vitalbuf += 1
if agilbuf > agil:agilbuf -= 1
if agilbuf < agil:agilbuf += 1
if husband > 0 and husbandrink ! 11:husbandrink = rand(0, 10)

inWorkYoungShop = 0
husbandsexday = 0
borsexkol = 0
givisexday = 0

if shantsr > 0:
	pay = shantsr * 5000
	karta += pay
	shantsr = 0
end

if shantbog > 0:
	:shantftb
	shantftbgrand = rand(0, 10)
	if shantftbgrand > 2:
		shantpopala += 1
		shantbog -= 1
		if shantbog > 0:jump 'shantftb'
	elseif shantftbgrand <= 2:
		karta += 30000
		shantbog -= 1
		if shantbog > 0:jump 'shantftb'
	end
end

petersexday = 0
klismaday1 = 0

!MJ: Add some (daily) interest to the bank account. 
!Not very realistic but wont make anyone too rich.
   
if bankAccount = 1:
	if karta >= 2000000:
		!yearly interest of 2.3% recalculated into daily interest = 0.006% daily
		smallmoneypos += (karta * 60)
	elseif karta >= 0 and karta < 2000000:
		!yearly interest of 0.4% recalculated into daily interest = 0.0011% daily
		smallmoneypos += (karta * 11)
	else
		!yearly overdraft interest of 20% recalculated into daily interest = 0.055% daily
		smallmoneydebt += (karta * 550)
	end
			
	:kopeckloop
	if smallmoneypos > 10000:
		karta += 1
		smallmoneypos -= 10000
		jump 'kopeckloop'
	else
		kartakop += smallmoneypos
		if kartakop >= 10000: karta += 1 & kartakop -= 10000
	end
	:kopeckloop2
	if smallmoneydebt < -10000:
		karta -= 1
		smallmoneydebt += 10000
		jump 'kopeckloop2'
	else
		kartakop += smallmoneydebt
		if kartakop < 0: karta -= 1 & kartakop += 10000
	end
	smallmoneypos = 0
	smallmoneydebt = 0
	      
	if atmDeposit > 0 and atmDepositDate <= daystart:
		karta += atmDeposit
		atmDeposit = 0
	end
end
   
!!payments
if day = 25:
	if PersSecWork = 1 and PersSecWorkTimes > 0 and paydaybistrosec = 0:
		Pay = PersSecWorkTimes * 2500
		PersSecWorkTimes = 0
		money += Pay
		paydaybistrosec = 1
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your job as a secretary.</font></b>'
	end

	if workKafe = 1 and paydayKafe = 0:
		paydayKafe = 1
		pay = smenaKafe * 600
		money += pay
		smenaKafe = 0
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your job as a waitress in a cafe.</font></b>'
	end

	if workhosp = 1 and nopaypoly = 0:
		pay = smena * 1000
		money += pay
		smena = 0
		nopaypoly = 1
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your work in the clinic.</font></b>'
	end

	if worksalon = 1 and nopaysalon = 0:
		pay = smena * 800
		money += pay
		smena = 0
		nopaysalon = 1
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your work in a beauty salon.</font></b>'
	end

	if tanwork = 1 and nopaytanwork = 0:
		nopaytanwork = 1
		money += 25000
		'<b><font color="green">Your salary of 25,000 <b>₽</b> has been paid into your bank account for your work as a house maid.</font></b>'
	end

	if workSec = 1 and paydaySec = 0:
		paydaySec = 1
		pay = sekDay * 800

		if officebestslut >= 3:pay += 20000
		karta += pay
		sekDay = 0
		'<b><font color="green">Your salary of <<pay>> <b>₽</b> has been paid into your bank account for your job as a secretary.</font></b>'
	end

	if husband > 0 and paydayHusb = 0:
		paydayHusb = 1

		if husbFin = 0:huspay = 15000
		if husbFin = 1:huspay = 25000
		if husbFin = 2:huspay = 40000

		money += huspay
		'<b><font color="green">Your husband has paid <<huspay>> <b>₽</b> into your bank account.</font></b>'
	end

	if stipuha = 1 and stipuhaday = 0:stipuhaday = 1 & money += 1200 & '<b><font color="green">You have received 1,200 <b>₽</b> scholarship.</font></b>'
	if housr = 1 and haday = 0:haday = 1 & money -= 3000 & '<b><font color="red">You paid 3,000 <b>₽</b> for your apartment.</font></b>'

	if housr = 1 and electroday = 0:
		electroday = 1
		if elektro >= 800:elektro = 800 + rand(0, 100)

		money -= elektro
		'<b><font color="red">You paid <<elektro>> for electricity.</font></b>'
	end

	if housr = 1 and kabel > 0 and kabelday = 0:kabelday = 1 & money -= 300 & '<b><font color="red">You have paid 300 <b>₽</b> for cable TV.</font></b>'
end

if day ! 25:
	if paydayHusb = 1:paydayHusb = 0
	if workKafe = 1 and paydayKafe = 1:paydayKafe = 0
	if workSec = 1 and paydaySec = 1:paydaySec = 0
	if housr = 1 and haday = 1:haday = 0
	if housr = 1 and electroday = 1:electroday = 0
	if housr = 1 and kabel > 0 and kabelday = 1:kabelday = 0
	if stipuhaday = 1:stipuhaday = 0
	if nopaytanwork = 1:nopaytanwork = 0
	if nopaypoly = 1:nopaypoly = 0
	if nopaysalon = 1:nopaysalon = 0
	if paydaybistrosec = 1:paydaybistrosec = 0
end

if sdaday = day and sdamonth = month and housr = 0:
	housr = 1
	'<b><font color="red">Your tenants have moved out and your apartment is now vacant.</font></b>'
	!msg 'Your tenants have moved out and your apartment is now vacant.'
end



if day > monthsEnd[month]:
	day -= monthsEnd[month]
	month += 1
	
	if month > 12: month = 1
	
	!MJ: Dont think that one is needed. But it was in the original loop.
	if month < 1: month = 1
	
	$month = $monthName[month]
end

!MJ: Dont think that one is needed. But it was here already.
if day <= 0:day = 1

if week > 7:
	:loopweek
	week -= 7
	husbandrink = 0

	if military = 1:military = 0

	if week > 7:jump 'loopweek'
end

if week = 1:$week = 'Monday'
if week = 2:$week = 'Tuesday'
if week = 3:$week = 'Wednesday'
if week = 4:$week = 'Thursday'
if week = 5:$week = 'Friday'
if week = 6:$week = 'Saturday'
if week = 7:$week = 'Sunday'

$holyday = ''
kanikuli = 0

if (month = 10 and day >= 27) or (month = 11 and day <= 4):
	$holyday = '<b>Autumn holidays</b>'
	kanikuli = 1
	if month = 11 and day = 4:$holyday += ' <b>Back to school tomorrow.</b>'
elseif (month = 12 and day >= 29) or (month = 1 and day <= 13):
	$holyday = '<b>Winter Break</b>'
	kanikuli = 2
	if month = 1 and day = 13:$holyday += ' <b>Back to school tomorrow.</b>'
elseif (month = 3 and day >= 25):
	$holyday = '<b>Spring Break</b>'
	kanikuli = 3
	if month = 3 and day = 31:$holyday += ' <b>Back to school tomorrow.</b>'
elseif (month = 5 and day >= 25) or month = 6 or month = 7 or month = 8:
	if month = 5 and day = 25 and age = 17:
		$holyday = '<b>Your graduation is today. Be there by 8h.</b>'
		kanikuli = 6
	else
		$holyday = '<b>Summer holidays</b>'
		kanikuli = 4
	end
	if month = 8 and day = 31:$holyday += ' <b>Back to school tomorrow.</b>'
elseif month = 1 and day = 1:
	$holyday = '<b>New Year!</b>'
	kanikuli = 5
end

if kanikuli ! 6 and kanikuli > 0 and kanicont = 0:
!holiday countdown by illume. countdown in [cikl], summer vacation pre-set in [startalt]
    if kanikuli = 1:kanicont = 9
    if kanikuli = 2:kanicont = 16
	if kanikuli = 3:kanicont = 7
	if kanikuli = 4:kanicont = 99
end

if kanikuli > 0 and kanikuli <5:$holyday += ', <<kanicont>> days left.</b>'

if hour >= 8 and hour < 16 and week < 6 and StoryLine > 0 and SchoolAtestat = 0 and kanikuli = 0 and schoolProgulDay ! daystart:
	!!absence from school
	schoolprogul += 1
	schoolProgulDay = daystart
end
--- cikl ---------------------------------

