# ykuh

$loc_arg = ''
$loc = 'ykuh'
$locclass = 'kitr'
$menu_loc = 'ykuh'
$menu_arg = ''
menu_off = 0
*clr & cla
gs 'stat'

'<center><b><font color="maroon">Kitchen</font></b></center>'
'<center>A well stocked kitchen containing all the necessities to make whatever meal you please.</center>'

if ymanrem[6] = 0:'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/ynill.jpg"></center>'
if ymanrem[6] = 1:'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/yrem.jpg"></center>'
if ymanrem[6] = 2:'<center><img <<$set_imgh>> src="images/locations/city/suburb/mansion/ykun.jpg"></center>'
if ymanrem[6] = 2:''

if dirttarelka > 0 and fairy >= dirttarelka:
	cltarelka += dirttarelka
	fairy -= dirttarelka
	dirttarelka = 0
	'You wash the dirty dishes in the dishwasher.'
elseif fairy < dirttarelka:
	'You can''t use the dishwasher. You have no detergent.'
end

if cltarelka > 0:
	'You have <b><<cltarelka>></b> clean plates left.'
else
	'<b><font color="red">You don''t have any clean plates left.</font></b>'
end

if dirttarelka > 0:'There are <b><<dirttarelka>></b> dirty dishes in the sink. <a href="exec:dynamic $dirtarm">Wash the dishes</a>.'

if fairy > 0:
	'Under the sink is some dishwashing detergent, which is enough for <b><<fairy>></b> ' + iif(fairy = 1, 'time.', 'times.')
else
	'<b><font color="red">You have nothing to wash dishes with. You should buy some detergent.</font></b>'
end

if eda > 0:
	if cltarelka = 0 or edahot > 0:$edagot = ''
	if cltarelka > 0 and edahot = 0:$edagot = '<a href="exec:dynamic $edagotd">Cook a meal (0:30)</a>'

	'There''s enough food for <b><<eda>></b> ' + iif(eda = 1, 'serving', 'servings') + '. <<$edagot>>'
elseif edaD = 0 and eda = 0:
	'<b><font color="red">The fridge is empty. You have nothing to eat.</font></b>'
end

act 'Leave the room':minut += 1 & gt 'ymans'

if edahot > 0:'<a href="exec:dynamic $edahotd">There''s a warm meal on the table.</a>'

if husband > 0 and husbanday > 0 and huseatday ! daystart and eda >= 2:
	act 'Cook a meal for your husband, 2 servings (1:00)':
		cla
		*clr
		husband += 5
		eda -= 2
		minut += 60
		huseatday = daystart
		pcs_mood -= 15
		'<center><img <<$set_imgh>> src="images/shared/home/kitchen/cook.jpg"></center>'
		'You make some delicious food for your husband.'

		act 'Put the food on the table':gt $curloc
	end
end

act 'Have a snack (0:15)':gs 'food', 'snack'

dynamic $sandwich
dynamic $driwater
dynamic $dritea
dynamic $fill_bottle
dynamic $edaD
dynamic $pranik
dynamic $fatdel
dynamic $lekarstvo
dynamic $vitamin


--- ykuh ---------------------------------

