glife/locations/sportShop.qsrc

# sportShop

if $ARGS[0] = 'start':
    $location_type = 'public_indoors'
	cls
	menu_off = 1
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">Danilovich sporting goods</font></b></center>'
	'<center><img src="images/locations/city/citycenter/mall/sportshop/sportshop.jpg"></center>'
	*nl
	'As soon as you enter, a high energy song with a thumping baseline fills your eardrums, making you feel pumped and awake. The store is sleek and professional, the walls and floors advertising all different kinds of sporting equipment and attire. The room is filled with beautifully fit people shopping, their bodies varying from big and muscular to lean and trim. If they don''t inspire you to want to work out, the posters advertising past and present famous athletes are motivating as hell.'
	*nl
	if refillable_bottle = 0 and money >= 1000 and bag > 0: 
		'You could buy a high-quality <a href="exec:minut += 5 & money -= 1000 & refillable_bottle = 1 & gt ''sportShop'', ''start''">water bottle (1000 <b>₽</b>)</a> that you can carry around in your purse.'
	elseif refillable_bottle = 0 and (money < 1000 or bag = 0):
		'The shop sells high-quality water bottles for 1,000 <b>₽</b>. You could carry one around in '+iif(bag > 0, 'your', 'a')+' purse.'
	end
	
	act 'Leave':minut += 3 & gt 'torgcentr'

	act 'View sports clothing':minut += 5 & gt 'sportshop', 'clo'

	act 'View sports bras':minut += 5 & gt 'sportshop', 'bras'
	
	act 'View sports panties':minut += 5 & gt 'sportshop', 'panties'
	
	act 'View exercise shoes':minut += 5 & gt 'sportshop', 'shoes'

	act 'View swimwear':minut += 5 & gt 'sportshop', 'swim'

	act 'View purses': minut += 5 & gt 'sportshop', 'purses'

	act 'View coats': minut += 5 & gt 'sportshop', 'coats'

	if skak = 0 and money >= 500:
		act 'Buy a skipping rope (500 <b>₽</b>)':
			cla
			minut += 5
			money -= 500
			skak = 1

			act 'Pick up a package':gt 'sportshop', 'start'
		end
	elseif skak = 0:
		act 'Buy a skipping rope (<font color="red">500 <b>₽</b></font>)': '<br><font color="red">You don''t have enough money to buy that.</font>'
	end

	if obruch = 0 and money >= 1500:
		act 'Buy a hula hoop (1,500 <b>₽</b>)':
			cla
			minut += 5
			money -= 1500
			obruch = 1

			act 'Pick up a package':gt 'sportshop', 'start'
		end
	elseif obruch = 0:
		act 'Buy a hula hoop (<font color="red">1500 <b>₽</b></font>)': '<br><font color="red">You don''t have enough money to buy that.</font>'
	end

	if bookYog = 0 and money >= 1500:
		act 'Buy "Benefits of yoga" (1,500 <b>₽</b>)':
			cla
			minut += 5
			money -= 1500
			bookYog = 1

			act 'Pick up a package':gt 'sportshop', 'start'
		end
	elseif bookYog = 0:
		act 'Buy "Benefits of yoga" (<font color="red">1500 <b>₽</b></font>)': '<br><font color="red">You don''t have enough money to buy that.</font>'
	end
	
	if konki = 0 and money >= 3000:
		act 'Buy some ice skates (3000 <b>₽</b>)':
			cla
			minut += 5
			money -= 3000
			konki = 1

			act 'Pick up a package':gt 'sportshop', 'start'
		end
	elseif konki = 0:
		act 'Buy some ice skates (<font color="red">3000 <b>₽</b></font>)': '<br><font color="red">You don''t have enough money to buy that.</font>'
	end
end

if $ARGS[0] = 'clo':
	$loc_arg = 'clo'
	$loc = 'sportShop'
	cls
	gs'stat'
	'<center><b><font color="maroon">Sportswear - one size fits all</font></b></center>'
	*nl

	gs 'clothing_QV', 'shop_header'

	act 'Return':
		cla
		minut += 1
		gt 'sportshop', 'start'
	end

	clothingfilter['qualitycheck'] = 7
	:loopquality2
		if Clothingstock > 16:
			i = 1
		elseif Clothingstock > 8:
			i = 2
		else
			i = 3
		end

		:loopdanilovich
			if danilovich[i] = 0:
				gs 'clothing_attributes', 'danilovich_outfits', i
				gs 'clothing_QV', 'shop_filter'
					
				if clothingfilter['quality'] = 0 or clothingfilter['qualitycheck'] = CloQuality:

					if clothingfilter_risk = 1 and clothingfilter_pandb = 1 and clothingfilter_norm2 = 1: *p '<a href="exec: i = <<i>> & gt ''sportshop'', ''danilovich''"><img src="images/pc/items/danilovich/outfits/<<i>>.jpg" 	height="250" /></a>'
				end
			end
			i += 3
		if i <= 170:jump 'loopdanilovich'
	if clothingfilter['quality'] = 1 and clothingfilter['qualitycheck'] > 0: clothingfilter['qualitycheck'] -=1 & jump 'loopquality2'
end

if $ARGS[0] = 'danilovich': gt 'clothing', 'view_clothing_item', 'shop', 'danilovich',i, 2000

