glife/locations/city_coffee_hole.qsrc

# city_coffee_hole

!!Joanna - owner, model = Joanna Angel
!!Klara - worker, model = Kleio Valentien

$location_type = 'public_indoors'

if $args[0]= 'start':
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'start'
	menu_off = 0
	'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/coffee_hole/street_sign.jpg"></center>'
	'Along the street is a sign advertising a cafe called the "Coffee Hole". Following the direction of the sign, you find the door to the cafe in a little nook between two buildings. It would have been hard to see from the street without the sign. Opening hours are 07:00 to 23:00.'
	act 'Return to the city': gt 'city_island'
	if hour >= 7 and hour < 23: act 'Enter the cafe': gt 'city_coffee_hole', 'inner'
end

if $args[0]= 'inner':
	$loc = 'city_coffee_hole'
	$loc_arg = 'inner'
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'inner'
	menu_off = 0
	gs 'katja_meynold_schedule'
	!!gs 'albina_uni_schedule'
	!!gs 'anushka_schedule'
	gs 'stat'
	'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/coffee_hole/inside.jpg"></center>'
	'The cafe looks like it was once some type of industrial building, with tall ceilings, exposed pipes, ductwork and lights. The counter is in the far corner, while the middle of the room contains several tables and chairs. Along the wall opposite the counter is an area with several couches for people to sit and relax. The menu board shows a wide range of flavoured coffees, teas, espressos and pastries, among other things.'
	if yearstart >= 2 and (((week = 2 or week = 4 or week = 7) and hour >= 18) or (week = 5 and hour >= 10 and hour < 16)):
		locat['A144'] = 9
		'You see a familiar face working behind the counter, your former classmate <a href="exec:gt ''city_coffee_hole'', ''anushka_work''">Anushka.</a>'
	end
	if locat['katja'] = 30 and (katjaQW['know_going_to_teaching_degree'] = 1 or mid($start_type,1,2) = 'sg'):
		'You see your classmate <a href="exec:gt ''katja_chat'', ''coffee_hole''">Katja</a> sitting at a table with a pile of books, a cup of coffee and a plate of food.'
	end
	!!if locat['albina'] = 17 and AlbinaQW['know_albina_uni'] > 0 or mid($start_type,1,2) = 'sg'):
		!!'You see <a href="exec:gt ''albina_uni'', ''coffee_hole''">Albina</a> sitting at a table with a woman who has her back turned to you.'
	!!end
	if mid($start_type,1,2) = 'sg' and yearstart >= 2 and day = 2 and nerd_game['fixed_uni_day'] = 0 and hour >= 18:
		'You see some familiar faces sitting in one of the corners. Some of the <a href="exec:gt ''nerd_game_night'', ''crash_gamenight_uni''">nerds</a> you went to school with back in Pavlovsk are gathered around a table. It looks like they''re playing some sort of game.'
	end

	if nerd_game['game_day'] = daystart and hour = 18: act '<b>Join nerds</b>': gt 'nerd_game_night','game'
	if week < 6 and hour >= 17:
		temprand = rand(1,10)
		if mid($start_type,1,2) = 'sg' and yearstart = 2:
			if temprand = 1:
				'You see a familiar face sitting at one of the tables, your classmate <a href="exec:gt ''city_coffee_hole'',''lazar''">Lazar.</a>'
			elseif temprand = 2:
				'You see a familiar face sitting at one of the tables, your classmate <a href="exec:gt ''city_coffee_hole'',''dimka''">Dimka.</a>'
			elseif temprand = 3:
				'You see a familiar face sitting at one of the tables, your classmate <a href="exec:gt ''city_coffee_hole'',''marcus''">Marcus.</a>'
			end
		end
		if temprand = 4:
			if meet_kendra = 1:
				'You see a familiar face sitting at one of the tables, <a href="exec:gt ''city_coffee_hole'',''kendra''">Kendra.</a>'
			elseif kendraslave >= 1:
				'You see a familiar face sitting at one of the tables, your mistress <a href="exec:gt ''city_coffee_hole'',''kendra''">Kendra.</a>'
			elseif hotcat >= 5:
				'As you look around, you see a beautiful young <a href="exec:gt ''city_coffee_hole'',''kendra''">black woman</a> sitting at one of the tables. She notices you and gives you a quick once-over before smiling and leaning back. She seems to be watching you with an inviting smile to join her.'
			else
				'As you look around, you see a beautiful young black woman sitting at one of the tables. She notices you and gives you a quick once-over before returning to what she was doing. After a few minutes, she finishes her drink before getting up and leaving.'
			end
		elseif temprand = 5:
			if DjibrilQW['meet'] = 1:
				'You see a familiar face sitting at one of the tables, Olu''s nephew <a href="exec:gt ''city_coffee_hole'',''djibril''">Djibril.</a>'
			elseif hotcat >= 5:
				'As you look around, you see an attractive young <a href="exec:gt ''city_coffee_hole'',''djibril''">black man</a> sitting at one of the tables. When he notices you looking at him, he gives you a friendly smile and a wave. It seems he is the friendly sort and seems to be interested in you.'
			else
				'As you look around, you see an attractive young black man sitting at one of the tables. He notices you and gives you a quick once-over before returning to what he is doing. After a few minutes, he finishes his drink before getting up and leaving.'
			end
		else 
			'As you look around, you don''t see anyone you recognize hanging out today.'
		end
	end
	act 'Exit the cafe': gt 'city_island'
	if hour >= 7 and hour < 23:
		act 'Go up to the counter to order': gt 'city_coffee_hole', 'counter'
		act 'Go to restroom': gt 'city_coffee_hole', 'toilet'
	end
