# gLake
CLOSE ALL
$metka = $ARGS[0]
$loc = $CURLOC
$metkaM = $ARGS[0]
$locM = $CURLOC
cls
gs'stat'
gs 'outdoors'
'<center><H4>Lake</H4></center>'
if tanga = 0:
	tangamemb = 0
else
	tangamemb = 1
end
! to memorize were cowards or not
if month>=3 and month<=5:
	if hour>=6 and hour<=17:
		'<center><img src="images/nigma/gor/Lake/lake.spring.jpg"></center>'
	else
		'<center><img src="images/nigma/gor/Lake/lake.spring.night.jpg"></center>'
	end
	'<center>A small lake, located not far from Pavlovsk. You''re not sure whether Pavlovsk was built near the lake on purpose or not.</center>'
	''
end
if month>=6 and month<=8:
	if hour>=6 and hour<=19:
		'<center><img src="images/nigma/gor/Lake/lake.summer.jpg"></center>'
	else
		'<center><img src="images/nigma/gor/Lake/lake.summer.night.jpg"></center>'
	end
	'<center>A small lake, located not far from Pavlovsk. You''re not sure whether Pavlovsk was built near the lake on purpose or not.</center>'
	''
end
if month>=9 and month<=11:
	if hour>=6 and hour<=18:
		'<center><img src="images/nigma/gor/Lake/lake.autumn.jpg"></center>'
	else
		'<center><img src="images/nigma/gor/Lake/lake.autumn.night.jpg"></center>'
	end
	'<center>A small lake, located not far from Pavlovsk. You''re not sure whether Pavlovsk was built near the lake on purpose or not.</center>'
	''
end
if month=1 or month=2 or month=12:
	if hour>=7 and hour<=16:
		'<center><img src="images/nigma/gor/Lake/lake.winter.jpg"></center>'
	'<center>A small lake, located not far from Pavlovsk. You''re not sure whether Pavlovsk was built near the lake on purpose or not.</center>'
	else
		'<center><img src="images/nigma/gor/Lake/lake.winter.night.jpg"></center>'
	'<center>A small lake, located not far from Pavlovsk. You''re not sure whether Pavlovsk was built near the lake on purpose or not.</center>'
	end
	'<center>Ever since winter arrived, the lake in Pavlovsk has been frozen over. The lake is being used as a skating rink and lots of people go to skate there every day; if you have skates you could join them.</center>'
	''
	if konki_stat>0: 'Your ice-skating skill is <<konki_stat>>.'
end

act 'Use changing room':gt 'changingroom', 'view_swim_list'

