# stripclub
!!2021/04/15
close all

if $ARGS[0] = 'start':
	*clr & cla
	minut += 5
	$menu_loc = 'stripclub'
	$menu_arg = 'start'
	menu_off = 0
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">Strip Club</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/stripclub.jpg"></center>'
	*nl

	act 'Leave': gt 'city_industrial', 'redlight'

	if hour = 2:
		'The strip club is closing, and a security guard ushers everyone out.'
	elseif hour > 2 and hour < 11:
		'The strip club is closed. You notice a sign on the door: The business hours are between 18:00 - 02:00.'
	else
		if stripdolg > 0:
			if money >= 50000:
				act 'Pay off your fine (50,000 <b>₽</b>)':
					stripdolg = 0
					money -= 50000
					gt 'stripclub', 'start'
				end
			else
				*nl
				'You still owe a 50,000 <b>₽</b> fine for your illegal actions. You cannot return to the club until you have paid it off.'
			end
		else
			if age >= 18 or fakepassport = 1:
				if stripwork = 1:
					'"Welcome back <<$pcs_nickname>>, are you working tonight?" he asks.'
					act 'Use the employee''s entrance':frost = 0 & gt 'stwork', 'start'
				else
					'The security guard stops you, looking you up and down, he asks to see your ID.'
					'"OK, your ID checks out, you are free to enter." he tells you.'
				end
				if stripdolg = 0:
					if cfnm = 1 and money >= 500:
						act 'Enter the club (500 <b>₽</b>)':
							cla
							money -= 500
							minut += 5
							frost = 0
							gt 'stripclub', 'forwoman'
						end
					elseif cfnm = 0 and money >= 300:
						act 'Enter the club (300 <b>₽</b>)':
							cla
							money -= 300
							minut += 5
							frost = 0
							gt 'stripclub', 'forman'
						end
					else
						*nl
						'You don''t have enough money to pay the entry fee.'
					end
				end
			else
				'The security guard stops you. Looking you up and down, he asks to see your ID.'
				'You make a show of rummaging through your purse. "Sorry, I must have left my ID at home."'
				'"You need to leave this establishment, be sure to come back when you are old enough," he tells you.'
			end
		end
	end
end