end

if $ARGS[0] = 'eat':
	!!set return to skip to post komp if you use computer
	$loc = 'city_coffee_hole'
	$loc_arg = 'post_komp'
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'eat'
	!! Sending the player to Katja''s table if she is sitting with Katja.
	if katjaQW['brunch_bought'] = 1:
		katjaQW['brunch_bought'] = 0
		gt 'katja_chat', 'coffee_hole_event'
	end
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/shared/date/cafequiet.jpg"></center>'
	if coffe_hole_ordered = 1:
		minut += 10
		mood += 5
		gs 'stat'
		'You take your order from the counter and find an empty table. You quietly enjoy the ambience of the place and feel your mood brightening as you look around.'
	else
		gs 'stat'
		'You''re sitting at a table in the cafe. It''s nice here.'
	end
	act 'Exit the cafe': gt 'city_island'
	act 'Get up from table': gt 'city_coffee_hole', 'inner'
	if komp = 1:
		act 'Open your laptop':
			gs 'internet_mobile', 'get_access', 'free', 'noporn', 'nocamshow'
			gt 'Komp','start'
		end
	end
end

if $ARGS[0] = 'post_komp':
	*clr & cla
	mood += 2
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/shared/date/cafequiet.jpg"></center>'
	'You''re sitting at a table in the coffee shop. You could use your laptop if you wanted, but should buy something to eat or drink first.'
	act 'Get up from table': gt 'city_coffee_hole', 'inner'
end

if $ARGS[0] = 'toilet':
	$locM = 'city_coffee_hole'
	$locM_arg = 'toilet'
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'toilet'
	*clr & cla
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/island/coffee_hole/restroom.jpg"></center>'
	'The first thing you notice about the restroom is there seems to be only one, and it''s co-ed. The walls are covered in what you can only describe as graffiti art, but it''s otherwise nice and clean. Several stalls are along one wall, and a row of sinks with mirrors line the other.'
	dynamic $tampon
    dynamic $quickwash
    dynamic $basin
    dynamic $publicpan
	act 'Exit restroom': gt 'city_coffee_hole', 'inner'
end

if $args[0]= 'counter':
	*clr & cla
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'counter'
	menu_off = 0
	minut += 5
	gs 'stat'
	if mid($start_type,1,2) = 'sg' and yearstart >= 2 and (((week = 2 or week = 4 or week = 7) and hour >= 18) or (week = 5 and hour >= 10 and hour < 16)):
			gt 'city_coffee_hole','anushka_work'
	else 
		temprand = rand(1,2)
		if temprand = 1:
			'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
			'<center><img <<$set_imgh>> src="images/locations/city/island/coffee_hole/npcs/worker1.jpg"></center>'
			'As you approach, the woman behind the counter looks up at you. She appears to be in her late twenties or maybe early thirties. She has dark hair with purple streaks, and her arms are covered in tattoos. "Welcome to the Coffee Hole. What can I get you?" she asks in a friendly and welcoming tone. You notice she has a familiar accent; it reminds you a little bit of Marcus'' accent.'
			act 'Exit the cafe': gt 'city_island'
			act 'Leave counter': gt 'city_coffee_hole', 'inner'
			act 'Order from the menu (0:05)':gs 'food_menu'
		else
			'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
			'<center><img <<$set_imgh>> src="images/locations/city/island/coffee_hole/npcs/worker2.jpg"></center>'
			'As you approach, the girl behind the counter looks up at you. She appears to be in her late teens or early twenties. She has short blond hair with one side shaved, her arms are covered in tattoos, and she has a large tattoo on her chest. "Welcome to the Coffee Hole. What can I get you?" she asks in a bored and monotone voice.'
			act 'Exit the cafe': gt 'city_island'
			act 'Leave counter': gt 'city_coffee_hole', 'inner'
			act 'Order from the menu (0:05)': gs 'food_menu'
		end
	end
end