if $clothingworntype = 'nude': 

	act'Put your clothes back on':
		cla
		minut+=5
		gs 'clothing', 'wear_last_worn'
		if $clothingworntype = 'nude':
			if storyline = 1:
				minut += 30
				manna -= 5
				willpower -= 5
				'You return to the place where you thought you put your clothes to get dressed... except you can''t find them. Oh crap, you can''t find them! You desperately search the beach for a while, while a few passers-by look amused at the naked girl running around the beach. When you can''t find them, you panic and run all the way home... hopefully they''ll turn up.'
				gt 'korrPar'
			else
				'You return to the place where you thought you put your clothes to get dressed... except you can''t find them. Oh crap, you can''t find them! You desperately search the beach for a while, while a few passers-by look amused at the naked girl running around the beach. Eventually a man approaches you. You can tell his eyes are darting over your body as he asks: "Is there a problem, sweetheart? You seem upset..."'
				if bag = 1:
					'Luckily, your bag is sitting right where you left it.'
				else
					money = 0
				end
				'You''re seriously panicking now, and with tears in your eyes you blurt out: "I can''t find my clothes! I left them right here and now they''re gone! I don''t know what to do!"'
				'He tries to put you at ease: "Don''t worry girl, you''re going to be fine. Come on, I happen to have some sportswear in my car."'
				'You dry your tears, profusely thanking him while he guides you to his car. He was not lying, he pulls out a set of sportswear that looks brand new. He doesn''t hand them over though, and says with a serious look: "Of course I can''t just give these away... they''re brand new. These cost me 3000 <b>₽</b>, if you can give me that they''re all yours."'
				if money >= 3000:
					act 'Pay 3,000 <b>₽</b>':
						money -= 3000
						exercise[1] = 1
						if exerciseH[1] > 40:exerciseH[1] = 40
						gs 'clothing', 'wear', 'exercise', 1
						'So... there''s the catch. The guy looks at your naked body while you mull over his proposition, and you come to the conclusion that you really don''t have any other choice. You can''t walk home through town naked! You silently nod and give him the money, quickly putting the clothes on when he hands them over. You feel relieved in the knowledge that at least you won''t have to go home naked... hopefully your clothes will turn up later.'
						gt 'glake'
					end
				end
				act 'Suggest alternative payment':
					'3000 <b>₽</b>... you know it''s a fair price for him to ask, but you don''t want to pay 3000 <b>₽</b> right now! This is not how you planned for your day to go. Too afraid to look him in the eye when you ask, you suggest: "Is there... is there some other way I can pay you? 3000 <b>₽</b> is a lot of money."'
					'He''s been gawking at your naked body the whole time you''ve been talking, and your suggestion seems to be exactly what he wanted to hear. He grins: "I can think of one way..."'
					'The growing bulge in his pants does an excellent job of telling exactly what he''s thinking.'
					act 'Agree to have sex':
						cla
						cls
						sex += 1
						horny += 20
						exercise[1] = 1
						if exerciseH[1] > 40:exerciseH[1] = 40
						gs 'clothing', 'wear', 'exercise', 1
						'<center><img src="images/Prost/sexcar.jpg"></center>'
						'He wastes no time for you to second guess yourself, and immediately throws you down on the back seat of his car when you agree. He quickly pulls down his pants and, after quickly putting a condom on, quickly guides his cock to your pussy lips. He obviously doesn''t plan on spending a lot of time with you and sinks it in in one firm thrust, fucking you with rapid, short strokes. Soon he shoots his load in the condom, ties a knot in it and throws it away. Seconds after he hands you the clothes as promised, he drives off.'
						'It was not the most pleasurable sex for you, but you convince yourself it was for a good cause when you put your well-earned clothes on. He used a condom too, without you even having to ask. You don''t have to go home naked now! With a sigh of relief you straighten the clothes and feel ready to take the day on again, hoping your own clothes will turn up at some point.'
						act 'Continue': gt 'glake'
					end
					if money >= 3000:
						act 'Pay 3,000 <b>₽</b>':
							money -= 3000
							exercise[1] = 1
							if exerciseH[1] > 40:exerciseH[1] = 40
							gs 'clothing', 'wear', 'exercise', 1
							'You don''t want to have sex with him... but you also don''t want to go home naked! Not seeing any other option, you decide to pay him the 3,000 <b>₽</b> after all. You quickly put on the clothes as he hands them over, feeling relieved in the knowledge that at least you don''t have to walk through town in the nude. Now that you''re clothed, you feel more confident in searching the beach a bit more; hopefully your clothes will turn up after all.'
							act 'Continue': gt 'glake'
						end
					end
				end
			end
		else
			if tangamemb = 1: tanga = 1
			'You return to the place where you left your clothes, and put them back on.'
			act'Continue':gt'glake'
		end
	end
end