if $ARGS[0] = 'manager':
	*clr & cla
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/tryout.jpg"></center>'
	minut += 15
	gs 'stat'
	'After you''ve introduced yourself, the manager observes you for a while and asks, "Are you really 18 years old? I had a visit from the police last week, and they found an under-aged girl working here. I was fortunate enough that the officers could be bribed."'
	*nl

	if age >= 18 or fakepassport = 1:
		if age >= 18:
			'"Yes I am," you answer him.'
		else
			'"Yes I am," you answer, handing him your fake passport.'
			'You see him frown as he checks your passport with suspicion. "Well, I guess everything is in order."'
		end
		'He leads you to one of the private booths and points to the pole. "Show me what you can do."'
		if pcs_dancero >= 40 and pcs_dancpol >= 30:
			'You dance sensually, clearly he''s smitten by you. He asks you to sit down. "Our business hours are between 18:00 to 02:00. Some days there are only male strippers performing. We don''t pay strippers, but the customers tip generously. Think of it as an incentive, perform well and you''ll earn a tip."'
			'"Strippers can perform lap dances for clients at their request for 1000 <b>₽</b> per lap dance. The stripper gets 400 <b>₽</b>, and the rest belongs to the club. They may want further entertainment. As the club doesn''t operate as a brothel, we don''t really accept that kind of business, but we usually turn a blind eye to it."'
			'"One last thing that I nearly forgot, dancing on stage involves a lot of work on the pole. Unless you do that, it is unlikely you will earn anything. There is no set schedule, the employees choose when they want to come to work. So what do you say, are you interested?"'
			act 'Accept his offer':
				*clr & cla
				stripwork = 1
				gs 'stat'
				'You think about it for a minute and smile at him as you accept his offer.'
				'The manager leads you to the dressing room and tells a woman responsible for the costumes that you''re going to join the club. He also introduces you to the chief of security, who takes your picture and makes you sign some documents.'
				if $pcs_stagename = '':
					'Most of our girls don''t perform under their own name for obvious reasons. What would you like your stripper name to be?'
						$pcs_stagename = input("Which name would you like to use at the strip club? (Leave blank for <<$pcs_nickname>>)")
					if $pcs_stagename = '':$pcs_stagename = '<<$pcs_nickname>>'
				end
				'After you''re done with the forms, you are sent back to the manager''s office.'
				'"Before you go on stage your first time, I expect you to drop by my office so that I can check if you are up to our club standards, <<$pcs_stagename>>. It''s just a routine check to make sure that the club''s reputation stays intact. Nothing to worry about," he tells you before ushering you out of his office again.'

				if cfnm = 0:act 'Head to the dressing room':gt 'stwork', 'start'
					if cfnm = 1:
					'There are only males performing tonight, so the room is full of guys getting ready to perform.'
					act 'Leave':gt 'stripclub', 'work_leave'
				end
			end

			act 'Reject his offer':
				*clr & cla
				gs 'stat'
				'You thank him for the offer, but you''re not ready to commit to anything yet.'
				'You can see on his face that he''s disappointed, but he can''t really do anything about your decision. He thanks you and tells you if you ever change your mind you''re welcome back.'
				act 'Leave':gt 'stripclub', 'work_leave'
			end
		elseif pcs_dancero >= 40:
			'After a minute, he stops you and shakes his head. "Your poledancing is still lacking <<$pcs_nickname>>. If you want this job, you''ll have to take some dance classes first. I believe you can do that at the gym."'
			'"Come back when you can handle the pole, and I''ll give you another chance."'
			act 'Leave':gt 'stripclub', 'work_leave'
		else
			'After a minute he stops you and shakes his head. "Your dancing is very lacking <<$pcs_nickname>>. If you want this job, you''ll have to take some dance classes first. I believe you can do that at the gym."'
			'"Come back when you can dance on stage without me having to worry you''ll fall off, and I''ll give you another chance."'
			act 'Leave':gt 'stripclub', 'work_leave'
		end
	else
		'"Nearly..." you say dejectedly.'
		'"Right. You need to leave this establishment, be sure to come back when you are old enough," he tells you.'

		act 'Leave':gt 'city_industrial', 'redlight'
	end
end

if $ARGS[0] = 'work_leave':
	if cfnm = 0:
		gt 'stripclub', 'forman'
	elseif cfnm = 1:
		gt 'stripclub', 'forwoman'
	end
end

if $ARGS[0] = 'forman':
	*clr & cla
	minut += 5
	gs 'stat'
	'<center><b><font color="maroon">Strip Club</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/stripclub1.jpg"></center>'
	'There are some girls on the stage, dancing to the music. You notice a sign offering private dances, costing 1000 <b>₽</b> per dance.'

	act 'Leave': minut += 5 & gt 'stripclub', 'start'
	if hour ! 2:
		act 'Watch a striptease':gt 'stripclub', 'stol'

		if money >= 1000: act 'Order a private dance (1,000 <b>₽</b>)':gt 'stripclub', 'privat'

		if money >= 5000:
			act 'Order a special show (5,000 <b>₽</b>)':
				stprrand = rand(0, 1)
				money -= 5000

				if stprrand = 0:gt 'stripclub', 'stpr1'
				if stprrand = 1:gt 'stripclub', 'stpr2'
			end
		end
	end
	if pcs_dancero > 0 and stripwork = 0 and pcs_inhib >= 60:
		act 'See the manager for work': gt 'stripclub', 'manager'
	elseif stripwork = 0 and pcs_inhib < 60:
		'You could ask the manager for a job, but you don''t feel confident enough to be a stripper. You should get more used to showing off your body first.'
	end
end

if $ARGS[0] = 'privat':
	*clr & cla
	money -= 1000
	minut += 60
	pcs_horny += 25

	gs 'stat'
	privrand = rand(0, 4)

	if privrand = 0:
		'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/priv2.jpg"></center>'
		'During the striptease, the girls seem to be enjoying the female company and begin to caress you openly, making the male customers a bit jealous as they don''t get to enjoy the same attention as you''re getting.'

		act 'Finish':gt 'stripclub', 'forman'
		act 'Let them continue on':gt 'stripclub', 'privsex'

	elseif privrand > 0:
		'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/privat.jpg"></center>'
		'There are some very hot girls dancing around you. You feel your pulse rise. Their movements are just like an aphrodisiac.'

		act 'Finish':gt 'stripclub', 'forman'
		if money >= 1000: act 'Order another dance (1,000 <b>₽</b>)':gt 'stripclub', 'privat'
	end
