glife/locations/parks.qsrc

# parks
!!2021/05/12

if $ARGS[0] = 'start':
	*clr & cla
	$location_type = 'public_outdoors'
	$loc_arg = 'start'
	$loc = 'parks'
	$menu_loc = 'parks'
	$menu_arg = 'start'
	$locclass = 'city_park'
	menu_off = 0
	gs'stat'
	'<center><B>Pushkin Town Park</B></center>'
	'<center><img <<$set_imgh>> src="images/locations/pushkin/park/parkus.jpg" ></center>'
	'The gardens of the old palace have been sculpted over many years into a wonder landscape with a tranquil atmosphere.'
	'The Pushkin Park is a must-see for tourists and servers as the main attraction of Pushkin.'

	'Wander deeper into the <a href="exec:gt ''lug'',''start''">park</a>.'


	act 'Go to Okhlopkov Square (0:05)': minut += 5 &  gt 'pushkin_sq'

	act 'Go to Town Center (0:10)': minut += 10 & gt 'pushkin'

	act 'Walk around the park (1 hour)':
		if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1', 1
		cla
		minut += 60
		pcs_mood += 10
		gs'stat'
		'You leisurely stroll through Pushkin Park, breathing in the fresh air, and reflecting on the vicissitudes of fate.'

		act 'Complete outing.':gt 'parks','start'
	end

	gs 'park_walkevents', 'run'

	if hour >= 20 or hour < 6 :
		if func('homes_properties', 'has_access', 'old_town_apartment') = 0 :
			!nowhere to live in town
			'It''s quite dark now, and you have no where to stay nearby. Maybe you should try to sleep on a bench?'
		else
			'It''s quite dark now, and you don''t feel like walking. Maybe you should try sleeping on a bench?'
		end
		act 'Sleep on a bench': gt'placer_sex','sleeping_park_bench'
	end

	act 'Sit down on the bench':gs 'placer_sex', 'sitting_park_bench'
	
	if mc_inventory['joints'] > 0 and drugVars['weed_high'] = 0: act 'Smoke a joint': minut += 10 & gs 'drugs', 'joint' & gt $loc, $loc_arg

	if pcs_inhib >= 35 or exhibitionist_lvl > 0:
		act 'Flash your tits':
			menu_off = 1
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			*clr & cla
			inhib_exp += rand(1,3)
			gs 'flash', 'tits', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'parks', 'start'
		end
	end

	if exhibitionist_lvl > 1:
		act 'Flash your pussy':
			menu_off = 1
			if pcs_exhib = 100 and exhibitionQW = 0: gt 'kseniyaQW', 'event1'
			*clr & cla
			gs 'flash', 'pussy', 'outdoors', 5
			gs 'stat'

			act 'Continue': gt 'parks', 'start'
		end
	end
end

--- parks ---------------------------------