if $ARGS[0] = 'shoes':
	$loc_arg = 'shoes'
	$loc = 'sportShop'
	cls
	gs'stat'

	act 'Return':
		cla
		minut += 1
		gt 'sportShop', 'start'
	end

	i = 1
	:loopdanilovich_shoes
		if sdanilovich[i] = 0:*p '<a href="exec: i = <<i>> & gt ''sportShop'', ''training_shoes''"><img src="images/pc/items/danilovich/shoes/<<i>>.jpg" height="250" /></a>'
		i += 1
	if i <= 40:jump 'loopdanilovich_shoes'
end

if $ARGS[0] = 'training_shoes': gt 'shoes', 'view_shoe_item', 'shop', 'danilovich',i, 1500

if $ARGS[0] = 'swim':
	$loc_arg = 'swim'
	$loc = 'sportShop'
	cls
	gs'stat'
	'<center><b><font color="maroon">Swimwear - one size fits all</font></b></center>'
	*nl

	gs 'clothing_QV', 'shop_header'

	act 'Return':
		cla
		minut += 1
		gt 'sportshop', 'start'
	end

	clothingfilter['qualitycheck'] = 7
	:loopquality
	!!4 is in he supermarket, so skipped
		i = 1

		:loopswim
			if danilovich_swimsuit[i] = 0:
				gs 'clothing_attributes', 'danilovich_swimsuit', i
				gs 'clothing_QV', 'shop_filter'

				if clothingfilter['quality'] = 0 or clothingfilter['qualitycheck'] = CloQuality:

					if clothingfilter_risk = 1 and clothingfilter_pandb = 1 and clothingfilter_norm2 = 1: *p '<a href="exec: i = <<i>> & gt ''sportshop'', ''swim1''"><img src="images/pc/items/danilovich/swimwear/<<i>>.jpg" 	height="250" /></a>'
				end
			end
			i += 4
		if i <= 30:jump 'loopswim'
	if clothingfilter['quality'] = 1 and clothingfilter['qualitycheck'] > 0: clothingfilter['qualitycheck'] -=1 & jump 'loopquality'
end

if $ARGS[0] = 'swim1': gt 'clothing', 'view_clothing_item', 'shop', 'danilovich_swimsuit',i, 1750

if $ARGS[0] = 'panties':
	$loc_arg = 'panties'
	$loc = 'sportShop'
	cls
	gs'stat'

	act 'Return':
		cla
		minut += 1
		gt 'sportShop', 'start'
	end

	i = 1

	:loopsport_panties
		if sport_panties[i] = 0:*p '<a href="exec: i = <<i>> & gt ''sportShop'', ''panties2''"><img src="images/pc/panties/sport/<<i>>.jpg" 	height="250" /></a> '
		i += 1
	if i <= 8:jump 'loopsport_panties'
end

if $ARGS[0] = 'panties2':
	cla
	
	if sport_panties[i] ! 0:
		msg 'You already own these panties.'
		gt 'sportShop', 'panties'
	end

	gt 'panties', 'view_panty_item', 'shop', 'sport',i, 1000

end

if $ARGS[0] = 'bras':
	$loc_arg = 'bras'
	$loc = 'sportShop'
	cls
	gs'stat'

	act 'Return':
		cla
		minut += 1
		gt 'sportShop', 'start'
	end

	i = 1

	:loopsport_bras
		if sport_bras[i] = 0:*p '<a href="exec: i = <<i>> & gt ''sportShop'', ''bras2''"><img src="images/pc/bras/sport/<<i>>.jpg" 	height="250" /></a> '
		i += 1
	if i <= 8:jump 'loopsport_bras'
end

if $ARGS[0] = 'bras2':
	cla
	
	if sport_bras[i] ! 0:
		msg 'You already own this bra.'
		gt 'sportShop', 'bras'
	end

	gt 'bras', 'view_bra_item', 'shop', 'sport',i, 1000

end

if $ARGS[0] = 'purses':
	$loc_arg = 'purses'
	$loc = 'sportShop'
	menu_off = 1
	*clr & cla
	gs'stat'

	act 'Return':
		cla
		minut += 1
		gt 'sportShop', 'start'
	end

	i = 1

	:loopdanilovich_purses
		if danilovich_purses[i] = 0:*p '<a href="exec: i = <<i>> & gt ''sportShop'', ''purses2''"><img src="images/pc/items/danilovich/purses/<<i>>.jpg" 	height="150" /></a> '
		i += 1
	if i <= 20:jump 'loopdanilovich_purses'
end

if $ARGS[0] = 'purses2': gt 'purses', 'view_purse_item', 'shop', 'danilovich',i, 1500

if $ARGS[0] = 'coats':
	$loc_arg = 'coats'
	$loc = 'sportShop'
	menu_off = 1
	*clr & cla
	gs'stat'

	act 'Return':
		cla
		minut += 1
		gt 'sportShop', 'start'
	end

	i = 1

	:loopdanilovich_coats
		if danilovich_coats[i] = 0:*p '<a href="exec: i = <<i>> & gt ''sportShop'', ''coats2''"><img src="images/pc/items/danilovich/coats/<<i>>.jpg" 	height="150" /></a> '
		i += 1
	if i <= 20:jump 'loopdanilovich_coats'
end

if $ARGS[0] = 'coats2': gt 'coats', 'view_coat_item', 'shop', 'danilovich',i, 1500

--- sportShop ---------------------------------