if $args[0]= 'anushka_work':
	*clr & cla
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'anushka_work'
	menu_off = 0
	minut += 5
	gs 'npc_relationship', 'modify', 'A144', 'like', 1, 'coffee_hole'
	gs 'stat'
	'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/coffee_hole/npcs/nush_counter.jpg"></center>'
	if anushkaQW['coffee_hole'] = 1:
		if npc_rel['A144'] >= 60:
			'As you approach the counter, you see your classmate Anushka working again. When she sees you, she gives you a friendly smile. "Welcome to the Coffee Hole. Need your holes filled with something hot and black again?" she says with a wink, even making ordering coffee sound dirty.'
			'You smile at her. "You are so bad."'
			if anushkaCityQW['first_visit'] = 0:
				'<br />'
				'"Like you. You didn''t even visit me yet!"'
			end
			if anushkaQW['photoshoot'] >= 1 and hour = 22:
				'She shrugs a little. "And you love it. It''s why you love hanging out with me." You chat about the university and her job. After talking for a bit, you notice that it''s close to closing, and the place is almost empty. Maybe she would be up for a little after-hours photo shoot for you?'
				act 'Let''s do a photo shoot':
					*clr & cla
					'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
					'<center><img <<$set_imgh>> src="images/locations/city/island/coffee_hole/npcs/nush_counter.jpg"></center>'
					'You grin at her. "We should totally do a photo shoot here."'
					'She gives you a slightly surprised look. "What? Now?"'
					'You find her reaction amusing. "Well, we could, but I was thinking after you closed up. So what do you say?"'
					'She bites her lower lip for a moment. "Fuck, okay, why not? Just hang around until I close up."'
					act 'Wait': gt 'city_coffee_hole', 'photo_shoot'
				end
			else
				'She shrugs a little. "And you love it. It''s why you love hanging out with me." You chat about the university and her job before you notice the line forming behind you. You start looking at the menu on the wall to see if you want to order something.'
			end
		elseif npc_rel['A144'] <= 20:
			'As you approach the counter, you see your classmate Anushka working again. When she sees you, she sighs, and you think she rolls her eyes. "Welcome to the Coffee Hole. What can I get you?"'
			'You smile at her. "So, do you like the job?"'
			'She doesn''t return your smile. "It''s a job. Do you want something or not? I''ve got work to do and can''t stand around chatting." You sigh. It seems she still doesn''t like you. You look up at the menu on the wall to see if you might want to order something.'
		else
			'As you approach the counter, you see your classmate Anushka working behind it. When she sees you, she gives you a friendly smile. "Welcome to the Coffee Hole. What can I get you?"'
			'You smile at her. "So you like working here?"'
			'She shrugs a little. "Yeah, it''s alright. As I said, it''s pretty easy, close to my place, and I can study when it''s slow. Plus, the owner, Joanna, is pretty cool and chill about what I do at work. As long as I don''t leave a mess or ignore customers, she doesn''t really care what I do." You chat about the university and her job when you notice the line forming behind you. You start looking at the menu on the wall to see if you want to order something.'
		end
	else
		anushkaQW['coffee_hole'] = 1
		if npc_rel['A144'] >= 60:
			'As you approach the counter, you see your classmate Anushka working behind it. When she sees you, she gives you a friendly smile. "Welcome to the Coffee Hole, where we can fill your holes with something hot and black, but maybe not in the way you would like..." she says with a wink, even making ordering coffee sound dirty.'
			'You smile at her. "Oh my god, you''re terrible. I didn''t know you worked here."'
			'She shrugs. "I need some extra money coming in to help pay for stuff. This is pretty easy, close to my place, and I can study when it''s slow." You chat about the university before you notice the line forming behind you. You start looking at the menu on the wall to see if you want to order something.'
			! Set her apartment to available
			anushkaCityQW['first_visit'] = 1
			'<br />'
			'"Ah, and before I forget, I live in a shared apartment, just around the corner. Maybe you can visit me some time?"'
			'Your smile grows. "That is great! I''m sure I won''t forget."'
		elseif npc_rel['A144'] <= 20:
			'As you approach the counter, you see your classmate Anushka working behind it. When she sees you, she sighs, and you think she rolls her eyes. "Welcome to the Coffee Hole. What can I get you?"'
			'You smile at her. "I didn''t know you worked here."'
			'She doesn''t return your smile. "Well, now you do, so do you want something or not? I''ve got work to do and can''t stand around chatting." You sigh. It seems she still doesn''t like you. You look up at the menu on the wall to see if you might want to order something.'
		else
			'As you approach the counter, you see your classmate Anushka working behind it. When she sees you, she gives you a friendly smile. "Welcome to the Coffee Hole. What can I get you?"'
			'You smile at her. "I didn''t know you worked here."'
			'She shrugs. "I need some extra money coming in to help pay for stuff. This is pretty easy, close to my place, and I can study when it''s slow." You chat about the university before you notice the line forming behind you. You start looking at the menu on the wall to see if you want to order something.'
		end
	end
	act 'Exit the cafe': gt 'city_island'
	act 'Leave counter': gt 'city_coffee_hole', 'inner'
	act 'Order from the menu (0:05)': gs 'food_menu'
