glife/locations/pav_commcenter.qsrc

# pav_commcenter
music_loop = 0
CLOSE ALL
$menu_loc = 'pav_commcenter'
$menu_arg = ''
menu_off = 0
$loc_arg = ''
$loc = 'pav_commcenter'
$location_type = 'public_outdoors'
gs 'stat'
'<center><b><font color="maroon">Community Centre</font></b></center>'

act 'Leave': minut += 2 & gt 'pav_residential'

if daystage = 2 or daystage = 3:
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/dk.jpg"></center>'
else
	'<center><img <<$set_imgh>> src="images/locations/pavlovsk/community/dk_night.jpg"></center>'
end

if month > 8 and ml_guitarlesson['advertisement']  = 0: gt 'music_guitarlesson', 'advertisement'

if hour >= 20 and hour <= 23 and week >= 5 and week < 7:
	'The entrance to the community centre is full of young people. The guys are just hanging around smoking and joking while the girls are in small groups, all dressed up and gossiping. You see the bushes moving - Pavlovsks'' famous make out garden.'
	'You hear people in the alley beside the club. <a href="exec:minut += 5 & gt ''ugel''">Investigate</a>.'
	if gdkincum = daystart and (cumloc[6] = 0 and cumloc[7] = 0) and cumloc[11] = 0: gdkincum = 0
	if gdkincum ! daystart:
		if gdkin_in = daystart:
			act 'Return to the dance': gt 'gdkin'
		elseif money >= 25:
			act 'Go to the dance (25 <b>₽</b>)': money -= 25 & minut += 5 & gt 'gdkin'
		end
	else
		*nl
		if (cumloc[6] = 1 or cumloc[7] = 1) and cumloc[11] = 1:
			'You should clean the cum off your face and clothes before heading back to the dance.'
		elseif cumloc[11] = 1:
			'You should clean the cum off your face before heading back to the dance.'
		elseif cumloc[6] = 1 or cumloc[7] = 1:
			'You should clean the cum off your clothes before heading back to the dance.'
		end
	end
else
	'The community centre has sports facilities and offers classes in the evening.'
	'It houses a small library which is open from 08:00 until 18:00.'
	'Upstairs, there are some hobby clubs available from 12:00 until 20:00.'
	'The sports section is open from 14:00 until 20:00 during the week and from 09:00 until 20:00 during the weekend.'
	'On Friday and Saturday evenings, from 20:00 to midnight, the main hall is used as a club with popular music and dancing. Entry fee is 25 <b>₽</b>.'
end


if (week < 6 and hour >= 14 and hour < 20) or (week >= 6 and hour >= 9 and hour < 20): act 'Go to the sports section': gt 'gdksport', 'start'

if hour >= 8 and hour < 18: act 'Go to the library': gt 'pav_library'

if hour >= 12 and hour < 20: act 'Go upstairs to the hobby clubs': gt'pav_commclubs'

if nerd_game['game_day'] = daystart and hour = 19: act 'Wait for game night to start': minut += 60-minut & gt 'pav_library'
if nerd_game['game_day'] = daystart and hour = 20: act 'Go up stairs to the hobby clubs and <b>Join nerds</b>': gt 'nerd_game_night', 'game'

if hour >= 8:act 'Go to the toilets': gt 'gdktoilet', 'start'

if joint > 0 and jointhigh = 0: act 'Smoke a joint': gs 'drugs', 'joint' & gt $loc, $loc_arg

act 'Wait': gs 'obj_din', 'wait'

gs'family'

--- pav_commcenter ---------------------------------