# volley
minut += 30
gs 'stat'
if volltime = 0:
	'<center><img src="images/qwest/alter/gdksport.jpg"></center>'
	'Teams took to the field and started playing.'

	if volleysostav = 1:'You sit on the bench watching your team plays.'
	poverkomandV = rand(500, 1500)

	if poverkomand > poverkomandV:
		volpoint += 1
		'Your team plays with the team opponents.'
	elseif poverkomand = poverkomandV:
		volpoint += 1
		volpointv += 1
		'The scales vary in one, then the other, obviously teams are equal on forces.'
	elseif poverkomand < poverkomandV:
		volpointv += 1
		'Team beats rivals your team.'
	end

	act 'further':volltime=1 & gt $curloc
elseif volltime = 1:
	'<center><img src="images/qwest/alter/gdksport.jpg"></center>'
	'There was a break, and both teams have a rest.'

	if volleysostav = 1:
		'You are sitting on the bench.'

		act 'Ask to play':
			cls
			gs 'stat'
			trenereparand = rand(0, 80)

			if trenerepa >= trenereparand:
				volleysostav = 2
				dom += 1
				poverkomand -= 100
				poverkomand += volleyboll
				'The coach has agreed to release you on the field.'

				act 'further':volltime = 2 & gt $curloc
			else
				'You have been asking the coach to play, but he shook his head and went on to explain the strategy of girls.'

				act 'further':volltime = 2 & gt $curloc
			end
		end
	end

	act 'further':volltime = 2 & gt $curloc
elseif volltime=2:
	'<center><img src="images/qwest/alter/gdksport.jpg"></center>'
	'Break is over and the team started to play again.'

	if volleysostav = 1:'You are sitting on the bench watching how your team plays.'

	if poverkomand > poverkomandV:
		volpoint += 1
		'Your team plays with the team opponents.'

		if volleysostav = 2:
			if volpointv > 0:trenerepa += 10
		end
	elseif poverkomand = poverkomandV:
		volpoint += 1
		volpointv += 1
		'The scales vary in one, then the other, obviously teams are equal on forces.'

		if volleysostav = 2:
			if volpointv > 0:trenerepa += 5
		end
	elseif poverkomand < poverkomandV:
		volpointv += 1
		'Team beats rivals your team.'

		if volleysostav = 2:
			if volpoint > 0:trenerepa -= 10
		end
	end

	act 'further':volltime = 3 & gt $curloc
elseif volltime = 3:
	volsesongame += 1
	'<center><img src="images/qwest/alter/gdksport.jpg"></center>'
	'Final whistle.'

	if volpoint > volpointv:
		volsesonwin += 1
		'Your team won.'
	elseif volpoint = volpointv:
		volsesondraw += 1
		'draw.'
	elseif volpoint < volpointv:
		volsesonloss += 1
		'Your team lost.'
	end

	if volleysostav = 2:volleysostav = 1 & poverkomand -= volleyboll & poverkomand += 100

	volpoint = 0
	volpointv = 0

	act 'Leave':gt 'gdksport'
	act 'Go to coaching':gt 'Voltrener'
end

--- volley ---------------------------------
