# univer
if $ARGS[0] = 'start':
	$sexloc = 'univer'
    $location_type = 'public_indoors'
	cla & *clr
	minut += 5
	$menu_loc = 'univer'
	$menu_arg = 'start'
	menu_off = 0
	gs 'stat'
	gs 'themes', 'indoors'
	'<center><b><font color="maroon">The University</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/university/univer.jpg"></center>'

	'University lectures begin at <b>'+func('uniutil', 'lecture', 'start_hour')+':00</b>. Students aren''t allowed to attend if late.'
	
	func('uniutil', 'semester', 'print_all_months')

	if func('uniutil', 'diploma', 'obtained'):
		'You have graduated from the University.'
	elseif func('uniutil', 'student', 'expelled_for_failing'):
		'You have been expelled from the University for failing your exams.'
	elseif func('uniutil', 'student', 'expelled_for_skipping'):
		'You have been expelled from the University for skipping your exams.'
	elseif func('uniutil', 'student', 'expelled_for_other_reason'):
		'You have been expelled from the University for reasons unrelated to your exam results.'
	elseif func('uniutil', 'student', 'enrolled'):
		if func('uniutil', 'passed_semesters', 'get') = func('uniutil', 'student', 'semesters_to_graduate'):
			gs 'uniutil', 'student', 'graduate'
			'Congratulations, you''ve earned your degree!'
		elseif func('uniutil', 'semester_result', 'is_failed'):
			gs 'uniutil', 'student', 'expel'
			'You got expelled from the University.'
		else
			'You are enrolled at the University.'
		end
	else
		if func('uniutil', 'prepclass', 'is_enrolled'):
			'You''ve enrolled in the preparatory classes.'
		else
			'You can take preparatory classes at the University on weekdays for '+func('uniutil', 'prepclass', 'cost')+' <b>₽</b>.'
		end
		'Admission examinations for the University are held in <b>'+func('uniutil', 'entrance_exam', 'print_month')+'</b>.'
	end

	act 'Leave':
		cla
		minut += 5
		gt 'city_island'
	end

	if func('uniutil', 'eligible_for_university'):
		if func('uniutil', 'prepclass', 'offered_this_month'):
			if func('uniutil', 'prepclass', 'is_enrolled'):
				if func('uniutil', 'prepclass', 'in_session'):
					act 'Attend preparatory class (1:00)':
						cla
						*clr
						minut += 60
						gs 'uniutil', 'prepclass', 'update_count'
						intel_exp += 1 + (mentats_dose - rand(0,mentats_dose))
						'<center><img <<$set_imgh>> src="images/locations/city/island/university/classroom.jpg"></center>'
						'You attend the preparatory class for an hour. You pay close attention to what is being said and take notes for the entrance examination later on.'

						act 'Leave class':gt 'univer', 'start'
					end
				end
			else
				if money >= func('uniutil', 'prepclass', 'cost'):
					act 'Pay for the preparatory classes ('+func('uniutil', 'prepclass', 'cost')+' <b>₽</b>)':
						cla
						minut += 5
						menu_off = 1
						gs 'uniutil', 'prepclass', 'enroll'
						'You paid '+func('uniutil', 'prepclass', 'cost')+' <b>₽</b> for the preparatory classes. They are held every weekday until <b>'+func('uniutil', 'prepclass', 'closing_hour')+':00</b>.'

						act 'Move away':gt 'univer', 'start'
					end
				end
			end
		end

		if func('uniutil', 'entrance_exam', 'offered_today'):
			'You can try to take an entrance exam.'

			act 'Take the entrance exam (1:00)':
				cla
				*clr
				minut += 60
				'<center><img <<$set_imgh>> src="images/locations/city/island/university/classroom.jpg"></center>'

				if func('uniutil', 'entrance_exam', 'is_passed'):
					gs 'uniutil', 'student', 'enroll'
					'You have successfully passed the entrance exam and can attend the University in '+func('uniutil', 'lecture', 'print_start_month', func('uniutil', 'semester', 'get'))+'.'
				else
					'You have failed the entrance exam. You need to study harder...'
				end

				act 'Leave class':gt 'univer', 'start'
			end
		end
	end

	if func('uniutil', 'student', 'enrolled'):
		if func('uniutil', 'lecture', 'offered_today'):
			act 'Visit the Dean':
				cla
				gt 'univer', 'deans_office'
			end
		elseif func('uniutil', 'exam', 'offered_today'):
			act 'Take the exam':gt 'univer', 'exam_room'
		end
	end