end

if $ARGS[0] = 'photo_shoot':
	*clr & cla
	anushkaQW['photoshoot'] += 1
	minut += 65 - minut
	gs 'exp_gain', 'photoskl', rand(1,2)
	gs 'npc_relationship', 'modify', 'A144', 'like', 1, 'coffee_hole_photo'
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/anushka/nush_model/sveta_photographer/coffee_hole/pose1.jpg"></center>'
	'Once the last of the customers are gone, Anushka locks the doors before you pull your camera out and have her stand in front of the counter. You start snapping photos of her standing in different poses as you direct her, asking her to hold various items for you as you snap pictures.'
	act 'Spice this up':
		minut += 5
		*clr & cla
		gs 'exp_gain', 'photoskl', rand(1,2)
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/anushka/nush_model/sveta_photographer/coffee_hole/pose2.jpg"></center>'
		'You want more, and you know she loves showing off. "Come on, famous model, let''s do something a little more risque!" Anushka reaches up and pulls down her top enough to expose her bra underneath as she poses while holding a coffee pot in her other hand.'
		gs 'arousal', 'voyeur', 5
		gs 'stat'
		act 'Let''s see that butt':
			minut += 5
			*clr & cla
			gs 'exp_gain', 'photoskl', rand(1,2)
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/anushka/nush_model/sveta_photographer/coffee_hole/pose3.jpg"></center>'
			'"Let''s see that tight little butt you love getting fucked in." She turns around to show off her butt covered in tight little booty shorts. "Okay, lose the bra now," you tell her. She takes off her bra and pulls down her shirt while still keeping her ass pointed towards you. "Okay, turn around, so we can see those firm little titties of yours."'
			act 'She turns':
				minut += 5
				*clr & cla
				gs 'exp_gain', 'photoskl', rand(1,2)
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/anushka/nush_model/sveta_photographer/coffee_hole/pose4.jpg"></center>'
				'She turns around, her top around her waist, and pulls her apron aside so you get a view of her firm little breasts. You snap a few more photos. "Lose the apron."' 
				'She tosses it aside, and you take a few more snaps of her. "Now the top." She pulls off the top and throws it on a nearby table. "Now the shorts."'
				act 'Keep taking photos':
					*clr & cla
					gs 'exp_gain', 'photoskl', rand(1,2)
					'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/anushka/nush_model/sveta_photographer/coffee_hole/pose5.jpg"></center>'
					'She slips her shorts off and kicks them at you, forcing you to duck to avoid being hit in the face by them. You snap a few more photos while she hooks her thumbs into her panties to pull them this way and that, teasing you by almost showing off her pussy at times but stopping just short. "That''s it, work the camera for me, Nush!"'
					gs 'arousal', 'voyeur', 5
					gs 'stat'
					act 'Stop teasing':
						*clr & cla
						gs 'exp_gain', 'photoskl', rand(1,2)
						'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/anushka/nush_model/sveta_photographer/coffee_hole/pose6.jpg"></center>'
						'She finally stops teasing and pulls her panties down just enough to give you glimpses of her pussy, until she finally pulls them about mid-way down her thighs, providing a much clearer view of her clean-shaven pussy. "Okay, lose them completely now," you tell her as you change spots and direct her into different poses for you.'
						gs 'arousal', 'voyeur', 5
						gs 'stat'
						act 'Completely naked':
							*clr & cla
							gs 'exp_gain', 'photoskl', rand(1,2)
							'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/anushka/nush_model/sveta_photographer/coffee_hole/pose7.jpg"></center>'
							'She slips the panties down her legs, stepping out of them and kicking them aside. Now all she is wearing is knee-high striped socks, sneakers and a smile. You keep moving around her, snapping photos as she changes poses for you. "Nice, nice. But how about you get up on the counter for me?" you tell her as you keep taking photos. She pauses a moment, then smirks before climbing up on the counter, where she gets down on her knees and starts posing some more.'
							gs 'arousal', 'voyeur', 5
							gs 'stat'
							act 'Work the camera':
								*clr & cla
								gs 'exp_gain', 'photoskl', rand(1,2)
								'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/anushka/nush_model/sveta_photographer/coffee_hole/pose8.jpg"></center>'
								'Under your direction, she spreads her legs wide while staying on her knees and sitting back on her heels, giving you a better shot at her pussy. After a bit, she starts playing with her nipples, pinching and pulling them as you keep taking pictures of her. "Okay, let''s see that little pussy of yours." You tell her.'
								gs 'arousal', 'voyeur', 5
								gs 'stat'
								act 'That''s it':
									*clr & cla
									gs 'exp_gain', 'photoskl', rand(1,2)
									gs 'stat'
									'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/anushka/nush_model/sveta_photographer/coffee_hole/pose9.jpg"></center>'
									'She turns and sits on her side, with one arm supporting her while reaching back to grab her butt cheek with the other. She spreads her thighs to give you a better view of her pussy and asshole.'
									gs 'arousal', 'voyeur', 5
									gs 'stat'
									act 'Final photos':
										*clr & cla
										gs 'exp_gain', 'photoskl', rand(1,2)
										!!portfolio_people[5] = 1
										!!I commented this out as I don''t know how to add another photo set to the portfolio and even if we want to add a second for nush
										gs 'stat'
										'<center><img <<$set_imgh>> src="images/characters/pavlovsk/school/girl/anushka/nush_model/sveta_photographer/coffee_hole/pose9.jpg"></center>'
										'She sits in various poses, some fully exposed and others not, before you finally think you have the perfect final image. She''s leaning back on her elbows with her legs together, pointing up in the air. The angle you pick doesn''t show off much of her naked body, yet is still erotic, and she looks so happy and alive. It seems especially fitting with the Coffee Hole sign behind her; it''s the perfect image to end this photo session.'
										*nl
										'With the image taken, you lower the camera. "Thanks, Nush, that was amazing. This place made for an amazing place to take photos in. You can get dressed now."'
										'She gets off the counter and grabs her panties off the floor before pulling them back on. "My pleasure. I love modelling almost as much as I love my music."' 
										'You review the photos on your camera as she gets dressed again. "Well, I should really finish cleaning up so I can go home and get some sleep before classes tomorrow."'
										gs 'arousal', 'voyeur', 5
										gs 'arousal', 'end'
										gs 'stat'
										act 'Head out': 
											*clr & cla
											minut +=5
											gs 'stat'
											'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big144.jpg"></center>'
											'You nod at her. "Sure thing, I should get going anyway. Thanks again. I''ll see you around campus, hopefully. If not, I''ll stop by sometime, and we can hang out." As she escorts you to the door, you ask; "Which room do you have over at the dorms?"'
											'She stops at the door without unlocking it. "I''m not. I was going to, but the boys wanted to get a place in the city, so we rented an apartment close to campus. Costs me less as I only have to pay a quarter of the bills than the dorm was going to cost. Living with three boys is a nightmare though, so I only regret it constantly," she says with a laugh.'
											*nl
											'"You should stop by sometime," she says and tells you where to find the place.'
											'You write it down on your phone. "Thanks, I will. See you later." With that, she unlocks the door, and you head out while she relocks the door behind you and sets about cleaning up for the night.'
											act 'Walk away': gt 'city_island'
										end
									end
								end
							end
						end
					end
				end
			end
		end
	end