if temper >= 20 and month>=5 and month<=9 and hour>=6 and hour<=20:
	act 'Take a walk along the beach (1:00)':
		cls
		minut += 60
		willpower += 5
		manna += 5
		gs'stat'
		gs 'outdoors'
		
		if $clothingworntype = 'swimwear' and bedra<=90:
			'<center><img src="images/nigma/gor/Lake/lake.walk.bikini0,'+rand(0,3)+'.JPG"></center>'
		elseif $clothingworntype = 'swimwear' and bedra >= 90 and bedra<=110:
			'<center><img src="images/nigma/gor/Lake/lake.walk.bikini.fat0,0.JPG"></center>'
		elseif $clothingworntype = 'swimwear' and bedra>=110:
			'<center><img src="images/nigma/gor/Lake/lake.walk.bikini.fat0,1.JPG"></center>'
		elseif $clothingworntype = 'nude':
			'<center><img src="images/lmps/qesvft7.jpg"></center>'
		else
			'<center><img src="images/nigma/gor/Lake/lake.walk0,'+rand(0,2)+'.JPG"></center>'
		end

		'You walk along the beach for an hour, enjoying the feeling of the sun on your body.'
		act 'Continue':gt'glake'

	end

	if $clothingworntype ! 'nude' and (exhibi > 0 or modelfoto > 0 or film > 0 or stripdance > 0 or stripdancesum > 0):
		act'Strip naked':
			cla
			minut += 5
			tanga = 0
			gs 'clothing', 'strip'
			'Without hesitation, you take off all your clothes and neatly fold them before putting them down on a pile. Without your clothes holding you back, you can go for a nice swim in the lake or just lie down in the sand and do some sunbathing.'
    
			act'Continue':gt'glake'
		end
	end

	
	if $clothingworntype = 'swimwear' or $clothingworntype = 'nude':
		act 'Go swim in the lake (1:00)':
			cla
			*clr
			cumspclnt = 4
			gs 'cum_cleanup'
			minut = minut + 60
			sweat -= 3
			manna = manna + 5
			willpower = willpower + 5
			if stren < 30:stren = stren + 1

			if $clothingworntype = 'nude':
				'<center><img src="images/pics/swimnude.jpg"></center>'
			else 
				'<center><img src="images/pics/swim.jpg"></center>' 
			end
			'You swim and play in the lake, feeling refreshed and invigorated by the clean lake water.'
			if $clothingworntype = 'nude':willpower -= 5 & manna -= 5 & 'After a few minutes, you feel the piercing gaze of several nearby women on you. They''re making an effort of whispering to one another, yet loud enough so you can hear them: "Look at that <<$surname>> slut! She has no decency whatsoever, shamelessly flaunting her naked body like that!" The men at the lake are much more appreciative, and openly stare at your attractive body. You can see bulges forming in the shorts of some of them.'

			act 'Get out of the water':gt'glake'
		end
		if sunWeather = 1:
			act 'Go sunbathing (1:00)':

				if $clothingworntype = 'nude':
					cla
					*clr
					willpower -= 5
					manna -= 5 
					'<center><img src="images/lmps/dogcaine.jpg"></center>'
					'As you lie down on your towel to catch some rays of sun and hopefully work on your tan a little, a stray dog appears out of nowhere. It keeps sniffing between your legs, which makes you feel very uncomfortable since you''re not wearing anything. You spend most of the hour trying to chase the dog away, but it comes back every time you think you got rid of it. You don''t get much sunbathing done as a result.'
					act 'Give up on sunbathing':gt'glake'

				else
					cla
					*clr
					minut = minut + 60
					sweat = sweat + 1
					manna = manna + 5
					gs'stat'
					gs 'outdoors'
					'<center><img src="images/pics/zagar.jpg"></center>'

					if krem = 0:
						tan = tan + 1
						'You lie down on your towel for some sunbathing and hopefully a nicer tan, and enjoy the warm rays of the sun for an hour.'
					elseif krem > 0:
						krem = krem - 1
						tan = tan + 3
						'You smear your body with sunscreen and lie down on your towel for some sunbathing, hoping to work on your tan. You enjoy the warm rays of the sun for an hour.'
					end

					gs'LakeBoyDy'
					if vnesh >= rand(1,400):
						tipelakeboyrand = rand(1,100)
						if tipelakeboyrand <= 5:
							if belgangQW > 0:
								'While you are sunbathing, you see Vadim Bely and his brother sitting not far away from you. The brother points at you, and moments later Vadim walks over to you and sits down next to you. He idly scratches his tattoo covered belly as he asks: "Hello <<$name>>, want to go for a ride with me?"'
								'The greedy look in his eyes tells you that when he says ''ride'', he doesn''t just mean in his car.'
								dynamic $LBD_ride
								dynamic $LBD_go
							end
							if belgangQW = 0:
								'While you are sunbathing you can''t help but notice a man walking towards you. He looks truly intimidating, his entire body covered in criminal gang tattoos. A bit further down the beach you see a younger man with similar tattoos, keeping an eye on the man approaching you.'
								'His head is mostly bald, and a large golden cross dangles on a thick chain from his neck. He sits his fat body down next to you before you can protest, idly scratching his belly as he begins to chat: "Hello! I''m not interrupting anything, am I?"'
								act'Be outraged':
									cls
									minut += 5
									gs'stat'
									'You were here first! You''re outraged by the way he just plants himself down next to you and exclaim: "Erm, excuse me!? I was here first!"'
									'The man is not impressed in the slightest, obviously having played this game before. He immediately challenges your claim: "Oh, excuse me princess! Is this your spot? Do you own it?"'
										
									act'Yes you do!':
										cls
										minut += 5
										gs'stat'
										'You respond indignantly: "Yes, this is my spot! I was here first, that''s how it works!"'
										'Suddenly you hear a deep voice behind you: "This beach is only used by prostitutes and bus drivers, and I don''t see a fucking bus."'
										'Damn, that voice startled you. You look behind you and you see the tattooed younger man behind you. He has tattoos over his whole body as well, most notably several tombs and skulls on his chest. He stares you down with a stone cold look on his face.'
										'The bald man smiles and puts his hand on your chest as if he owns it, roughly squeezing you tit through your swimsuit.'
										'"So... how much?"'
										dynamic $LBD_go

										dynamic $LBD_hand

									end
									dynamic $LBD_go
								end
		 
								act'Try to ignore them':
									cls
									minut+=5
									gs'stat'
									'Those guys look intimidating. You don''t want any trouble and just pretend they''re not there, laying on the beach with your eyes closed. However, a few moments later you feel a strange tickling on your stomach. You open your eyes to see what''s causing it, and you see the fat man running a blade of grass over your stomach with a smug grin on his face. Looks like you can''t ignore them any longer.'
									dynamic $LBD_go
									dynamic $LBD_hand

									act'Try to keep ignoring them':
										cls
										minut+=5
										gs'stat'
										'You try to ignore them anyway, closing your eyes again. You feel the blade of grass continuously teasing your body, and after a few minutes his sweaty hand is pawing at your breasts through your swimsuit.'
										'He whispers in your ear: "Come with me baby, I''ll make you feel good. You won''t regret it". His groping becomes more insistent and he''s roughly pinching your nipples now, and the outline of them slowly but surely becomes visible through your swimsuit.'
										dynamic $LBD_hand
										dynamic $LBD_ride
									end
								end

								dynamic $LBD_go
							end
							exit
						elseif tipelakeboyrand <= 30:
							gs'BnameGen'
							'While you are sunbathing, three guys sit down near you. While you notice them looking at you and talking about you, they don''t come over.'
								
							act 'Continue':gt'glake'
							exit
						elseif tipelakeboyrand <= 80:
							gs'BnameGen'
							gs'LakeBoyZ'
							'While you are sunbathing, a guy sits down next to you. He''s kind of cute, actually.'
							'He tries to chat you up: "Hey there beautiful, I''m <<$bname>>. What''s your name?"'
			
							act 'Get away from him':gt'glake'
							dynamic $gL_boy_z
							exit

						else
							'While you are sunbathing, three guys sit down near you. While you notice them looking at you and talking about your body, they don''t come over.'
							act 'Get away from them':gt'glake'
							exit
						end
					else
						cla
						act'Stop sunbathing':gt'glake'
					end
				end
			end
		end
	end