end

if $ARGS[0] = 'stol':
	*clr & cla
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/stripclub2.jpg"></center>'
	'The stage is lit up as a girl is dancing and undressing erotically before a strenuous male audience.'

	act 'Watch the striptease':
		*clr & cla
		gs 'stat'
		minut += 15
		'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/stripclub4.jpg"></center>'
		'The girl dances in front of you, clearly hoping you''ll give her a tip.'

		if money >= 50:
			act 'Give her 50 <b>₽</b>':
				*clr & cla
				pcs_horny += 5
				minut += 10
				money -= 50
				'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/stripclub6.jpg"></center>'
				'You stick 50 <b>₽</b> in the strippers panties, and she invitingly starts wagging her hips and shaking her tits in front of you. You feel yourself slowly getting excited.'

				act 'Further':gt 'stripclub', 'stol'
			end
		end

		act 'Downcast eyes':
			*clr & cla
			pcs_horny -= 5
			minut += 15
			'You decide not to give any money to the stripper and look away from her. You feel a little ashamed as your arousal goes down a bit.'

			act 'Further':gt 'stripclub', 'stol'
		end
	end

	act 'Move away':gt 'stripclub', 'forman'
end

if $ARGS[0] = 'forwoman':
	*clr & cla
	stripguy = 0
	minut += 5
	gs 'stat'
	'<center><b><font color="maroon">Strip Club</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/stripclub1.jpg"></center>'

	act 'Leave': minut += 5 & gt 'stripclub', 'start'

	if hour ! 2 and zenit > 0 and minifoto = 0:
		act 'Photograph':
			minut += 10
			'As soon as you take the camera out, you are immediately approached by a security guard that informs you that there is no photography allowed. You apologize and put the camera back in your purse.'
		end

	elseif hour ! 2 and minifoto > 0:
		act 'Photograph':
			*clr & cla
			minut += 60
			'You put on the mini camera, keeping it half hidden by your chest, and discreetly start walking through the club.'
			stripfotorand = rand(0, 10)

			if stripfotorand < 2:
				minifoto = 0
				stripdolg = 1
				'You fail to hide the camera well enough and get spotted out by the security guard. He grabs you by the hand and leads you to his office. Already waiting there for you is the owner. He takes your camera and says that you owe him 50,000 <b>₽</b> for snooping around and until you pay up you are barred from the club.'

				act 'Leave':gt 'stripclub', 'start'
			elseif stripfotorand >= 2 and stripfotorand < 6:
				shantfoto += 1
				'You struggle to take a normal picture. The girls surrounding you are moving obscurely while they strip, and the guard is very close, so you have to be careful. You finally manage to take a normal picture in the end.'

				act 'Return':gt 'stripclub', 'forwoman'
			elseif stripfotorand >= 6:
				'You struggle to take a normal picture. The girls surrounding you are moving obscurely while they strip, and the guard is very close, so you decide that you don''t want to risk anything.'

				act 'Return':gt 'stripclub', 'forwoman'
			end
		end
	end

	if hour ! 2: act 'Watch a striptease': gt 'stripclub', 'stolW'
	if pcs_dancero > 0 and stripwork = 0 and pcs_inhib >= 60:
		act 'See the manager for work': gt 'stripclub', 'manager'
	elseif stripwork = 0 and pcs_inhib < 60:
		'You could ask the manager for a job, but you don''t feel confident enough to be a stripper. You should get more used to showing off your body first.'
	end
end