end

if $args[0]= 'lazar':
	*clr & cla
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'lazar'
	menu_off = 0
	minut += 5
	gs 'npc_relationship', 'modify', 'A149', 'like', 1, 'coffee_hole'
	gs 'stat'
	'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big149.jpg"></center>'
	if fame['pav_slut'] > 300:
		'You notice Lazar sitting at a table. As you approach, he says "Well, look who it is; The Queen of Cocks." You sit and talk to him for a few minutes, but all he does is talk about how easy you were back in school. "Sorry, but I need to go. Marcus, Andrey and I are renting a place together. You should come sometime and hang out, so we can have some fun."' 
		'How he says it leaves no doubt about what he means by fun. Even moving to a new city won''t let get away from your reputation as a slut. He tells you where they live before he heads outside and walks away.'
	else
		if npc_rel['A149'] >= 60:
			lazarQW['city_invite'] = 1
			if hotcat >= 6:
				'You notice Lazar sitting at a table. As you approach, he says "What''s up, hottie? You enjoying the city?" You sit and talk to him for a few minutes before his phone buzzes. He looks at it and then finishes his drink. "Sorry, but I need to go. Marcus, Andrey and I are renting a place together. You should really come by sometime. We would love to have you over." He tells you where they live before he heads outside and walks away.'
			else
				'You notice Lazar sitting at a table. As you approach, he says "Hey <<$pcs_nickname>>, how have you been?" You sit and talk to him for a few minutes before his phone buzzes. He looks at it and then finishes his drink. "Sorry, but I need to go. Marcus, Andrey and I are renting a place together. You should really come by sometime and hang out." He tells you where they live before he heads outside and walks away.'
			end
		elseif npc_rel['A149'] <= 20:
			'You notice Lazar sitting at a table. As you approach, all he says is "Hey." You sit and talk to him for a few minutes, but he doesn''t say much to you before he checks his phone and finishes his drink. "Sorry, but I need to go." He heads outside and walks away.'
		else
			if hotcat >= 6:
				'You notice Lazar sitting at a table. As you approach, he says "Hey, good looking. What have you been up to?" You sit and talk to him for a few minutes before his phone buzzes. He looks at it and then finishes his drink. "I need to get going. Give me your number, and I''ll give you a call sometime. We can go out and have some fun or something sometime." You exchange phone numbers with him before he heads outside and walks away.'
			else
				'You notice Lazar sitting at a table. As you approach, he says "Hey <<$pcs_nickname>>, how have you been?" You sit and talk to him for a few minutes before his phone buzzes. He looks at it and then finishes his drink. "I need to get going, but it was nice catching up. Maybe I''ll see you around sometime?" he says before heading outside and walking away.'
			end
		end
	end
	act 'Exit the cafe': gt 'city_island'
	act 'Leave him be': gt 'city_coffee_hole', 'inner'