end	

act'Go to the secluded beach':gt'gLakeNude'

!winter
if month = 12 or month = 1 or month = 2:
	if konki_cloth = 1:
		act'Take off your skates':
			cla
			*clr
			minut+=10
			konki_cloth=0
			'<center><img src="images/nigma/gor/Lake/Katok/konki0,1.jpg"></center>'
			'You take off your skates and put your shoes back on. For a while it feels kinda weird to walk, after you got used to skating.'
			act'Continue':gt'glake'
		end
	end
	if hour >= 8 and hour <= 17:
		if konki > 0 and konki_cloth ! 1:
			act'Put your skates on':
				cla
				*clr
				minut += 5
				konki_cloth = 1
				'<center><img src="images/nigma/gor/Lake/Katok/konki0,0.jpg"></center>'
				'You take off your shoes, and put your skates on. Now you''re ready to go ice skating.'
				act'Done':gt'glake'
			end
		end
		if konki_cloth = 1:
			act'Skate on the ice rink': dynamic $katok_base
		end
	end
end

$katok_base = {
	cla
	*clr
	minut += 3
	gs'stat'
	'<center><img src="images/nigma/gor/Lake/Katok/katok0,'+rand(0,3)+'.jpg"></center>'
	'You slowly make your way over to the ice rink, where a lot of people are already skating. Some people are really good at skating and basically fly around the lake on their skates, while others carefully shuffle around, doing their best to just stay on their skates without falling.'
	act'Skate on the rink':dynamic $katok_start
	act'Leave the rink':gt'glake'
}

