glife/locations/fight1

# fight1
$resultUderDin = {
	if Aktiv > Passiv:
		point += 1
		Ku += 1
		'<center><img src="images/locations/city/citycenter/gym/kickboxing/f1u.jpg"></center>'
		'You have successfully commit rival'

		act '...':stoper = 0 & gt 'fight2'
	elseif Aktiv < Passiv:
		pointE += 1
		KzE += 1
		'<center><img src="images/locations/city/citycenter/gym/kickboxing/f1u1.jpg"></center>'
		'You can not do anything about my opponent flips.'

		act '...':stoper = 0 & gt 'fight3'
	elseif Aktiv = Passiv:
		'<center><img src="images/locations/city/citycenter/gym/kickboxing/f1u2.jpg"></center>'
		'You have two little turns and you are struggling without success.'

		act '...':gt $curloc
	end
}

!!you top
!!opponent lies on his back after throwing -15%
koef = 100
koefE = 85
rMin -= 1
stoper += 1
gs 'fightStat'
'<center><img src="images/locations/city/citycenter/gym/kickboxing/f1.jpg"></center>'
'<<$nameE>> lying on his back after throwing a little confused, while you sit on top of it. <<$nameE>> trying to wriggle out.'

if endur <= 0 or lustw <= 0:gt 'SubLoss'
if endurE <= 0 or lustwE <= 0:gt 'SubWin'

if stoper < 3:
	if rMin > 0:
		act 'Make an attempt to hold':
			cls
			dynamic $uderdin
			dynamic $resultUderDin
		end
	else
		'The referee blows a whistle and throws you. End of round.'

		act 'up':gt 'RoundEnd'
	end
elseif stoper >= 3:
	pointE += 1
	'The referee blows a whistle and throws you. Your time to attack happened. <<$nameE>> receives one point.'

	act 'Get up':gt 'RoundStop'
end

--- fight1 ---------------------------------