end

if $args[0]= 'dimka':
	*clr & cla
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'dimka'
	menu_off = 0
	minut += 5
	gs 'npc_relationship', 'modify', 'A1', 'like', 1, 'coffee_hole'
	gs 'stat'
	'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big1.jpg"></center>'
	if fame['pav_slut'] > 225:
		'You notice Dimka sitting at a table. As you approach, he says "Get away from me, you disgusting slut! I don''t want any of the diseases you have." He starts ignoring you, so you turn and walk away.'
	else
		if npc_rel['A1'] >= 60:
			if grupTipe = 1:
				'You notice Dimka sitting at a table. As you approach, he says "Well well, look who it is. It seems spending some time around me did you good. I always thought you had it in you to make it out of Pavlovsk before you got knocked up and married to some loser. Seems my judgment was as correct as always." You sit and talk to him for a few minutes. He is relatively nice to you, even asking about what you''ve been up to until he finishes his drink. "I know you love thinking this is like the old days when we could hang out all the time, but now things are different. Maybe I''ll see you around, and if you''re good, I''ll introduce you to the cool crowd at the uni," he says in a haughty tone, as if he''s already the King of the university. He then stands and walks away.'
			else
				'You notice Dimka sitting at a table. As you approach, he says "Well well, look who it is. I always thought you had it in you to make it out of Pavlovsk before you got knocked up and married to some loser. Seems my judgment was as correct as usual." You sit and talk to him for a few minutes, but all he does is give you back-handed compliments until he finishes his drink. "I know you love being seen with me, but I have better things to do. Maybe I''ll see you around?" he says before getting up and walking away.'
			end
		elseif npc_rel['A1'] <= 20:
			'You notice Dimka sitting at a table. As you approach, he says "What the fuck do you want, loser? Never mind, I don''t want to know. Just go away." He starts ignoring you, so you turn and walk away.'
		else
			if grupTipe = 1:
				'You notice Dimka sitting at a table. As you approach, he says "Well well, look who it is. It seems spending some time around on me did you good. You managed to make it out of Pavlovsk before you got knocked up  by some loser." You sit down and talk to him for a few minutes, but all he does is make snide remarks until he finishes his drink. "I know you love being seen with me, but we''re not in Pavlovsk anymore and no longer run in the same social circles." He gets up and walks away, leaving you alone in the cafe.'
			else
				'You notice Dimka sitting at a table. As you approach, he says "Well well, look who it is. I honestly never thought you would make it out of Pavlovsk. I figured you would be knocked up and married to some loser by now." You sit and talk to him for a few minutes, but all he does is berate you until he finishes his drink. "I know you love being seen with me, but I have better things to do." he says before getting up and walking away.'
			end
		end
	end
	act 'Exit the cafe': gt 'city_island'
	act 'Leave him be': gt 'city_coffee_hole', 'inner'
end

if $args[0] = 'marcus':
	*clr & cla
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'marcus'
	menu_off = 0
	minut += 5
	gs 'npc_relationship', 'modify', 'A146', 'like', 1, 'coffee_hole'
	gs 'stat'
	'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big146.jpg"></center>'
	if fame['pav_slut'] > 250:
		marcusQW['city_invite'] = 1
		'You notice Marcus sitting at a table. As you approach, he says "Hey you." You sit and talk to him for a few minutes before his phone buzzes. He looks at it and then finishes his drink. "Sorry, but I need to go. Lazar, Andrey and I are renting a place together, you should come by sometime and hang out, so we can have some fun." How he says it leaves no doubt about what he means by fun. Seems that even moving to a new city can''t get you away from your reputation as a slut. He tells you where they live before he heads outside and walks away.'
	else
		if npc_rel['A146'] >= 50:
			marcusQW['city_invite'] = 1
			'You notice Marcus sitting at a table. As you approach, he says "Hey <<$pcs_nickname>>, how have you been?" You sit and talk to him for a few minutes before his phone buzzes. He looks at it and finishes his drink. "Sorry, but I need to go. Lazar, Andrey and I are renting a place together. You should really come by sometime and hang out." He tells you where they live before he heads outside and walks away.'
		elseif npc_rel['A146'] <= 20:
			'You notice Marcus sitting at a table. As you approach, he says "Hey." You sit down and talk to him for a few minutes. He doesn''t say much to you before he checks his phone and finishes his drink. "Sorry, but I need to go." After that, he walks outside and walks away.'
		else
			'You notice Marcus sitting at a table. As you approach, he says "Hey <<$pcs_nickname>>, how have you been?" You sit and talk to him for a few minutes before his phone buzzes. He looks at it and finishes his drink. "Sorry, but I need to go. It was nice catching up. Maybe I''ll see you around?" he asks before he heads outside and walks away.'
		end
	end
	act 'Exit the cafe': gt 'city_island'
	act 'Leave him be': gt 'city_coffee_hole', 'inner'