$katok_start = {
	cla
	*clr
	willpower += 5
	fat -= 1
	sweat += 1
	if speed < 100:speed += 1
	if agil < 70:agil += 1
	if react < 70:react += 1
	konki_stat += 1
	minut += 30
	gs'stat'
	'<center><img src="images/nigma/gor/Lake/Katok/katok_do0,'+rand(0,7)+'.jpg"></center>'
	if konki_stat <= 10:
		manna -= 10
		'You do your best to ride your skates, but you''re not very good at it. You fall flat on your ass several times, and your butt is starting to feel a bit sore.'
		'Some of the friendlier skaters are cheering you on and try to give you some tips, while others just laugh when you fall down on your ass yet again.'
	elseif konki_stat <= 30:
		manna -= 5
		'Your persistent attempts to learn how to skate are starting to pay off. You don''t fall as often any more, even though it still happens on occasion. Ice skating is a lot more fun when you''re not falling flat on your ass all the time!'
		if rand(1,3) = 1:
			konki_stat += 1
			'While you''re trying some new things, you suddenly figure out how to do a certain move properly. It definitely improves your skating skills.'
		end
	elseif konki_stat <= 50: 
		manna+=5
		'At long last, you finally manage to skate for a full 100 meters without falling. It''s definitely going a lot better. Some of the other regulars who have seen you struggle before notice how much better you''re doing, and congratulate you on your progress.'
		'You become a bit more daring as you continue to ride, almost never falling any more.'
		if rand(1,3)=1: 
			konki_stat+=2
			'You fall down, just this once. One of the more experienced skaters notices, and helps you up. Once you''re up on your skates again, he explains what you did wrong. His explanation will go a long way in you not making the same mistake again, and you feel like you''re a better skater for it. You thank him as you skate off, trying to apply the trick he just taught you.'
		end
	elseif konki_stat<=70:
		manna+=10
		'You''re getting better and better at ice skating. You basically never fall any more, and enjoy the flow of the wind on your face as you dare to go faster and faster.'
		if rand(1,3)=1: 
			konki_stat+=3
			'As you ride you watch the more experienced skaters, trying to pick up new tricks. You try to copy some of the things they are doing, and notice that those moves are indeed more efficient than how you were doing it before.'
		end
	else
		manna+=15
		'You''ve pretty much mastered ice skating now, and won''t get any better without professional training. Occasionally you do some tricks while you skate around the rink, and others admire your skills as you fly past them.'
	end
	
	if hour <= 17:
		act'Skate some more':dynamic $katok_start
		act'Leave the rink':gt'glake'
	else
		cla
		*clr
		'<center><img src="images/nigma/gor/Lake/Katok/katok0,'+rand(0,3)+'.jpg"></center>'
		'It''s too dark to go ice skating now, and the rink is closed.'
		act'Escape':gt'glake'
	end
}

act'Return to Pavlovsk':
	if konki_cloth = 1:
		cla
		'You need to remove your skates. How are you going to walk on the streets in those?'
		act'Back':gt'glake'
	elseif $clothingworntype = 'swimwear':
		cla
		'You need to get dressed in regular clothing first.'
		act'Return':gt'glake'
	elseif $clothingworntype ! 'nude':
		gt'pavResidential'
	else
		cla
		'You need to wear some clothes. It''s not decent to walk the streets naked.'
		act'Return':gt'glake'
	end
end

--- gLake ---------------------------------