end

if $ARGS[0] = 'deans_office':
	$sexloc = 'univer'
	cla & *clr
	minut += 5

	gs 'stat'
	'<center><b><font color="maroon">Dean</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/university/dekanat.jpg"></center>'
	'You are enrolled at the University for semester '+func('uniutil', 'semester', 'get')+'.'
	'At the end of your semester, you must pass your exams. Attending lectures will help you prepare.'
	'You must also complete at least '+func('uniutil', 'assignments_done', 'min_num')+' assignment'+iif(func('uniutil', 'assignments_done', 'min_num') = 1, '', 's')+', though it is positively looked upon if you manage to complete more.'
	'You''ve complete '+func('uniutil', 'assignments_done', 'get')+' assignment'+iif(func('uniutil', 'assignments_done', 'get') = 1, '', 's')+' so far.'

	if func('uniutil', 'scholarship', 'is_active'):
		'You are receiving a scholarship of '+func('uniutil', 'scholarship', 'get')+' <b>₽</b> per month from the University this semester because of how you did in the previous one.'
	else
		'The University is known to award scholarships to students with exceptional performance.'
	end

	act 'Leave the Dean''s office':gt 'univer', 'start'

	if func('uniutil', 'lecture', 'in_session') and func('uniutil', 'student', 'enrolled'):
		act 'Attend the lecture ('+func('uniutil', 'lecture', 'length')+':00)':
			cla 
			*clr
			hour = func('uniutil', 'lecture', 'start_hour') + func('uniutil', 'lecture', 'length')
			minut = 0
			gs 'uniutil', 'attendance', 'update'
			intel_exp += 1 + (mentats_dose - rand(0,mentats_dose))
			menu_off = 1
			gs 'stat'
			'<center><img <<$set_imgh>> src="images/locations/city/island/university/classroom1.jpg"></center>'
			'You attend the lecture, taking notes as the professor calmly goes through the course material.'
			zanrand = rand(0, 9)

			if zanrand = 0:
				minut += 60
				'During the lecture, professor Krupin asks you a question that you do not have the answer for. You let him know, and he asks that you stay behind after class so he can help you.'
!!expanded this scene a lot, check code.
				act 'Stay after class':
					cla 
					*clr
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/locations/city/island/university/krupin.jpg"></center>'
					'The professor patiently explains some of the material he went through in class in an effort to help you better understand so you don''t fall too far behind.'
					
					act 'Leave':gt 'univer', 'deans_office'
					
					act 'Seduce':
						cla
						*clr
						gs 'npcgeneratec', 0, 'professor Krupin', 51
						dick = 15
						$dick_girth = 'well proportioned'
						gs 'boyStat', $npclastgenerated
						'<center><img <<$set_imgh>> src="images/locations/city/island/university/sex/gradepay.jpg"></center>'
						'Feeling pressured, you move over to his desk and take a seat on it, making sure he has a good view of your legs and short skirt. You grab his scarf and slide it back and forth across his neck as you open your legs, giving him a glimpse up your skirt. "This is all so "hard" to understand" you say, "but maybe if I do you a favor, you can repay me by giving me a passing grade." You don''t have a lot of time to be subtle as you need to make sure you''re going to pass the class before you leave.'
						'For a moment, he seems unsure. "Well what do you have in mind?" he asks as he looks around the classroom.'
						'You bite your lower lip seductively, knowing you have him trapped. You pull him by his scarf till he is standing, while you get on all fours. You look up at him, "let me show you, professor Krupin."'
						gs 'arousal', 'foreplay', 5
						gs 'stat'

						act 'Give him a blow job':
							cla
							*clr
						    '<center><img <<$set_imgh>> src="images/locations/city/island/university/sex/gradepay1.jpg"></center>'
							'You undo his belt and pants, letting them drop down to his knees. You start stroking his cock, and it doesn''t take long before it''s grown hard in your hand. You lick up and down along the shaft, then wrap your lips around his cock and start bobbing your head up and down while stroking it with your hand.'
							'He reaches over you and pulls up your skirt, pulling aside your panties. He rubs your pussy till he gets it wet, and then he slips his fingers inside and starts finger fucking you, causing you to moan in pleasure.'
							gs 'arousal', 'vaginal_finger', 10
							gs 'arousal', 'bj', 10
							minut -= 10
							gs 'stat'
							
							act 'A for sure':
								cla 
								*clr
								gs 'cum_call', 'face', $boy, 1, '', '', 20
								gs 'cum_call', 'breasts', $boy, 1, '', '', 20
								gs 'arousal', 'end'
							    '<center><img <<$set_imgh>> src="images/locations/city/island/university/sex/gradepay2.jpg"></center>'
								'Either your mouth or hand is constantly pleasuring his cock, often both at once. He begins pulling off your clothes, and you offer no resistance. Once you are completely naked and back in place he goes back to fingering your pussy.'
								'You know he is yearning to fuck you, but you want to save that in case you start doing even worse in class and need to raise your grades again, so you intensify your efforts sucking him off and start deep throating him while fondling his balls.'
								'He starts groaning, as he''s on the edge but trying to hold back. Suddenly he says, "I''m about to cum. I want to cum all over your face." At those words, you let go of his cock and start stroking him with your hand. Soon he is spurting loads of sperm all over you, splattering your face and perky breasts. Once he finishes, you sit up to give him a perfect view of your naked body covered in his cum. You grin at him. "So about my grades..."'
								'He collapses back in his chair and nods his head, "yes yes, don’’t worry you did well this time, you little minx." With a final smile and wink, you gather your stuff and get dressed and head out of classroom.'
								gs 'arousal', 'hj', 5
								gs 'arousal', 'bj', 5, 'deepthroat'
								gs 'stat'
								minut -= 5
								
								act 'Leave':gt 'univer', 'deans_office'
							end
						end
					end
				end