if $ARGS[0] = 'stolW':
	*clr & cla
	stripguy = 0
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/stripw.jpg"></center>'
	'There are some athletic guys performing on the stage. The women are all excited, squealing and shoving money down their pants.'

	if hour < 23:
		act 'Watch a striptease':
			*clr & cla
			minut += 15
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/stripw1.jpg"></center>'
			'A male stripper walks over to you and begins moving his hips in a circular movement. He''s trying to get you excited enough so you''ll give him a tip.'

			if money >= 50:
				act 'Shove 50 <b>₽</b> down his pants':
					*clr & cla
					pcs_horny += 5
					minut += 10
					money -= 50
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/stripw2.jpg"></center>'
					'You shove 50 <b>₽</b> down his pants, and he leads you over to sit on a chair and starts dancing in front of you. Before you know it, he is completely naked, and you have a great view of his cock. The stripper gropes your chest, trying to get your breasts out from under your blouse.'

					act 'Stop':gt 'stripclub', 'stolW'
					!!act 'Touch his hand member':gt 'cfnm', 'start'
					act 'Let him expose your breasts':gs 'npcgeneratec', 0, 'Stripper', rand(18,28) & gs 'boyStat', $npclastgenerated & gt 'cfnm', 'start'
				end
			end

			act 'Downcast eyes':
				cla
				pcs_horny -= 5
				minut += 15
				'You decide not to give any money to the stripper and look away from him. You feel a little ashamed as your arousal goes down a bit.'

				act 'Further':gt 'stripclub', 'stolW'
			end
		end
	end

	act 'Move away':gt 'stripclub', 'forwoman'
end

if $ARGS[0] = 'privsex':
	*clr & cla
	girl += 2
	lesbian += 1
	gs 'arousal', 'cuni', 15, 'lesbian', 'group'
	$orgasm_or = 'yes'
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/priv3.jpg"></center>'
	'The girls lead you away from the center stage into a private booth. Before you know it, they''ve taken off your clothes and have you widely spreading your legs as one of them licks your pussy, bringing you to orgasm, while the other girl continues to caress your body.'

	act 'Finish':gt 'stripclub', 'forman'
	act 'More':gt 'stripclub', 'privsex1'
end

if $ARGS[0] = 'privsex1':
	*clr & cla
	privpicrand = rand(4, 7)
	girl += 2
	lesbian += 1
	gs 'arousal', 'cuni', 15, 'lesbian', 'group'
	$orgasm_or = 'yes'
	gs 'arousal', 'end'
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/priv<<privpicrand>>.jpg"></center>'
	'The other girl lets out a sigh, "You''ve already made her orgasm... I don''t care I also want in on the action..." as she gently pushes her friend away and begins eating you out. It doesn''t take long before you reach an orgasm once again. As you manage to calm down, you notice that you''re all alone in the booth.'

	act 'Finish':gt 'stripclub', 'forman'
end

if $ARGS[0] = 'stpr1':
	*clr & cla
	gs 'arousal', 'voyeur_sex', 5, 'lesbian', 'group'
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/prsex1.jpg"></center>'
	'You wait for a moment before the security guard walks up to you and tells you to follow him.'
	'He leads you to a room, and as you enter, you notice a girl fucking another one with a strap-on. You sit down and enjoy the moans coming from the girl getting fucked for a moment.'

	act 'Leave':gt 'stripclub', 'forman'

	act 'Join them':
		*clr & cla
		girl += 2
		lesbian += 1
		gs 'arousal', 'bj', 10, 'lesbian', 'sub', 'group'
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/prsex2.jpg"></center>'
		'Wanting in on the action, you start to undress and tell the other girl to put on a strap-on. As the girl finishes, you kneel in front of them as they stand beside you and rest their strap-ons against your face. You start greedily sucking, licking the remnants of one of the girl''s juices while lubing the other cock.'

		act 'Doggy-Style':
			*clr & cla
			gs 'arousal', 'bj', 10, 'lesbian', 'sub', 'group'
			gs 'arousal', 'vaginal_strap', 10, 'lesbian', 'sub', 'group'
			minut -= 10
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/prsex3.jpg"></center>'
			'The girls chuckle a little as they see you this submissive, and after they deem you''ve sucked enough, they push you onto your hands and knees as one of them stands behind you and enters your moist pussy while you continue to suck the other.'

			act 'Two Smoking Barrels':
				*clr & cla
				gs 'arousal', 'anal_strap', 10, 'lesbian', 'sub', 'group'
				gs 'arousal', 'vaginal_strap', 10, 'lesbian', 'sub', 'group'
				minut -= 10
				$orgasm_or = 'yes'
				gs 'stat'
				'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/prsex4.jpg"></center>'
				'You look up at the girl in front of you and lustily plead, "I want both of you inside me." It appears they were thinking the same thing as one of the girls quickly slides underneath you, while the other girl standing behind you eases her way into your ass.'
				'They begin to fuck you in full force, and it doesn''t take long before they bring you to orgasm.'

				act 'Further':
					*clr & cla
					gs 'cum_call', 'mouth', 'strippers'
					gs 'cum_call', 'face', 'strippers'
					gs 'cum_call', 'breasts', 'strippers'
					gs 'arousal', 'end'
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/prsex5.jpg"></center>'
					'As you finish, the girls pull out, stand over you and jerk their strap-ons until a liquid pours out that tastes much like sperm. The liquid covers your mouth, face and chest.'

					act 'Finish':gt 'stripclub', 'forman'
				end
			end
		end
	end