end

if $args[0]= 'kendra':
	*clr & cla
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'kendra'
	menu_off = 0
	minut += 5
	gs 'stat'
	'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big84.jpg"></center>'
	if meet_kendra = 1:
		'As you walk  over to her, she invites you to sit down. You talk for a few minutes before she seems to get bored of the idle chit-chat and just bluntly asks you "You change your mind about serving me?"'
		act 'No':
			*clr & cla
			kendrano = 1
			gs 'npc_relationship', 'modify', 'A84', 'dislike', 1, 'coffee_hole'
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big84.jpg"></center>'
			'You smile at her. "Sorry, no. I still don''t belong to anyone."'
			'She sighs softly. "Such a waste. Oh well, there are plenty of pretty little white Russian bitches that love being owned by an ebony Mistress. Perhaps we''ll meet again, and you''ll change your mind. I go to the university, so you should stop by sometime." She gives you directions to her dorm room before she returns to browsing.'
			act 'Exit the cafe': gt 'city_island'
			act 'Leave her be': gt 'city_coffee_hole', 'inner'
		end
		act 'Yes':
			*clr & cla
			gs 'npc_relationship', 'modify', 'A84', 'like', 1, 'coffee_hole'
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big84.jpg"></center>'
			'You look down a little to show your submission to her. "Yes, Mistress Kendra."'
			'She smiles widely. "I think you''re going to make a great little slave. We''re going to have a lot of fun together. I wish I had time to start your training now, but I have things I need to do. Come by my dorm room as soon as you can." With that, she finishes her drink, gets up, and walks out.'
			act 'Exit the cafe': gt 'city_island'
			act 'Leave the table': gt 'city_coffee_hole', 'inner'
		end
	elseif kendraslave >= 1:
		gs 'npc_relationship', 'modify', 'A84', 'like', 1, 'coffee_hole'
		'As you walk over to her, she invites you to sit down. You talk for a few minutes before she seems to get bored of the idle chit-chat and just bluntly asks you, "Who do we have here? My favourite little white bitch. Come to service me? I wish I had time for a training session, but unfortunately, I have things to do. Come by my dorm room as soon as you can." With that, she finishes her drink, gets up, and walks out.'
	elseif hotcat >= 5:
		'As you walk over to her, she invites you to sit down. You take a seat opposite her as she says. "You''re a pretty little thing. What''s your name?"'
		'"<<$pcs_firstname>>, but most people call me <<$pcs_nickname>>. What''s your name?" you reply.'
		'She smiles. "<<$pcs_nickname>>, what a pretty name. I''m Kendra, but you can call me Mistress Kendra," she says confidently.'
		'"Oh..." you reply. She''s one of those people.'
		act 'Exit the cafe': gt 'city_island'
		act 'Leave the table': gt 'city_coffee_hole', 'inner'
		act 'Talk to her':
			*clr & cla
			meet_kendra = 1
			npc_rel['A84'] = 45
			'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big84.jpg"></center>'
			if mid($start_type,1,2) = 'sg' and SchoolAtestat = 0:
			  'You start talking with her. You tell her that you live in Pavlovsk and are in your final year of school. She replies by saying she''s a student from the Republic of Congo who attends the local university on a student visa. You talk about a wide range of subjects for a while before she eventually says, "You''re beautiful. I love making pretty little Russian bitches my slaves. Call me Mistress Kendra, <<$pcs_nickname>>, and become mine." Should you call her mistress? You have no doubt where that will lead.'
			else
			  'You start talking with her. You tell her a bit about yourself, and she replies by saying that she''s a student from the Republic of Congo attending the local university on a student visa. You talk about a wide range of subjects for a while before she eventually says, "You''re beautiful. I love making pretty little Russian bitches my slaves. Call me Mistress Kendra, <<$pcs_nickname>>, and become mine." Should you call her mistress? You have no doubt where that will lead.'
			end
			act 'Call her Kendra':
				*clr & cla
				kendrano = 1
				gs 'npc_relationship', 'modify', 'A84', 'dislike', 1, 'coffee_hole'
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/redlight/erotomaniac/sex/shkend.jpg"></center>'
				'You smile at her. "Sorry, but I don''t belong to anyone."'
				'She sighs softly. "Such a waste. Oh well, there are plenty of pretty little white Russian bitches that love being owned by an ebony Mistress. Perhaps we''ll meet again, and you''ll change your mind?" She gives you directions to her dorm room, and she returns to browsing.'
				act 'Exit the cafe': gt 'city_island'
				act 'Leave the table': gt 'city_coffee_hole', 'inner'
			end
			act 'Call her Mistress Kendra':
				*clr & cla
				gs 'npc_relationship', 'modify', 'A84', 'like', 1, 'coffee_hole'
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/redlight/erotomaniac/sex/shkend.jpg"></center>'
				'You look down a little to show your submission to her. "Yes, Mistress Kendra."'
				'She smiles widely. "I think you''re going to make a great little slave. We''re going to have a lot of fun together. I wish I had time to start your training now, but I have things I need to do. Do come by my dorm room as soon as you can." With that, she finishes her drink, gets up, and walks out.'
				act 'Exit the cafe': gt 'city_island'
				act 'Leave the table': gt 'city_coffee_hole', 'inner'
			end
		end
	elseif npc_rel['A84'] < 40:
		gs 'npc_relationship', 'modify', 'A84', 'like', 1, 'coffee_hole'
		'You walk over to her table and stand next to it. "Hi," you smile at her as you greet her.'
		'She looks up at you with an annoyed look. "I don''t have time for games, and I''m tired of yours. Now get lost." She proceeds to ignore you, so you turn and leave.'
	end
	act 'Exit the cafe': gt 'city_island'
	act 'Leave her be': gt 'city_coffee_hole', 'inner'