!!end of first scene expansion
			elseif zanrand = 1:
				minut += 60
				'During the lecture, professor Krupin asks you a question that you do not have the answer for. You let him know, and you hear a girl smirk behind you. Without any hesitation, the professor calls her out and tells her to speak with him after class. He also asks you to stay behind so he can help you.'

				act 'Stay after class':
					cla
					*clr
					gs 'stat'
					'<center><img <<$set_imgh>> src="images/locations/city/island/university/krupin.jpg"></center>'
					'The professor patiently explains some of the material he went through in class to you in an effort to help you better understand so you don''t fall too far behind. He tells the other girl that it''s not polite to do what she did in class and she needs to properly behave.'
					
					act 'Leave':gt 'univer', 'deans_office'
!!expanding scene two. check code.
					act 'Seduce':
						cla
						*clr
						gs 'npcgeneratec', 0, 'professor Krupin', 51
						dick = 15
						$dick_girth = 'well proportioned'
						gs 'boyStat', $npclastgenerated
						'<center><img <<$set_imgh>> src="images/locations/city/island/university/sex/gradepay.jpg"></center>'
						'Feeling pressured, you move over to his desk and take a seat on it, making sure he has a good view of your legs and short skirt. You grab his scarf and slide it back and forth across his neck as you open your legs, giving him a glimpse up your skirt. "This is all so "hard" to understand" you say, "but maybe if I do you a favor, you can repay me by giving me a passing grade." You don''t have a lot of time to be subtle as you need to make sure you''re going to pass the class before you leave.'
						'For a moment he seems unsure. "You should stop that..." he says, glancing at the other girl, but you can tell he doesn''t mean it.'
						'You bite your lower lip seductively, knowing you have him trapped. You pull him by his scarf till he is standing, while you get on all fours. You look up at him, "let me show you what I mean, professor Krupin."'
						'The other girl''s eyes almost pop out as she realizes what you are trying to do. She looks at the professor and then the exit, unsure how to respond.'
						gs 'arousal', 'foreplay', 5
						gs 'stat'
						
						act 'Give him a blow job':
							cla
							*clr
							gs 'arousal', 'bj', 10
							gs 'stat'
						    '<center><img <<$set_imgh>> src="images/locations/city/island/university/sex/2forone.jpg"></center>'
							'You undo his belt and pants, letting them drop down to his knees. You start stroking his cock, and it doesn''t take long before it''s grown hard in your hand. You lick up and down along the shaft, then wrap your lips around his cock and start bobbing your head up and down while stroking it with your hand.'
							'The other girl stands off to the side with her mouth open while you do this, her face showing a combination of shock and arousal. The arousal wins out in the end however. Turned on, she kneels down beside you, giving you a little smile, and joins in on the action.'
							
							act 'Share':
								cla
								*clr
							    '<center><img <<$set_imgh>> src="images/locations/city/island/university/sex/2forone1.jpg"></center>'
								'With her kneeling beside you, you continue to suck on the professors cock for a bit and then pass it over to her. She eagerly locks her lips around it and slowly starts bobbing her head up and down. She seems really good at this, and it dawns on you that if you don''t match her, she might be the only one professor Krupin gives a free pass! Well you can''t have that, so you start sucking his balls as she continues sucking his cock.'
								gs 'arousal', 'bj', 5, 'group'
								gs 'stat'
								
								act 'A for sure':
									cla
									*clr
									gs 'cum_call', 'mouth', $boy, 1, '', '', 20
									'<center><img <<$set_imgh>> src="images/locations/city/island/university/sex/2forone2.jpg"></center>'
									'The two of you trade back and forth, taking turns sucking your professor''s cock, each trying to outdo the other. Under this relentless tag team competition, he''s unable to last for long.'
									'He starts groaning, as he''s on the edge but trying to hold back. Suddenly he says, "I''m about to cum. I''m going to cum in your mouth and then the two of you share it as you please." The other girl happens to have him in her mouth, and she dutifully sucks his cock until he finishes. Once he''s done, she removes her mouth, and you lick his cock clean.'
									'You then turn to her and french kiss her, the two of you swapping cum in each other''s mouths. As professor Krupin collapses back into his chair, you stop kissing and swallow the remains of the sperm you ended up with. You turn to him, grinning, "so about my grades..." "And my behavior..." the other girl chimes in.'
									'He peacefully observes the two of you and waves his hand absently at the question, "yes yes, I will make sure you get a passing grade, while you''re let off the hook, missy." The two of you smile at each other, then straighten your clothes up and give the professor a last little smile as you leave the classroom.'
									gs 'arousal', 'bj', 10, 'group'
									gs 'arousal', 'kiss', 10, 'lesbian'
									minut -= 10
									gs 'arousal', 'end'
									gs 'stat'
									
									act 'Leave':gt 'univer', 'deans_office'
								end
							end
						end
					end
				end
			else
				act 'Leave':gt 'univer', 'deans_office'
			end
		end
	end