end

if $ARGS[0] = 'stpr2':
	*clr & cla
	girl += 2
	lesbian += 1
	gs 'arousal', 'foreplay', 5, 'lesbian', 'group'
	gs 'stat'
	'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/prsex6.jpg"></center>'
	'You wait for a moment before the security guard walks up to you and tells you to follow him.'
	'He leads you to a room, and as you enter, you notice two girls, each holding a strap-on in their hands. Without any hesitation, they walk over to you, strip you down and await further instructions.'
	gs 'willpower', 'sex', 'force', 'medium'
	if will_cost <= pcs_willpwr:
		act 'Have them suck you off (<<will_cost>> Willpower)':
			*clr & cla
			gs 'willpower', 'pay', 'force'
			gs 'arousal', 'foreplay', 10, 'lesbian', 'dom', 'group'
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/prsex7.jpg"></center>'
			'You tell one of the girls to hand over her strap-on, which you put on. You command the girls to kneel and stick the cock in front of their faces. Not needing a cue, they start sucking on it, lubing it up the best they can.'

			act 'Fuck them':
				*clr & cla
				gs 'arousal', 'vaginal_strap_give', 30, 'lesbian', 'dom', 'group'
				$orgasm_or = 'yes'
				gs 'arousal', 'end'
				gs 'stat'
				prsexrand = rand(9, 13)
				'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/prsex<<prsexrand>>.jpg"></center>'
				'After a while, you get a bit bored of this and, smirking, tell them that you want to fuck them. They eagerly position themselves, ready for your fake cock. You fuck them as your heart desires, eventually stopping after you have your first orgasm. As for them, hmm... you''ve lost count, and all you hear is panting.'

				act 'Finish':gt 'stripclub', 'forman'
			end
		end
	else
		act 'Have them suck you off (<font color="red"><<will_cost>> Willpower</font>)': '<br><font color="red">You don''t have enough willpower to use this action.</font>'
	end	
	act 'Suck them off':
		*clr & cla
		gs 'arousal', 'bj', 10, 'lesbian', 'sub', 'group'
		gs 'stat'
		'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/prsex8.jpg"></center>'
		'You want to get used today, so you order them to put on the strap-ons as you get on your knees and joyfully begin sucking them off.'

		act 'Have them fuck you':
			*clr & cla
			gs 'arousal', 'vaginal_strap', 30, 'lesbian', 'sub', 'group'
			gs 'arousal', 'anal_strap', 30, 'lesbian', 'sub', 'group'
			minut -= 30
			$orgasm_or = 'yes'
			gs 'arousal', 'end'
			gs 'stat'
			prsexrand = rand(14, 19)
			'<center><img <<$set_imgh>> src="images/locations/city/redlight/stripclub/sex/prsex<<prsexrand>>.jpg"></center>'
			'You yearn to have your holes filled as you stop sucking them and order them to fill your orifices. The girls quickly position themselves and start fucking you.'
			'Losing yourselves to the moment, it is no longer clear who is the customer and who isn''t. As they fuck you in different positions and orifices, you lose count of how many times you orgasm. In the end, you are all quite satisfied.'

			act 'Finish':gt 'stripclub', 'forman'
		end
	end
end

--- stripclub ---------------------------------