end

if $args[0]= 'djibril':
	*clr & cla
	$menu_loc = 'city_coffee_hole'
	$menu_arg = 'djibril'
	menu_off = 0
	minut += 5
	DjibrilQW['invite'] = 1
	DjibrilQW['meet'] = 1
	gs 'npc_relationship', 'modify', 'A82', 'like', 1, 'coffee_hole', 1, 'coffee_hole'
	gs 'stat'
	'<center><h4><font color="maroon">Cafe "Coffee Hole"</font></h4></center>'
	'<center><img <<$set_imgh>> src="images/characters/shared/headshots_main/big82.jpg"></center>'
	if DjibrilQW['invite'] = 1:
		'You notice Djibril sitting at a table. As you approach, he says "Hello again, <<$pcs_nickname>>. I didn''t expect to see you here." You sit and talk to him for a few minutes before his phone buzzes. He looks at it and then finishes his drink. "Sorry, but I need to go. You should really stop by my dorm room. We could hang out and have some fun." He reminds you which dorm room is his before he heads outside and walks away.'	
	elseif DjibrilQW['meet'] = 1 and DjibrilQW['invite'] = 0:
		'<center><img <<$set_imgh>> src="images/locations/city/centralpark/cafe/djibril_talk.jpg"></center>'
		'You notice Djibril sitting at a table. As you approach, he says "Hello again, <<$pcs_nickname>>. I didn''t expect to see you here." You sit and talk to him for a few minutes before his phone buzzes. He looks at it and then finishes his drink. "Sorry, but I need to go. If you like, you should stop by my dorm room sometime, and we can hang out and talk more." He tells you which building it is and which room is his before he heads outside and walks away.'
		
	elseif hotcat >= 5:
		DjibrilQW['meet'] = 1
		'As you approach him, the young African man sitting at the table introduces himself. "I am Djibril Maina. What''s your name?"'
		'You smile at him. "<<$pcs_firstname>> <<$pcs_lastname>>, but most people just call me <<$pcs_nickname>>."'
		'He looks surprised for a moment. "Are you from Pavlovsk?" When you nod your head, he looks even more surprised. "Do you have an Aunt Luda dating a man named Olu?"'
		'Now it''s your turn to look surprised. "Yes, how did you know that?"'
		*nl
		'He shakes his head with a slight laugh. "He is my uncle. They''ve told me about you. Small world, huh?"'
		'You giggle as well. "Yeah, it really is."'
		'You sit and talk to him for a few minutes before his phone buzzes. He looks at it and then finishes his drink. "Sorry, but I need to go. If you like, you should stop by my dorm room sometime, and we can hang out and talk more." He tells you which building it is and which room is his before he heads outside and walks away.'
	end
	act 'Exit the cafe': gt 'city_island'
	act 'Leave him be': gt 'city_coffee_hole', 'inner'
end

--- city_coffee_hole ---------------------------------