!!end of second scene expansion.

	if func('uniutil', 'assignment_progress', 'is_finished'):
		act 'Hand in your assignment':
			cla
			*clr
			intel_exp += 1 + (mentats_dose - rand(0,mentats_dose))
			gs 'uniutil', 'assignments_done', 'update'
			'<center><img <<$set_imgh>> src="images/locations/city/island/university/classroom1.jpg"></center>'
			'You hand in your completed assignment.'

			act 'Leave the lecture hall':gt 'univer', 'deans_office'
		end
	end
end

if $ARGS[0] = 'exam_room':
	cla
	clr
	*clr
	minut += 60
	gs 'stat'
	'<center><b><font color="maroon">Exam</font></b></center>'
	'<center><img <<$set_imgh>> src="images/locations/city/island/university/examen.jpg"></center>'

	if func('uniutil', 'attendance', 'is_great') and func('uniutil', 'assignments_done', 'did_min_num'):
		gs 'uniutil', 'exam_outcome', 'passed_honors'
		'You completed all your examinations, passing them with honors, and on top of that, you had outstanding attendance.'

	elseif pcs_intel >= 100 and func('uniutil', 'attendance', 'is_bad') and func('uniutil', 'assignments_done', 'did_great_num'):
		gs 'uniutil', 'exam_outcome', 'passed_honors'
		'Despite missing a lot of classes, you still managed to complete all the assignments and somehow still managed to pass with honors.'

	elseif pcs_intel >= 100 and func('uniutil', 'attendance', 'is_ok') and func('uniutil', 'assignments_done', 'did_min_num'):
		gs 'uniutil', 'exam_outcome', 'passed_honors'
		'You completed all your examinations, passing them with honors.'

	elseif (pcs_intel >= 80 or func('uniutil', 'attendance', 'is_ok')) and func('uniutil', 'assignments_done', 'did_min_num'):
		gs 'uniutil', 'exam_outcome', 'passed'
		'You completed all your assignments and passed the exam.'

	else
		gs 'uniutil', 'exam_outcome', 'failed'
		'You failed to pass the exam.'
	end

	if func('uniutil', 'scholarship', 'is_active'):
		'Based on your results, you will receive a scholarship of '+func('uniutil', 'scholarship', 'get')+' <b>₽</b> per month next semester.'
	end

	act 'Leave the exam room':gt 'univer', 'start'
end

--- univer ---------------------------------

